Télécharger ohno1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : ohno1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. complet = faux;
  6. * ajout de option epsilon lineaire pour la precision des test!
  7. OPTION epsilon lineaire;
  8.  
  9. *
  10. *************************************************
  11. * pour calcul complet mettre complet à : vrai;
  12. ***************************************************
  13. **************************************************
  14. * *
  15. * TEST DE VALIDATION D'UNE LOI DE COMPORTEMENT *
  16. * -------------------------------------------- *
  17. * DE MATERIAU *
  18. * ----------- *
  19. * *
  20. * LOI DE COMPORTEMENT VISCOPLASTIQUE DE: *
  21. * OHNO ( CHABOCHE MODIFIE OHNO ) *
  22. * *
  23. * TEST POUR DES ELEMENTS MASSIFS *
  24. * ------------------------------ *
  25. * *
  26. * MAILLAGE: *
  27. * UNE BARRE DE SECTION CARREE *
  28. * LONGUEUR L=.5 M *
  29. * LARGEUR l=.01 M *
  30. * *
  31. * CHARGEMENT: *
  32. * ESSAI DE TRACTION *
  33. * DEPLACEMENTS IMPOSES *
  34. * *
  35. **************************************************
  36. *
  37. *
  38. 'DEBPROC' VISOHNO ta1*'TABLE' i0*'ENTIER'
  39. sigx01*'FLOTTANT' eps0*'FLOTTANT'
  40. R01*'FLOTTANT'
  41. epsx01*'FLOTTANT'
  42. Xx11*'FLOTTANT'
  43. Xx21*'FLOTTANT' ;
  44. *
  45. * Résolution des lois viscoplastiques de OHNO dans
  46. * le cas unidirectionnel
  47. *
  48. mat0 = ta1 .'CARACTERISTIQUES' ;
  49. mod0 = ta1 .'MODELE' ;
  50. *q00 = 'MAXI' ( ta1 .'QQ' ) ;
  51. q00 = 0. ;
  52. *
  53. youn0 = 'MAXI' ( 'EXCO' mat0 'YOUN' ) ;
  54. n0 = 'MAXI' ( 'EXCO' mat0 'N' ) ;
  55. kk0 = 'MAXI' ( 'EXCO' mat0 'KK' ) ;
  56. k00 = 'MAXI' ( 'EXCO' mat0 'K0' ) ;
  57. alfk0 = 'MAXI' ( 'EXCO' mat0 'ALFK0' ) ;
  58. alfr0 = 'MAXI' ( 'EXCO' mat0 'ALFR0' ) ;
  59. alf0 = 'MAXI' ( 'EXCO' mat0 'ALF' ) ;
  60. a10 = 'MAXI' ( 'EXCO' mat0 'A1' ) ;
  61. c10 = 'MAXI' ( 'EXCO' mat0 'C1' ) ;
  62. bet10 = 'MAXI' ( 'EXCO' mat0 'BET1' ) ;
  63. r10 = 'MAXI' ( 'EXCO' mat0 'R1' ) ;
  64. a20 = 'MAXI' ( 'EXCO' mat0 'A2' ) ;
  65. c20 = 'MAXI' ( 'EXCO' mat0 'C2' ) ;
  66. bet20 = 'MAXI' ( 'EXCO' mat0 'BET2' ) ;
  67. r20 = 'MAXI' ( 'EXCO' mat0 'R2' ) ;
  68. phi0 = 'MAXI' ( 'EXCO' mat0 'PHI' ) ;
  69. b0 = 'MAXI' ( 'EXCO' mat0 'B' ) ;
  70. gama0 = 'MAXI' ('EXCO' mat0 'GAMA' ) ;
  71. m0 = 'MAXI' ( 'EXCO' mat0 'M' ) ;
  72. qmax0 = 'MAXI ' ( 'EXCO' mat0 'QMAX' ) ;
  73. qsta0 = 'MAXI' ( 'EXCO' mat0 'QSTA' ) ;
  74. mu0 = 'MAXI' ( 'EXCO' mat0 'MU' ) ;
  75. eta0 = 'MAXI' ( 'EXCO' mat0 'ETA' ) ;
  76. exp10 = 'MAXI' ( 'EXCO' mat0 'EXP1' ) ;
  77. exp20 = 'MAXI' ( 'EXCO' mat0 'EXP2' ) ;
  78. *
  79. depl0 = ta1 .'DEPLACEMENTS'.( i0 - 1 ) ;
  80. temp1 = ta1 .'TEMPS'.i0 ;
  81. temp0 = ta1 .'TEMPS'.( i0 - 1 ) ;
  82. temp01 = temp0 ;
  83. eps_old = 'MAXI' ( 'EXCO' ( 'EPSI' mod0 depl0 ) 'EPXX' ) ;
  84. *
  85. niter0 = 50 ;
  86. dt0 = ( temp1 - temp0 ) / niter0 ;
  87. sigx00 = sigx01 ;
  88. R00 = R01 ;
  89. epsx00 = epsx01 ;
  90. Xx10 = Xx11 ;
  91. Xx20 = Xx21 ;
  92. *
  93. * Incrément de contrainte test
  94. *
  95. spt0 = youn0 * ( eps0 - eps_old ) / ( temp1 - temp0 ) ;
  96. *mess ' sigx00 R00 epsx00 Xx10 Xx20=' sigx00 R00 epsx00 Xx10 Xx20 ;
  97. *
  98. 'REPETER' bloc0 niter0 ;
  99. *
  100. * Initialisation du calcul pour un pas de temps
  101. *
  102. temp01 = temp01 + dt0 ;
  103. depsx9 = 0. ;
  104. dXx8 = 0. ;
  105. dXx9 = 0. ;
  106. dr9 = 0. ;
  107. sigx0 = sigx00 ;
  108. R0 = R00 ;
  109. epsx0 = epsx00 ;
  110. Xx1 = Xx10 ;
  111. Xx2 = Xx20 ;
  112. *
  113. 'REPETER' bloc1 2 ;
  114. i1 = &bloc1 ;
  115. *
  116. * Memoire en déformation inélastique
  117. *
  118. qq = eta0 * epsx0 ;
  119. Q0 = qmax0 -
  120. ( ( qmax0 - q00 ) * ( 'EXP' ( -2. * mu0 * eta0 * epsx0 ) ) ) ;
  121. YX0 = ( 1. - eta0 ) * epsx0 ;
  122. QR = Q0 - ( qsta0 * ( 1. - ( ( ( qmax0 - Q0 ) / qmax0 ) ** 2. ) ) ) ;
  123. RR0 = alfr0 * R0 ;
  124. KR0 = k00 + ( alfk0 * R0 ) ;
  125. * mess ' qq, Q0, YX0, QR, RR0, KR0=' qq Q0 YX0 QR RR0 KR0 ;
  126. *
  127. * Critère
  128. *
  129. Xx0 = Xx1 + Xx2 ;
  130. F0 = sigx0 - ( 3. * Xx0 / 2. ) - RR0 - kk0 ;
  131. *
  132. * Ecrouissages
  133. *
  134. 'SI' ( F0 '>' 0. ) ;
  135. depsx0 = ( F0 / KR0 ) ** ( n0 ) ;
  136. depsx1 = alf0 * ( ( F0 / KR0 ) ** ( n0 + 1. ) ) ;
  137. depsx1 = 'EXP' ( depsx1 ) ;
  138. depsx0 = depsx0 * depsx1 * dt0 ;
  139. 'SINON' ;
  140. depsx0 = 0. ;
  141. 'FINSI' ;
  142. * mess ' depsx0 F0 = ' depsx0 F0 ;
  143. dr0 = b0 * ( Q0 - R0 ) * depsx0 ;
  144. dr1 = gama0 * ( ( 'ABS' ( QR - R0 ) ) ** ( m0 - 1. ) ) ;
  145. dr1 = dr1 * ( QR - R0 ) ;
  146. dr0 = dr0 + ( dr1 * dt0 ) ;
  147. phi = phi0 + ( ( 1. - phi0 ) * ( 'EXP' ( -1. * b0 * epsx0 ) ) ) ;
  148. X1lim = a10 / phi ;
  149. X2lim = a20 / phi ;
  150. dXx1 = 2. * a10 * c10 * depsx0 / 3. ;
  151. dXx1 = dXx1 -
  152. ( c10 * Xx1 * depsx0 * phi *
  153. (( 3. * Xx1 / ( 2. * X1lim )) ** ( exp10 ))) ;
  154. dXx1 = dXx1 -
  155. ( ( ( 3. * Xx1 / ( 2. * bet10 ) ) ** ( r10 - 1. ) ) * Xx1 * dt0 ) ;
  156. dXx2 = 2. * a20 * c20 * depsx0 / 3. ;
  157. dXx2 = dXx2 -
  158. ( c20 * Xx2 * depsx0 * phi *
  159. (( 3. * Xx2 / ( 2. * X2lim )) ** ( exp20 ))) ;
  160. dXx2 = dXx2 -
  161. ( ( ( 3. * Xx2 / ( 2. * bet20 ) ) ** ( r20 - 1. ) ) * Xx2 * dt0 ) ;
  162. * mess ' dr0 phi dXx1 dXx2 i1 =' dr0 phi dXx1 dXx2 i1 ;
  163. *
  164. * Somme ( Runge-Kutta )
  165. *
  166. dr0 = ( dr0 + dr9 ) / i1 ;
  167. depsx0 = ( depsx0 + depsx9 ) / i1 ;
  168. dXx1 = ( dXx1 + dXx8 ) / i1 ;
  169. dXx2 = ( dXx2 + dXx9 ) / i1 ;
  170. dr9 = dr0 ;
  171. depsx9 = depsx0 ;
  172. dXx8 = dXx1 ;
  173. dXx9 = dXx2 ;
  174. * mess ' dr0 depsx0 dXx1 dXx2 i1 =' dr0 depsx0 dXx1 dXx2 i1 ;
  175. *
  176. * Calcul des grandeurs actuelles
  177. *
  178. R0 = R00 + dr0 ;
  179. epsx0 = epsx00 + depsx0 ;
  180. Xx1 = Xx10 + dXx1 ;
  181. Xx2 = Xx20 + dXx2 ;
  182. sigx0 = sigx00 + ( dt0 * spt0 )
  183. - ( youn0 * depsx0 ) ;
  184. * mess ' R00 epsx00 Xx10 Xx20 sigx00 =' R00 epsx00 Xx10 Xx20 sigx00 ;
  185. * mess ' R0 epsx0 Xx1 Xx2 sigx0 =' R0 epsx0 Xx1 Xx2 sigx0 ;
  186. *
  187. 'FIN' bloc1 ;
  188. *
  189. * Mise à jour des valeurs
  190. *
  191. R00 = R0 ;
  192. epsx00 = epsx0 ;
  193. Xx10 = Xx1 ;
  194. Xx20 = Xx2 ;
  195. sigx00 = sigx0 ;
  196. *
  197. 'FIN' bloc0 ;
  198. *
  199. 'MESS' ' Temps final ' temp01 temp1 ;
  200. *
  201. 'FINP' sigx00 R00
  202. epsx0 Xx10 Xx20 ;
  203. *
  204. *---------------------------------------------------------------
  205. opti echo 0 dime 3 elem cub8 ;
  206. *
  207. *
  208. * Maillage
  209. *
  210. l1 = .5 ;
  211. l2 = .01 ;
  212. l3 = .01 ;
  213. n1 = 50 ;
  214. n2 = 1 ;
  215. n3 = 1 ;
  216. p1 = 0. 0. 0. ;
  217. p2 = l1 0. 0. ;
  218. p3 = l1 l2 0. ;
  219. p4 = 0. l2 0. ;
  220. p5 = 0. 0. l3 ;
  221. p6 = l1 0. l3 ;
  222. p7 = l1 l2 l3 ;
  223. p8 = 0. l2 l3 ;
  224. d1 = d p1 n3 p5 ;
  225. d2 = d p5 n2 p8 ;
  226. d3 = d p8 n3 p4 ;
  227. d4 = d p4 n2 p1 ;
  228. sur1 = 'DALL' d1 d2 d3 d4 ;
  229. d5 = d p2 n3 p6 ;
  230. d6 = d p6 n2 p7 ;
  231. d7 = d p7 n3 p3 ;
  232. d8 = d p3 n2 p2 ;
  233. sur2 = 'DALL' d5 d6 d7 d8 ;
  234. vol1 = sur1 'VOLU' n1 sur2 ;
  235. *
  236. * Modele de calcul
  237. *
  238. mod0 = 'MODE' vol1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  239. 'VISCOPLASTIQUE' 'OHNO' ;
  240. mat0 = 'MATE' mod0 'YOUN' 7.34E10 'NU' 0.33
  241. 'RHO' 7.8E3 'ALPHA' 1.E-5 'N' 24
  242. 'KK' 10.E6 'K0' 116.E6 'ALFK' 1.5 'ALFR' 0.35 'ALF' 2.E6
  243. 'A1' 67.5E6 'C1' 1300 'BET1' 4807.E6 'R1' 4
  244. 'A2' 80.E6 'C2' 45 'BET2' 58480.E6 'R2' 4 'PHI' 1.
  245. 'B' 12 'GAMA' 2.E-7 'M' 2
  246. 'QMAX' 455.E6 'QSTA' 200.E6 'MU' 19 'ETA' 0.06
  247. 'EXP1' 2. 'EXP2' 2. ;
  248. *q00 = 'MANU' 'CHML' vol1 'QQ' 30.E6 ;
  249. *
  250. * Conditions aux limites
  251. *
  252. cl1 = 'BLOQ' sur1 'UX' ;
  253. cl2 = 'BLOQ' sur2 'UX' ;
  254. cl3 = 'BLOQ' p1 'UX' 'UY' 'UZ' ;
  255. cl4 = 'BLOQ' p5 'UX' 'UY' ;
  256. cl0 = cl1 'ET' cl2 'ET' cl3 'ET' cl4 ;
  257. *
  258. * Chargement
  259. *
  260. dep1 = 'DEPI' cl2 .02 ;
  261. ev0 = 'EVOL' 'MANU' temps ( 'PROG' 0. 10000. ) y ( 'PROG' 0. 1. ) ;
  262. cha0 = 'CHAR' 'DIMP' dep1 ev0 ;
  263. *
  264. * Temps du calcul
  265. *
  266. dt0 = 50. ;
  267. si complet;
  268. tfin0 = 1000. ;
  269. sinon;
  270. tfin0 = 300.;
  271. finsi;
  272. *
  273. *
  274. * Resolution par PASAPAS
  275. *---------------------------------------
  276. *
  277. ta1 = 'TABLE' ;
  278. *ta1 .'QQ' = 'TABLE' ;
  279. ta1 .'MODELE' = mod0 ;
  280. ta1 .'CARACTERISTIQUES' = mat0 ;
  281. ta1 .'BLOCAGES_MECANIQUES' = cl0 ;
  282. ta1 .'CHARGEMENT' = cha0 ;
  283. *ta1 .'QQ'. 0 = q00 ;
  284. ta1 .'TEMPS_CALCULES' = 'PROG' 0. 'PAS' dt0 tfin0 ;
  285. *
  286. TMASAU=table;
  287. ta1 . 'MES_SAUVEGARDES'=TMASAU;
  288. TMASAU .'DEFTO'=VRAI;
  289. TMASAU .'DEFIN'=VRAI;
  290. PASAPAS ta1 ;
  291. *
  292. mat0 = ta1 .'CARACTERISTIQUES' ;
  293. mod0 = ta1 .'MODELE' ;
  294. *q00 = ta1 .'QQ' ;
  295. q00 = 0. ;
  296. *
  297. n0 = 'MAXI' ( 'EXCO' mat0 'N' ) ;
  298. kk0 = 'MAXI' ( 'EXCO' mat0 'KK' ) ;
  299. k00 = 'MAXI' ( 'EXCO' mat0 'K0' ) ;
  300. alfk0 = 'MAXI' ( 'EXCO' mat0 'ALFK0' ) ;
  301. alfr0 = 'MAXI' ( 'EXCO' mat0 'ALFR0' ) ;
  302. alf0 = 'MAXI' ( 'EXCO' mat0 'ALF' ) ;
  303. a10 = 'MAXI' ( 'EXCO' mat0 'A1' ) ;
  304. c10 = 'MAXI' ( 'EXCO' mat0 'C1' ) ;
  305. bet10 = 'MAXI' ( 'EXCO' mat0 'BET1' ) ;
  306. r10 = 'MAXI' ( 'EXCO' mat0 'R1' ) ;
  307. a20 = 'MAXI' ( 'EXCO' mat0 'A2' ) ;
  308. c20 = 'MAXI' ( 'EXCO' mat0 'C2' ) ;
  309. bet20 = 'MAXI' ( 'EXCO' mat0 'BET2' ) ;
  310. r20 = 'MAXI' ( 'EXCO' mat0 'R2' ) ;
  311. phi0 = 'MAXI' ( 'EXCO' mat0 'PHI' ) ;
  312. b0 = 'MAXI' ( 'EXCO' mat0 'B' ) ;
  313. gama0 = 'MAXI' ('EXCO' mat0 'GAMA' ) ;
  314. m0 = 'MAXI' ( 'EXCO' mat0 'M' ) ;
  315. qmax0 = 'MAXI ' ( 'EXCO' mat0 'QMAX' ) ;
  316. qsta0 = 'MAXI' ( 'EXCO' mat0 'QSTA' ) ;
  317. mu0 = 'MAXI' ( 'EXCO' mat0 'MU' ) ;
  318. eta0 = 'MAXI' ( 'EXCO' mat0 'ETA' ) ;
  319. exp10 = 'MAXI' ( 'EXCO' mat0 'EXP1' ) ;
  320. exp20 = 'MAXI' ( 'EXCO' mat0 'EXP2' ) ;
  321. *
  322. dim0 = 'DIME' ta1 .'TEMPS' ;
  323. *
  324. sig_th0 = 0. ;
  325. r_th0 = 0. ;
  326. eps_th0 = 0. ;
  327. xx_th10 = 0. ;
  328. xx_th20 = 0. ;
  329. sig_th1 = 'PROG' 0. ;
  330. eps_th1 = 'PROG' 0. ;
  331. si ( non complet);
  332. sig_th1 = 'PROG' 0.
  333. 1.46800E+07 2.93600E+07 4.40400E+07 5.87196E+07 7.30534E+07
  334. 8.20293E+07 9.01555E+07 9.82258E+07 1.06163E+08
  335. 1.13855E+08 1.21148E+08 1.27849E+08 1.33737E+08 1.38604E+08
  336. 1.42342E+08 1.45023E+08 1.46884E+08 1.48214E+08 1.49240E+08
  337. 1.50108E+08;
  338. eps_th1 = 'PROG' 0.
  339. 2.62535E-34 5.81971E-19 7.73859E-13 6.03725E-09 4.72149E-06
  340. 8.24351E-05 1.71724E-04 2.61774E-04 3.53633E-04
  341. 4.48845E-04 5.49487E-04 6.58189E-04 7.77970E-04 9.11658E-04
  342. 1.06073E-03 1.22421E-03 1.39885E-03 1.58074E-03 1.76676E-03
  343. 1.95494E-03 ;
  344. finsi;
  345. *
  346. *
  347. 'REPETER' bloc0 ( dim0 - 1 ) ;
  348. i0 = &bloc0 ;
  349. depl0 = ta1 .'DEPLACEMENTS'.i0 ;
  350. sigm0 = ta1 .'CONTRAINTES'.i0 ;
  351. var0 = ta1 .'VARIABLES_INTERNES'.i0 ;
  352. def0 = ta1 .'DEFORMATIONS_INELASTIQUES'.i0 ;
  353. temp0 = ta1 .'TEMPS'.i0 ;
  354. eps0 = 'MAXI' ( 'EXCO' ( 'EPSI' mod0 depl0 ) 'EPXX' ) ;
  355. *
  356. * Contraintes et déformations inélastiques équivalentes
  357. *
  358. vm0 = 'MAXI' ( 'VMIS' sigm0 mod0 ) ;
  359. epsp0 = 'MAXI' ( 'EXCO' var0 'EPSE' ) ;
  360. *
  361. * Déformation totale et inélastique suivant x
  362. *
  363. epst0 = 'MAXI' ( 'EXCO' ( 'EPSI' depl0 mod0 ) 'EPXX' ) ;
  364. epsx0 = 'MAXI' ( 'EXCO' def0 'EIXX' ) ;
  365. *
  366. * Contraintes suivant x
  367. *
  368. sigx0 = 'MAXI' ( 'EXCO' sigm0 'SMXX' ) ;
  369. *
  370. * Calcul theorique
  371. *
  372. si complet;
  373. sig_th00 r_th00 eps_th00 xx_th1 xx_th2 = VISOHNO ta1 i0 sig_th0
  374. eps0 r_th0 eps_th0 xx_th10 xx_th20 ;
  375. *
  376. sig_th0 = sig_th00 ;
  377. r_th0 = r_th00 ;
  378. eps_th0 = eps_th00 ;
  379. xx_th10 = xx_th1 ;
  380. xx_th20 = xx_th2 ;
  381. sig_th1 = sig_th1 'ET' ( 'PROG' sig_th0 ) ;
  382. eps_th1 = eps_th1 'ET' ( 'PROG' eps_th0 ) ;
  383. sinon;
  384. sig_th00 = extr sig_th1 ( i0 + 1);
  385. eps_th00 = extr eps_th1 ( i0 + 1);
  386. finsi;
  387.  
  388. *
  389. * Calcul d'erreur
  390. *
  391. 'SI' ( epsx0 '<' ( 1.E-2 * eps0) ) ;
  392. err_e0 = 0. ;
  393. 'SINON' ;
  394. err_e0 = ( 'ABS' ( eps_th00 - epsx0 ) ) / epsx0 ;
  395. err_e0 = err_e0 * 100. ;
  396. 'FINSI' ;
  397. 'SI' ( sigx0 'EGA' 0. ) ;
  398. err_s0 = 0. ;
  399. 'SINON' ;
  400. err_s0 = ( 'ABS' ( sig_th00 - sigx0 ) ) / sigx0 ;
  401. err_s0 = err_s0 * 100. ;
  402. 'FINSI' ;
  403. *
  404. 'SI' ( (err_e0 '>' 1.E-1) 'OU' (err_s0 '>' 1.E-1 ) ) ;
  405. prob0 = vrai ;
  406. 'SINON' ;
  407. prob0 = faux ;
  408. 'FINSI' ;
  409. 'MESS' ' Fin du calcul de restitution au temps:' temp0 ;
  410. *
  411. 'FIN' bloc0 ;
  412. *
  413. 'SI' ( prob0 'EGA' vrai ) ;
  414. 'ERRE' 5 ;
  415. 'SINON' ;
  416. 'ERRE' 0 ;
  417. 'FINSI' ;
  418. *
  419. 'FIN' ;
  420.  
  421.  
  422.  
  423.  
  424.  
  425.  
  426.  
  427.  
  428.  
  429.  
  430.  
  431.  
  432.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales