Télécharger muliq.dgibi

Retour à la liste

Numérotation des lignes :

  1. *
  2. *
  3. * Viscosité dynamique de l'eau
  4. * Valeurs de référence : tables VDI
  5. * Comparaisons de différentes formules et tests de 'VARI' 'MULIQ'
  6. *
  7. *
  8. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' 'TRAC' 'PSC' 'EPTR' 10 'DENS' 1. ;
  9. graph = faux ;
  10. *
  11. *- Calcul de la viscosité dynamique de l'eau (formule Cathare)
  12. *
  13. 'DEBP' muliqk TW0*'LISTREEL' ;
  14. *
  15. UN = TW0 / TW0 ;
  16. *TW1 = 273.15 * UN + TW0 ;
  17. *
  18. a0 = 570.58058 * UN ;
  19. b0 = -140.D0 * UN ;
  20. L1 = 2.414D-5 * ('EXP' (a0 / (b0 + TW0))) ;
  21. *
  22. 'FINP' L1 ;
  23. *
  24. *- Calcul de la viscosité dynamique de l'eau (formule VDI)
  25. *
  26. 'DEBP' muliqv TW0*'LISTREEL' PW0*'FLOTTANT' ;
  27. *
  28. UN = TW0 / TW0 ;
  29. *TW1 = 273.15 * UN + TW0 ;
  30. PW1 = PW0 * UN ;
  31. *
  32. a1 = 241.4 ;
  33. a2 = 0.3828209486 ;
  34. a3 = 0.2162830218 ;
  35. a4 = 0.1498693949 ;
  36. a5 = 0.4711880117 ;
  37. *
  38. PC0 = 221.2D5 * UN ;
  39. TC0 = (374.15 + 273.15) * UN ;
  40. BETA = PW1 / PC0 ;
  41. TETA = TW0 / TC0 ;
  42. PS1 = 'VARI' 'PSATT' TW0 ;
  43. BETAS = PS1 / PC0 ;
  44. *
  45. L1 = (a4 * (BETA - BETAS) * (TETA - (a5 * UN)) + UN) * a1 * 1.D-7 ;
  46. L2 = ('EXP' ( ((a2*UN) / (teta - (a3*un))) * ('LOG' 10.) ) ) * L1 ;
  47. *
  48. 'FINP' L2 ;
  49. *
  50. *
  51. *----------------------------------------------
  52. *- Température et pression pour comparaison
  53. *----------------------------------------------
  54. *
  55. *
  56. TW1 = ('PROG' 20. 40. 60. 80. 90.) + 273.15 ;
  57. PW1 = 1.D5 ;
  58. LREF1 = 1.D-6 * ('PROG' 1000. 651. 463. 351. 311.) ;
  59. L10 = MULIQK TW1 ;
  60. L11 = MULIQV TW1 PW1 ;
  61. *
  62. TW2 = ('PROG' 10. 30. 50. 100. 130. 150. 170.) + 273.15 ;
  63. PW2 = 10.D5 ;
  64. LREF2 = 1.D-6 * ('PROG' 1300. 797. 544. 279. 211. 181. 159.) ;
  65. L20 = MULIQK TW2 ;
  66. L21 = MULIQV TW2 PW2 ;
  67. *
  68. TW3 = ('PROG' 10. 50. 100. 150. 200. 220.) + 273.15 ;
  69. PW3 = 25.D5 ;
  70. LREF3 = 1.D-6 * ('PROG' 1300. 544. 279. 182. 134. 122.) ;
  71. L30 = MULIQK TW3 ;
  72. L31 = MULIQV TW3 PW3 ;
  73. *
  74. * Test de VARI avec T sous forme de FLOTTANT
  75. 'DEBP' testf t*'LISTREEL' ;
  76. nb = 'DIME' t ;
  77. listmu = 'PROG' ;
  78. 'REPE' blo1 nb ;
  79. valt = 'EXTR' t &blo1 ;
  80. valmu = 'VARI' 'MULIQ' valt ;
  81. listmu = listmu 'ET' ('PROG' valmu) ;
  82. 'FIN' blo1 ;
  83. 'FINP' listmu ;
  84. test_f1 = testf tw1 ;
  85. test_f2 = testf tw2 ;
  86. test_f3 = testf tw3 ;
  87. *
  88. * Test de VARI avec T sous forme de LISTREEL
  89. test_l1 = vari 'MULIQ' tw1 ;
  90. test_l2 = vari 'MULIQ' tw2 ;
  91. test_l3 = vari 'MULIQ' tw3 ;
  92. *
  93. * Test de VARI avec T sous forme de CHPO
  94. 'DEBP' testc t*'CHPOINT' mail1*'MAILLAGE' ;
  95. test1 = 'VARI' 'MULIQ' t ;
  96. listmu = 'EXTR' test1 'VALE' mail1 ;
  97. 'FINP' listmu ;
  98. P1 = 1. 0. ; P2 = 2. 0. ;
  99. GEO1 = P1 'DROI' 4 P2 ; PT1 = 'CHAN' 'POI1' GEO1 ;
  100. GEO2 = P1 'DROI' 6 P2 ; PT2 = 'CHAN' 'POI1' GEO2 ;
  101. GEO3 = P1 'DROI' 5 P2 ; PT3 = 'CHAN' 'POI1' GEO3 ;
  102. T1 = 'MANU' 'CHPO' PT1 'SCAL' TW1 ;
  103. T2 = 'MANU' 'CHPO' PT2 'SCAL' TW2 ;
  104. T3 = 'MANU' 'CHPO' PT3 'SCAL' TW3 ;
  105. test_c1 = testc t1 pt1 ;
  106. test_c2 = testc t2 pt2 ;
  107. test_c3 = testc t3 pt3 ;
  108. *
  109. * Comparaisons mise en oeuvre Esope/Gibi pour Cathare
  110. d10 = 'EVOL' 'MANU' tw1 (l10 - test_L1 / l10 * 100.) ;
  111. d20 = 'EVOL' 'VERT' 'MANU' tw2 (l20 - test_l2 / l20 * 100.) ;
  112. d30 = 'EVOL' 'ROUG' 'MANU' tw3 (l30 - test_l3 / l30 * 100.) ;
  113. *
  114. *-------------------------------------
  115. *- Sorties Graphiques
  116. *-------------------------------------
  117. *
  118. 'SI' graph ;
  119. *
  120. ev10 = 'EVOL' 'MANU' tw1 l10 ;
  121. ev20 = 'EVOL' 'VERT' 'MANU' tw2 l20 ;
  122. ev30 = 'EVOL' 'ROUG' 'MANU' tw3 l30 ;
  123. ev11 = 'EVOL' 'MANU' tw1 l11 ;
  124. ev21 = 'EVOL' 'VERT' 'MANU' tw2 l21 ;
  125. ev31 = 'EVOL' 'ROUG' 'MANU' tw3 l31 ;
  126. evr1 = 'EVOL' 'MANU' tw1 lref1 ;
  127. evr2 = 'EVOL' 'VERT' 'MANU' tw2 lref2 ;
  128. evr3 = 'EVOL' 'ROUG' 'MANU' tw3 lref3 ;
  129. rela10 = 'EVOL' 'MANU' tw1 (l10 - lref1 / lref1 * 100.) ;
  130. rela20 = 'EVOL' 'VERT' 'MANU' tw2 (l20 - lref2 / lref2 * 100.) ;
  131. rela30 = 'EVOL' 'ROUG' 'MANU' tw3 (l30 - lref3 / lref3 * 100.) ;
  132. rela11 = 'EVOL' 'MANU' tw1 (l11 - lref1 / lref1 * 100.) ;
  133. rela21 = 'EVOL' 'VERT' 'MANU' tw2 (l21 - lref2 / lref2 * 100.) ;
  134. rela31 = 'EVOL' 'ROUG' 'MANU' tw3 (l31 - lref3 / lref3 * 100.) ;
  135. *
  136. TAB1 = TABLE ;
  137. TAB1 . 'TITRE' = TABLE ;
  138. TAB1 . 1 = ' MARQ PLEIN ROND NOLI' ;
  139. TAB1 . 2 = ' MARQ PLEIN CARR NOLI' ;
  140. TAB1 . 3 = ' MARQ PLEIN LOSA NOLI' ;
  141. TAB1 . 4 = ' MARQ ROND NOLI' ;
  142. TAB1 . 5 = ' MARQ CARR NOLI' ;
  143. TAB1 . 6 = ' MARQ LOSA NOLI' ;
  144. *
  145. TIT1 = 'Dynamic viscosity of water (Cathare)' ;
  146. TIT2 = ' C' ;
  147. TIT3 = 'kg/m/s' ;
  148. TAB1 . 'TITRE' . 1 = 'MOT' ' 1 bar' ;
  149. TAB1 . 'TITRE' . 2 = 'MOT' '10 bar' ;
  150. TAB1 . 'TITRE' . 3 = 'MOT' '25 bar' ;
  151. TAB1 . 'TITRE' . 4 = 'MOT' 'ref 1' ;
  152. TAB1 . 'TITRE' . 5 = 'MOT' 'ref 10' ;
  153. TAB1 . 'TITRE' . 6 = 'MOT' 'ref 25' ;
  154. 'DESS' (ev10 'ET' ev20 'ET' ev30 'ET' evr1 'ET' evr2 'ET' evr3)
  155. 'MIMA' 'TITR' TIT1 'TITX' TIT2 'TITY' TIT3 'LEGE' TAB1 ;
  156. *
  157. TIT1 = 'Dynamic viscosity of water (VDI)' ;
  158. TIT2 = ' C' ;
  159. TIT3 = 'kg/m/s' ;
  160. TAB1 . 'TITRE' . 1 = 'MOT' ' 1 bar' ;
  161. TAB1 . 'TITRE' . 2 = 'MOT' '10 bar' ;
  162. TAB1 . 'TITRE' . 3 = 'MOT' '25 bar' ;
  163. TAB1 . 'TITRE' . 4 = 'MOT' 'ref 1' ;
  164. TAB1 . 'TITRE' . 5 = 'MOT' 'ref 10' ;
  165. TAB1 . 'TITRE' . 6 = 'MOT' 'ref 25' ;
  166. 'DESS' (ev11 'ET' ev21 'ET' ev31 'ET' evr1 'ET' evr2 'ET' evr3)
  167. 'MIMA' 'TITR' TIT1 'TITX' TIT2 'TITY' TIT3 'LEGE' TAB1 ;
  168. *
  169. TIT1 = 'Dynamic viscosity of water. Relative error of Cathare (x100).' ;
  170. TIT2 = ' C' ;
  171. TIT3 = ' %' ;
  172. TAB1 . 'TITRE' . 1 = 'MOT' 'Cat. (1 bar)' ;
  173. TAB1 . 'TITRE' . 2 = 'MOT' 'Cat. (10 bar)' ;
  174. TAB1 . 'TITRE' . 3 = 'MOT' 'Cat. (25 bar)' ;
  175. 'DESS' (rela10 'ET' rela20 'ET' rela30)
  176. 'MIMA' 'TITR' TIT1 'TITX' TIT2 'TITY' TIT3 'LEGE' TAB1 ;
  177. *
  178. TIT1 = 'Dynamic viscosity of water. Relative error of VDI (x100).' ;
  179. TIT2 = ' C' ;
  180. TIT3 = ' %' ;
  181. TAB1 . 'TITRE' . 1 = 'MOT' 'VDI. (1 bar)' ;
  182. TAB1 . 'TITRE' . 2 = 'MOT' 'VDI. (10 bar)' ;
  183. TAB1 . 'TITRE' . 3 = 'MOT' 'VDI. (25 bar)' ;
  184. 'DESS' (rela11 'ET' rela21 'ET' rela31)
  185. 'MIMA' 'TITR' TIT1 'TITX' TIT2 'TITY' TIT3 'LEGE' TAB1 ;
  186. *
  187. TIT1 = 'Dynamic viscosity of water. Relative error (x100).' ;
  188. TIT2 = ' C' ;
  189. TIT3 = ' %' ;
  190. TAB1 . 'TITRE' . 1 = 'MOT' 'Cat. (1 bar)' ;
  191. TAB1 . 'TITRE' . 2 = 'MOT' 'Cat. (10 bar)' ;
  192. TAB1 . 'TITRE' . 3 = 'MOT' 'Cat. (25 bar)' ;
  193. TAB1 . 'TITRE' . 4 = 'MOT' 'VDI. (1 bar)' ;
  194. TAB1 . 'TITRE' . 5 = 'MOT' 'VDI. (10 bar)' ;
  195. TAB1 . 'TITRE' . 6 = 'MOT' 'VDI. (25 bar)' ;
  196. 'DESS' (rela10 'ET' rela20 'ET' rela30 'ET'
  197. rela11 'ET' rela21 'ET' rela31)
  198. 'MIMA' 'TITR' TIT1 'TITX' TIT2 'TITY' TIT3 'LEGE' TAB1 ;
  199. *
  200. TIT1 =
  201. 'Esope/Gibi relative error for Cathare formula (x100)' ;
  202. TIT2 = ' C' ;
  203. TIT3 = ' %' ;
  204. TAB1 . 'TITRE' . 1 = 'MOT' 'Esope/Gibi (1 bar)' ;
  205. TAB1 . 'TITRE' . 2 = 'MOT' 'Esope/Gibi (10 bar)' ;
  206. TAB1 . 'TITRE' . 3 = 'MOT' 'Esope/Gibi (25 bar)' ;
  207. 'DESS' (d10 'ET' d20 'ET' d30)
  208. 'MIMA' 'TITR' TIT1 'TITX' TIT2 'TITY' TIT3 'LEGE' TAB1 ;
  209. 'FINSI' ;
  210. *
  211. *----------------------------------------------------------------------
  212. *- Tests de bon fonctionnement
  213. *- (Comparaisons des différents types et de la mise en oeuvre en gibi)
  214. *----------------------------------------------------------------------
  215. *
  216. diff1 = 'MAXI' (test_f1 - test_l1 / l10) 'ABS' ;
  217. diff2 = 'MAXI' (test_f2 - test_l2 / l20) 'ABS' ;
  218. diff3 = 'MAXI' (test_f3 - test_l3 / l30) 'ABS' ;
  219. diff4 = 'MAXI' (test_f1 - test_c1 / l10) 'ABS' ;
  220. diff5 = 'MAXI' (test_f2 - test_c2 / l20) 'ABS' ;
  221. diff6 = 'MAXI' (test_f3 - test_c3 / l30) 'ABS' ;
  222. diff7 = 'MAXI' (test_f1 - l10 / l10) 'ABS' ;
  223. diff8 = 'MAXI' (test_f2 - l20 / l20) 'ABS' ;
  224. diff9 = 'MAXI' (test_f3 - l30 / l30) 'ABS' ;
  225. didi = diff1 + diff2 + diff3 + diff4 + diff5
  226. + diff6 + diff7 + diff8 + diff9 ;
  227. 'MESS' 'Sommes du max des différences relatives ' didi ;
  228. 'SI' (didi > 1.D-14) ;
  229. 'ERRE' 5 ;
  230. 'FINSI' ;
  231. *
  232. 'FIN' ;
  233.  
  234.  
  235.  
  236.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales