Télécharger metallurgie_10.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : metallurgie_10.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *__________________________________________________________________*
  6. * TEST METALLURGIE_10 *
  7. * *
  8. * CALCUL DES PROPORTIONS DE PHASE METALLURGIQUE *
  9. * *
  10. * *
  11. * Le modele metallurgique est code en ESOPE (Cast3m) *
  12. * *
  13. *__________________________________________________________________*
  14. * *
  15. * Vitesse de refroidissement : 4 C/s *
  16. * - Transformation (type Leblond) de l'autenite *
  17. * en ferrite seulement *
  18. * - La valeur calculee de la proportion d'AUSTENITE est *
  19. * comparée avec la valeur analytique *
  20. *__________________________________________________________________*
  21. *
  22. 'OPTI' 'TRAC' PSC 'EPTR' 10 ;
  23. IDESS = VRAI ;
  24.  
  25. OPTI DIME 2 ELEM 'TRI3';
  26.  
  27. P1 = 0. 0. ;
  28. P2 = 1. 0. ;
  29. P3 = 0. 1. ;
  30.  
  31. MAILT = MANU 'TRI3' P1 P2 P3;
  32.  
  33. LISTPHA = MOTS 'AUST' 'FERR' ;
  34. LISTREAC = MOTS 'AUST' ;
  35. LISTPROD = MOTS 'FERR' ;
  36. LISTTYPE = MOTS 'LEBL' ;
  37. NOMCONS = '16MND5';
  38.  
  39. MODCP1 = MODE MAILT 'METALLURGIE' 'PHASES' LISTPHA
  40. 'REACTIFS' LISTREAC
  41. 'PRODUITS' LISTPROD
  42. 'TYPE' LISTTYPE
  43. 'CONS' NOMCONS ;
  44.  
  45. TINI = 735. ;
  46. TFIN = 730. ;
  47.  
  48. PEQ1 = 'EVOL' 'MANU' 'T' (PROG 625 630 730 735)
  49. 'PEQ' (PROG 0 1 1 0) ;
  50.  
  51. F1 = 'EVOL' 'MANU' 'TPOI' (PROG -8.5 -6.2 -4.7 -4.6 0 1.D-6)
  52. 'F' (PROG 0.001 0.13 1.5 1.5 1.5 0) ;
  53.  
  54. TAU1 = 5. ;
  55.  
  56. *Declaration de la vitesse de refroidissement : en Degres/s
  57. DT_vit = -4. ;
  58.  
  59. F1L = 'IPOL' DT_vit F1 ;
  60.  
  61. *Calcul de la duree du refroidissement :
  62. DUREE = -1. * (TINI - TFIN) / DT_vit ;
  63.  
  64. *Declaration du Temps initial :
  65. TEMPINI = 1.D0 ;
  66. *Calcul du Temps final :
  67. TEMPFIN = TEMPINI + DUREE ;
  68. *Calcul du pas de temps en fonction de la vitesse de refroidissement :
  69. DTPS = -10 / DT_vit ;
  70.  
  71. LTCAL ='PROG' TEMPINI 'PAS' DTPS TEMPFIN ;
  72. T = TINI + (DT_vit * (LTCAL - TEMPINI)) ;
  73.  
  74. ALPHA = 1. ;
  75. *Initialisation de CHE1 : proportions de phases initiales :
  76. PROP = 'PROG' ALPHA ;
  77. CTYP = 'CHAI' 'VARIABLES_INTERNES' ;
  78. CHE1 ='MANU' 'CHML' MODCP1 'AUST' ('EXTR' PROP 1)
  79. 'FERR' 0.
  80. 'TYPE' CTYP 'NOEUD' ;
  81.  
  82. nbpas = (DIME LTCAL) - 1;
  83. REPE CTEMP nbpas;
  84.  
  85. * On recupere le temps debut de pas et le temps fin de pas :
  86. temp0 = EXTR LTCAL &CTEMP ;
  87. temp1 = EXTR LTCAL (&CTEMP + 1);
  88. CHETPS0 = 'MANU' 'CHML' MAILT 'TEMP' temp0 ;
  89. CHETPS1 = 'MANU' 'CHML' MAILT 'TEMP' temp1 ;
  90. * On calcule la temperature debut de pas et la temperature fin de pas :
  91. T0 = EXTR T &CTEMP ;
  92. T1 = EXTR T (&CTEMP + 1) ;
  93. CHT0 = 'MANU' 'CHML' MAILT 'T' T0 ;
  94. CHT1 = 'MANU' 'CHML' MAILT 'T' T1 ;
  95.  
  96. * On determine les differents parametres materiaux :
  97. PEQ11L = 'IPOL' T0 PEQ1 ;
  98. PEQ12L = 'IPOL' T1 PEQ1 ;
  99.  
  100. * On definit le Materiaux debut de pas et le materiaux fin de pas :
  101. MATCP1 = 'MATE' MODCP1 'PEQ1' PEQ11L 'TAU1' TAU1 'F1' F1L;
  102. MATCP2 = 'MATE' MODCP1 'PEQ1' PEQ12L 'TAU1' TAU1 'F1' F1L;
  103.  
  104.  
  105. CHE1 = COMP MODCP1 (CHE1 'ET' CHETPS0 'ET' CHT0 'ET' MATCP1 ) ( CHETPS1 'ET' CHT1 'ET' MATCP2 ) ;
  106.  
  107. * Extraction pour tracer :
  108. Pi ='EXCO' CHE1 AUST 'AUST';
  109. PiEvol = 'EXTR' Pi AUST 1 1 1;
  110. PROP = PROP 'ET' PiEvol ;
  111.  
  112. FIN CTEMP;
  113.  
  114. *Evolution calculee :
  115. EVO = 'EVOL' 'NOIR' 'MANU' 'TEMP' LTCAL 'PROP' PROP;
  116.  
  117. *Evolution analytique :
  118. *PANALY = ( F1 * (TEMPFIN - LTCAL) + (TAU1 * (1 - EXP( -1 * F1 * (LTCAL - TEMPINI) / TAU1 ) )) ) / ( F1 * (TEMPFIN - LTCAL) ) ;
  119. PANALY = EXP( -1 * F1L * (LTCAL - TEMPINI) / TAU1 ) ;
  120. PANALY = (F1L * (TEMPFIN - LTCAL)) + (TAU1 * (1 - PANALY )) ;
  121. PANALY = PANALY / ( F1L * (TEMPFIN - TEMPINI) ) ;
  122. EVOANA = 'EVOL' 'VERT' 'MANU' 'TEMP' LTCAL 'AUST' PANALY;
  123.  
  124. *Erreur absolue entre analytique et calculee :
  125. ERRABS = 'ABS' (PANALY '-' PROP) ;
  126. EVOERR = 'EVOL' 'ROUG' 'MANU' 'TEMP' LTCAL 'ERREUR' ERRABS ;
  127.  
  128. 'SI' IDESS ;
  129.  
  130. TL = TABL ;
  131. TL . 1 = 'TIRR' ;
  132. TL . 2 = 'MARQ ROND NOLI' ;
  133. TL . 'TITRE' = TABL ;
  134. TL . 'TITRE' . 1 = 'Evolution analytique' ;
  135. TL . 'TITRE' . 2 = 'Evolution calculee' ;
  136. DESS ( EVOANA 'ET' EVO ) 'GRIL' 'TIRC' 'GRIS'
  137. 'LEGE' TL
  138. 'TITR' 'LEBLOND - Refroidissement acier 16MND5 -10 deg/s' ;
  139.  
  140. TL = TABL ;
  141. TL . 1 = 'TIRR' ;
  142. TL . 'TITRE' = TABL ;
  143. TL . 'TITRE' . 1 = 'Erreur';
  144. DESS EVOERR 'GRIL' 'TIRC' 'GRIS'
  145. 'LEGE' TL
  146. 'TITR' 'LEBLOND - Refroidissement acier 16MND5 -10 deg/s' ;
  147.  
  148. 'FINSI' ;
  149.  
  150. *Emission d'une erreur GIBIANE si l'erreur analytique - cast3m est trop grande :
  151. Diff1 = 'MAXI' ERRABS;
  152. Tol1 = 1.D-2; COMM 'Valeur fixee en 2018 par Thibault LINDECKER';
  153.  
  154. MESS (CHAI ' Erreur : ' Diff1 ' | Tolerence : ' Tol1);
  155. SI (Diff1 >EG Tol1);
  156. MESS 'Erreur dans le calcul de la proportion d AUSTENITE';
  157. ERRE 5;
  158. FINS;
  159.  
  160. fin;
  161.  
  162.  
  163.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales