Télécharger mistral_axi.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : mistral_axi.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test mistral_axi.dgibi: Jeux de donnees *
  6. * --------------------------------------- *
  7. * *
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10. *
  11. opti echo 0 ;
  12. opti dime 2 mode axis elem qua8 ;
  13. *
  14. *******************************************************
  15. * TEST DE VALIDATION *
  16. * ------------------ *
  17. * *
  18. * MODELE MISTRAL *
  19. * ELASTICITE ET VISCOPLASTICITE *
  20. * *
  21. * MAILLAGE: *
  22. * TUBE CYLINDRIQUE (AXISYMETRIQUE) *
  23. * *
  24. * CHARGEMENT: *
  25. * PRESSION IMPOSEE : RAMPE RAPIDE ET PLATEAU *
  26. *******************************************************
  27. *
  28. * Geometrie
  29. *
  30. * ------------------------------------------
  31. RI = 49.5E-3 ; RE = 50.5E-3 ; H = 0.010 ;
  32. * ------------------------------------------
  33. RM = (RI+RE)/2. ;
  34. RE2MRI2 = (RE**2)-(RI**2) ;
  35. COEFI = (RI**2)/RE2MRI2 ;
  36. E = RE-RI ;
  37. VECR = 1. 0. ;
  38. *
  39. PIB = RI 0 ; PEB = RE 0 ;
  40. PIH = RI H ; PEH = RE H ;
  41. *
  42. LB = droi 2 PIB PEB ;
  43. LE = droi 1 PEB PEH ;
  44. LH = droi 2 PEH PIH ;
  45. LI = droi 1 PIH PIB ;
  46. *
  47. * Maillage
  48. *
  49. EPROU = dall LB LE LH LI ;
  50. * trac EPROU ;
  51. *
  52. POMB = RM 0. ; POMH = RM H ;
  53. PMB = EPROU poin proc POMB ;
  54. PMH = EPROU poin proc POMH ;
  55. *
  56. * Modele et materiau
  57. *
  58. MODG = mode EPROU mecanique elastique orthotrope
  59. viscoplastique mistral ;
  60. *
  61. * ------------------------------------------------------------
  62. SENSIP1 = 1 ; SENSIP2 = -3 ; ICBASE = 0 ;
  63. fichier = 'CHAINE' DIVERS '/mimataxi_par' ;
  64. PDILT E1 E2 E3 NU12 NU23 NU13 MU12 MU23 MU13
  65. PNBRE PCOHI PECOU PEDIR PRVCE PECRX PDVDI PCROI PINCR
  66. = @mistpar fichier SENSIP1 SENSIP2 ;
  67. * ------------------------------------------------------------
  68. MAZY = mate MODG 'YG1 ' E1 'YG2 ' E2 'YG3 ' E3
  69. 'NU12' NU12 'NU23' NU23 'NU13' NU13
  70. 'G12 ' MU12
  71. 'ALP1' 0. 'ALP2' 0. 'ALP3' 0. 'TALP' 0. 'TREF' 623.15
  72. 'DILT' PDILT 'NBRE' PNBRE 'COHI' PCOHI 'ACOU' PECOU 'EDIR' PEDIR
  73. 'RVCE' PRVCE 'ECRX' PECRX 'DVDI' PDVDI 'CROI' PCROI 'INCR' PINCR
  74. 'SIP1' SENSIP1 'SIP2' SENSIP2 'IBAS' ICBASE
  75. 'DIRECTION' VECR ;
  76. *
  77. * Conditions aux limites
  78. *
  79. CLB = bloq uz LB ;
  80. CLH = rela ense uz LH ;
  81. CL = CLB et CLH ;
  82. *
  83. * Chargement
  84. *
  85. * -------------------------------------------------------
  86. T1 = 0.001 ; T2 = 2000.001 ;
  87. DT1 = 25. ;
  88. TEMPSCAL = prog 0. T1 pas DT1 100.001
  89. 150.001 200.001 300.001
  90. 500.001 700.001 1000.001 1400.001 T2 ;
  91. SIGTT1 = 400.E6 ;
  92. TT0 = 623.15 ; TT1 = 623.15 ; TT2 = 623.15 ;
  93. PHIT0 = 2.E25 ;
  94. * -------------------------------------------------------
  95. TEMPS = prog 0. T1 T2 ;
  96. *
  97. PRI = E/RI ;
  98. PRESI = pres mass MODG (PRI) LI ;
  99. SZPRI = PRI*COEFI ;
  100. PRHPI = (-1.)*SZPRI ;
  101. PRESHPI = pres mass MODG (PRHPI) LH ;
  102. EVPI = evol manu TEMPS (prog 0. SIGTT1 SIGTT1) ;
  103. CHAPI = char meca (PRESI et PRESHPI) EVPI ;
  104. *
  105. TT = manu chpo EPROU 1 'T' 1. ;
  106. EVTT = evol manu TEMPS (prog TT0 TT1 TT2) ;
  107. CHTT = char 'T' TT EVTT ;
  108. *
  109. PHI = manu chpo EPROU 1 'FI' 1. ;
  110. EVFI = evol manu TEMPS (prog 0. 0. 0.) ;
  111. CHFI = char 'FI' PHI EVFI ;
  112. *
  113. CHA = CHAPI et CHTT et CHFI ;
  114. *
  115. * Valeurs initiales
  116. *
  117. VINT0 = zero MODG 'VARINTER' ;
  118. FIT0 = manu chml MODG 'FIT ' PHIT0 type 'SCALAIRE' 'STRESSES' ;
  119. VINT0 = VINT0 + FIT0 ;
  120. *
  121. * Calcul
  122. *
  123. TAB = TABLE ;
  124. TAB.'VARIABLES_INTERNES' = TABLE ;
  125. TAB.'BLOCAGES_MECANIQUES' = CL ;
  126. TAB.'CARACTERISTIQUES' = MAZY ;
  127. TAB.'MODELE' = MODG ;
  128. TAB.'CHARGEMENT' = CHA ;
  129. TAB.'VARIABLES_INTERNES' . 0 = VINT0 ;
  130. TAB.'TEMPS_CALCULES' = TEMPSCAL ;
  131. PASAPAS TAB ;
  132. *
  133. * Traitement des resultats
  134. *
  135. TEM = TAB.'TEMPS' ;
  136. SIG = TAB.'CONTRAINTES' ;
  137. DEP = tab.'DEPLACEMENTS' ;
  138. VI = tab.'VARIABLES_INTERNES' ;
  139. NT = dime TEMPSCAL-1 ;
  140. * ---------------
  141. ERMAX = 0.01 ;
  142. * ---------------
  143. T = TEM.NT ;
  144. *
  145. SIGT = SIG.NT ;
  146. SIGT_PO = chang chpo MODG SIGT ;
  147. SIGRR = extr SIGT_PO SMRR PMB ;
  148. SIGTT = extr SIGT_PO SMTT PMB ;
  149. SIGZZ = extr SIGT_PO SMZZ PMB ;
  150. SIGRZ = extr SIGT_PO SMRZ PMB ;
  151. *
  152. DEPT = DEP.NT ;
  153. EPSIT = epsi DEPT MODG ;
  154. EPSIT_PO = chang chpo MODG EPSIT ;
  155. EPSRR = extr EPSIT_PO EPRR PMB ;
  156. EPSTT = extr EPSIT_PO EPTT PMB ;
  157. EPSZZ = extr EPSIT_PO EPZZ PMB ;
  158. EPSRZ = (extr EPSIT_PO GARZ PMB)/2. ;
  159. *
  160. VIT = VI.NT ;
  161. VIT_PO = chang chpo MODG VIT ;
  162. EPSFRR = extr VIT_PO EP11 PMB ;
  163. EPSFTT = extr VIT_PO EP12 PMB ;
  164. EPSFZZ = extr VIT_PO EP13 PMB ;
  165. EPSFRZ = extr VIT_PO EP15 PMB ;
  166. *
  167. mess ;
  168. mess 'T : ' T ;
  169. mess ;
  170. mess 'SIGRR SIGTT SIGZZ : ' SIGRR SIGTT SIGZZ ;
  171. mess 'SIGRZ : ' SIGRZ ;
  172. mess 'EPSRR EPSTT EPSZZ : ' EPSRR EPSTT EPSZZ ;
  173. mess 'EPSRZ : ' EPSRZ ;
  174. mess 'EPSFRR EPSFTT EPSFZZ : ' EPSFRR EPSFTT EPSFZZ ;
  175. mess 'EPSFRZ : ' EPSFRZ ;
  176. mess ;
  177. *
  178. * SIGT_RR = exco SIGT 'SMRR' ;
  179. * trac SIGT_RR MODG ;
  180. * SIGT_TT = exco SIGT 'SMTT' ;
  181. * trac SIGT_TT MODG ;
  182. * SIGT_ZZ = exco SIGT 'SMZZ' ;
  183. * trac SIGT_ZZ MODG ;
  184. * SIGT_RZ = exco SIGT 'SMRZ' ;
  185. * trac SIGT_RZ MODG ;
  186. *
  187. * ------------------------------------------------------------
  188. YOUNGR = 1.1E11 ; YOUNGZ = 0.9E11 ; YOUNGT = 1.E11 ;
  189. POISRZ = 0.3 ; POISZT = 0.3 ; POISRT = 0.3 ;
  190. MURZ = 4.E10 ;
  191. * ------------------------------------------------------------
  192. SIGRR1 = (-1.)*SIGTT1*E/(2.*RM) ;
  193. SIGZZ1 = SIGTT1*SZPRI ;
  194. EPSERR1 = (SIGRR1/YOUNGR)-((POISRT/YOUNGR)*SIGTT1)
  195. -((POISRZ/YOUNGR)*SIGZZ1) ;
  196. EPSETT1 = (SIGTT1/YOUNGT)-((POISZT/YOUNGZ)*SIGZZ1)
  197. -((POISRT/YOUNGR)*SIGRR1) ;
  198. EPSEZZ1 = (SIGZZ1/YOUNGZ)-((POISRZ/YOUNGR)*SIGRR1)
  199. -((POISZT/YOUNGZ)*SIGTT1) ;
  200. * --------------------------
  201. EPSFRR1 = -0.00199068 ;
  202. EPSFTT1 = 0.001931867 ;
  203. EPSFZZ1 = 0.0000588108 ;
  204. * --------------------------
  205. EPSRR1 = EPSERR1 + EPSFRR1 ;
  206. EPSTT1 = EPSETT1 + EPSFTT1 ;
  207. EPSZZ1 = EPSEZZ1 + EPSFZZ1 ;
  208. *
  209. ERSIGRR = (SIGRR/SIGRR1) - 1. ;
  210. ERSIGTT = (SIGTT/SIGTT1) - 1. ;
  211. ERSIGZZ = (SIGZZ/SIGZZ1) - 1. ;
  212. P_ER = prog ERSIGRR ERSIGTT ERSIGZZ ;
  213. ERSIGMA = maxi P_ER 'ABS' ;
  214. *
  215. EREPSRR = (EPSRR/EPSRR1) - 1. ;
  216. EREPSTT = (EPSTT/EPSTT1) - 1. ;
  217. EREPSZZ = (EPSZZ/EPSZZ1) - 1. ;
  218. P_ER = prog EREPSRR EREPSTT EREPSZZ ;
  219. EREPSMA = maxi P_ER 'ABS' ;
  220. *
  221. EREPSFRR = (EPSFRR/EPSFRR1) - 1. ;
  222. EREPSFTT = (EPSFTT/EPSFTT1) - 1. ;
  223. EREPSFZZ = (EPSFZZ/EPSFZZ1) - 1. ;
  224. P_ER = prog EREPSFRR EREPSFTT EREPSFZZ ;
  225. EREPSFMA = maxi P_ER 'ABS' ;
  226. *
  227. si (ERSIGMA > ERMAX) ;
  228. mess ;
  229. mess 'ABS(erreur relative) sur SIGRR, SIGTT ou SIGZZ > ' ERMAX ;
  230. mess ERSIGRR ERSIGTT ERSIGZZ ;
  231. finsi ;
  232. si (EREPSMA > ERMAX) ;
  233. mess ;
  234. mess 'ABS(erreur relative) sur EPSRR, EPSTT ou EPSZZ > ' ERMAX ;
  235. mess EREPSRR EREPSTT EREPSZZ ;
  236. finsi ;
  237. si (EREPSFMA > ERMAX) ;
  238. mess ;
  239. mess 'ABS(erreur relative) sur EPSFRR, EPSFTT ou EPSFZZ > ' ERMAX ;
  240. mess EREPSFRR EREPSFTT EREPSFZZ ;
  241. mess ;
  242. finsi ;
  243. P_ER = prog ERSIGMA EREPSMA EREPSFMA ;
  244. ERMA = maxi P_ER ;
  245. si (ERMA > ERMAX) ;
  246. ERRE 5 ;
  247. finsi ;
  248.  
  249. fin ;
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales