Télécharger nlsb_pasapas.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. ************************************************************************
  3. ************************************************************************
  4. *______________________________________________________________________*
  5. * *
  6. * Cas test de l'implantation Nonlocal Stress Based (NLSB) *
  7. *______________________________________________________________________*
  8. *----------------------------------------------------------------------*
  9. * Description du cas test : Chargement uniaxial sur un cube *
  10. * ----------------------- *
  11. * *
  12. * L'objectif de l'essai est de verifier le bon fonctionnement de la *
  13. * regularisation nonlocale base sur l'etat de contrainte dans un calcul*
  14. * nonlineaire (PASAPAS). Le modeles d'endommagement considere pour *
  15. * le test de validation est le modele MAZARS. *
  16. * *
  17. * On remarquera, que la regularisation n'est pas dependante du modele *
  18. * et qu'elle peut-etre applique a n'importe quel modele a partir du *
  19. * moment ou la variable a regulariser est fournie. *
  20. * *
  21. * C. Giry, F. Dufour, J. Mazars *
  22. * ----------------------------- *
  23. * (fichier base sur ricrag_3D.dgibi) *
  24. ************************************************************************
  25. graph = 'N';
  26. COMPLET = FAUX ;
  27.  
  28. * Choix du modele d'endommagement teste
  29. * -------------------------------------
  30. * nmod = 1; modele MAZARS
  31.  
  32. nmod = 1;
  33. *
  34. *-------------- Options de calcul ---------------------
  35. *
  36. OPTION DIME 3 ELEM CUB8;
  37.  
  38. nbel = 5;
  39. tele = 1./nbel;
  40. tdef = 0.02;
  41. nbelh = 2;
  42. *
  43. *-------------- Definition de la geometrie ------------
  44. *
  45. P1 = 0. 0. 0.;
  46. P2 = 1. 0. 0.;
  47. P3 = 1. 1. 0.;
  48. P4 = 0. 1. 0.;
  49.  
  50. L1 = P1 DROIT nbel P2 ;
  51. L2 = P2 DROIT nbel P3 ;
  52. L3 = P3 DROIT nbel P4 ;
  53. L4 = P4 DROIT nbel P1 ;
  54.  
  55. SURF1 = DALL L1 L2 L3 L4;
  56.  
  57. P11 = tdef tdef (0.5-(0.5*tele));
  58. P21 = (1-tdef) tdef (0.5-(0.5*tele));
  59. P31 = (1-tdef) (1-tdef) (0.5-(0.5*tele));
  60. P41 = tdef (1-tdef) (0.5-(0.5*tele));
  61.  
  62. L11 = P11 DROIT nbel P21 ;
  63. L21 = P21 DROIT nbel P31 ;
  64. L31 = P31 DROIT nbel P41 ;
  65. L41 = P41 DROIT nbel P11 ;
  66.  
  67. SURF11 = DALL L11 L21 L31 L41;
  68.  
  69. P12 = tdef tdef (0.5+(0.5*tele));
  70. P22 = (1-tdef) tdef (0.5+(0.5*tele));
  71. P32 = (1-tdef) (1-tdef) (0.5+(0.5*tele));
  72. P42 = tdef (1-tdef) (0.5+(0.5*tele));
  73.  
  74. L12 = P12 DROIT nbel P22 ;
  75. L22 = P22 DROIT nbel P32 ;
  76. L32 = P32 DROIT nbel P42 ;
  77. L42 = P42 DROIT nbel P12 ;
  78.  
  79. SURF12 = DALL L12 L22 L32 L42;
  80.  
  81. P13 = 0. 0. 1.;
  82. P23 = 1. 0. 1.;
  83. P33 = 1. 1. 1.;
  84. P43 = 0. 1. 1.;
  85.  
  86. L13 = P13 DROIT nbel P23 ;
  87. L23 = P23 DROIT nbel P33 ;
  88. L33 = P33 DROIT nbel P43 ;
  89. L43 = P43 DROIT nbel P13 ;
  90.  
  91. SURF2 = DALL L13 L23 L33 L43;
  92.  
  93.  
  94. VOLTO = SURF1 VOLU nbelh SURF11 ;
  95. VOLT1 = SURF11 VOLU 1 SURF12 ;
  96. VOLT2 = SURF12 VOLU nbelh SURF2 ;
  97.  
  98. VOLTOT = VOLTO ET VOLT1 ET VOLT2;
  99. *
  100. *------- Definition des conditions aux limites --------
  101. *----------- et des deplacements imposes --------------
  102. *
  103. CL = BLOQ SURF1 UZ;
  104. CLL = BLOQ P1 'DEPL';
  105. CL1 = BLOQ SURF2 UZ;
  106. CL2 = bloq P2 UY;
  107. CL = CL et CL2;
  108.  
  109. D1 = DEPI CL1 1;
  110. *
  111. *----- Definition du modele ---------------------------
  112. *
  113. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE ENDOMMAGEMENT MAZARS;
  114.  
  115. * Parametres
  116. * ----------
  117. EBETON = 34100E6;
  118. NUBETON = 0.16;
  119.  
  120. * Longueur interne
  121. lc = 0.3;
  122.  
  123. * Module d'Young
  124. youngn = EBETON;
  125.  
  126. * Coefficient de Poisson
  127. nun = NUBETON;
  128.  
  129. * Résistance en traction
  130. ftn = 3.6e6;
  131.  
  132. ***************** Modele MAZARS **************
  133.  
  134. * Seuil de deformation 1ere fissuration
  135. y0 = ftn/ebeton ;
  136.  
  137. * Parametres At et Bt (comportement post-pic en traction)
  138. at = 0.95 ;
  139. bt = 10000.;
  140.  
  141. * Parametres At et Bt (comportement non lineaire en compression)
  142. ac = 1.25 ;
  143. bc = 1000.;
  144.  
  145. * Parametre beta (correction pour le cisaillement)
  146. bet = 1.06 ;
  147.  
  148. *
  149. * Material
  150. *
  151. mat1 = MATE mod1 YOUN youngn NU nun KTR0 y0
  152. ATRA at BTRA bt
  153. ACOM ac BCOM bc BETA bet ;
  154. *
  155. *----- Definition du chargement -------------------
  156. *
  157. LI1 = PROG 0. 1. ;
  158. LI2 = PROG 0. 2.e-3;
  159. 'SI' ('NON' COMPLET) ;
  160. LIS1 = PROG 0. PAS 0.005 0.15 ;
  161. 'SINON' ;
  162. LIS1 = PROG 0. PAS 0.005 1.00 ;
  163. 'FINSI' ;
  164. EV = EVOL MANU LI1 LI2 ;
  165. CHA1 = CHAR 'DIMP' D1 EV ;
  166. *
  167. *----------- Calcul par l'operateur PASAPAS ------------
  168. *
  169. CO1 = CONNEC mod1 LC NORMAL;
  170. CHAMFT = MANU 'CHML' mod1 'FT' ftn 'STRESSES';
  171.  
  172. TAB1 = TABLE ;
  173. TAB1.'BLOCAGES_MECANIQUES' = CL ET CLL ET CL1;
  174. TAB1.'MODELE' = MOD1;
  175. TAB1.'MOVA' = 'MOT' 'D ';
  176. TAB1.'CHARGEMENT' = CHA1;
  177. TAB1.'CARACTERISTIQUES' = MAT1;
  178. TAB1.'TEMPS_CALCULES' = LIS1;
  179. TAB1.'NON_LOCAL' = 'MOT' 'SB' ;
  180. TAB1.'LVIAM' = 'MOTS' 'EPTI' ;
  181. TAB1.'LCAR' = LC;
  182. TAB1.'CONN' = CO1;
  183. TAB1.'NLOC_SB_MODL' = MOD1;
  184. **TAB1.'NLOC_SB_FT' = CHAMFT;
  185. TAB1.'NLOC_SB_FT' = ftn ;
  186.  
  187. PASAPAS TAB1 ;
  188.  
  189. dd = dime tab1.deplacements;
  190.  
  191. *
  192. *----------- Courbe effort-deplacement -----------------
  193. *
  194. si (ega graph 'O');
  195. ev2=@global tab1 CL1 EV fz;
  196. DESS EV2;
  197. endf = EXCO (tab1.variables_internes.(dd-1)) 'D';
  198. trac endf mod1;
  199. finsi;
  200.  
  201. endf = EXCO (tab1.variables_internes.(dd-1)) 'D';
  202. 'SI' ('NON' COMPLET) ;
  203. dlim = 0.99 ;
  204. 'SINO' ;
  205. dlim = 0.999 ;
  206. 'FINSI' ;
  207. mailend = endf ELEM 'SUPERIEUR' dlim;
  208. XX1 YY1 ZZ1 = COOR MAILEND;
  209. Zmin = MINI ZZ1;
  210. Zmax = MAXI ZZ1;
  211.  
  212. message 'Taille zone completement endommagee';
  213. err = Zmax-Zmin;
  214. list err;
  215.  
  216. si (err > (1.1*tele));
  217. erreur(5);
  218. finsi;
  219.  
  220. fin;
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales