Exemples de jeux de données Cast3M

* fichier : ottovari_tritraction.dgibi
************************************************************************
*               Test du modele OTTOVARI en tri-traction                *
************************************************************************
 
ITRAC = FAUX ;
 
TITRE 'Test en tri-traction' ;
OPTI 'DIME' 3 'ELEM' 'CUB8' 'MODE' 'TRID' ;
 
*------------------------------------------------------
*           DEFINITION DE LA GEOMETRIE
*------------------------------------------------------
A1= 0.   0.   0.;
B1= 0.8  0.   0.;
C1= 0.8  1.   0.;
D1= 0.   1.   0.;
A2= 0.   0.  1.5;
B2= 0.8  0.  1.5;
C2= 0.8  1.  1.5;
D2= 0.   1.  1.5;
*
L1 = A1 DROIT 3 B1  ;
L2 = B1 DROIT 4 C1  ;
L3 = C1 DROIT 3 D1  ;
L4 = D1 DROIT 4 A1  ;
LL = L1 ET L2 ET L3 ET L4 ;
SU1= SURF LL 'PLAN' ;
M1 = A2 DROIT 3 B2  ;
M2 = B2 DROIT 4 C2  ;
M3 = C2 DROIT 3 D2  ;
M4 = D2 DROIT 4 A2  ;
MM = M1 ET M2 ET M3 ET M4 ;
SU2= SURF MM 'PLAN' ;
SU = SU1 VOLU 2 SU2 ;
SYZ1 = TRAN L4 2 (0 0 1.5) ;   SYZ1 = SYZ1 COUL 'VERT' ;
ELIM (SU ET SYZ1) 0.00001 ;
SXZ1 = TRAN L1 2 (0 0 1.5) ;   SXZ1 = SXZ1 COUL 'ROSE' ;
ELIM (SU ET SXZ1) 0.00001 ;
SYZ2 = SYZ1 PLUS (0.8 0. 0.) ; SYZ2 = SYZ2 COUL 'TURQ' ;
ELIM (SU ET SYZ2) 0.00001 ;
SXZ2 = SXZ1 PLUS (0. 1. 0.) ;  SXZ2 = SXZ2 COUL 'ORAN' ;
ELIM (SU ET SXZ2) 0.00001 ;
 
*------------------------------------------------------
*           DEFINITION DES CONDITIONS AUX LIMITES
*                ET DES DEPLACEMENTS IMPOSES
*------------------------------------------------------
CL1 = BLOQ SYZ1  'UX' ;
CL2 = BLOQ SXZ1  'UY' ;
CL3 = BLOQ SU1   'UZ' ;
CL4 = BLOQ SYZ2  'UX' ;
CL5 = BLOQ SXZ2  'UY' ;
CL6 = BLOQ SU2   'UZ' ;
CL = CL1 ET CL2 ET CL3 ET CL4 ET CL5 ET CL6 ;
 
DEPZ= DEPI CL6 1.5E-4 ;
DEPY= DEPI CL5 1.5E-4 ;
DEPX= DEPI CL4 1.5E-4 ;
DEP = DEPZ ET DEPY ET DEPX ;
 
*------------------------------------------------------
*           DEFINITION DES PROPRIETES MATERIELLES
*------------------------------------------------------
MO   = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'PLASTIQUE' 'OTTOVARI' 'CONS' 'BETON' ;
TBET = TAILLE MO ;
 
YG  = 40000. ;
RTR = 1.1 ;
GF  = (RTR * 3.E-4) * 0.5 ;
MA = MATE MO 'YOUN' YG 'NU' 0.21 'LTR' RTR 'GFTR' GF 'BTR' 0.2 'LCS' 20. ;
MA = MA ET TBET ;
 
LI1 = PROG 0. 'PAS' 0.5 2. 'PAS'  0.5  10. 'PAS' 0.5 16. ;
LI2 = PROG 0. 'PAS' 0.5 2. 'PAS' -0.5  -1. 'PAS' 0.5 4. 'PAS' -0.5 -2. ;
EV  = EVOL 'MANU' 'T' LI1 'F(T)' LI2 ;
 
*------------------------------------------
*            APPEL A PASAPAS
*------------------------------------------
CHA1 = CHAR 'DIMP' DEP EV ;
LIS1 = PROG 0. 'PAS' 0.1 16. ;
TAB1 = TABLE ;
TAB1.'MODELE' = MO ;
TAB1.'CARACTERISTIQUES' = MA ;
TAB1.'BLOCAGES_MECANIQUES' = CL ;
TAB1.'CHARGEMENT' = CHA1 ;
TAB1.'TEMPS_CALCULES' = LIS1 ;
TAB1.FTOL = 0.000001 ;
PASAPAS TAB1 ;
 
*------------------------------------------
*          POST TRAITEMENT
*------------------------------------------
PGXZ = PROG 0. ;
PGYZ = PROG 0. ;
PGXY = PROG 0. ;
PGYY = PROG 0. ;
PGXX = PROG 0. ;
PGYX = PROG 0. ;
TT = TAB1 . CONTRAINTES ;
NN = (DIME TT) - 1  ;
REPE BOU NN ;
  FFZ = EXTR (REDU TAB1 . CONTRAINTES . &BOU MO) 'SMZZ' 1 1 1 ;
  FFY = EXTR (REDU TAB1 . CONTRAINTES . &BOU MO) 'SMYY' 1 1 1 ;
  FFX = EXTR (REDU TAB1 . CONTRAINTES . &BOU MO) 'SMXX' 1 1 1 ;
  EPS = EPSI MO (TAB1 . DEPLACEMENTS . &BOU) ;
  GGZ = EXTR EPS 'EPZZ' 1 1 1 ;
  GGY = EXTR EPS 'EPYY' 1 1 1 ;
  GGX = EXTR EPS 'EPXX' 1 1 1 ;
  PGXZ = PGXZ ET (PROG GGZ) ;
  PGYZ = PGYZ ET (PROG FFZ) ;
  PGXY = PGXY ET (PROG GGY) ;
  PGYY = PGYY ET (PROG FFY) ;
  PGXX = PGXX ET (PROG GGX) ;
  PGYX = PGYX ET (PROG FFX) ;
FIN BOU ;
EVZ = EVOL 'ROUG' 'MANU' 'ABS' PGXZ 'ORD' PGYZ ;
EVY = EVOL 'VERT' 'MANU' 'ABS' PGXY 'ORD' PGYY ;
EVX = EVOL 'TURQ' 'MANU' 'ABS' PGXX 'ORD' PGYX ;
SI ITRAC ;
  DESS EVZ 'AXES' ;
  DESS EVY 'AXES' ;
  DESS EVX 'AXES' ;
  DESS (EVZ ET EVY ET EVX ) 'AXES' ;
FINSI ;
 
FIN ;