Télécharger panach1.dgibi

Retour à la liste

Numérotation des lignes :

  1. *****************************************************
  2. * fichier : panach1.dgibi *
  3. ** modifie le 15/06/2014 passage EQPR -> EQEX *
  4. *****************************************************
  5. ************************************************
  6. * JET/PANACHE 2D - SEMI-INFINI *
  7. * Comparaison K - Epsilon / RNG K - Epsilon *
  8. * il suffit pour cela d'enlever ou remettre*
  9. * l'option RNG devant NSKE *
  10. * Mode axisymetrique *
  11. * La procedure FILTREKE est incorporee *
  12. * Le Richardson est parametrable Ri = -5.e-2 *
  13. * Gregory Turbelin 29/12/1998 *
  14. ************************************************
  15.  
  16. OPTI DIME 2 ELEM QUA8;
  17. OPTI MODE AXIS; OPTI ISOV SULI;
  18. GRAPH='N' ;
  19. COMPLET=FAUX ;
  20.  
  21. DISCR = 'MACRO' ;
  22. KPRESS = 'CENTRE' ;
  23. BETA = 1. ;
  24.  
  25. ** PROCEDURE DE FILTRE DE LA CONCENTRATION
  26.  
  27. DEBP 4FILTRE ; ARGU RX*TABLE ;
  28. rv=rx.'EQEX' ;
  29. cn=rv.inco.'cn';
  30. cn=KOPS cn '|<' 0.;
  31. cn=KOPS cn '>|' 1.;
  32. rv.inco.'cn'=cn ;
  33. as2 ama1 = 'KOPS' 'MATRIK' ;
  34. 'FINPROC' as2 ama1 ;
  35.  
  36. DEBP FILTREKE ;
  37. ARGU RX*TABLE ;
  38. * Filtre sur K et Epsilon
  39. * - Echelle de vitesse (K**0.5) inférieure à une fraction (alfk)
  40. * de Uref (vitesse caractéristique) (alfk=1 pour l'instant)
  41. * Uref=max(UN,U0)
  42. * - K > K0
  43. * - Epsilon tel que l'echelle de longueur reste inférieure
  44. * à (L0/a) où L0 = diamètre enceinte et a=f(Re)
  45. * => Nut < Uref*L0/a
  46.  
  47. rv=rx.'EQEX' ;
  48. iarg=rx.'IARG' ;
  49.  
  50. si( non ( ega iarg 4)) ;
  51. mess 'Procedure FILTREKE : nombre d arguments incorrect ' iarg ;
  52. quitter FILTREKE ;
  53. finsi ;
  54. si ( ega ('TYPE' rx.'ARG1') 'MOT ') ;
  55. U1=rv.'INCO'.(rx.'ARG1') ;
  56. sinon ;
  57. si ( ega ('TYPE' (rx.'ARG1')) 'FLOTTANT') ;
  58. U1=rx.'ARG1' ;
  59. sinon ;
  60. mess 'Procedure FILTREKE : type argument 1 invalide ' ;
  61. quitter FILTREKE ;
  62. finsi ;
  63. finsi ;
  64.  
  65. si ( ega ('TYPE' rx.'ARG2') 'MOT ') ;
  66. L0=rv.'INCO'.(rx.'ARG2') ;
  67. sinon ;
  68. si ( ega ('TYPE' (rx.'ARG2')) 'FLOTTANT') ;
  69. L0=rx.'ARG2' ;
  70. sinon ;
  71. mess 'Procedure FILTREKE : type argument 2 invalide ' ;
  72. quitter FILTREKE ;
  73. finsi ;
  74. finsi ;
  75.  
  76. si ( ega ('TYPE' rx.'ARG3') 'MOT ') ;
  77. NU=rv.'INCO'.(rx.'ARG3') ;
  78. sinon ;
  79. si ( ega ('TYPE' (rx.'ARG3')) 'FLOTTANT') ;
  80. NU=rx.'ARG3' ;
  81. sinon ;
  82. mess 'Procedure FILTREKE : type argument 3 invalide ' ;
  83. quitter FILTREKE ;
  84. finsi ;
  85. finsi ;
  86.  
  87. si ( ega ('TYPE' rx.'ARG4') 'MOT ') ;
  88. UN=rv.'INCO'.(rx.'ARG4') ;
  89. sinon ;
  90. si ( ega ('TYPE' (rx.'ARG4')) 'CHPOINT') ;
  91. UN=rx.'ARG4' ;
  92. sinon ;
  93. mess 'Procedure FILTREKE : type argument 4 invalide ' ;
  94. quitter FILTREKE ;
  95. finsi ;
  96. finsi ;
  97.  
  98.  
  99. nic=dime (rx.'LISTINCO') ;
  100. si( non ( ega nic 2)) ;
  101. mess 'Procedure FILTREKE : nombre d inconnues incorrect ' nic ;
  102. quitter FILTREKE ;
  103. finsi ;
  104.  
  105. nomi1=extr 1 (rx.'LISTINCO');
  106. nomi2=extr 2 (rx.'LISTINCO');
  107. nom1= mot (text (chai nomi1)) ;
  108. nom2= mot (text (chai nomi2)) ;
  109.  
  110. en=rv.'INCO'.nom2 ;
  111. kn=rv.'INCO'.nom1 ;
  112.  
  113. Rec=100.;
  114. k0 = 1.e-10 ;
  115. cnu=0.09;
  116.  
  117. lcu=extr un 'COMP' ;
  118. mdu=un lcu 'PSCA' un lcu;
  119. mdu=mdu ** 0.5 ;
  120.  
  121. Re=kops (kops (kops mdu '*' L0) '/' nu) '+' (Rec / 10.) ;
  122. a= exp (kops Rec '/' Re ) ;
  123.  
  124. mdu = kops mdu '|<' u1 ;
  125. mdu2= kops mdu '*' mdu ;
  126.  
  127. kn=kops kn '|<' k0 ;
  128. kn=kops kn '>|' mdu2 ;
  129.  
  130. E0= kops (kops kn '**' 1.5) '*' (a / L0) ;
  131. en=kops en '|<' E0 ;
  132.  
  133. rv.'INCO'.nom2=en ;
  134. rv.'INCO'.nom1=kn ;
  135.  
  136. as2 ama1 = 'KOPS' 'MATRIK' ;
  137. 'FINPROC' as2 ama1 ;
  138.  
  139. ****************************
  140. * CONSTRUCTION DU MAILLAGE *
  141. ****************************
  142. DJ=1. ;RJ=DJ/2. ;
  143.  
  144. ** POINTS
  145. P0=0. 0.; P1=RJ 0.;
  146. P2=8. 0.; P3=8. 15.;
  147. P4=RJ 15.; P5=0. 15.;
  148.  
  149. P1b=4. 0. ; P2b=8. 8.;
  150. P3b=4. 15.; P5b=0. 8.;
  151. P6=8. 5.; P7=8. 10.;
  152. P9=0. 10.; P10=0. 5.;
  153.  
  154. Pe1=20. 0. ; Pe2=20. 8.;
  155. Pe3=20. 15.; Pe4=20. 50.;
  156. Pe5=8. 50. ; Pe6=4. 50.;
  157. Pe7=RJ 50. ; Pe8=0. 50. ;
  158.  
  159. ***** SEGMENTS *****
  160. Si complet ;
  161. N1=5 ; N2=-18 ; N3=-10 ; N4=-12 ; N5=-30 ; N6=-38 ;
  162. sinon ;
  163. N1=1 ; N2=-4 ; N3=-2 ; N4=-3 ; N5=-7 ; N6=-9 ;
  164. finsi ;
  165.  
  166. ENT=P0 DROI N1 P1;
  167. BA1=P1 DROI N2 P1b DINI (0.008*DJ) DFIN (0.1*DJ);
  168. BA2=P1b DROI N3 P2 DINI (1.1*DJ) DFIN (1.4*DJ);
  169. BA3=P2 DROI N4 Pe1 DINI (1.6*DJ) DFIN (3.*DJ);
  170. BAS=BA1 ET BA2 ET BA3;
  171. BAT=ENT ET BAS;
  172.  
  173. CO1=Pe1 DROI N5 Pe2 DINI (0.008*DJ) DFIN (0.1*DJ);
  174. CO2=Pe2 DROI N2 Pe3 DINI (1.35*DJ) DFIN (1.5*DJ);
  175. CO3=Pe3 DROI N6 Pe4 DINI (1.8*DJ) DFIN (3.*DJ);
  176. COT=CO1 ET CO2 ET CO3;
  177.  
  178. HT1=Pe4 DROI N4 Pe5 DINI (3.*DJ) DFIN (1.6*DJ);
  179. HT2=Pe5 DROI N3 Pe6 DINI (1.4*DJ) DFIN (1.1*DJ);
  180. HT3=Pe6 DROI N2 Pe7 DINI (0.1*DJ) DFIN (0.008*DJ);
  181. HT4=Pe7 DROI N1 Pe8;
  182. HTT=HT1 ET HT2 ET HT3 ET HT4;
  183.  
  184. AX1=Pe8 DROI N6 P5 DINI (3.*DJ) DFIN (1.8*DJ);
  185. AX2=P5 DROI N2 P5b DINI (1.5*DJ) DFIN (1.35*DJ);
  186. AX3=P5b DROI N5 P0 DINI (0.1*DJ) DFIN (0.008*DJ);
  187. AXE=AX1 ET AX2 ET AX3;
  188.  
  189. ELIM (BAT ET COT ET HTT ET AXE) 1.e-5;
  190. MT=DALL BAT COT HTT AXE PLAN;
  191. ORIENTER MT;
  192.  
  193. ***** TABLES DOMAINE *****
  194.  
  195. Mmt = chan mt 'QUAF' ;
  196. Mcot = chan cot 'QUAF';
  197. Maxe = chan axe 'QUAF';
  198. Mbat = chan bat 'QUAF';
  199. Mhtt = chan htt 'QUAF';
  200. ELIM (Mmt et Mcot et Maxe et Mbat et Mhtt) 1.e-5;
  201.  
  202. $MT =MODE MMT 'NAVIER_STOKES' DISCR;
  203. $COT=MODE MCOT 'NAVIER_STOKES' DISCR;
  204. $AXE=MODE MAXE 'NAVIER_STOKES' DISCR;
  205. $BAT=MODE MBAT 'NAVIER_STOKES' DISCR;
  206. $HTT=MODE MHTT 'NAVIER_STOKES' DISCR;
  207. MT =DOMA $MT 'MAILLAGE';
  208. AXE =DOMA $AXE 'MAILLAGE';
  209. BAT =DOMA $BAT 'MAILLAGE';
  210. COT =DOMA $COT 'MAILLAGE';
  211. HTT =DOMA $HTT 'MAILLAGE';
  212. DOMA $MT 'IMPR';
  213. * TRAC MT;
  214.  
  215. **********************
  216. * DONNEES PHYSIQUES *
  217. **********************
  218. rhoa=2*1.19; rhof=2*0.58;
  219. mua=1.8e-5 ; nua=mua/rhoa;
  220. cref=0. ; Ri=0. -5.e-2;
  221. Re=3000. ; iRe=1./Re;
  222. db=1.e-5 ; iSc=db/nua;
  223. RS=iRe*iSc ; Sct=0.7;
  224.  
  225. ***DONNEES POUR FILTREKE
  226. U0=1.; L0=10.;
  227.  
  228. ***************
  229. * EQUATIONS *
  230. ***************
  231. rv=EQEX $MT ITMA 80 ALFA 0.5
  232. OPTI 'SUPG' 'RNG'
  233. ZONE $MT OPER FILTREKE U0 L0 nua 'un' INCO 'kn' 'en'
  234. ZONE $MT OPER NSKE iRe 'nut' Ri 'cn' cref INCO 'un' 'kn' 'en'
  235. ZONE $MT OPER 4FILTRE
  236. ZONE $MT OPER TSCA RS 'un' 0. 'nut' Sct INCO 'cn';
  237.  
  238. RV=EQEX RV OPTI EFM1 'CENTREE'
  239. 'ZONE' $MT 'OPER' 'DFDT' 1. 'un' 'DELTAT' 'INCO' 'un'
  240. 'ZONE' $MT 'OPER' 'DFDT' 1. 'cn' 'DELTAT' 'INCO' 'cn'
  241. 'ZONE' $MT 'OPER' 'DFDT' 1. 'kn' 'DELTAT' 'INCO' 'kn'
  242. 'ZONE' $MT 'OPER' 'DFDT' 1. 'en' 'DELTAT' 'INCO' 'en'
  243. ;
  244.  
  245. rv.nomvi='un';
  246. rv=eqex rv
  247. CLIM 'un' VIMP ENT 1.
  248. 'un' VIMP BAS 0.
  249. 'un' UIMP AXE 0.
  250. 'un' VIMP COT 0.
  251. 'kn' TIMP ENT 2.e-5
  252. 'en' TIMP ENT 1.e-6;
  253. rv=eqex rv
  254. CLIM 'cn' TIMP ENT 1.
  255. 'cn' TIMP COT 0.
  256. 'cn' TIMP BAS 0.
  257. 'kn' TIMP COT 1.e-5
  258. 'en' TIMP COT 1.e-6;
  259.  
  260. RVP = EQEX 'OPTI' 'EF' KPRESS
  261. 'ZONE' $MT 'OPER' 'KBBT' -1. beta INCO 'un' 'PRES'
  262. ;
  263.  
  264. rvp.'METHINV'.TYPINV=1 ;
  265. rvp.'METHINV'.IMPINV=0 ;
  266. rvp.'METHINV'.NITMAX=300;
  267. rvp.'METHINV'.PRECOND=3 ;
  268. rvp.'METHINV'.RESID =1.e-8 ;
  269. rvp.'METHINV' . 'FCPRECT'=100 ;
  270. rvp.'METHINV' . 'FCPRECI'=100 ;
  271.  
  272. RV.'PROJ' =RVP ;
  273.  
  274. ** INITIALISATIONS
  275. rv.inco=TABLE INCO;
  276. rv.inco.'un' =KCHT $MT 'VECT' 'SOMMET' (1.e-7 1.e-7);
  277. rv.inco.'PRES'=KCHT $MT 'SCAL' KPRESS 0.;
  278. rv.inco.'kn'=KCHT $MT SCAL SOMMET 1.e-3;
  279. rv.inco.'en'=KCHT $MT SCAL SOMMET 1.e-4;
  280. rv.inco.'nut'=KCHT $MT SCAL CENTRE nua;
  281. rv.inco.'cn'=KCHT $MT SCAL SOMMET 0.;
  282.  
  283. lh= (POIN MT PROC (0.75 1.)) et (POIN MT PROC (0.75 5.))
  284. et (POIN MT PROC (0.75 10.)) et (POIN MT PROC (0.75 15.))
  285. et (POIN MT PROC (0.75 20.)) et (POIN MT PROC (0.75 25.))
  286. et (POIN MT PROC (0.75 33.)) et (POIN MT PROC (0.75 40.))
  287. et (POIN MT PROC (0.75 45.)) et (POIN MT PROC (0.75 50.));
  288.  
  289. his=khis 'un' 1 lh
  290. 'un' 2 lh
  291. 'kn' lh
  292. 'cn' lh
  293. 'en' lh;
  294. rv.hist=his;
  295.  
  296. EXEC rv;
  297.  
  298.  
  299. ** POST-TRAITEMENT
  300. **----------------
  301. ** HISTORIQUES
  302. **------------
  303. TAB1=TABLE;
  304. TAB1.'TITRE'= table ;
  305. TAB1.1 ='TIRR MARQ CROI';
  306. TAB1.'TITRE' . 1 ='P1';
  307. TAB1.2 ='TIRR MARQ TRIA';
  308. TAB1.'TITRE' . 2 ='P2';
  309. TAB1.3 ='TIRR MARQ CARR';
  310. TAB1.'TITRE' . 3 ='P3';
  311. TAB1.4 ='TIRR MARQ ETOI';
  312. TAB1.'TITRE' . 4 ='P4';
  313. TAB1.5 ='TIRR MARQ PLUS';
  314. TAB1.'TITRE' . 5 ='P5';
  315. TAB1.6 ='TIRR MARQ LOSA';
  316. TAB1.'TITRE' . 6 ='P6';
  317. TAB1.7 ='TIRR MARQ TRIB';
  318. TAB1.'TITRE' . 7 ='P7';
  319.  
  320. si ('EGA' graph 'O' );
  321. DESS (his.'1un') LEGE TAB1 ;
  322. DESS (his.'2un') LEGE TAB1 ;
  323. DESS (his.'kn') LEGE TAB1;
  324. DESS (his.'cn') LEGE TAB1;
  325. DESS (his.'en') LEGE TAB1;
  326. finsi ;
  327.  
  328. ** PROFILS SUR LE DOMAINE TOTAL
  329. **------------------------------
  330. vv = vect rv.inco.'un' 5. ux uy jaune ;
  331. kk = rv.inco.'kn' ;
  332. ee = rv.inco.'en';
  333. cc = rv.inco.'cn' ;
  334. nn = elno (rv.inco.'nut') $MT;
  335.  
  336. si ('EGA' graph 'O' );
  337. titre 'Vecteur Vitesse';
  338. trac vv MT (CONT MT); ;
  339. titre 'Energie Cinetique Turbulente';
  340. trac kk MT (CONT MT);
  341. titre 'NUT';
  342. trac nn MT (CONT MT);
  343. titre 'dissipation';
  344. trac ee MT (CONT MT);
  345. finsi ;
  346.  
  347. ** PROFILS A DIFFERENTES ALTITUDES
  348. **---------------------------------
  349. LMT=CHAN LIGNE MT;
  350. ** ALTITUDES
  351. alt1 = 1. ; alt2 = 5.;
  352. alt3 = 10.; alt4 = 25.;
  353.  
  354. ** LIGNES HORIZONTALES
  355. lign1=POIN MT DROI (POIN MT PROC (0. alt1))
  356. (POIN MT PROC (20. alt1)) 1.e-3;
  357. lign2=POIN MT DROI (POIN MT PROC (0. alt2))
  358. (POIN MT PROC (20. alt2)) 1.e-3;
  359. lign3=POIN MT DROI (POIN MT PROC (0. alt3))
  360. (POIN MT PROC (20. alt3)) 1.e-3;
  361. lign4=POIN MT DROI (POIN MT PROC (0. alt4))
  362. (POIN MT PROC (20. alt4)) 1.e-3;
  363.  
  364. L1=ELEM LMT APPUYE lign1;
  365. L2=ELEM LMT APPUYE lign2;
  366. L3=ELEM LMT APPUYE lign3;
  367. L4=ELEM LMT APPUYE lign4;
  368.  
  369. nut=elno (rv.inco.'nut') $MT;
  370.  
  371. prvy1=EVOL CHPO (rv.inco.'un') uy L1;
  372. prvx1=EVOL CHPO (rv.inco.'un') ux L1;
  373. prc1=EVOL CHPO (rv.inco.'cn') scal L1;
  374. prk1=EVOL CHPO (rv.inco.'kn') scal L1;
  375. prnut1=EVOL CHPO nut scal L1;
  376.  
  377. prvy2=EVOL CHPO (rv.inco.'un') uy L2;
  378. prvx2=EVOL CHPO (rv.inco.'un') ux L2;
  379. prc2=EVOL CHPO (rv.inco.'cn') scal L2;
  380. prk2=EVOL CHPO (rv.inco.'kn') scal L2;
  381. prnut2=EVOL CHPO nut scal L2;
  382.  
  383. prvy3=EVOL CHPO (rv.inco.'un') uy L3;
  384. prvx3=EVOL CHPO (rv.inco.'un') ux L3;
  385. prc3=EVOL CHPO (rv.inco.'cn') scal L3;
  386. prk3=EVOL CHPO (rv.inco.'kn') scal L3;
  387. prnut3=EVOL CHPO nut scal L3;
  388.  
  389. prvy4=EVOL CHPO (rv.inco.'un') uy L4;
  390. prvx4=EVOL CHPO (rv.inco.'un') ux L4;
  391. prc4=EVOL CHPO (rv.inco.'cn') scal L4;
  392. prk4=EVOL CHPO (rv.inco.'kn') scal L4;
  393. prnut4=EVOL CHPO nut scal L4;
  394.  
  395. TAB2=TABLE;
  396. TAB2.'TITRE'= TABLE ;
  397. TAB2.1='TIRR ';
  398. TAB2.'TITRE' . 1 = MOT 'Z=1';
  399. TAB2.2='TIRC';
  400. TAB2.'TITRE' . 2 = MOT 'Z=5';
  401. TAB2.3='TIRL';
  402. TAB2.'TITRE' . 3 = MOT 'Z=10';
  403. TAB2.4='TIRM';
  404. TAB2.'TITRE' . 4 = MOT 'Z=25';
  405.  
  406. ** ZOOM SUR L'AXE X
  407. xbinf = 0.;
  408. xbsup = 6.;
  409. xbsup2 =1.2;
  410.  
  411. si ('EGA' graph 'O' );
  412. dess (prvy1 et prvy2 et prvy3 et prvy4) titr 'PROFIL VITESSE
  413. (Uz)' Xbor xbinf xbsup LEGE TAB2 titx 'R/DJ' tity 'Uz';;
  414. dess (prc1 et prc2 et prc3 et prc4) titr 'PROFIL
  415. CONCENTRATION' Xbor xbinf xbsup LEGE TAB2 titx 'R/DJ' tity 'Cf';
  416. dess (prk1 et prk2 et prk3 et prk4) titr 'PROFIL EN CINET
  417. TURB' Xbor xbinf xbsup LEGE TAB2 titx 'R/DJ' tity 'K';
  418. dess (prnut1 et prnut2 et prnut3 et prnut4) titr 'PROFIL VISCO
  419. TURB' Xbor xbinf xbsup LEGE TAB2 titx 'R' tity 'Nut';
  420. finsi ;
  421.  
  422. ** DIAMETRES CARACTERISTIQUES
  423. **----------------------------
  424. DEBP ADIM VISU*EVOLUTIO ;
  425. LV = EXTR VISU 'ORDO' ;
  426. LX = EXTR VISU 'ABSC' ;
  427.  
  428. ** Recherche des grandeurs d'adimensionnalisation
  429. Vaxe = EXTR LV 1 ;
  430. V12 = Vaxe / 2. ;
  431. i = 1 ;
  432. REPETER BOUCLE (dime LV) ;
  433. Vcour = EXTR LV i ;
  434. SI (Vcour < V12) ; quitter boucle ;
  435. SINON ; i = i + 1 ;
  436. FINSI ;
  437. FIN BOUCLE ;
  438.  
  439. ** Determination de X12
  440. Xi = EXTR LX i ;
  441. Xii = EXTR LX (i - 1) ;
  442. Vi = EXTR LV i ;
  443. Vii = EXTR LV (i - 1) ;
  444. X12 = (((Vii - V12) * Xi) + ((V12 -Vi) * Xii)) / (Vii - Vi) ;
  445.  
  446. ** Adimensionnalisation
  447. LVA = LV / (Vaxe + 1e-20) ;
  448. LXA = LX / (X12 + 1e -20) ;
  449. VISUA = EVOL 'MANU' 'X / X1/2' LXA 'V / Vmax' LVA ;
  450. FINP X12 ;
  451.  
  452. yaxe=COOR 2 AXE;
  453. lyaxe=PROG;
  454. i=0;
  455. repe bloc (nbno AXE);
  456. i=i+1;
  457. vyaxe=EXTR yaxe SCAL (AXE POIN i);
  458. lyaxe=lyaxe et (prog vyaxe);
  459. fin bloc;
  460. lyaxe = ORDO lyaxe;
  461. LMT=CHAN LIGNE MT;
  462. diam2=prog;
  463. i=0;
  464. repeter boucl3 (dime lyaxe);
  465. i=i+1;
  466. *mess 'i vaut' i;
  467. yi=extr lyaxe i;
  468. lign6=POIN MT DROI (POIN MT PROC (0. yi))
  469. (POIN MT PROC (10. yi)) 1.e-3;
  470. L6=elem lmt appuye lign6;
  471. visu1=evol chpo rv.inco.'un' uy L6;
  472. XD=adim visu1;
  473. diam2=diam2 et (prog XD);
  474. menage;
  475. fin boucl3;
  476. dcar1=evol manu diam2 lyaxe;
  477.  
  478. si ('EGA' graph 'O' );
  479. dess (dcar1) titx 'R' tity 'Z';
  480. finsi ;
  481.  
  482. ** GRANDEURS SUR L'AXE ADIMENSIONNEES
  483. **------------------------------------
  484.  
  485. ** Vitesse
  486. si complet ;
  487. evv4=EVOL CHPO (rv.inco.'un') uy (INVE AXE);
  488. ev4=EXTR evv4 ORDO ; ev4=ENLE ev4 173;
  489. evn4=LOG ev4;
  490.  
  491. z4=EXTR evv4 ABSC ; z4=ENLE z4 1; zn4=LOG z4;
  492. nevv4=EVOL MANU zn4 evn4;
  493. dess evv4 titr 'UY SUR L AXE (ADIM)';
  494. dess nevv4 titr 'UY SUR L AXE (ADIM) ECHELLE LOG';
  495. finsi ;
  496.  
  497. ** Concentration
  498. ** Attention, on ne peut calculer la concentration
  499. ** qu'à partir d'un grand nombre de pas de temps
  500. *
  501. * Xa=287.; Xhe=2079.;
  502. * cn1=KOPS (KOPS Xa '*' (rv.inco.'cn')) '/'
  503. * (KOPS (KOPS (KOPS 1 '-' (rv.inco.'cn')) '*' Xhe)
  504. * '+' (KOPS (rv.inco.'cn') '*' Xa));
  505.  
  506.  
  507. * evc1=EVOL CHPO cn1 SCAL (INVE AXE);
  508. * ec1=extr evc1 ORDO; ec1=ENLE ec1 1; ecn1=LOG ec1;
  509. * zc1=extr evc1 ABSC ;zc1=ENLE zc1 1; zcn1=LOG zc1;
  510. * nevc1=EVOL MANU zcn1 ecn1;
  511.  
  512. *dess evc1 titr 'CONCENTRATION SUR L AXE (ADIM)';
  513. *dess nevc1 titr 'CONCENTRATION SUR L AXE (ADIM) ECHELLE LOG';
  514.  
  515. * TAB3=TABLE;
  516. * TAB3.'TITRE'= TABLE ;
  517. * TAB3.'TITRE' . 1 = MOT 'VITESSE AXIALE';
  518. * TAB3.2='TIRC';
  519. * TAB3.'TITRE' . 2 = MOT 'CONCENTRATION';
  520.  
  521. * dess (evv4 et evc1) LEGE TAB3;
  522. * dess (nevv4 et nevc1) LEGE TAB3;
  523.  
  524. ** Energie
  525. evk1=EVOL CHPO (rv.inco.'kn') SCAL (INVE AXE);
  526. ek1=EXTR evk1 ORDO ;ek1=ENLE ek1 1;ek1=ABS ek1; ekn1=LOG ek1;
  527. zk1=EXTR evk1 ABSC ;zk1=ENLE zk1 1;zk1=ABS zk1; zkn1=LOG zk1;
  528. nevk1=EVOL MANU 'Z' zkn1 'K' ekn1;
  529.  
  530. si ('EGA' graph 'O' );
  531. dess evk1 titr 'EN. CINET. TURB. SUR L AXE (ADIM)';
  532. dess nevk1 titr 'EN. CINET. TURB. SUR L AXE (ADIM) ECHELLE LOG';
  533. finsi ;
  534.  
  535. * fin;
  536.  
  537. **************************
  538. *RESULTATS COMPLEMENTAIRES*
  539. ***************************
  540. ** LIGNES DE COURANT
  541. **-----------------
  542. corx=COOR 1 MT;
  543. un=rv.inco.'un';
  544. un1=EXCO un ux; un1=-1*corx*un1;
  545. un2=EXCO un uy; un3=corx*un2;
  546. un1=KCHT $MT SCAL SOMMET un1;
  547. un2=KCHT $MT SCAL SOMMET un2;
  548. un3=KCHT $MT SCAL SOMMET un3;
  549. uncz=NOEL $MT un2;
  550. uncz=KCHT $MT SCAL CENTRE uncz;
  551.  
  552. rt2d=KOPS un 'ROT' $MT;
  553. corx=KCHT $MT SCAL SOMMET corx;
  554. corm=NOEL $MT corx;
  555.  
  556. unn1=KCHT $BAT SCAL SOMMET un1;
  557. unn2=KCHT $COT SCAL SOMMET un3;
  558. unn3=KCHT $HTT SCAL SOMMET (-1*un1);
  559. unn4=KCHT $AXE SCAL SOMMET (-1*un3);
  560.  
  561. unn1=NOEL $BAT unn1;
  562. unn1=KCHT $BAT SCAL CENTRE unn1;
  563. unn2=NOEL $COT unn2;
  564. unn2=KCHT $COT SCAL CENTRE unn2;
  565. unn3=NOEL $HTT unn3;
  566. unn3=KCHT $HTT SCAL CENTRE unn3;
  567. unn4=NOEL $AXE unn4;
  568. unn4=KCHT $AXE SCAL CENTRE unn4;
  569.  
  570. sw=2*uncz - (corm*rt2d);
  571.  
  572. rk=EQEX $MT 'OPTI' 'EF' 'IMPL'
  573. ZONE $MT OPER LAPN 1. inco 'psi'
  574. ZONE $MT OPER FIMP sw inco 'psi'
  575. ZONE $BAT OPER FIMP unn1 inco 'psi'
  576. ZONE $COT OPER FIMP unn2 inco 'psi'
  577. ZONE $HTT OPER FIMP unn3 inco 'psi'
  578. ZONE $AXE OPER FIMP unn4 inco 'psi'
  579. CLIM 'psi' TIMP BAS 0.;
  580. rk.inco.'psi'=KCHT $MT SCAL SOMMET 0.;
  581. exec rk;
  582.  
  583. si ('EGA' graph 'O' );
  584. psi=rk.inco.'psi';
  585. OPTI ISOV LIGNE;
  586. TRAC psi MT (CONT (MT)) titr 'LIGNES DE COURANT';
  587.  
  588. psi1=EVOL CHPO psi SCAL COT;
  589. db1=EXTR psi1 ORDO;db2=EXTR psi1 ABSC;
  590. npsi1=EVOL MANU 'Z' db2 'DEBIT' db1 ;
  591. DESS npsi1;
  592. titr 'DEBIT D ENTRAINEMENT';
  593.  
  594. FINSI ;
  595.  
  596.  
  597. FIN;
  598.  
  599.  
  600.  
  601.  
  602.  
  603.  
  604.  
  605.  
  606.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales