Télécharger mistral_D3r.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : mistral_D3r.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test mistral_D3r.dgibi: Jeux de donnees *
  6. * --------------------------------------- *
  7. * *
  8. opti echo 0 ;
  9. opti dime 3 mode tridim elem cu20 ;
  10. * ajout de option epsilon lineaire pour la precision des test!
  11. OPTION epsilon lineaire;
  12.  
  13. *
  14. *******************************************************
  15. * TEST DE VALIDATION *
  16. * ------------------ *
  17. * *
  18. * MODELE MISTRAL *
  19. * DILATATION THERMIQUE, ELASTICITE ET CROISSANCE *
  20. * *
  21. * MAILLAGE : *
  22. * SECTEUR DE TUBE CYLINDRIQUE *
  23. * *
  24. * CHARGEMENT : *
  25. * CONTRAINTE AXIALE, *
  26. * TEMPERATURE ET FLUX NEUTRONIQUE *
  27. *******************************************************
  28. *
  29. * Geometrie
  30. *
  31. * ------------------------------------------------------
  32. RI = 49.5E-3 ; RE = 50.5E-3 ; H = 0.010 ;
  33. TETA = 30. ; NMAILT = 2 ;
  34. * ------------------------------------------------------
  35. RM = (RI+RE)/2. ;
  36. P11 = COS(TETA) ; P12 = SIN(TETA) ; P13 = 0. ;
  37. P21 = (-1.)*(SIN(TETA)) ; P22 = COS(TETA) ; P23 = 0. ;
  38. P31 = 0. ; P32 = 0. ; P33 = 1. ;
  39. *
  40. * Maillage
  41. *
  42. PIB = RI 0. 0. ; PEB = RE 0. 0. ;
  43. PIH = RI 0. H ; PEH = RE 0. H ;
  44. LB = droi 2 PIB PEB ;
  45. LE = droi 1 PEB PEH ;
  46. LH = droi 2 PEH PIH ;
  47. LI = droi 1 PIH PIB ;
  48. PLR0Z = dall LB LE LH LI plan ;
  49. *
  50. POMB = RM 0. 0. ; POMH = RM 0. H ;
  51. PMB = PLR0Z poin proc POMB ;
  52. PMH = PLR0Z poin proc POMH ;
  53. *
  54. * trac PLR0Z ;
  55. *
  56. * ------------------
  57. CRITELIM = 1.E-5 ;
  58. * ------------------
  59. PAXB = 0. 0. 0. ; PAXH = 0. 0. H ;
  60. EPROU = PLR0Z volu NMAILT rota TETA PAXB PAXH ;
  61. *
  62. PLR1Z = face 2 EPROU ;
  63. VECT1 = P21 P22 P23 ;
  64. FACE3 = face 3 EPROU ;
  65. POMB1 = (RM*P11) (RM*P12) 0. ;
  66. PMB1 = EPROU poin proc POMB1 ;
  67. POMH1 = (RM*P11) (RM*P12) H ;
  68. PMH1 = EPROU poin proc POMH1 ;
  69. PLRT0 = EPROU poin plan PIB PEB PMB1 CRITELIM ;
  70. PLRTHH = EPROU poin plan PIH PEH PMH1 CRITELIM ;
  71. PLRTH = FACE3 elem appu stri PLRTHH ;
  72. *
  73. * trac EPROU ;
  74. *
  75. * Modele et materiau
  76. *
  77. MOD3 = mode EPROU mecanique elastique orthotrope
  78. viscoplastique mistral ;
  79. * ------------------------------------------------------------
  80. SENSIP1 = -2 ; SENSIP2 = -3 ; ICBASE = 0 ;
  81. fichier = '/u/castem/divers/mimatD3r_par' ;
  82. PDILT E1 E2 E3 NU12 NU23 NU13 MU12 MU23 MU13
  83. PNBRE PCOHI PECOU PEDIR PRVCE PECRX PDVDI PCROI PINCR
  84. = @mistpar fichier SENSIP1 SENSIP2 ;
  85. * ------------------------------------------------------------
  86. MAT3 = mate MOD3 'YG1 ' E1 'YG2 ' E2 'YG3 ' E3
  87. 'NU12' NU12 'NU23' NU23 'NU13' NU13
  88. 'G12 ' MU12 'G23 ' MU23 'G13 ' MU13
  89. 'ALP1' 0. 'ALP2' 0. 'ALP3' 0.
  90. 'DILT' PDILT 'NBRE' PNBRE 'COHI' PCOHI 'ACOU' PECOU 'EDIR' PEDIR
  91. 'RVCE' PRVCE 'ECRX' PECRX 'DVDI' PDVDI 'CROI' PCROI 'INCR' PINCR
  92. 'SIP1' SENSIP1 'SIP2' SENSIP2 'IBAS' ICBASE
  93. 'RADIAL' PAXB PAXH ;
  94. *
  95. * Conditions aux limites
  96. *
  97. * CLORT = bloq ortho PAXB PAXH EPROU ;
  98. CL0 = bloq uy PLR0Z ;
  99. CL1 = rela depl dire VECT1 PLR1Z ;
  100. CLB = bloq uz PLRT0 ;
  101. CLH = rela ense uz PLRTH ;
  102. *
  103. CL = CL0 et CL1 et CLB et CLH ;
  104. *
  105. * Chargement
  106. *
  107. * -------------------------------------------------------
  108. T1 = 1.E8 ;
  109. TEMPSCAL = prog 0. 0.01 0.02 0.05 0.1 0.2
  110. 0.3 0.4 0.5 0.7 1. ;
  111. TT0 = 300. ; TT1 = 600. ;
  112. PHI0 = 1.E18 ;
  113. SZ0 = 0. ; SZ1 = 100.E6 ;
  114. * -------------------------------------------------------
  115. *
  116. TEMPS = prog 0. T1 ;
  117. TEMPSCAL = T1*TEMPSCAL ;
  118. *
  119. TT = manu chpo EPROU 1 'T' 1. ;
  120. EVTT = evol manu TEMPS (prog TT0 TT1) ;
  121. CHTT = char 'T' TT EVTT ;
  122. *
  123. PHI = manu chpo EPROU 1 'FI' 1. ;
  124. EVFI = evol manu TEMPS (prog PHI0 PHI0) ;
  125. CHFI = char 'FI' PHI EVFI ;
  126. *
  127. PRESH = pres mass MOD3 (-1.) PLRTH ;
  128. EVSZ = evol manu TEMPS (prog SZ0 SZ1) ;
  129. CHSZ = char meca PRESH EVSZ ;
  130. *
  131. CHA = CHTT et CHFI et CHSZ ;
  132. *
  133. * Valeurs initiales
  134. *
  135. VINT0 = zero MOD3 'VARINTER' ;
  136. *
  137. * Calcul
  138. *
  139. TAB = TABLE ;
  140. TAB.'VARIABLES_INTERNES' = TABLE ;
  141. TAB.'BLOCAGES_MECANIQUES' = CL ;
  142. TAB.'CARACTERISTIQUES' = MAT3 ;
  143. TAB.'MODELE' = MOD3 ;
  144. TAB.'CHARGEMENT' = CHA ;
  145. TAB.'VARIABLES_INTERNES' . 0 = VINT0 ;
  146. * TAB.'GRANDS_DEPLACEMENTS' = VRAI ;
  147. TAB.'TEMPS_CALCULES' = TEMPSCAL ;
  148. PASAPAS TAB ;
  149. *
  150. * Traitement des resultats
  151. *
  152. TEM = TAB.'TEMPS' ;
  153. SIG = TAB.'CONTRAINTES' ;
  154. DEP = TAB.'DEPLACEMENTS' ;
  155. VI = TAB.'VARIABLES_INTERNES' ;
  156. NT = dime TEMPSCAL-1 ;
  157. * ---------------
  158. ERMAX = 0.005 ;
  159. * ---------------
  160. T = TEM.NT ;
  161. SIGT = SIG.NT ;
  162. SIGT_PO = chang chpo MOD3 SIGT ;
  163. SIGXX = extr SIGT_PO SMXX PMH1 ;
  164. SIGYY = extr SIGT_PO SMYY PMH1 ;
  165. SIGZZ = extr SIGT_PO SMZZ PMH1 ;
  166. SIGXY = extr SIGT_PO SMXY PMH1 ;
  167. SIGXZ = extr SIGT_PO SMXZ PMH1 ;
  168. SIGYZ = extr SIGT_PO SMYZ PMH1 ;
  169. SIGRR = ((P11*P11)*SIGXX)+((P12*P12)*SIGYY)
  170. +(2.*(P11*P12)*SIGXY) ;
  171. SIGTT = ((P21*P21)*SIGXX)+((P22*P22)*SIGYY)
  172. +(2.*(P21*P22)*SIGXY) ;
  173. SIGRT = ((P11*P21)*SIGXX)+((P12*P22)*SIGYY)
  174. +(((P11*P22)+(P12*P21))*SIGXY) ;
  175. SIGRZ = ((P11*P33)*SIGXZ)+((P12*P33)*SIGYZ) ;
  176. SIGTZ = ((P21*P33)*SIGXZ)+((P22*P33)*SIGYZ) ;
  177. *
  178. DEPT = DEP.NT ;
  179. *
  180. UXT = extr DEPT UX PMH1 ;
  181. UYT = extr DEPT UY PMH1 ;
  182. URT = (UXT*(COS(TETA)))+(UYT*(SIN(TETA))) ;
  183. UTT = (UXT*(-1.)*(SIN(TETA)))+(UYT*(COS(TETA))) ;
  184. EPST = URT/RM ;
  185. *
  186. EPSIT = epsi DEPT MOD3 ;
  187. EPSIT_PO = chang chpo MOD3 EPSIT ;
  188. EPSXX = extr EPSIT_PO EPXX PMH1 ;
  189. EPSYY = extr EPSIT_PO EPYY PMH1 ;
  190. EPSZZ = extr EPSIT_PO EPZZ PMH1 ;
  191. EPSXY = (extr EPSIT_PO GAXY PMH1)/2. ;
  192. EPSXZ = (extr EPSIT_PO GAXZ PMH1)/2. ;
  193. EPSYZ = (extr EPSIT_PO GAYZ PMH1)/2. ;
  194. EPSRR = ((P11*P11)*EPSXX)+((P12*P12)*EPSYY)
  195. +(2.*(P11*P12)*EPSXY) ;
  196. EPSTT = ((P21*P21)*EPSXX)+((P22*P22)*EPSYY)
  197. +(2.*(P21*P22)*EPSXY) ;
  198. EPSRT = ((P11*P21)*EPSXX)+((P12*P22)*EPSYY)
  199. +(((P11*P22)+(P12*P21))*EPSXY) ;
  200. EPSRZ = ((P11*P33)*EPSXZ)+((P12*P33)*EPSYZ) ;
  201. EPSTZ = ((P21*P33)*EPSXZ)+((P22*P33)*EPSYZ) ;
  202. *
  203. VIT = VI.NT ;
  204. VIT_PO = chang chpo MOD3 VIT ;
  205. EPSTHRR = extr VIT_PO ETH1 PMH1 ;
  206. EPSTHTT = extr VIT_PO ETH2 PMH1 ;
  207. EPSTHZZ = extr VIT_PO ETH3 PMH1 ;
  208. EPSTHRZ = extr VIT_PO ETH4 PMH1 ;
  209. EPSTHRT = extr VIT_PO ETH5 PMH1 ;
  210. EPSTHTZ = extr VIT_PO ETH6 PMH1 ;
  211. EPSCRR = extr VIT_PO ECR1 PMH1 ;
  212. EPSCTT = extr VIT_PO ECR2 PMH1 ;
  213. EPSCZZ = extr VIT_PO ECR3 PMH1 ;
  214. EPSCRT = extr VIT_PO ECR4 PMH1 ;
  215. EPSCRZ = extr VIT_PO ECR5 PMH1 ;
  216. EPSCTZ = extr VIT_PO ECR6 PMH1 ;
  217. *
  218. mess ;
  219. mess 'T : ' T ;
  220. mess ;
  221. mess 'SIGRR SIGTT SIGZZ : ' SIGRR SIGTT SIGZZ ;
  222. mess 'SIGRT SIGRZ SIGTZ : ' SIGRT SIGRZ SIGTZ ;
  223. mess ;
  224. mess 'UR EPST UT : ' URT EPST UTT ;
  225. mess ;
  226. mess 'EPSRR EPSTT EPSZZ : ' EPSRR EPSTT EPSZZ ;
  227. mess 'EPSRT EPSRZ EPSTZ : ' EPSRT EPSRZ EPSTZ ;
  228. mess ;
  229. mess 'EPSTHRR EPSTHTT EPSTHZZ :' EPSTHRR EPSTHTT EPSTHZZ ;
  230. mess 'EPSTHRT EPSTHRZ EPSTHTZ :' EPSTHRT EPSTHRZ EPSTHTZ ;
  231. mess ;
  232. mess 'EPSCRR EPSCTT EPSCZZ : ' EPSCRR EPSCTT EPSCZZ ;
  233. mess 'EPSCRT EPSCRZ EPSCTZ : ' EPSCRT EPSCRZ EPSCTZ ;
  234. mess ;
  235. *
  236. * SIGT_XX = exco SIGT 'SMXX' ;
  237. * trac SIGT_XX MOD3 ;
  238. * SIGT_YY = exco SIGT 'SMYY' ;
  239. * trac SIGT_YY MOD3 ;
  240. * SIGT_ZZ = exco SIGT 'SMZZ' ;
  241. * trac SIGT_ZZ MOD3 ;
  242. * EPST_XX = exco EPSIT 'EPXX' ;
  243. * trac EPST_XX MOD3 ;
  244. * EPST_YY = exco EPSIT 'EPYY' ;
  245. * trac EPST_YY MOD3 ;
  246. * EPST_ZZ = exco EPSIT 'EPZZ' ;
  247. * trac EPST_ZZ MOD3 ;
  248. *
  249. * ------------------------------------------------------------
  250. YOUNGZ = 1.E11 ;
  251. POISZR = 0.2 ; POISZT = 0.4 ;
  252. * ------------------------------------------------------------
  253. EPSTHRR0 = (2.E-5)*(TT1-TT0) ;
  254. EPSTHTT0 = (1.E-5)*(TT1-TT0) ;
  255. EPSTHZZ0 = (5.E-6)*(TT1-TT0) ;
  256. EPSEZZ0 = (SZ1-SZ0)/YOUNGZ ;
  257. EPSERR0 = (-1.)*POISZR*EPSEZZ0 ;
  258. EPSETT0 = (-1.)*POISZT*EPSEZZ0 ;
  259. FITC0 = 1.E18 ;
  260. T00 = (FITC0/PHI0)**0.5 ;
  261. T01 = (T1+(FITC0/PHI0))**0.5 ;
  262. EPSCRR0 = (-1.5E-15)*(PHI0**0.5)*(T01-T00) ;
  263. EPSCTT0 = (-0.5E-15)*(PHI0**0.5)*(T01-T00) ;
  264. EPSCZZ0 = (2.E-15)*(PHI0**0.5)*(T01-T00) ;
  265. EPSRR0 = EPSTHRR0+EPSERR0+EPSCRR0 ;
  266. EPSTT0 = EPSTHTT0+EPSETT0+EPSCTT0 ;
  267. EPSZZ0 = EPSTHZZ0+EPSEZZ0+EPSCZZ0 ;
  268. *
  269. EREPSRR = (EPSRR/EPSRR0) - 1. ;
  270. EREPSTT = (EPSTT/EPSTT0) - 1. ;
  271. EREPSZZ = (EPSZZ/EPSZZ0) - 1. ;
  272. P_ER = prog EREPSRR EREPSTT EREPSZZ ;
  273. EREPSMA = maxi P_ER 'ABS' ;
  274. *
  275. EREPSTRR = (EPSTHRR/EPSTHRR0) - 1. ;
  276. EREPSTTT = (EPSTHTT/EPSTHTT0) - 1. ;
  277. EREPSTZZ = (EPSTHZZ/EPSTHZZ0) - 1. ;
  278. P_ER = prog EREPSTRR EREPSTTT EREPSTZZ ;
  279. EREPSTMA = maxi P_ER 'ABS' ;
  280. *
  281. EREPSCRR = (EPSCRR/EPSCRR0) - 1. ;
  282. EREPSCTT = (EPSCTT/EPSCTT0) - 1. ;
  283. EREPSCZZ = (EPSCZZ/EPSCZZ0) - 1. ;
  284. P_ER = prog EREPSCRR EREPSCTT EREPSCZZ ;
  285. EREPSCMA = maxi P_ER 'ABS' ;
  286. *
  287. si (EREPSMA > ERMAX) ;
  288. mess ;
  289. mess 'ABS(erreur rel.) sur EPSRR, EPSTT ou EPSZZ > ' ERMAX ;
  290. mess EREPSRR EREPSTT EREPSZZ ;
  291. finsi ;
  292. si (EREPSTMA > ERMAX) ;
  293. mess ;
  294. mess 'ABS(erreur rel.) sur EPSTHRR, EPSTHTT ou EPSTHZZ > ' ERMAX ;
  295. mess EREPSTRR EREPSTTT EREPSTZZ ;
  296. finsi ;
  297. si (EREPSCMA > ERMAX) ;
  298. mess ;
  299. mess 'ABS(erreur rel.) sur EPSCRR, EPSCTT ou EPSCZZ > ' ERMAX ;
  300. mess EREPSCRR EREPSCTT EREPSCZZ ;
  301. mess ;
  302. finsi ;
  303. P_ER = prog EREPSMA EREPSTMA EREPSCMA ;
  304. ERMA = maxi P_ER ;
  305. si (ERMA > ERMAX) ;
  306. ERRE 5 ;
  307. finsi ;
  308.  
  309. fin ;
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales