Télécharger motrtrac.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Mooney_LRGTreloar_Traction.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE MOONEY-RIVLIN INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION SELON LA DIRECTION Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2006) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2006, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. option epsilon 'UTILISATEUR';
  25.  
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = FAUX ;
  28. *GRAPH = VRAI ;
  29. title = 'CHAINE' 'MOONEY-RIVLIN - ' 'TRACTION UNIAXIALE Y' ;
  30.  
  31. *======================================================================*
  32. * Geometrie - Maillage *
  33. *======================================================================*
  34. * Longueur (direction x) de la plaque/membrane :
  35. Lg_x = 1. ;
  36. * Largeur (direction y) de la plaque/membrane :
  37. Lg_y = 1. ;
  38. * Nombre d'elements selon les directions x et y :
  39. Nel_x = 2 ;
  40. Nel_y = 2 ;
  41. *
  42. 'OPTION' 'ELEM' 'TRI6' ;
  43. *
  44. P1 = 0. 0. ;
  45. P2 = Lg_x 0. ;
  46. P3 = Lg_x Lg_y ;
  47. P4 = 0. Lg_y ;
  48. *
  49. L1 = 'DROITE' Nel_x P1 P2 ;
  50. L2 = 'DROITE' Nel_y P2 P3 ;
  51. L3 = 'DROITE' Nel_x P3 P4 ;
  52. L4 = 'DROITE' Nel_y P4 P1 ;
  53. *
  54. SU = 'DALLER' L1 L2 L3 L4 ;
  55. 'SI' GRAPH ;
  56. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  57. 'FINSI' ;
  58.  
  59. *======================================================================*
  60. * Modele - Materiau - Caracteristiques (en MPa) *
  61. *======================================================================*
  62. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'ET'
  63. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  64. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  65. 'ERREUR' 5 ;
  66. 'FINSI' ;
  67. *
  68. * Ne pas oublier de definir les parametres lies a l'elasticite.
  69. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  70. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  71. *
  72. LCMAT = 'MOTS' 'YOUN' 'NU ' 'C1 ' 'C2 ' ;
  73. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  74. 'NON_LINEAIRE' 'UTILISATEUR'
  75. 'NUME_LOI' 31 'C_MATERIAU' LCMAT ;
  76. *
  77. * Coefficients du modele de Mooney-Rivlin (en Pa) :
  78. C1 = 0.183E+6 ; C2 = 0.0034E+6 ;
  79. *
  80. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  81. * du fait de l'incompressibilite inherente au modele.
  82. * Le module de Young YOU est alors connu, car, pour ce modele, le
  83. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  84. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  85. * de la traction. En fonction du niveau de deformation atteinte en
  86. * traction, il faut augmenter cette valeur afin de pouvoir faire
  87. * converger les calculs (module tangent en fin de calculs).
  88. * Prendre des valeurs superieures n'entraine pas de modification des
  89. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  90. *
  91. XNU = 0.497 ;
  92. YOUini = 3.*(2.*(C1+C2)) ; YOU = 1000. * YOUini ;
  93. *
  94. MA = 'MATERIAU' MO 'YOUN' YOU 'NU ' XNU
  95. 'C1 ' C1 'C2 ' C2 ;
  96.  
  97. *======================================================================*
  98. * Conditions aux limites - Traction suivant UY *
  99. *======================================================================*
  100. BL1 = 'BLOQUER' 'UY ' L1 ;
  101. BL2 = 'BLOQUER' 'UY ' L3 ;
  102. BL4 = 'BLOQUER' 'UX ' P1 ;
  103. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  104. *
  105. * Definition des instants du chargement :
  106. t_deb = 0. ; t_fin = 10. ;
  107. L_tps = 'PROG' t_deb t_fin ;
  108. * Deplacement suivant Y :
  109. L_UY = 'PROG' 0. ( 3. * Lg_y) ;
  110. FF_y = 'DEPIMP' BL2 1. ;
  111. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  112. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  113.  
  114. *======================================================================*
  115. * Initialisation de la table pour appel a PASAPAS *
  116. *======================================================================*
  117. TAB1 = 'TABLE' ;
  118. TAB1.'MODELE' = MO ;
  119. TAB1.'CARACTERISTIQUES' = MA ;
  120. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  121. TAB1.'CHARGEMENT' = CHARTOT ;
  122. *TAB1.'PRECISION' = 1.E-5 ;
  123. *TAB1.'FTOL' = 1.E-5 ;
  124. *TAB1.'MTOL' = 1.E-5 ;
  125. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  126. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  127. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  128. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  129. TAB1.'REAC_GRANDS'=500.;
  130. *
  131. L_abs = TAB1.'TEMPS_SAUVES' ;
  132. n_abs = 'DIMENSION' L_abs ;
  133. *
  134. PASAPAS TAB1 ;
  135. *
  136. * Quelques traces de controle apres calculs
  137. 'SI' GRAPH ;
  138. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  139. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  140. 'TRACER' (Defo_0 'ET' Defo_1)
  141. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  142. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  143. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  144. 'FINSI' ;
  145. *
  146. *======================================================================*
  147. * Construction de la solution analytique *
  148. *======================================================================*
  149. * Definitions :
  150. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  151. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  152. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  153. * Dans le cas du modele de Mooney-Rivlin :
  154. * W = C1*(I1-3.)+C2*(I2-3.) , soit dW/dI1 = C1 et dW/dI2 = C2
  155. *
  156. * Les contraintes de Cauchy sont calculables analytiquement :
  157. * - SCxx = 0.
  158. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  159. * - SCxy = 0 (pas de cisaillement)
  160. * - SCzz = 0 (hypothese des contraintes planes)
  161. *
  162. L_Un = 'PROG' n_abs '*' 1. ;
  163. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  164. *
  165. SCxx_th = 0. * L_Un ;
  166. L_z1 = Lamy * Lamy ; L_z2 = L_Un / Lamy ;
  167. SCyy_th = (L_z1 - L_z2) * ((2.*C1*L_Un) + (2.*C2*L_z2)) ;
  168. SCxy_th = 0. * L_Un ;
  169.  
  170. *======================================================================*
  171. * Comparaison des resultats avec la solution analytique *
  172. *======================================================================*
  173. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  174. * calculees et les solutions analytiques correspondantes.
  175. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  176. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  177. *
  178. TabD = TAB1.'DEPLACEMENTS' ;
  179. TabS = TAB1.'CONTRAINTES' ;
  180. Confini = 'FORM' ;
  181. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  182. *
  183. SCxx = 'PROG' 0. ;
  184. SCyy = 'PROG' 0. ;
  185. SCxy = 'PROG' 0. ;
  186. 'REPETER' Boucle (n_abs - 1) ;
  187. 'FORM' (TabD.&Boucle) ;
  188. VolSU = 'INTG' MO ChmUn ;
  189. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  190. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  191. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  192. 'FORM' Confini ;
  193. 'FIN' Boucle ;
  194. *
  195. 'SI' GRAPH ;
  196. tlege = 'TABLE' ;
  197. tlege. 1 = 'MARQ CROI' ;
  198. tlege.'TITRE' = 'TABLE' ;
  199. tlege.'TITRE'. 1 = 'Numerique' ;
  200. tlege.'TITRE'. 2 = 'Analytique' ;
  201. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  202. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  203. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  204. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  205. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  206. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  207. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  208. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  209. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  210. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  211. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  212. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  213. 'FINSI' ;
  214. *
  215. * Tests de bon fonctionnement :
  216. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  217. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  218. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  219. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  220. *
  221. MESS ' RESULTATS : ' title ;
  222. MESS ' ------------------------------------------------- ';
  223. 'SAUTER' 1 'LIGNE' ;
  224. 'MESS' ' Tests de bon fonctionnement :' ;
  225. 'MESS' ' -------------------------------' ;
  226. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  227. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  228. 'calculee' ;
  229. 'MESS' ' et la '
  230. 'solution analytique associee' ;
  231. 'MESS' ' Composante XX : ' r_xx ;
  232. 'MESS' ' Composante YY : ' r_yy ;
  233. 'MESS' ' Composante XY : ' r_xy ;
  234. 'SAUTER' 1 'LIGNE' ;
  235. * Ecart relatif maximal tolere
  236. Sigref = 1.E-3 ;
  237. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  238. 'MESS' ' ---------------------' ;
  239. 'MESS' ' ECHEC DU CAS-TEST !' ;
  240. 'MESS' ' ---------------------' ;
  241. 'ERREUR' 5 ;
  242. 'SINON' ;
  243. 'MESS' ' ----------------------' ;
  244. 'MESS' ' SUCCES DU CAS-TEST !' ;
  245. 'MESS' ' ----------------------' ;
  246. 'FINSI' ;
  247. 'SAUTER' 1 'LIGNE' ;
  248.  
  249. 'FIN' ;
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales