Télécharger palier_stationnaire_coq4.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : palier_stationnaire_coq4.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ************************************************************************
  5. *
  6. * Mots-clés : machines tournantes, palier, hydrodynamique, lubrification
  7. * equation de Reynolds
  8. * ETUDE DU CHAMP DE PRESSION D'UNE LAME FLUIDE
  9. * ENTRE 2 CYLINDRES CONCENTRIQUES par analogie avec la thermique
  10. * Creation : BP, 10/06/2013
  11. *
  12. ************************************************************************
  13.  
  14. *** OPTIONS GENERALES **************************************************
  15.  
  16. COMPLET = faux;
  17. GRAPH = faux;
  18. OPTI DIME 3 ELEM QUA4;
  19. opti trac PSC EPTR 5 POTR 'HELVETICA_16';
  20. eye1 = -10. -50. 30.;
  21. OEIL = eye1;
  22.  
  23.  
  24. *** PARAMETRES DU PALIER *****************************************
  25.  
  26. * Longueur Rayon intérieur jeu
  27. L = 10.E-3; R = 0.5*L;
  28. C = 0.5E-3;
  29. * on en deduit :
  30. D = 2.*R; LsurD = L / D;
  31.  
  32. * % comportement du fluide
  33. * (masse volumique, viscosité cinematique et dynamique)
  34. rho = 1000.;
  35. nu = 150.E-6;
  36. mu = rho*nu;
  37.  
  38. * discretisation
  39. * discretisation circonferentielle, axiale
  40. * nth = 200 ; nL = 100 ;
  41. nth = 100 ; nL = 40 ;
  42. * nth = 24 ; nL = 10 ;
  43.  
  44. * densites associees
  45. dth = (2.*pi*R) / nth; dL = L / nL;
  46. dx = (dth*dL)**0.5;
  47. delim = 1.E-4 * (mini (prog dth dL));
  48. DENS dx;
  49.  
  50.  
  51. *** MAILLAGE 2D **************************
  52.  
  53. p0 = 0. 0. 0.;
  54. p1 = (2.*pi*R) 0. 0.;
  55. l1 = p0 droi nth p1;
  56. l2 = l1 plus (0. (L/2) 0.);
  57. Sfilm = l1 regl nL l2;
  58. l0 = INVE (Sfilm COTE 4 COUL ORAN);
  59. l2pi = Sfilm COTE 2 COUL JAUN;
  60. trac (Sfilm et l0 et l2pi);
  61. ConSfilm = CONT Sfilm;
  62. Sfilm0 = Sfilm plus (0. 0. 0.);
  63.  
  64. * MODELE *********************
  65.  
  66. MOfilm = Sfilm MODE THERMIQUE ISOTROPE 'COQ4';
  67.  
  68. * CONDITONS DE CHARGEMENT **************************
  69.  
  70. * vitesse de rotation > 0 si rotor
  71. OMEGA = 100. * 2*pi ;
  72. * vitesse de rotation imposée du centre du cylindre interieur
  73. vphi = 0. ;
  74. ve = 0.;
  75. phi = 0.;
  76.  
  77. * excentrements imposés
  78. si COMPLET;
  79. presurC = prog 0.01 0.02 0.05 PAS 0.05 0.9 0.92
  80. 0.94 PAS 0.01 0.96 PAS 0.002
  81. 0.97 PAS 0.01 0.99 0.999;
  82. sino;
  83. presurC = prog 0.01 0.1 PAS 0.1 0.9 0.95 0.99;
  84. fins;
  85.  
  86. * un trait pour l'affichage
  87. chatrait = chai '--------------------------------------------'
  88. '-------------------------------';
  89. * listreels pour le stockage des resultats
  90. prFX = prog; prFY = prog;
  91. prFXG = prog; prFYG = prog;
  92. prCXX = prog; prKXX = prog;
  93. prCYX = prog; prKYX = prog;
  94. prCXY = prog; prKXY = prog;
  95. prCYY = prog; prKYY = prog;
  96. prCXXG = prog; prKXXG = prog;
  97. prCYXG = prog; prKYXG = prog;
  98. prCXYG = prog; prKXYG = prog;
  99. prCYYG = prog; prKYYG = prog;
  100.  
  101. ne = dime presurC;
  102. ie = 0;
  103. *>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> boucle sur les valeurs d'excentrements
  104. REPE BOUE ne; ie = ie + 1 ;
  105.  
  106. esurC = extr presurC ie;
  107. * cha_e = extr mots_e ie;
  108. e = esurC * C ;
  109. chacha = chai '======================================== ' ie ' / ' ne
  110. ' ==== e/C=' FORMAT '(F6.3)' esurC;
  111. MESS chacha;
  112.  
  113.  
  114. * QUELQUES CHPOINT UTILES ****************
  115.  
  116. un0 = MANU 'CHPO' Sfilm 'SCAL' 1.;
  117.  
  118. * theta en degrés
  119. s0 = coor Sfilm 1;
  120. theta0 = s0 * (180./(pi*R)) ;
  121. cth0 = cos theta0;
  122. sth0 = sin theta0;
  123.  
  124. * phi - theta en degrés
  125. phi0 = MANU 'CHPO' Sfilm 'SCAL' phi;
  126. phimth0 = phi0 - theta0;
  127. cphimth0 = cos phimth0;
  128. sphimth0 = sin phimth0;
  129.  
  130. * hauteur du film
  131. h0 = (C*un0) - (e * cphimth0);
  132. h02 = h0**2;
  133.  
  134.  
  135. * QUELQUES CHAML UTILES ****************
  136.  
  137. un_e = MANU 'CHML' Mofilm 'SCAL' 1. 'STRESSES';
  138.  
  139. * theta et (phi - theta) en degrés
  140. theta_e = chan 'CHAM' theta0 MOfilm 'STRESSES';
  141. cth_e = cos theta_e;
  142. sth_e = sin theta_e;
  143. phimth_e = chan 'CHAM' phimth0 MOfilm 'STRESSES';
  144. c_e = cos phimth_e;
  145.  
  146. * hauteur du film
  147. h_e = (C*un_e) - (e * c_e) ;
  148. h3_e = h_e**3;
  149.  
  150. * epaisseur de la coque (arbitrairement assez petit mais pas trop)
  151. epfilm = 1.E-4*C;
  152. mess 'epaisseur du film = ' epfilm;
  153.  
  154.  
  155. * MATERIAU *********************
  156.  
  157. * definition de la conductivite = mchaml = h(theta)^3
  158. MAfilm = MATE MOfilm 'K' h3_e 'EPAI' epfilm;
  159. * trac MAfilm MOfilm 'TITR' 'conductivite K (h^{3}) et EPAI (\e_{0})';
  160.  
  161.  
  162. * CALCUL DES MATRICES ********************
  163.  
  164. * conductivity
  165. CONfilm = (1./epfilm) * (COND MOfilm MAfilm);
  166.  
  167. * CL en pression
  168. * CLp0 = BLOQ 'T' (l1 et l2);
  169. CLp0 = BLOQ 'T' l2;
  170. CLppi= RELA 'T' l0 - 'T' l2pi;
  171.  
  172. * * CL en flux pour la symetrie de la solution
  173. * MOsym = MODE l1 THERMIQUE CONVECTION;
  174. * MAsym = MAT MOsym
  175. * CLdp0 = CONV
  176.  
  177. * CL pour n'avoir qu'une seule Temperature
  178. CLsup = RELA 'TSUP' Sfilm - 'T' Sfilm;
  179. CLinf = RELA 'TINF' Sfilm - 'T' Sfilm;
  180.  
  181. * assemblage
  182. CONtot = CONfilm et CLp0 et CLppi
  183. et CLsup et CLinf;
  184.  
  185.  
  186. * 2nd MEMBRE *****************************
  187.  
  188. * CHPOINTS
  189. * du a la rotation de l'arbre,
  190. * a la translation et a la rotation du centre de l'arbre
  191. FOMEGA = -6. * mu * OMEGA * e * sphimth0;
  192. FTRANS = -12. * mu * ve * cphimth0;
  193. FROTA = 12. * mu * e * vphi * sphimth0;
  194. * mess (maxi FOMEGA abs) (maxi FTRANS abs) (maxi FROTA abs);
  195.  
  196. Qtot = NOMC (FOMEGA + FTRANS + FROTA) 'Q' 'NATU' 'DISCRET';
  197. Qtot = -1. * (FLUX MOfilm Qtot 'SUPE');
  198. * TRAC Qtot Sfilm 'TITR' '2nd membre';
  199.  
  200.  
  201. * RESOLUTION *****************************
  202. * regime stationnaire
  203. p_0 = RESO CONtot Qtot;
  204.  
  205. * POST TRAITEMENT ************************
  206.  
  207. si GRAPH;
  208. * tracé de la pression
  209. TRAC eye1 (exco p_0 T) Sfilm ConSfilm 'DIX'
  210. 'TITR' 'Pression (T) du film - calcul Cast3m' ;
  211.  
  212. * evolution de la pression delon theta
  213. p_0theta = extr (EVOL 'ROUG' 'CHPO' p_0 'T' l1) 'COUR' 1;
  214. DESS (p_0theta) MIMA
  215. TITX 'R\q' TITY 'p' 'TITR' 'p(\q)';
  216.  
  217. * evolution de la pression delon Z
  218. * il faut trouver thmax tq pmax = max(p)
  219. ithmax thmax pmax = maxi p_0theta;
  220. lthmax = l0 plus (thmax 0. 0.);
  221. elim lthmax Sfilm (delim);
  222. p_0z = extr (EVOL 'ROUG' 'CHPO' p_0 'T' lthmax) 'COUR' 1;
  223. DESS p_0z
  224. TITX 'Z' TITY 'p' 'TITR' 'p(Z)';
  225. fins;
  226.  
  227. * CALCUL DE LA FORCE RESULTANTE **********
  228.  
  229. * hypothese de film complet
  230. p_0cham = chan 'CHAM' (p_0 exco 'T') MOfilm 'STRESSES';
  231. FX = 2. * (INTG (p_0cham * cth_e) MOfilm);
  232. FY = 2. * (INTG (p_0cham * sth_e) MOfilm);
  233. * mess FX FY;
  234.  
  235. * hypothese de Gumbel (p>0)
  236. * p_0pos = 0.5 *(p_0cham + (abs p_0cham));
  237. masq0 = MASQ p_0cham 'EGSUPE' 0.;
  238. p_0pos = masq0 * p_0cham;
  239. FXG = 2. * (INTG (p_0pos * cth_e) MOfilm);
  240. FYG = 2. * (INTG (p_0pos * sth_e) MOfilm);
  241. * mess FXG FYG;
  242.  
  243.  
  244. * AFFICHAGE DES RESULTATS ************************
  245. OPTI ECHO 0;
  246. mess chatrait;
  247. mess '-------------' ie ' : e/C=' esurC '-------------';
  248. mess 'hyp : film complet & Gumbel ' ;
  249. mess chatrait;
  250. mess 'FX = ' FX ' & ' FXG;
  251. mess 'FY = ' FY ' & ' FYG;
  252. mess chatrait;
  253. OPTI ECHO 1;
  254.  
  255. * STOCKAGE DES RESULTATS ************************
  256.  
  257. * efforts
  258. prFX = prFX et FX;
  259. prFY = prFY et FY;
  260. prFXG = prFXG et FXG;
  261. prFYG = prFYG et FYG;
  262.  
  263.  
  264. fin BOUE ;
  265. *<<<<<<<<<<<<<<<<<<<<<<< fin de boucle sur les valeurs d'excentrements
  266.  
  267.  
  268.  
  269. * opti donn 5 trac X;
  270. * TRACE DES RESULTATS STATIONNAIRES ************************
  271.  
  272. * table de dessin
  273. Tdess1 = tabl;
  274. Tdess1 . 2 = mot 'MARQ TRIU REGU';
  275. Tdess1 . 2 = mot 'MARQ PLUS REGU';
  276. Tdess1 . 3 = mot 'NOLI MARQ L LOSA';
  277. Tdess1 . 'TITRE' = tabl;
  278. Tdess1 . 'TITRE' . 1 = mot 'Film complet' ;
  279. Tdess1 . 'TITRE' . 2 = mot 'Gumbel' ;
  280. Tdess1 . 'TITRE' . 3 = chai '[Frene] L/D=' FORMAT '(F4.1)'LsurD ;
  281.  
  282. * calcul norme de la charge - angle de calage
  283. prFAMP = ((prFX**2) + (prFY**2))**0.5;
  284. prbeta = atg prFY prFX;
  285. prFAMPG = ((prFXG**2) + (prFYG**2))**0.5;
  286. prbetaG = atg prFYG prFXG;
  287.  
  288. * normalisation et comparaison avec Frene
  289. * Frene, p139 L/D = 1/2
  290. e_Frene = prog 0.1 PAS 0.1 0.9 0.95;
  291. si (LsurD ega 0.5);
  292. S_Frene = prog 4.32 2.03 1.21 0.784 0.508 0.318 0.184 0.0912 0.0309
  293. 0.0116;
  294. b_Frene = prog 82 75 68.5 61.53 55 48 41 33 23.5 17.;
  295. finsi;
  296. si (LsurD ega 1.);
  297. S_Frene = prog 1.33 0.631 0.388 0.260 0.178 0.120 0.0776 0.0443
  298. 0.0185 0.00831;
  299. b_Frene = prog 79.5 74 68 62.5 56.5 50.5 44 36 26 19;
  300. finsi;
  301. si (LsurD ega 2.);
  302. S_Frene = prog 0.559 0.271 0.173 0.122 0.0893 0.0654 0.0463 0.0297
  303. 0.0143 0.00707;
  304. b_Frene = prog 75 71 67 62.5 58 52.5 46.5 39 29 21;
  305. finsi;
  306. evAMP_F = EVOL MANU e_Frene (S_Frene**-1);
  307. evbeta_F = EVOL MANU e_Frene (-1.*b_Frene);
  308.  
  309. * evolution + dessin : norme de la charge
  310. evFAMP = EVOL 'BLEU' MANU 'e/C' presurC '|F|' prFAMP;
  311. evFAMPG = EVOL 'ROUG' MANU 'e/C' presurC '|F|' prFAMPG;
  312. DESS (evFAMP et evFAMPG)
  313. GRIL 'POIN' 'GRIS'
  314. TITX 'e/C' POSX 'CENT'
  315. TITY '|F| (N)' POSY 'CENT' LOGY
  316. 'TITR' 'Evolution de la charge admissible - Résultats Cast3M'
  317. Tdess1 LEGE 'NO';
  318. INTGr = mu * L * R * OMEGA * ((R/C)**2) / pi;
  319. DESS ((evFAMP/INTGr) et (evFAMPG/INTGr) et evAMP_F)
  320. GRIL 'POIN' 'GRIS'
  321. TITX 'e/C' POSX 'CENT'
  322. TITY '|F|/F*' POSY 'CENT' LOGY
  323. 'TITR' 'Evolution de la charge admissible - Résultats Cast3M'
  324. Tdess1 LEGE 'NO';
  325.  
  326. * evolution + dessin : angle de calage beta
  327. evbeta = EVOL 'BLEU' MANU 'e/C' presurC '\b' prbeta;
  328. evbetaG = EVOL 'ROUG' MANU 'e/C' presurC '\b' prbetaG;
  329. DESS (evbeta et evbetaG)
  330. GRIL 'POIN' 'GRIS'
  331. TITX 'e/C' POSX 'CENT'
  332. TITY '\b' POSY 'CENT' YBOR -90. 0. YGRA 10.
  333. 'TITR' 'Evolution de l angle de calage - Résultats Cast3M'
  334. Tdess1 LEGE 'NO';
  335. DESS (evbeta et evbetaG et evbeta_F)
  336. GRIL 'POIN' 'GRIS'
  337. TITX 'e/C' POSX 'CENT'
  338. TITY '\b' POSY 'CENT' YBOR -90. 0. YGRA 10.
  339. 'TITR' 'Evolution de l angle de calage - Résultats Cast3M'
  340. Tdess1 LEGE 'NO';
  341. * representation polaire
  342. evXY = EVOL 'BLEU' MANU 'eX' (esurC * (cos prbeta))
  343. 'eY' (esurC * (sin prbeta));
  344. evXYG = EVOL 'ROUG' MANU 'eX' (esurC * (cos prbetaG))
  345. 'eY' (esurC * (sin prbetaG));
  346. DESS (evXY et evXYG)
  347. GRIL 'POIN' 'GRIS' CARR
  348. TITX 'e_{X}' POSX 'CENT' XBOR 0. 1. XGRA 0.2
  349. TITY 'e_{Y}' POSY 'CENT' YBOR -1. 0. YGRA 0.2
  350. 'TITR' 'Evolution de la position stationnaire - Résultats Cast3M'
  351. Tdess1 LEGE 'NO';
  352.  
  353.  
  354. * opti donn 5 trac X;
  355.  
  356. * TEST DE BON FONCTIONNEMENT ******************************************
  357. Fref = ipol 0.5 evAMP_F;
  358. FG = ipol 0.5 (evFAMPG/INTGr) ;
  359.  
  360. ecart = abs (FG / Fref - 1.);
  361.  
  362. si (ecart > 0.15); ERRE 5; fins;
  363.  
  364. FIN ;
  365.  
  366.  
  367.  
  368.  
  369.  
  370.  
  371.  
  372.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales