Télécharger onera3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : onera3.dgibi
  2. * section : Mecanique Viscoplastique
  3. *----------------------------------------------------------------------*
  4. * ONERA3.DGIBI *
  5. *----------------------------------------------------------------------*
  6. *
  7. * Objet :
  8. * -------
  9. *
  10. * Test de validation d'une loi de comportement de materiau.
  11. * Loi de comportement elastoviscoplastique ONERA (Chaboche unifie).
  12. * Validation de la loi de comportement en condition anisotherme.
  13. *
  14. *
  15. * Description :
  16. * -------------
  17. * Test "Satoh" : dilatation thermique d'un element de volume empeche
  18. * suivant (O,z)
  19. *
  20. * Type de calcul : Thermomecanique
  21. * Mode de calcul : TRIDIMENSIONNEL
  22. * Type d'element : CUB8
  23. * Chargement : Temperature imposee
  24. * Reference : solution obtenue avec SiDoLo, elle-meme validee
  25. * par comparaison au logiciel Zebulon.
  26. * Objectif : Ecart relatif sur la contrainte SMZZ < 2%
  27. *
  28. * Remarque :
  29. * ----------
  30. * Les instants de calcul et les valeurs imposees de la temperature
  31. * sont celles de la solution de reference.
  32. *
  33. * Remarque 2 :
  34. * ------------
  35. * La loi d'evolution de la variable d'ecrouissage isotrope R n'est pas
  36. * identique a celle de la solution de reference :
  37. * - Reference : R=b(T).Q(T).q et dq=(1.-bq)dp
  38. * - Cast3M : voir notice operateur MATE
  39. *
  40. * Remarque 3 :
  41. * ------------
  42. * Solution de reference aimablement communiquee par Philippe PILVIN,
  43. * Université de Bretagne Sud.
  44. *
  45. *----------------------------------------------------------------------*
  46. *
  47. * Pour afficher les traces, mettre IGRAPH a vrai :
  48. IGRAPH = faux ;
  49. *
  50. *----------------------- Resultats de reference -----------------------*
  51. *
  52. * Lecture de la solution de reference :
  53. ta2 = lire csv '/u2/castem/divers/chaboche3.txt' debu 3 sepa ' ' ;
  54.  
  55. * liste des temps de calcul ;
  56. ltps1 = ta2.1 ;
  57. * liste des valeurs de temeprature associee
  58. lt1 = ta2.5 ;
  59. * liste des valeurs de la contrainte SMZZ associee
  60. lszz1 = ta2.3 ;
  61. *
  62. * Courbes d'evolution :
  63. evtref = evol defa manu temps ltps1 'T' lt1 ;
  64. evsref = evol defa manu temps ltps1 smzz lszz1 ;
  65. evref = evol defa manu 'T' lt1 smzz lszz1 ;
  66.  
  67. *--------------------- Mise en donnees du calcul ----------------------*
  68. *
  69. opti dime 3 elem cub8 ;
  70.  
  71. * Maillage d'un "cube unite" :
  72. L1 = (0 0 0) droi 1 (1 0 0) ;
  73. S1 = L1 tran (0 1 0) 1 ;
  74. V1 = S1 volu tran 1 (0 0 1) ;
  75.  
  76. si IGRAPH ;
  77. trac noeud elem V1 titr ' Maillage ' ;
  78. fins ;
  79.  
  80. * Parametres de la loi ONERA :
  81. ym1 = evol manu 'T' (prog 20. 600.) 'YOUN' (prog 190.e9 140.e9) ;
  82. nu1 = 0.3 ;
  83. al1 = 20.e-6 ;
  84. KK1 = evol manu 'T' (prog 20. 600.) 'KK' (prog 82.e6 6.e6) ;
  85. gK0 = evol manu 'T' (prog 20. 600.) 'K0' (prog 151.e6 150.e6) ;
  86. pn1 = evol manu 'T' (prog 20. 600.) 'N' (prog 24. 12.) ;
  87. gA1 = evol manu 'T' (prog 20. 600.) 'A1' (prog 58.e6 82.7e6) ;
  88. gC1 = evol manu 'T' (prog 20. 600.) 'C1' (prog 2800. 300.) ;
  89. gQ1 = evol manu 'T' (prog 20. 600.) 'QT' (prog 60.e6 80.e6) ;
  90. pb1 = evol manu 'T' (prog 20. 600.) 'B' (prog 8. 10.) ;
  91.  
  92. * Modele / Caracteristiques :
  93. mo1 = 'MODE' V1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE' 'ONERA' ;
  94. ma1 = 'MATE' mo1 'YOUN' ym1 'NU' nu1 'ALPH' al1 'KK' KK1
  95. 'K0' gK0 'N' pn1 'QT' gQ1 'B' pb1
  96. 'ALFK' 0. 'ALFR' 1. 'ALF' 0.
  97. 'A1' gA1 'C1' gC1 'BET1' 0. 'R1' 0.
  98. 'A2' 0. 'C2' 0. 'BET2' 0. 'R2' 0.
  99. 'PHI' 1. 'GAMA' 0. 'M' 0.
  100. 'QMAX' 1. 'QSTA' 0. 'MU' 0. 'ETA' 0. ;
  101.  
  102. * Blocages mecaniques :
  103. ptx0 = V1 coor 1 poin infe 0.1 ;
  104. pty0 = V1 coor 2 poin infe 0.1 ;
  105. ptz0 = V1 coor 3 poin infe 0.1 ;
  106. ptz1 = V1 coor 3 poin supe 0.9 ;
  107.  
  108. CLX0 = bloq ux ptx0 ;
  109. CLY0 = bloq uy pty0 ;
  110. CLZ0 = bloq uz (ptz0 et ptz1) ;
  111.  
  112. * Conditions initiales / Chargement :
  113. * Evolution de la temperature :
  114. CHT0 = manu chpo V1 1 'T' 1. ;
  115. CGT0 = char T CHT0 evtref ;
  116.  
  117. * Valeur initiale du parametre Q de la loi ONERA (nom de composante QQQ) :
  118. CHQ0 = manu chml mo1 'EPSE' 0. 'QQQ' 60.e6 stresses ;
  119.  
  120. * Resolution PASAPAS :
  121. ta1 = table ;
  122. ta1.modele = mo1 ;
  123. ta1.caracteristiques = ma1 ;
  124. ta1.blocages_mecaniques = clx0 et cly0 et clz0 ;
  125. ta1.chargement = cgt0 ;
  126. ta1.temps_calcules = ltps1 ;
  127. ta1.variables_internes = table ;
  128. ta1.variables_internes.0 = CHQ0 ;
  129. ** ta1.processeurs = mot automatique ;
  130.  
  131. opti epsi lineaire ;
  132.  
  133. PASAPAS ta1 ;
  134.  
  135. * Post-traitement de la courbe SMZZ vs T :
  136. nb1 = dime ta1.temps ;
  137. i1 = 0 ;
  138. lt1 = prog ;
  139. lszz2 = prog ;
  140. repe b1 nb1 ;
  141. tpsi1 = ta1.temps.i1 ;
  142. ti1 = (tire ta1.chargement T tpsi1) maxi ;
  143. szzi1 = ta1.contraintes.i1 maxi avec (mots smzz) ;
  144. lt1 = lt1 et (prog ti1) ;
  145. lszz2 = lszz2 et (prog szzi1) ;
  146. i1 = i1 + 1 ;
  147. fin b1 ;
  148. lszz2 = 1.e-6 * lszz2 ;
  149. evcal = evol roug manu 'T' lt1 smzz lszz2 ;
  150. evscal = evol roug manu temps ltps1 smzz lszz2 ;
  151.  
  152. * Affichages :
  153. si IGRAPH ;
  154. ta3 = table ;
  155. ta3 . 1 = chai 'TIRR MARQ ROND REGU' ;
  156. ta3 . 'TITRE' = table ;
  157. ta3 . 'TITRE' . 1 = mot 'Zebulon/SiDoLo' ;
  158. ta3 . 'TITRE' . 2 = mot 'Cast3M' ;
  159. dess (evsref et evscal) xbor -5. 65. ygra 5. ybor -250. 300. ygra 50. gril
  160. titr 'Essai Satoh : SMZZ (MPa) vs. temps (s) ' lege ta3 ;
  161. dess (evref et evcal) gril ybor -250. 300. ygra 50.
  162. titr 'Essai Satoh : SMZZ (MPa) vs. T (degC) ' lege ta3 ;
  163. fins ;
  164. *
  165. * Test de validation :
  166. err0 = (maxi abs (lszz2 - lszz1)) / (maxi abs lszz2) ;
  167.  
  168. opti echo 0 ;
  169. mess ' Comparaison solution calculee / reference ' ;
  170. mess ' ----------------------------------------- ' ;
  171. mess ' Max.|SMZZ(cal.) - SMZZ(Ref.)| / Max.|SMZZ(cal.)| =' err0 ;
  172. opti echo 1 ;
  173. *
  174. si (err0 > 0.02) ;
  175. erre 5 ;
  176. fins ;
  177. *
  178. fin ;
  179.  
  180.  
  181.  
  182.  
  183.  
  184.  
  185.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales