Télécharger moontrac3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : moontrac3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE MOONEY RIVLIN QUASI-INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE INCOMPRESSIBLE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2008) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2006, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  24. option epsilon 'UTILISATEUR';
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ;
  27. * Mettre 1 ou 2 selon le type de calcul voulu
  28. ICALCUL = 1 ;
  29. *
  30. 'SI' ('>' ICALCUL 2) ;
  31. 'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  32. 'ERREUR' 5 ;
  33. 'FINSI' ;
  34.  
  35. title = 'CHAINE' 'MOONEY RIVLIN - ' 'TRACTION UNIAXIALE Z' ;
  36.  
  37. *======================================================================*
  38. * Geometrie - Maillage *
  39. *======================================================================*
  40. * Longueur (direction x) du pave :
  41. Lg_x = 1. ;
  42. * Largeur (direction y) du pave :
  43. Lg_y = 1. ;
  44. * Hauteur (direction z) du pave :
  45. Lg_z = 1. ;
  46. * Nombre d'elements selon les directions x, y et z :
  47. 'SI' ('EGA' ICALCUL 1) ;
  48. Nel_x = 2 ;
  49. Nel_y = 2 ;
  50. Nel_z = 2 ;
  51. 'OPTION' 'ELEM' 'CUB8' ;
  52. 'FINSI' ;
  53. 'SI' ('EGA' ICALCUL 2) ;
  54. Nel_x = 3 ;
  55. Nel_y = 3 ;
  56. Nel_z = 7 ;
  57. 'OPTION' 'ELEM' 'CU20' ;
  58. 'FINSI' ;
  59. *
  60. P1 = 0. 0. 0. ;
  61. P2 = Lg_x 0. 0. ;
  62. P3 = Lg_x Lg_y 0. ;
  63. P4 = 0. Lg_y 0. ;
  64. *
  65. L1 = 'DROITE' Nel_x P1 P2 ;
  66. L2 = 'DROITE' Nel_y P2 P3 ;
  67. L3 = 'DROITE' Nel_x P3 P4 ;
  68. L4 = 'DROITE' Nel_y P4 P1 ;
  69. *
  70. SBas = 'DALLER' L1 L2 L3 L4 ;
  71. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  72. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  73. 'SI' GRAPH ;
  74. 'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') 'CACH' ;
  75. 'FINSI' ;
  76.  
  77. *======================================================================*
  78. * Modele - Materiau - Caracteristiques (en MPa) *
  79. *======================================================================*
  80. * Ne pas oublier de definir les parametres lies a l'elasticite.
  81. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  82. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  83. *
  84. LCMAT = 'MOTS' 'YOUN' 'NU ' 'D ' 'C1' 'C2' ;
  85. MO = 'MODELISER' Pave 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  86. 'NON_LINEAIRE' 'UTILISATEUR'
  87. 'NUME_LOI' 31 'C_MATERIAU' LCMAT ;
  88. *
  89. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  90. CoeC1 = 0.183 ; CoeC2 = 0.0034 ;
  91. * CoeC1 = 1. MPa et CoeD = 1.E-4 MPa**-1 !
  92. * Lorsque CoeD tend vers 0, on retrouve un modele de type Mooney-Rivlin
  93. * incompressible. Ici on met une valeur "petite" de CoeD pour pouvoir
  94. * utiliser la solution analytique du modele de Mooney-Rivlin correspon-
  95. * dant pour les tests de comparaison. Si CoeD a une valeur trop "impor-
  96. * tante", il faut modifier la valeur du coefficient de Poisson, qui
  97. * s'eloigne alors de 0.5 (incompressibilite).
  98. * On fixe le coefficient de Poisson ("proche" de 0.5 si D est "petit").
  99. * Le module de Young initial est alors connu :
  100. * (le module de cisaillement vaut pour ce modele : mu = 2.CoeC1)
  101. * La valeur du module de Young utilise pour les estimations elastiques
  102. * doit etre superieure au module tangent pour le niveau de deformation
  103. * atteint en fin de calcul (sinon risque de non convergence).
  104.  
  105. *XNU = 0.499 ;
  106. YOUini = 3.*(2.*(CoeC1+CoeC2)) ;
  107. *
  108. 'SI' ('EGA' ICALCUL 1) ;
  109. XNU = 0.497 ;
  110. CoeD = 1.E-4 ;
  111. YOU = 100. * YOUini ;
  112. 'FINSI' ;
  113. 'SI' ('EGA' ICALCUL 2) ;
  114. XNU = 0.495 ;
  115. CoeD = 1.E-2 ;
  116. YOU = 200. * YOUini ;
  117. 'FINSI' ;
  118. *
  119. MA = 'MATERIAU' MO 'YOUN' YOU 'NU ' XNU
  120. 'D ' CoeD 'C1 ' CoeC1 'C2 ' CoeC2 ;
  121.  
  122. *==================================================================*
  123. * Conditions aux limites *
  124. *==================================================================*
  125. BL1 = 'BLOQUER' 'UZ ' Shau ;
  126. BL2 = 'BLOQUER' 'UZ ' Sbas ;
  127. BL3 = 'BLOQUER' 'UX ' L4 ;
  128. BL4 = 'BLOQUER' 'UY ' L1 ;
  129. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  130. *
  131. * Definition des instants du chargement :
  132. t_deb = 0. ; t_fin = 10. ;
  133. L_tps = 'PROG' t_deb t_fin ;
  134. * Deplacement suivant Z :
  135. L_UZ = 'PROG' 0. (3.0 * Lg_z) ;
  136. FF_z = 'DEPIMP' BL1 1. ;
  137. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMZ' L_UZ ;
  138. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  139.  
  140. *======================================================================*
  141. * Initialisation de la table pour appel a PASAPAS *
  142. *======================================================================*
  143. TAB1 = 'TABLE' ;
  144. TAB1.'MODELE' = MO ;
  145. TAB1.'CARACTERISTIQUES' = MA ;
  146. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  147. TAB1.'CHARGEMENT' = CHARTOT ;
  148. *TAB1.'PRECISION' = 1.E-7 ;
  149. *TAB1.'FTOL' = 1.E-5 ;
  150. *TAB1.'MTOL' = 1.E-5 ;
  151. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  152. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  153. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  154. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  155. tab1.reac_grands=500.;
  156. *
  157. L_abs = TAB1.'TEMPS_SAUVES' ;
  158. n_abs = 'DIMENSION' L_abs ;
  159. *
  160. PASAPAS TAB1 ;
  161. *
  162. * Quelques traces de controle apres calculs
  163. 'SI' GRAPH ;
  164. Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  165. Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  166. 'TRACER' (Defo_0 'ET' Defo_1)
  167. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  168. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  169. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  170. 'FINSI' ;
  171. *
  172. *======================================================================*
  173. * Construction de la solution analytique INCOMPRESSIBLE *
  174. *======================================================================*
  175. * Definitions :
  176. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  177. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  178. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  179. * Dans le cas du modele Neo-Hookeen :
  180. * W = CoeC1*(I1-3.) , soit dW/dI1 = CoeC1 et dW/dI2 = 0.
  181. *
  182. * Les contraintes de Cauchy sont calculables analytiquement :
  183. * - SCxx = 0.
  184. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  185. * - SCxy = 0 (pas de cisaillement)
  186. * - SCzz = 0 (hypothese des contraintes planes)
  187. *
  188. L_Un = 'PROG' n_abs '*' 1. ;
  189. Lamz = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  190. *
  191. SCxx_th = 0. * L_Un ;
  192. SCyy_th = 0. * L_Un ;
  193. L_z1 = Lamz * Lamz ; L_z2 = L_Un / Lamz ;
  194. SCzz_th = (L_z1 - L_z2) * ((2.*CoeC1*L_Un) + (2.*CoeC2*L_z2)) ;
  195. SCxy_th = 0. * L_Un ;
  196. SCxz_th = 0. * L_Un ;
  197. SCyz_th = 0. * L_Un ;
  198. *
  199. *======================================================================*
  200. * Comparaison des resultats avec la solution analytique *
  201. *======================================================================*
  202. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  203. * calculees et les solutions analytiques correspondantes.
  204. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  205. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  206. *
  207. TabD = TAB1.'DEPLACEMENTS' ;
  208. TabS = TAB1.'CONTRAINTES' ;
  209. Confini = 'FORM' ;
  210. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  211. *
  212. SCxx = 'PROG' 0. ;
  213. SCyy = 'PROG' 0. ;
  214. SCzz = 'PROG' 0. ;
  215. SCxy = 'PROG' 0. ;
  216. SCxz = 'PROG' 0. ;
  217. SCyz = 'PROG' 0. ;
  218. 'REPETER' Boucle (n_abs - 1) ;
  219. 'FORM' (TabD.&Boucle) ;
  220. VolSU = 'INTG' MO ChmUn ;
  221. mess ' volsu ' volsu;
  222. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  223. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  224. SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  225. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  226. SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  227. SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  228. 'FORM' Confini ;
  229. 'FIN' Boucle ;
  230. *
  231. * LG lamb
  232. L_abs = Lamz;
  233. *
  234. 'SI' GRAPH ;
  235. tlege = 'TABLE' ;
  236. tlege. 1 = 'MARQ CROI' ;
  237. tlege.'TITRE' = 'TABLE' ;
  238. tlege.'TITRE'. 1 = 'Numerique' ;
  239. tlege.'TITRE'. 2 = 'Analytique' ;
  240. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  241. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  242. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  243. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  244. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  245. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  246. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  247. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  248. Evzz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  249. Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  250. 'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  251. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  252. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  253. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  254. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  255. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  256. Evxz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  257. Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  258. 'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  259. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  260. Evyz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  261. Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  262. 'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  263. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  264. 'FINSI' ;
  265. *
  266. * Tests de bon fonctionnement :
  267. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  268. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  269. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  270. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  271. uu= ('ABS' (SCzz - SCzz_th)) / Smaxref;
  272. list sczz; list SCzz_th; list uu;
  273. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  274. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  275. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  276. *
  277. MESS ' RESULTATS : ' title ;
  278. MESS ' ------------------------------------------------- ';
  279. 'SAUTER' 1 'LIGNE' ;
  280. 'MESS' ' Tests de bon fonctionnement :' ;
  281. 'MESS' ' -------------------------------' ;
  282. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  283. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  284. 'MESS' ' et la solution analytique' ;
  285. 'MESS' ' Composante XX : ' r_xx ;
  286. 'MESS' ' Composante YY : ' r_yy ;
  287. 'MESS' ' Composante ZZ : ' r_zz ;
  288. 'MESS' ' Composante XY : ' r_xy ;
  289. 'MESS' ' Composante XZ : ' r_xz ;
  290. 'MESS' ' Composante YZ : ' r_yz ;
  291. 'SAUTER' 1 'LIGNE' ;
  292. * Ecart relatif maximal tolere
  293. 'SI' ('EGA' ICALCUL 1) ;
  294. Sigref = 1.E-3 ;
  295. 'FINSI' ;
  296. 'SI' ('EGA' ICALCUL 2) ;
  297. Sigref = 1.E-2 ;
  298. 'FINSI' ;
  299. *
  300. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  301. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  302. 'MESS' ' ---------------------' ;
  303. 'MESS' ' ECHEC DU CAS-TEST !' ;
  304. 'MESS' ' ---------------------' ;
  305. 'ERREUR' 5 ;
  306. 'SINON' ;
  307. 'MESS' ' ----------------------' ;
  308. 'MESS' ' SUCCES DU CAS-TEST !' ;
  309. 'MESS' ' ----------------------' ;
  310. 'FINSI' ;
  311. 'SAUTER' 1 'LIGNE' ;
  312.  
  313. 'FIN' ;
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales