Télécharger la plaquette Cast3M


fr en

Télécharger nlsb_operateur.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : nlsb_operateur.dgibi
  2. ***********************************************************************
  3. *_______________________________________________________________________
  4. *
  5. *                  Simulation COMPACT TENSION TEST
  6. *_______________________________________________________________________
  7. *-----------------------------------------------------------------------
  8. *                      ^ ^   ^  ^  ^  ^
  9. *                      | |   |  |  |  |
  10. *                      ________________ 
  11. *                     |                |   
  12. *                     |                |
  13. *                     |                    |  
  14. *                     |                    | 
  15. *                     |                    | 
  16. *                     |                    |  
  17. *                    >|________________|
  18. *                              ^^^^^^^^^
  19. *-----------------------------------------------------------------------
  20. *
  21. * Analyse de la description du champs nonlocal en pointe d'entaille
  22. * C. Giry, F. Dufour, J. Mazars
  23. * -----------------------------
  24. ************************************************************************
  25. graph = 'N';
  26.  
  27. opti dime 2 elem qua4 mode plan cont;
  28.  
  29. * Taille element
  30. * --------------
  31. telem = 0.02;
  32.  
  33.  
  34. dens telem;
  35.  
  36. *-----------------------------------------------------------------------
  37. * Maillage
  38. *-----------------------------------------------------------------------
  39.  
  40.  
  41. *----- Largeur de l'éprouvette
  42. b = 1.;
  43.  
  44. *------Hauteur de l'éprouvette
  45. h = 1.;
  46.  
  47. p1    = 0. 0.;
  48. p1bis = (b/2.) 0.;
  49. p2    = b  0.;
  50. p3    = b  h;
  51. p3bis = (b/2.) h;
  52. p4    = 0. h;
  53. d1    = d p1 p1bis ;
  54. d1bis = d p1bis p2 ;
  55. d2    = d p2 p3 ;
  56. d2bis = d p3 p3bis ;
  57. d3    = d p3bis p4 ;
  58. d4    = d p4 p1 ;
  59. s1    = (d1 et d1bis et d2 et d2bis et d3 et d4);
  60. s1    = surf s1 ;
  61.  
  62. *-----------------------------------------------------------------------
  63. * Modèle et matériau 
  64. *-----------------------------------------------------------------------
  65.  
  66.  MOD1 = MODE S1 MECANIQUE ELASTIQUE ISOTROPE 
  67.            NON_LOCAL 'SB' 'V_MOYENNE' (MOTS 'EPTI');
  68. *
  69. * Paramètres
  70. * ----------
  71. * ft    : limite de traction
  72. * younc : module d'Young
  73. * nuc   : coefficient de Poisson
  74. * y0    : seuil en deformation de premiere fissuration
  75. * ll    : longueur interne
  76.  
  77.  ft    = 3.E+6; 
  78.  younc = 3.D+9 ; 
  79.  nuc   = 0.2;  
  80.  y0    = ft/younc; 
  81.  ll    = 0.3   ;
  82.  
  83.  
  84.  MAT1 = MATE mod1 'YOUN' younc 'NU' nuc 'RHO' 2.5e+3  ;
  85.  
  86. *-----------------------------------------------------------------------
  87. * Connectivites 
  88. *-----------------------------------------------------------------------
  89.  conn1 = CONN mod1 ll 'NORMAL' 'INTERIEUR' ;
  90.  conn2 = CONN mod1 ll 'DROITE' P1bis P2  'CENTRE' ;
  91.  connt = conn1 et conn2;
  92.  
  93. *-----------------------------------------------------------------------
  94. * Conditions limites
  95. *-----------------------------------------------------------------------
  96. cl1   = bloq (d1bis) UY;
  97. cl2   = bloq p4 UX;
  98. CL3   = RELA 'ENSE' UY (d2bis et d3);
  99. CLTOT = CL1 ET CL2 ET CL3;
  100. forc1 = FORC (d2bis et d3) (0. 1.) ; 
  101.  
  102. *-----------------------------------------------------------------------
  103. * Rigidité
  104. *-----------------------------------------------------------------------
  105.  rbet = RIGI mod1 mat1 ;
  106.  rigt = rbet ET CLTOT ;
  107.  
  108. *-----------------------------------------------------------------------
  109. * Analyse elastique
  110. *-----------------------------------------------------------------------
  111.  depl1 = RESO rigt forc1 ;
  112.  
  113.  cont1 = SIGM mod1 mat1 depl1;
  114.  conp1 = PRIN mod1 cont1;
  115.  
  116.  contmax = MAXI (EXCO conp1 'SI11');
  117.  f2      = ft/contmax;
  118.  forc1   = FORC (d2bis et d3) (0. f2) ;
  119.  depl1   = RESO rigt forc1 ;
  120.  
  121. *----------------------------------------------------------------------- 
  122. * Analyse du champ nonlocal
  123. *-----------------------------------------------------------------------
  124.  defo1 = EPSI mod1 depl1;
  125.  cont1 = SIGM mod1 mat1 depl1; 
  126.  defp1 = PRIN mod1 defo1;
  127.  conp1 = PRIN mod1 cont1; 
  128.  
  129.  
  130. * Deformation equivalente Mazars
  131. * ------------------------------
  132.  epeq11 = EXCO defp1 'SI11';
  133.  epeq12 = MASQ epeq11 'SUPERIEUR' 0.;
  134.  epeq1  = NOMC 'EPTI' (epeq11 * epeq12);
  135.  epeq21 = EXCO defp1 'SI22';
  136.  epeq22 = MASQ epeq21 'SUPERIEUR' 0.;
  137.  epeq2  = NOMC 'EPTI' (epeq21 * epeq22);
  138.  epeq31 = EXCO defp1 'SI33';
  139.  epeq32 = MASQ epeq31 'SUPERIEUR' 0.;
  140.  epeq3  = NOMC 'EPTI' (epeq31 * epeq32); 
  141.  
  142.  epeqm = ((epeq1)**2) + ((epeq2)**2) + ((epeq3)**2);
  143.  epeqm = (epeqm)**(0.5);
  144.  
  145. * Calcul de la longueur par element et limite de traction
  146. * -------------------------------------------------------
  147. CHAMLO = MANU 'CHML' MOD1 'LONG' 1.0 'STRESSES';
  148. CHAML1 = INTG CHAMLO MOD1 ELEM 'LONG';
  149. CHAML2 = CHAML1**(1./2.); 
  150. CHAML3 = NOMC 'LONG' (CHAN 'STRESSES'  MOD1 CHAML2);
  151. CHAMFT = MANU 'CHML' MOD1 'SBFT' ft 'STRESSES';
  152.  
  153. * Calcul du champ nonlocal de deformation equivalente
  154. * ---------------------------------------------------
  155. epeqmsb  = epeqm + conp1 + chamft + chaml3;
  156. epeqnlm  = 'NLOC'  epeqmsb connt ;
  157. Pmax1    = POIN (EXCO epeqnlm 'EPTI') 'MAXI';
  158. XX1 YY1  = COOR PMAX1;
  159. lerr     = ABS((MAXI XX1) - (0.5*b));
  160.  
  161. list lerr;
  162.  
  163. si (ega graph 'O');
  164.  TRAC epeqnlm mod1;
  165. finsi;
  166.  
  167. * Test sur la position du maximum du champ nonlocal par rapport a la
  168. * pointe de l'entaille
  169. * --------------------
  170.  
  171. si (lerr > telem); 
  172.   erre 5;
  173. sinon;         
  174.   erre 0; 
  175. finsi;
  176.  
  177.  
  178. fin;
  179.  
  180.  
  181.  
  182.  
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales