Télécharger la plaquette Cast3M


fr en

Télécharger ottovari_compression_traction.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : ottovari_compression_traction.dgibi
  2. ************************************************************************
  3. *         Test du modele OTTOVARI en compression puis traction         *
  4. ************************************************************************
  5.  
  6. ITRAC = FAUX ;
  7.  
  8. TITR 'Test en compression-traction' ;
  9. OPTI 'DIME' 3 'ELEM' 'CUB8' 'MODE' 'TRID' ;
  10.  
  11. *------------------------------------------------------
  12. *           DEFINITION DE LA GEOMETRIE
  13. *------------------------------------------------------
  14. A1= 0.   0.   0.;
  15. B1= 0.8  0.   0.;
  16. C1= 0.8  1.   0.;
  17. D1= 0.   1.   0.;
  18. A2= 0.   0.  1.5;
  19. B2= 0.8  0.  1.5;
  20. C2= 0.8  1.  1.5;
  21. D2= 0.   1.  1.5;
  22. *
  23. L1 = A1 DROIT 1 B1  ;
  24. L2 = B1 DROIT 1 C1  ;
  25. L3 = C1 DROIT 1 D1  ;
  26. L4 = D1 DROIT 1 A1  ;
  27. LL = L1 ET L2 ET L3 ET L4 ;
  28. SU1= SURF LL 'PLAN' ;
  29. M1 = A2 DROIT 1 B2  ;
  30. M2 = B2 DROIT 1 C2  ;
  31. M3 = C2 DROIT 1 D2  ;
  32. M4 = D2 DROIT 1 A2  ;
  33. MM = M1 ET M2 ET M3 ET M4 ;
  34. SU2= SURF MM 'PLAN' ;
  35. SU = SU1 VOLU 1 SU2 ;
  36. SYZ1 = TRAN L4 2 (0 0 1.5) ;   SYZ1 = SYZ1 COUL 'VERT' ;
  37. ELIM (SU ET SYZ1) 0.00001 ;
  38. SXZ1 = TRAN L1 2 (0 0 1.5) ;   SXZ1 = SXZ1 COUL 'ROSE' ;
  39. ELIM (SU ET SXZ1) 0.00001 ;
  40. SYZ2 = SYZ1 PLUS (0.8 0. 0.) ; SYZ2 = SYZ2 COUL 'TURQ' ;
  41. ELIM (SU ET SYZ2) 0.00001 ;
  42. SXZ2 = SXZ1 PLUS (0. 1. 0.) ;  SXZ2 = SXZ2 COUL 'ORAN' ;
  43. ELIM (SU ET SXZ2) 0.00001 ;
  44.  
  45. *------------------------------------------------------
  46. *           DEFINITION DES CONDITIONS AUX LIMITES
  47. *                ET DES DEPLACEMENTS IMPOSES
  48. *------------------------------------------------------
  49. CL1 = BLOQ SYZ1  'UX' ;
  50. CL2 = BLOQ SXZ1  'UY' ;
  51. CL3 = BLOQ SU1   'UZ' ;
  52. CL4 = BLOQ SU2   'UZ' ;
  53. CL = CL1 ET CL2 ET CL3 ET CL4 ;
  54.  
  55. DEPZ= DEPI CL4 -1.E-3 ;
  56. DEP = DEPZ  ;
  57.  
  58. *------------------------------------------------------
  59. *           DEFINITION DES PROPRIETES MATERIELLES
  60. *------------------------------------------------------
  61. MO   = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'PLASTIQUE' 'OTTOVARI' 'CONS' 'BETON' ;
  62. TBET = TAILLE MO ;
  63.  
  64. YG  = 40000. ;
  65. RTR = 1.1 ;
  66. GF  = (RTR * 3.E-4) * 0.5 ;
  67. MA = MATE MO 'YOUN' YG 'NU' 0.21 'LTR' RTR 'GFTR' GF 'BTR' 0.2 'LCS' 20. ;
  68. MA = MA ET TBET ;
  69.  
  70. LI1 = PROG 0. 'PAS' 0.5 4. 'PAS'  0.2  11. ;
  71. LI2 = PROG 0. 'PAS' 0.5 4. 'PAS' -0.2   3.4 'PAS' 0.2 4.4 'PAS' -0.2 -1. ;
  72. EV  = EVOL 'MANU' 'T' LI1 'F(T)' LI2 ;
  73.  
  74. *------------------------------------------
  75. *            APPEL A PASAPAS
  76. *------------------------------------------
  77. CHA1 = CHAR 'DIMP' DEP EV ;
  78. LIS1 = PROG 0. 'PAS' 0.1 11. ;
  79. TAB1 = TABLE ;
  80. TAB1.'MODELE' = MO ;
  81. TAB1.'CARACTERISTIQUES' = MA ;
  82. TAB1.'BLOCAGES_MECANIQUES' = CL ;
  83. TAB1.'CHARGEMENT' = CHA1 ;
  84. TAB1.'TEMPS_CALCULES' = LIS1 ;
  85. TAB1.FTOL = 0.000001 ;
  86. PASAPAS TAB1 ;
  87.  
  88. *------------------------------------------
  89. *          POST TRAITEMENT
  90. *------------------------------------------
  91. PGXZ = PROG 0. ;
  92. PGYZ = PROG 0. ;
  93. TT = TAB1 . CONTRAINTES ;
  94. NN = (DIME TT) - 1  ;
  95. REPE BOU NN ;
  96.   FFZ = EXTR (REDU TAB1 . CONTRAINTES . &BOU MO) 'SMZZ' 1 1 1 ;
  97.   EPS = EPSI MO (TAB1 . DEPLACEMENTS . &BOU) ;
  98.   GGZ = EXTR EPS 'EPZZ' 1 1 1 ;
  99.   PGXZ = PGXZ ET (PROG GGZ) ;
  100.   PGYZ = PGYZ ET (PROG FFZ) ;
  101. FIN BOU ;
  102. EVZ = EVOL 'ROUG' 'MANU' 'ABS' PGXZ 'ORD' PGYZ ;
  103. SI ITRAC ;
  104.   DESS EVZ 'AXES' ;
  105. FINSI ;
  106.  
  107. FIN ;
  108.  
  109.  
  110.  
  111.  
  112.  
  113.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales