Télécharger nloc1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : nloc1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. graph='N';
  5. saut page;
  6. mess 'test CONN et NLOC';
  7. *********************************************************************
  8. *
  9. * construction de connectivites sur des domaines differents
  10. * mesh12=1/4 de disque, mesh1 et mesh2=1/2 disque et
  11. * mesh=disque complet, avec ou sans symetrie de tel facon
  12. * que la reduction sur mesh12 d'un calcul non local mene a l'aide
  13. * de ces 4 conectivites soit toujours identique
  14. *
  15. *********************************************************************
  16. *
  17. opti dime 2 mode plan defo;
  18. *
  19. * 1) maillage: mesh est un maillage bi-symetrique
  20. * mesh12 en est le 1/4 (compose de me1[tri3] et me2[qua4])
  21. * mesh1 et mesh2 2 en sont des moities contenant mesh12
  22. *
  23. p1=0 0; p2=1 0; p22=.01 0; p3=0 1; p33=0 .01;
  24. *
  25. opti elem tri3;
  26. c1=(c 3 p22 p1 p33);
  27. nnc1=nbno c1;
  28. j=1; pci=c1 poin j;
  29. repeter lab1 (nnc1-1);
  30. j=j+1;
  31. pcf=c1 poin j;
  32. mecj=surf ((p1 d 1 pci) et (pci d 1 pcf) et (pcf d 1 p1)) 'PLANE';
  33. si (j ega 2); me1=mecj;
  34. sinon ; me1=me1 et mecj;
  35. finsi;
  36. pci=pcf;
  37. fin lab1;
  38. *
  39. opti elem qua4;
  40. me2=dall c1 (p33 d 3 p3) (c 3 p3 p1 p2) (p2 d 3 p22) 'PLAN';
  41. *
  42. mesh12=me1 et me2;
  43. *
  44. mesh2=mesh12 syme 'DROI' p1 p2;
  45. mesh3=mesh12 syme 'DROI' p1 p3;
  46. mesh4=mesh2 syme 'DROI' p1 p3;
  47. *
  48. mesh=mesh12 et mesh2 et mesh3 et mesh4;
  49. elim mesh 1.d-5;
  50. *
  51. mmesh1=mesh12 et mesh2; mesh1=mmesh1;
  52. mmesh2=mesh12 et mesh3; mesh2=mmesh2;
  53. *
  54. * 2) modele (tous les mesh ont mesh12 en commun)
  55. *
  56. mo=modeli mesh mecanique NON_LOCAL 'MOYE'
  57. 'V_MOYENNE' (MOTS 'SCAL') consti constia;
  58. mo12=modeli mesh12 mecanique NON_LOCAL 'MOYE'
  59. 'V_MOYENNE' (MOTS 'SCAL') consti constia;
  60. mo1=modeli mesh1 mecanique NON_LOCAL 'MOYE'
  61. 'V_MOYENNE' (MOTS 'SCAL') consti constia;
  62. mo2=modeli mesh2 mecanique NON_LOCAL 'MOYE'
  63. 'V_MOYENNE' (MOTS 'SCAL') consti constia;
  64. *
  65. * 3) listmot des composantes a moyenner
  66. *
  67. *
  68. * 4) calcul sur le disque complet
  69. *
  70. mess 'calcul sur le disque complet';
  71. *
  72. * 4.1) connectivite (normale)
  73. *
  74. co =conn mo 1. 'NORMAL' 'NO-MESH';
  75. *
  76. * 4.2) chamelem a moyenner
  77. * (construit par projection d'un chpoint nul partout sauf au centre)
  78. *
  79. ssca=(manu 'CHPO' p1 1 'SCAL' 1.)
  80. + (manu 'CHPO' mesh 1 'SCAL' 0.);
  81. csca=chan 'CHAM' ssca mo;
  82. ssca=chan 'STRESSES' mo csca;
  83. *
  84. * 4.3) moyenne non-locale
  85. *
  86. moy=nloc ssca co ;
  87. *
  88. * 4.4) reduction sur le 1/4
  89. *
  90. mmoy=(redu moy me1) et (redu moy me2);
  91. *
  92. * 5) calcul sur le 1/4 de disque
  93. *
  94. mess 'calcul sur le 1/4 de disque';
  95. *
  96. * 5.1) connectivite avec symetries par rapport a 2 axes obtenues
  97. * de facon "orthogonale" a partir d'une symetrie point et de
  98. * 2 symetries droite
  99. *
  100. co12ecn=conn mo12 1. 'NORMAL' 'NO-MES12';
  101. co12ecv=conn mo12 1. 'DROITE' p1 p2 'HO-MES12';
  102. co12ech=conn mo12 1. 'DROITE' p1 p3 'VE-MES12';
  103. co12ecp=conn mo12 1. 'POINT' p1 'PT-MES12';
  104. co12vhp=co12ecn et co12ecv et co12ech et co12ecp;
  105. *
  106. * 5.2) chamelem a moyenner
  107. * (construit par projection d'un chpoint nul partout sauf au centre)
  108. *
  109. ssca12=(manu 'CHPO' p1 1 'SCAL' 1.)
  110. + (manu 'CHPO' mesh12 1 'SCAL' 0.);
  111. csca12=chan 'CHAM' ssca12 mo12;
  112. ssca12=chan 'STRESSES' mo12 csca12;
  113. *
  114. * 5.3) moyenne non-locale
  115. *
  116. moy12=nloc ssca12 co12vhp ;
  117. *
  118. * 6) calcul sur le 1/2 disque vertical
  119. *
  120. mess 'calcul sur le 1/2 disque vertical';
  121. *
  122. * 6.1) connectivite avec une symetrie droite
  123. *
  124. co1ecn=conn mo1 1. 'NORMAL' 'NO-MESH1';
  125. co1ecv=conn mo1 1. 'DROITE' p1 p3 'VE-MESH1';
  126. co1v=co1ecn et co1ecv;
  127. *
  128. * 6.2) chamelem a moyenner
  129. * (construit par projection d'un chpoint nul partout sauf au centre)
  130. *
  131. ssca1=(manu 'CHPO' p1 1 'SCAL' 1.)
  132. + (manu 'CHPO' mesh1 1 'SCAL' 0.);
  133. csca1=chan 'CHAM' ssca1 mo1;
  134. ssca1=chan 'STRESSES' mo1 csca1;
  135. *
  136. * 6.3) moyenne non-locale
  137. *
  138. moy1=nloc ssca1 co1v;
  139. *
  140. * 6.4) reduction sur le 1/4
  141. *
  142. mmoy1=(redu moy1 me1) et (redu moy1 me2);
  143. *
  144. *
  145. * 7) calcul sur le 1/2 disque horizontal
  146. *
  147. mess 'calcul sur le 1/2 disque horizontal';
  148. *
  149. * 7.1) connectivite avec une symetrie droite
  150. *
  151. co2ecn=conn mo2 1. 'NORMAL' 'NO-MESH2';
  152. co2ech=conn mo2 1. 'DROITE' p1 p2 'VE-MESH2';
  153. co2h=co2ecn et co2ech;
  154. *
  155. * 7.2) chamelem a moyenner
  156. * (construit par projection d'un chpoint nul partout sauf au centre)
  157. *
  158. ssca2=(manu 'CHPO' p1 1 'SCAL' 1.)
  159. + (manu 'CHPO' mesh2 1 'SCAL' 0.);
  160. csca2=chan 'CHAM' ssca2 mo2;
  161. ssca2=chan 'STRESSES' mo2 csca2;
  162. *
  163. * 7.3) moyenne non-locale
  164. *
  165. moy2=nloc ssca2 co2h ;
  166. *
  167. * 7.4) reduction sur le 1/4
  168. *
  169. mmoy2=(redu moy2 me1) et (redu moy2 me2);
  170. *
  171. * 8) erreur
  172. *
  173. m12m =(abs (moy12 - mmoy )) masque 'SUPERIEUR' 'SOMME' 1.d-10;
  174. m12m1=(abs (moy12 - mmoy1)) masque 'SUPERIEUR' 'SOMME' 1.d-10;
  175. m12m2=(abs (moy12 - mmoy2)) masque 'SUPERIEUR' 'SOMME' 1.d-10;
  176. lerr=m12m + m12m1 + m12m2;
  177. si (lerr > 0); erre 5;
  178. sinon; erre 0; finsi;
  179. *
  180. fin;
  181.  
  182.  
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales