Télécharger mistral_cp.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : mistral_cp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test mistral_cp.dgibi: Jeux de donnees *
  6. * --------------------------------------- *
  7. * *
  8. opti echo 0 ;
  9. opti dime 2 elem qua8 ;
  10. opti mode plan cont ;
  11. * ajout de option epsilon lineaire pour la precision des test!
  12. OPTION epsilon lineaire;
  13. *
  14. *******************************************************
  15. * TEST DE VALIDATION *
  16. * ------------------ *
  17. * MODELE MISTRAL *
  18. * ELASTICITE ET PLASTICITE INSTANTANE *
  19. * *
  20. * MAILLAGE: *
  21. * EPROUVETTE RECTANGULAIRE *
  22. * *
  23. * CHARGEMENT: *
  24. * DEPLACEMENT LATERAL IMPOSE MONOTONE CROISSANT *
  25. *******************************************************
  26. *
  27. * Geometrie
  28. *
  29. * ------------------------------------------
  30. XX = 1. ; YY = 0.5 ;
  31. * ------------------------------------------
  32. *
  33. P00 = 0. 0. ; P10 = XX 0. ;
  34. P11 = XX YY ; P01 = 0. YY ;
  35. *
  36. LX0 = droi 1 P00 P10 ;
  37. LY1 = droi 1 P10 P11 ;
  38. LX1 = droi 1 P11 P01 ;
  39. LY0 = droi 1 P01 P00 ;
  40. *
  41. * Maillage
  42. *
  43. EPROU = dall LX0 LY1 LX1 LY0 ;
  44. * trac EPROU ;
  45. *
  46. * Modele et materiau
  47. *
  48. MODL = mode EPROU mecanique elastique orthotrope
  49. viscoplastique mistral ;
  50. * ------------------------------------------------------------
  51. VEC1 = 1. 1. ; TETA = 45. ;
  52. SENSIP1 = -2 ; SENSIP2 = 1 ; ICBASE = 0 ;
  53. fichier = '/u/castem/divers/mimatcp_par' ;
  54. PDILT E1 E2 E3 NU12 NU23 NU13 MU12 MU23 MU13
  55. PNBRE PCOHI PECOU PEDIR PRVCE PECRX PDVDI PCROI PINCR
  56. = @mistpar fichier SENSIP1 SENSIP2 ;
  57. * ------------------------------------------------------------
  58. MATER = mate MODL
  59. 'YG1 ' E1 'YG2 ' E2 'YG3 ' E3
  60. 'NU12' NU12 'NU23' NU23 'NU13' NU13
  61. 'G12 ' MU12
  62. 'ALP1' 0. 'ALP2' 0.
  63. 'DILT' PDILT 'NBRE' PNBRE 'COHI' PCOHI 'ACOU' PECOU 'EDIR' PEDIR
  64. 'RVCE' PRVCE 'ECRX' PECRX 'DVDI' PDVDI 'CROI' PCROI 'INCR' PINCR
  65. 'SIP1' SENSIP1 'SIP2' SENSIP2 'IBAS' ICBASE
  66. 'DIRECTION' VEC1 'INCLINE' TETA ;
  67. *
  68. * Conditions aux limites
  69. *
  70. CLX0 = bloq ux LX0 ;
  71. CLX1 = bloq ux LX1 ;
  72. CLY0 = bloq uy LY0 ;
  73. CLY1 = bloq uy LY1 ;
  74. CL = CLX0 et CLX1 et CLY0 et CLY1 ;
  75. *
  76. * Chargement
  77. *
  78. * -------------------------------------------------------
  79. T1 = 100. ; DT1 = 10. ;
  80. EPSXY1 = 0.01 ;
  81. TT0 = 300. ; TT1 = TT0 ;
  82. PHIT0 = 0. ;
  83. * -------------------------------------------------------
  84. TEMPS = prog 0. T1 ;
  85. TEMPSCAL = prog 0. pas DT1 T1 ;
  86. *
  87. DEPX = depi CLX1 YY ;
  88. DEPY = depi CLY1 XX ;
  89. EVEPS = evol manu TEMPS (prog 0. EPSXY1) ;
  90. CHADE = char dimp (DEPX et DEPY) EVEPS ;
  91. *
  92. TT = manu chpo EPROU 1 'T' 1. ;
  93. EVTT = evol manu TEMPS (prog TT0 TT1) ;
  94. CHTT = char 'T' TT EVTT ;
  95. *
  96. PHI = manu chpo EPROU 1 'FI' 1. ;
  97. EVFI = evol manu TEMPS (prog 0. 0.) ;
  98. CHFI = char 'FI' PHI EVFI ;
  99. *
  100. CHA = CHADE et CHTT et CHFI ;
  101. *
  102. * Valeurs initiales
  103. *
  104. VINT0 = zero MODL 'VARINTER' ;
  105. FIT0 = manu chml MODL 'FIT ' PHIT0 type 'SCALAIRE' 'STRESSES' ;
  106. VINT0 = VINT0 + FIT0 ;
  107. *
  108. * Calcul
  109. *
  110. TAB = TABLE ;
  111. TAB.'VARIABLES_INTERNES' = TABLE ;
  112. TAB.'BLOCAGES_MECANIQUES' = CL ;
  113. TAB.'CARACTERISTIQUES' = MATER ;
  114. TAB.'MODELE' = MODL ;
  115. TAB.'CHARGEMENT' = CHA ;
  116. TAB.'VARIABLES_INTERNES' . 0 = VINT0 ;
  117. TAB.'TEMPS_CALCULES' = TEMPSCAL ;
  118. PASAPAS TAB ;
  119. *
  120. * Traitement des resultats
  121. *
  122. SIG = TAB.'CONTRAINTES' ;
  123. DEP = tab.'DEPLACEMENTS' ;
  124. VI = tab.'VARIABLES_INTERNES' ;
  125. NT = dime TEMPSCAL-1 ;
  126. * ----------------
  127. ERMAX = 0.001 ;
  128. * ----------------
  129. *
  130. SIGT = SIG.NT ;
  131. SIGT_PO = chang chpo MODL SIGT ;
  132. SIGXX = extr SIGT_PO SMXX P00 ;
  133. SIGYY = extr SIGT_PO SMYY P00 ;
  134. SIGZZ = extr SIGT_PO SMZZ P00 ;
  135. SIGXY = extr SIGT_PO SMXY P00 ;
  136. *
  137. DEPT = DEP.NT ;
  138. EPSIT = epsi DEPT MODL ;
  139. EPSIT_PO = chang chpo MODL EPSIT ;
  140. EPSXX = extr EPSIT_PO EPXX P00 ;
  141. EPSYY = extr EPSIT_PO EPYY P00 ;
  142. EPSZZ = extr EPSIT_PO EPZZ P00 ;
  143. EPSXY = (extr EPSIT_PO GAXY P00)/2. ;
  144. *
  145. VIT = VI.NT ;
  146. VIT_PO = chang chpo MODL VIT ;
  147. EPSP11 = extr VIT_PO EP01 P00 ;
  148. EPSP22 = extr VIT_PO EP02 P00 ;
  149. EPSP33 = extr VIT_PO EP03 P00 ;
  150. EPSP12 = extr VIT_PO EP04 P00 ;
  151. EPSP13 = extr VIT_PO EP05 P00 ;
  152. EPSP23 = extr VIT_PO EP06 P00 ;
  153. *
  154. mess ;
  155. mess 'SIGXX SIGYY SIGZZ : ' SIGXX SIGYY SIGZZ ;
  156. mess 'SIGXY : ' SIGXY ;
  157. mess ;
  158. mess 'EPSXX EPSYY EPSZZ : ' EPSXX EPSYY EPSZZ ;
  159. mess 'EPSXY : ' EPSXY ;
  160. mess ;
  161. mess 'EPSP11 EPSP22 EPSP33 : ' EPSP11 EPSP22 EPSP33 ;
  162. mess 'EPSP12 EPSP13 EPSP23 : ' EPSP12 EPSP13 EPSP23 ;
  163. mess ;
  164.  
  165. * SIGT_XY = exco SIGT 'SMXY' ;
  166. * trac SIGT_XY MODL ;
  167. * GAMA_XY = exco EPSIT 'GAXY' ;
  168. * trac GAMA_XY MODL ;
  169. * ------------------------------------------------------------
  170. MUXY = 4.E10 ;
  171. * ------------------------------------------------------------
  172. AA = 400.E6 ; BB = 1.E10 ;
  173. A0 = AA/(2.*MUXY) ;
  174. A1 = 1. + (BB/MUXY) ;
  175. EPSPXY1 = (EPSXY1-A0)/A1 ;
  176. SIGXY1 = AA + (2.*BB*EPSPXY1) ;
  177. EPSEXY1 = SIGXY1/(2.*MUXY) ;
  178. * -----------------------------------------------------
  179. *
  180. ERSIGXY = ABS( (SIGXY/SIGXY1) - 1. ) ;
  181. EREPSXY = ABS( (EPSXY/EPSXY1) - 1. ) ;
  182. EREPSPXY = ABS( (EPSP12/EPSPXY1) - 1. ) ;
  183. *
  184. si (ERSIGXY > ERMAX) ;
  185. mess ;
  186. mess 'ABS(erreur relative) sur la contrainte > ' ERMAX ;
  187. mess ERSIGXY ;
  188. finsi ;
  189. si (EREPSXY > ERMAX) ;
  190. mess ;
  191. mess 'ABS(erreur relative) sur la deformation > ' ERMAX ;
  192. mess EREPSXY ;
  193. finsi ;
  194. si (EREPSPXY > ERMAX) ;
  195. mess ;
  196. mess 'ABS(erreur relative) sur la deformation plastique > ' ERMAX ;
  197. mess EREPSPXY ;
  198. mess ;
  199. finsi ;
  200. P_ER = prog ERSIGXY EREPSXY EREPSPXY ;
  201. ERMA = maxi P_ER ;
  202. si (ERMA > ERMAX) ;
  203. ERRE 5 ;
  204. finsi ;
  205.  
  206. fin ;
  207.  
  208.  
  209.  
  210.  
  211.  
  212.  
  213.  
  214.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales