Télécharger metallurgie_07.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : metallurgie_07.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *__________________________________________________________________*
  5. * TEST METALLURGIE_07 *
  6. * *
  7. * CALCUL DES PROPORTIONS DE PHASE METALLURGIQUE *
  8. * CALCUL DE LA DEFORMATION THERMIQUE METALLURGIQUE *
  9. * TEMPERATURE IMPOSEE DURANT TOUT LE CALCUL *
  10. * *
  11. * Un modele THERMO-METALLURGIQUE + MECANIQUE est cree *
  12. * en 2D Axisymetrique *
  13. * *
  14. * Utilisation de PASAPAS et de procedures utilisateur : *
  15. * - Procedure PARATHER : + Mise a jour du materiaux THERMIQUE *
  16. * avec la proportion de phase. *
  17. * + Mise a jour du chargement 'TPOI' *
  18. * representant dT/dt *
  19. * necessaire pour instancier les *
  20. * caractéristiques métallurgiques *
  21. * *
  22. * - Procedure REEV_THE : Mise a jour des proportions de phase *
  23. * pour le modele de MELANGE *
  24. * *
  25. * Le modele metallurgique contient 5 phases ayant des cinetiques *
  26. * de transformation differentes *
  27. * - Metal de Base (MB) *
  28. * - Austenite *
  29. * - Martensite *
  30. * - Bainite *
  31. * - Ferrite *
  32. *__________________________________________________________________*
  33. * MAILLAGE : *
  34. * - Eprouvette cylindrique de hauteur 100mm et de rayon 12,5mm *
  35. * P4 _____ P3 *
  36. * | | ^ *
  37. * | | | *
  38. * | | | *
  39. * | | | h0 Y *
  40. * | | | ^ *
  41. * | | | | *
  42. * P1 _____ P2 v o --> X *
  43. * *
  44. * <-----> r0 *
  45. * Origine du repere : P1 *
  46. * *
  47. * CHARGEMENT : *
  48. * - Rampe de temperature lineaire de 20°C a 900°C a 5°C/s *
  49. * - Maintient a 900°C durant 60s *
  50. * - Rampe de temperature lineaire de 900°C a 20°C a -10°C/s *
  51. * *
  52. * CL : *
  53. * - Blocage de la temperature (imposee partout) *
  54. * - Blocage 'UZ' de la ligne reliant P1 et P2 *
  55. * - Blocage 'UR' de la ligne reliant P1 et P4 *
  56. *__________________________________________________________________*
  57.  
  58. 'OPTI' 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA4' ;
  59. 'OPTI' 'TRAC' PSC 'EPTR' 10 ;
  60.  
  61. ************************************************************************
  62. * Parametrage du Jeu de Donnees
  63. ************************************************************************
  64. * Parametrage MAILLAGE
  65. h0 = 100.; 'COMM' 'hauteur du cylindre' ;
  66. r0 = 12.5; 'COMM' 'rayon du cylindre' ;
  67.  
  68. * Parametrage THERMIQUE
  69. TMIN = 20.; 'COMM' 'Temperature ambiante' ;
  70. TMAX = 900.; 'COMM' 'Temperature du palier isotherme' ;
  71. VCHAUFF = 5.; 'COMM' 'vitesse de chauffage' ;
  72. VCHAUFF = 5.; 'COMM' 'Vitesse de chauffage [°C/s]';
  73. VREFROI = -10.; 'COMM' 'Vitesse de refroidissement [°C/s]';
  74. PALLIER = 60.; 'COMM' 'Duree du palier isotherme [s]' ;
  75.  
  76. * Parametrage METALLURGIE (Proportions initiales de phases)
  77. MB_ini = 0.1 ;
  78. MART_ini= 0.2 ;
  79. BAIN_ini= 0.3 ;
  80. FERR_ini= 0.4 ;
  81. AUST_ini= 0.0 ;
  82.  
  83. * Parametrage DISCRETISATION
  84. dens0 = 10.0 ; 'COMM' 'densite du maillage' ;
  85. DT = 0.25 ; 'COMM' 'pas de temps pour le calcul';
  86.  
  87. ************************************************************************
  88. * Pour faire des beaux DESSINS
  89. ************************************************************************
  90. * LISTMOTS contenant les couleurs
  91. LESCOUL = 'MOTS' 'VIOL' 'VERT' 'CYAN' 'BRIQ' 'BOUT' 'JAUN' 'OLIV'
  92. 'ORAN' 'ROUG' 'BLEU' 'BRUN' 'CARA' 'GRIS' 'NOIR' ;
  93. NBCOUL = 'DIME' LESCOUL ;
  94.  
  95. * LISTMOTS contenant les marques dans DESS
  96. LESMARQ = 'MOTS' 'CROI' 'PLUS' 'MOIN' 'BARR' 'ETOI' 'CARR'
  97. 'LOSA' 'ROND' 'TRID' 'TRIU' 'TRIL' 'TRIR';
  98. NBMARQ = 'DIME' LESMARQ ;
  99. ************************************************************************
  100.  
  101. ************************************************************************
  102. * Debut de la procedure PARATHER
  103. ************************************************************************
  104. 'DEBP' PARATHER PRECED*'TABLE' TPS1*'FLOTTANT';
  105. ************************************************************************
  106. * PROCEDURE PARATHER :
  107. * DESCRIPTION :
  108. * -------------
  109. * Cette procedure permet de modifier le materiaux avant l'appel a
  110. * VARI 'NUAG' dans TRANSNON.
  111. * - Les composantes K, C et RHO sont une moyenne arithmethique
  112. * ponderee par la fraction de phase des Ki, Ci et RHOi
  113. * L'indice ETAB.'MAT_TOT' est remplace
  114. * Cette procedure permet de modifier le chargement 'TPOI' avant
  115. * l'appel a VARI 'NUAG' dans TRANSNON.
  116. * L'indice ETAB . 'CHARGEMENT' est remplace
  117. *
  118. * ENTREES :
  119. * ---------
  120. * - PRECED : TABLE complete de PASAPAS
  121. * - TPS1 : Temps courant
  122. *
  123. * SORTIES :
  124. * ---------
  125. * - Aucune
  126. *
  127. ************************************************************************
  128.  
  129. *I - Mise a jour du materiau Thermique avec les proportions de phases
  130. ETAB = PRECED.'WTABLE';
  131. MOD1 = ETAB.'MOD_TOT' ;
  132. T1 = ETAB.'THER_COURANT' ;
  133. T1 ='CHAN' 'CHAM' T1 MOD1 'RIGIDITE' 'CARACTERISTIQUES';
  134.  
  135. MAT_ORIG= ETAB.'MAT_TOT';
  136. COMPORIG='EXTR' MAT_ORIG 'COMP';
  137. NBCOMP ='DIME' COMPORIG;
  138.  
  139. MAT0 ='VIDE' 'MCHAML';
  140. REPE SURCOM NBCOMP;
  141. II = &SURCOM;
  142. LACOMP ='EXTR' COMPORIG II;
  143. SI(('NEG' LACOMP 'K') 'ET' ('NEG' LACOMP 'RHO') 'ET' ('NEG' LACOMP 'C'));
  144. MAT0 = MAT0 'ET' ('EXCO' MAT_ORIG LACOMP LACOMP);
  145. FINS;
  146. FIN SURCOM;
  147.  
  148. * Instanciation du materiaux de chaque phase
  149. MATPHAS ='REDU' MOD1 MATPHAS ;
  150. MAT2 ='VARI' 'NUAG' MOD1 MATPHAS T1 'RIGIDITE';
  151.  
  152. * On fait ensuite la moyenne qui nous interesse (Ponderation par la proportion de phase)
  153. MCHPHA = PRECED.'ESTIMATION'.'PROPORTIONS_PHASES';
  154.  
  155. MCHPHA ='CHAN' 'CONS' MCHPHA 'THE1' ;
  156. MCHPHA ='REDU' MCHPHA ETAB.'MOD_COND' ;
  157. MCHPHA ='CHAN' 'RIGIDITE' MCHPHA MOD1 ;
  158. MCHPHA ='CHAN' 'TYPE' MCHPHA 'CARACTERISTIQUES' ;
  159.  
  160. MOPROP1 ='EXTR' MCHPHA 'COMP' ;
  161. MOMAT2 ='EXTR' MAT2 'COMP' ;
  162.  
  163. MCHK ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  164. MCHR ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  165. MCHC ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  166.  
  167. * Boucle sur les phases
  168. NBPHA ='DIME' MOPROP1;
  169. REPE SURP NBPHA;
  170. IP = &SURP ;
  171. PROPIP='EXCO' MCHPHA ('EXTR' MOPROP1 IP) 'SCAL' ; 'COMM' 'Prop de la phase numero IP' ;
  172.  
  173. * Moyenne sur les K
  174. IB = IP;
  175. RATIO ='EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  176. MCHK =(PROPIP * RATIO) + MCHK ;
  177.  
  178. * Moyenne sur les RHO
  179. IB = IB + NBPHA;
  180. RATIO2='EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  181. MCHR =(PROPIP * RATIO2) + MCHR ;
  182.  
  183. * Moyenne sur les CP
  184. IB = IB + NBPHA;
  185. RATIO3='EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  186. MCHC =(PROPIP * RATIO3) + MCHC ;
  187. FIN SURP;
  188.  
  189. MCHK ='CHAN' 'COMP' 'K' MCHK ;
  190. MCHR ='CHAN' 'COMP' 'RHO' MCHR ;
  191. MCHC ='CHAN' 'COMP' 'C' MCHC ;
  192.  
  193. * REMPLACEMENT DU MATERIAUX
  194. ETAB.'MAT_TOT'= MCHK 'ET' MCHR 'ET' MCHC 'ET' MAT0 ;
  195.  
  196.  
  197. *II - Mise a jour du Chargement TPOI avec les champs de temperatures initiaux et finaux
  198. * 'TPOI' represente simplement la derivee de la temperature avec le temps, cette
  199. * donnee n'est pas connue de Cast3M nativement, on la crée sous forme d'un CHARGEMENT
  200.  
  201. * On recupere le modele complet : Conduction + Convection + Metallurgie :
  202. MODTOT = ETAB.'MOD_TOT';
  203.  
  204. ETAB = PRECED . 'WTABLE';
  205. CHARG = ETAB . 'CHARGEMENT';
  206.  
  207. * On modifie uniquement le chargement TPOI, on conserve les autres chargements.
  208. CHAR_T ='ENLE' CHARG 'TPOI';
  209.  
  210. * On recupere tempINI et tempFIN
  211. NPA ='DIME' PRECED.'TEMPS' ;
  212. temps0 = PRECED.'TEMPS'.(NPA - 1);
  213. temps1 = TPS1 ;
  214.  
  215. * On recupere T_INI et T_FIN
  216. T_CHPO1='EXCO' PRECED.'CONTINUATION'.'TEMPERATURES' 'T' 'SCAL' ;
  217. T_CHPO2='EXCO' ETAB .'THER_COURANT' 'T' 'SCAL' ;
  218. T_CHAM1='CHAN' 'CHAM' T_CHPO1 MODTOT 'RIGIDITE';
  219. T_CHAM2='CHAN' 'CHAM' T_CHPO2 MODTOT 'RIGIDITE';
  220.  
  221. * Dependance temporelle du chargement TPOI :
  222. LTPSCHA='PROG' temps0 temps1 ;
  223. LTPOI ='PROG' 1.D0 1.D0 ;
  224. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  225.  
  226. * Dependance spatiale du chargement TPOI :
  227. TPOIN ='EXCO' ( ( T_CHPO2 - T_CHPO1 ) / (temps1 - temps0) ) 'SCAL' 'TPOI' ;
  228.  
  229. * Le chargement TPOI :
  230. CHAR_TPO='CHAR' 'TPOI' TPOIN EVT ;
  231.  
  232. * Le chargement complet (TPOI + le reste) :
  233. CHAR_TOT= CHAR_T 'ET' CHAR_TPO ;
  234.  
  235. * Mise a jour du chargement :
  236. ETAB.'CHARGEMENT' = CHAR_TOT ;
  237.  
  238. 'FINP';
  239. ************************************************************************
  240. * Fin de la procedure PARATHER
  241. ************************************************************************
  242.  
  243.  
  244. ************************************************************************
  245. * Debut de la procedure PARATHER
  246. ************************************************************************
  247. 'DEBP' REEV_THE PRECED*'TABLE' N1*'ENTIER';
  248. ************************************************************************
  249. * PROCEDURE REEV_THE :
  250. * DESCRIPTION :
  251. * -------------
  252. * Cette procedure met a jour le materiau pour le modele de MELANGE
  253. * - Passage des proportions de phases de la METALLURGIE a la MECANIQUE
  254. * - AMELIORATION POSSIBLE : Que ce soit fait automatiquement...
  255. * + Changement du CONSTITUANT automatiquement
  256. * + Projection si demandé (TAB1.'PROJECTION' = VRAI ;)
  257. *
  258. * ENTREES :
  259. * ---------
  260. * - PRECED : TABLE complete de PASAPAS
  261. * - N1 : Numero d'appel (initialisation ou apres THERMIQUE)
  262. *
  263. * SORTIES :
  264. * ---------
  265. * - Aucune
  266. *
  267. ************************************************************************
  268. WTAB = PRECED.'WTABLE';
  269. MODAUTR ='ENLE' WTAB.'MODELE' 'FORM' 'MELANGE';
  270. MATAUTR ='REDU' WTAB.'CARACTERISTIQUES' MODAUTR;
  271.  
  272. MCHPHA = PRECED.'ESTIMATION'.'PROPORTIONS_PHASES';
  273.  
  274. * Passage des PROPORTIONS_PHASES sur le modele de MELANGE (Sans PROJECTION)
  275. MCHPMEL ='CHAN' 'CONS' MCHPHA 'MEL1';
  276. MCHPMEL ='CHAN' MCHPMEL 'TYPE' 'CARACTERISTIQUES';
  277.  
  278. * REMPLACEMENT DU MATERIAUX DANS WTAB
  279. WTAB.'CARACTERISTIQUES'=MCHPMEL 'ET' MATAUTR ;
  280. 'FINP';
  281. ************************************************************************
  282. * Fin de la procedure REEV_THE
  283. ************************************************************************
  284.  
  285.  
  286. ************************************************************************
  287. *MAILLAGE
  288. ************************************************************************
  289. axes = @repere (0. 0.) ('PROG' 25. 25.) 'ROUG' ;
  290. P1 ='POIN' 0. 0. ;
  291. P2 ='POIN' r0 0. ;
  292. P3 ='POIN' r0 h0 ;
  293. P4 ='POIN' 0. h0 ;
  294.  
  295. L1 ='DROI' P1 P2 'DINI' dens0 'DFIN' dens0 ;
  296. L2 ='DROI' P2 P3 'DINI' dens0 'DFIN' dens0 ;
  297. L3 ='DROI' P3 P4 'DINI' dens0 'DFIN' dens0 ;
  298. L4 ='DROI' P4 P1 'DINI' dens0 'DFIN' dens0 ;
  299.  
  300. MAILT ='DALL' L1 L2 L3 L4 ;
  301. 'TRAC' 'QUAL' MAILT;
  302.  
  303. ************************************************************************
  304. * Definition des MODELES
  305. ************************************************************************
  306. MODTHE ='MODE' MAILT 'THERMIQUE' 'CONDUCTION' 'QUA4' 'CONS' 'THE1' ;
  307.  
  308. TPHASE = TABL;
  309. * LISTMOTS utiles pour la metallurgie
  310. * 1- Metal de base 100% initialement
  311. * 2- Martensite
  312. * 3- Bainite
  313. * 4- Ferrite
  314. * 5- Austenite
  315. TPHASE.'PHASES' ='MOTS' 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' ;
  316. TPHASE.'REACTIFS'='MOTS' 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' 'AUST' 'AUST' ;
  317. TPHASE.'PRODUITS'='MOTS' 'AUST' 'AUST' 'AUST' 'AUST' 'MART' 'BAIN' 'FERR' ;
  318. TPHASE.'TYPE' ='MOTS' 'LEBL' 'LEBL' 'LEBL' 'LEBL' 'KOIS' 'LEBL' 'LEBL' ;
  319.  
  320. NBCOMP ='DIME' TPHASE.'PHASES';
  321.  
  322. MODCP1 ='MODE' MAILT 'METALLURGIE' 'PHASES' TPHASE.'PHASES'
  323. 'REACTIFS' TPHASE.'REACTIFS'
  324. 'PRODUITS' TPHASE.'PRODUITS'
  325. 'TYPE' TPHASE.'TYPE'
  326. 'CONS' 'MET1';
  327.  
  328. MOMMB ='MODE' MAILT 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC1' 'PHASE' 'MB' ;
  329. MOMMART ='MODE' MAILT 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC2' 'PHASE' 'MART';
  330. MOMBAIN ='MODE' MAILT 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC3' 'PHASE' 'BAIN';
  331. MOMFERR ='MODE' MAILT 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC4' 'PHASE' 'FERR';
  332. MOMAUST ='MODE' MAILT 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' 'CONS' 'MEC5' 'PHASE' 'AUST';
  333.  
  334. MODMEC = MOMMB 'ET' MOMMART 'ET' MOMBAIN 'ET' MOMFERR 'ET' MOMAUST ;
  335. MOMELMEC='MODE' MAILT 'MELANGE' 'PARALLELE' MODMEC 'CONS' 'MEL1' ;
  336.  
  337. MODTOT = MODTHE 'ET' MODCP1 'ET' MODMEC 'ET' MOMELMEC ;
  338.  
  339. *******************************************************************************
  340. * Definition des materiaux des phases pures (THERMIQUE & MECANIQUE)
  341. *******************************************************************************
  342. MCHK ='VIDE' 'MCHAML' ; 'COMM' 'Conductivite thermique' ;
  343. MCHRHO ='VIDE' 'MCHAML' ; 'COMM' 'Masse volumique' ;
  344. MCHC ='VIDE' 'MCHAML' ; 'COMM' 'Capacite calorifique' ;
  345. CTYP ='MOT' 'CARACTERISTIQUES';
  346.  
  347. ********************
  348. * 1- Metal de base *
  349. ********************
  350. IPAHS = 1;
  351. ICOUL = @MOD IPAHS NBCOUL;
  352. COUL1 ='EXTR' LESCOUL ICOUL;
  353. CPHAS ='CHAI' 'K' IPAHS;
  354. LTKP1 ='PROG' 0 55 113 162 191 243 293 392
  355. 457 507 605 655 756 795 840 856
  356. 900 950 1000 1101 1202 1303 1400 1500
  357. 1502 1600 ;
  358. LKP1 ='PROG' 0.0376 0.0389 0.0401 0.0407 0.0407 0.0404 0.0398 0.038
  359. 0.0364 0.0352 0.0329 0.0317 0.0291 0.0273 0.0252 0.0248
  360. 0.0253 0.0261 0.027 0.0283 0.0299 0.0314 0.0328 0.0343
  361. 0.05 0.05;
  362. EVKP1 ='EVOL' COUL1 'MANU' 'T' LTKP1 CPHAS LKP1;
  363. MCHK = MCHK 'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  364.  
  365. CPHAS ='CHAI' 'R' IPAHS;
  366. LTRHOP1='PROG' 0 20 100 200 300 400
  367. 500 600 700 800 900 1440
  368. 2500 ;
  369. LRHOP1 ='PROG' 7852.D-9 7852.D-9 7815.D-9 7778.D-9 7741.D-9 7705.D-9
  370. 7668.D-9 7633.D-9 7595.D-9 7562.D-9 7527.D-9 7345.D-9
  371. 7011.D-9 ;
  372. EVRHOP1='EVOL' COUL1 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  373. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  374.  
  375. CPHAS ='CHAI' 'C' IPAHS;
  376. LTCP1 ='PROG' 21 50 150 200 250 300 350 450 550
  377. 650 700 750 850 1000 1200 1300 1400 1440
  378. 1465 1490 1540 1590 1615 1640 2500 ;
  379. LCP1 ='PROG' 460.5 485.6 519.1 531.6 556.7 573.5 598.6 661.4 749.3
  380. 845.6 1431.6 950.2 900 845.6 800 815 840 850
  381. 1210 1840 2470 1840 1210 840 707 ;
  382. EVCP1 ='EVOL' COUL1 'MANU' 'T' LTCP1 CPHAS LCP1;
  383. MCHC = MCHC 'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  384.  
  385. CPHAS ='CHAI' 'ALP' IPAHS;
  386. LTALP1 ='PROG' 20. 'PAS' 1. 700. ;
  387. LALP1 = 16.1D-6 * (LTALP1 ** 0) ;
  388. EVALP1 ='EVOL' COUL1 'MANU' 'T' LTALP1 'ALPH' LALP1;
  389.  
  390. *****************
  391. * 2- Martensite *
  392. *****************
  393. IPAHS = 2;
  394. ICOUL = @MOD IPAHS NBCOUL;
  395. COUL1 ='EXTR' LESCOUL ICOUL;
  396. CPHAS ='CHAI' 'K' IPAHS;
  397. EVKP1 ='EVOL' COUL1 'MANU' 'T' LTKP1 CPHAS LKP1;
  398. MCHK = MCHK 'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  399.  
  400. CPHAS ='CHAI' 'R' IPAHS;
  401. EVRHOP1='EVOL' COUL1 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  402. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  403.  
  404. CPHAS ='CHAI' 'C' IPAHS;
  405. EVCP1 ='EVOL' COUL1 'MANU' 'T' LTCP1 CPHAS LCP1;
  406. MCHC = MCHC 'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  407.  
  408. CPHAS ='CHAI' 'ALP' IPAHS;
  409. LALP2 = LALP1 ;
  410. EVALP2 ='EVOL' COUL1 'MANU' 'T' LTALP1 'ALPH' LALP1;
  411.  
  412. **************
  413. * 3- Bainite *
  414. **************
  415. IPAHS = 3;
  416. ICOUL = @MOD IPAHS NBCOUL;
  417. COUL1 ='EXTR' LESCOUL ICOUL;
  418. CPHAS ='CHAI' 'K' IPAHS;
  419. EVKP1 ='EVOL' COUL1 'MANU' 'T' LTKP1 CPHAS LKP1;
  420. MCHK = MCHK 'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  421.  
  422. CPHAS ='CHAI' 'R' IPAHS;
  423. EVRHOP1='EVOL' COUL1 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  424. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  425.  
  426. CPHAS ='CHAI' 'C' IPAHS;
  427. EVCP1 ='EVOL' COUL1 'MANU' 'T' LTCP1 CPHAS LCP1;
  428. MCHC = MCHC 'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  429.  
  430. CPHAS ='CHAI' 'ALP' IPAHS;
  431. EVALP3 ='EVOL' COUL1 'MANU' 'T' LTALP1 'ALPH' LALP1;
  432.  
  433. **************
  434. * 4- Ferrite *
  435. **************
  436. IPAHS = 4;
  437. ICOUL = @MOD IPAHS NBCOUL;
  438. COUL1 ='EXTR' LESCOUL ICOUL;
  439. CPHAS ='CHAI' 'K' IPAHS;
  440. EVKP1 ='EVOL' COUL1 'MANU' 'T' LTKP1 CPHAS LKP1;
  441. MCHK = MCHK 'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  442.  
  443. CPHAS ='CHAI' 'R' IPAHS;
  444. EVRHOP1='EVOL' COUL1 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  445. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  446.  
  447. CPHAS ='CHAI' 'C' IPAHS;
  448. EVCP1 ='EVOL' COUL1 'MANU' 'T' LTCP1 CPHAS LCP1;
  449. MCHC = MCHC 'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  450.  
  451. CPHAS ='CHAI' 'ALP' IPAHS;
  452. EVALP4 ='EVOL' COUL1 'MANU' 'T' LTALP1 'ALPH' LALP1;
  453.  
  454. ****************
  455. * 5- Austenite *
  456. ****************
  457. IPAHS = 5;
  458. ICOUL = @MOD IPAHS NBCOUL;
  459. COUL1 ='EXTR' LESCOUL ICOUL;
  460. CPHAS ='CHAI' 'K' IPAHS;
  461. LTKP5 ='PROG' 0 20 100 200 400 600 800 856
  462. 900 1000 1200 1500 1502 1600 ;
  463. LKP5 ='PROG' 0.0121 0.0124 0.0136 0.015 0.018 0.021 0.0239 0.0248
  464. 0.0254 0.0269 0.0298 0.0343 0.05 0.05;
  465. EVKP5 ='EVOL' COUL1 'MANU' 'T' LTKP5 CPHAS LKP5;
  466. MCHK = MCHK 'ET' ('MANU' 'CHML' MODTHE CPHAS EVKP5 'TYPE' CTYP) ;
  467.  
  468. CPHAS ='CHAI' 'R' IPAHS;
  469. LTRHOP5='PROG' 0 20 100 200 300 400
  470. 500 600 700 800 900 1440
  471. 2500 ;
  472. LRHOP5 ='PROG' 7852.D-9 7841.D-9 7794.D-9 7736.D-9 7680.D-9 7624.D-9
  473. 7569.D-9 7514.D-9 7458.D-9 7408.D-9 7356.D-9 7087.D-9
  474. 6613.D-9 ;
  475. EVRHOP5='EVOL' COUL1 'MANU' 'T' LTRHOP5 CPHAS LRHOP5;
  476. MCHRHO = MCHRHO'ET' ('MANU' 'CHML' MODTHE CPHAS EVRHOP5 'TYPE' CTYP);
  477.  
  478.  
  479. CPHAS ='CHAI' 'C' IPAHS;
  480. LTCP5 ='PROG' 21 50 150 200 250 300 350 475 575 675 800
  481. 950 1000 1100 1200 1300 1400 1440 1465 1490 1540 1590
  482. 1615 1640 2500 ;
  483. LCP5 ='PROG' 460.5 485.6 519.1 531.6 556.7 573.5 598.6 652 671 685 715
  484. 742 750 774 795 815 840 850 1210 1840 2470 1840
  485. 1210 840 707 ;
  486. EVCP5 ='EVOL' COUL1 'MANU' 'T' LTCP5 CPHAS LCP5;
  487. MCHC = MCHC 'ET' ('MANU' 'CHML' MODTHE CPHAS EVCP5 'TYPE' CTYP) ;
  488.  
  489.  
  490. CPHAS ='CHAI' 'ALP' IPAHS;
  491. LTALP5 ='PROG' 600. 'PAS' 1. 1000. ;
  492. LALP5 = 22.6D-6 * (LTALP5 ** 0.) ;
  493. EVALP5 ='EVOL' COUL1 'MANU' 'T' LTALP5 'ALPH' LALP5;
  494.  
  495.  
  496. TDESS1 ='TABL' ;
  497. TDESS1 . 'TITRE' ='TABL' ;
  498. 'REPE' SURPHA NBCOMP;
  499. NOMP ='EXTR' TPHASE.'PHASES' &SURPHA;
  500. * TDESS1 . &SURPHA ='CHAI' 'MARQ ' LAMAR ' REGU';
  501. TDESS1 . 'TITRE' . &SURPHA = NOMP;
  502. 'FIN' SURPHA;
  503. EVALP = EVALP1 'ET' EVALP2 'ET' EVALP3 'ET' EVALP4 'ET' EVALP5 ;
  504. 'DESS' EVALP 'LEGE' TDESS1 'TITR' 'Evolution des APLHA de chaque phase en fonction de la temperature';
  505.  
  506. *******************************************************************************
  507. * Proprietes pour la metallurgie : DEBUT
  508. *******************************************************************************
  509. PROG_T ='PROG' 716. 802. ;
  510. PROG_TPO ='PROG' -1.D-6 0. ;
  511. PROG_PEQ ='PROG' 0. 1. ;
  512. PROG_F ='PROG' 0. 1. ;
  513. PROG_TAU ='PROG' 12. 0.5 ;
  514.  
  515. *1ere transformation : 'MB' --> 'AUST'
  516. PEQ1 ='EVOL' 'MANU' 'T' PROG_T 'PEQ1' PROG_PEQ ;
  517. F1 ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F1' PROG_F ;
  518. TAU1 ='EVOL' 'MANU' 'T' PROG_T 'TAU1' PROG_TAU ;
  519.  
  520. *2eme transformation : 'MART' --> 'AUST' parametres identiques a la premiere
  521. PEQ2 ='EVOL' 'MANU' 'T' PROG_T 'PEQ2' PROG_PEQ ;
  522. F2 ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F2' PROG_F ;
  523. TAU2 ='EVOL' 'MANU' 'T' PROG_T 'TAU2' PROG_TAU ;
  524.  
  525. *3eme transformation : 'BAIN' --> 'AUST' parametres identiques a la premiere
  526. PEQ3 ='EVOL' 'MANU' 'T' PROG_T 'PEQ3' PROG_PEQ ;
  527. F3 ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F3' PROG_F ;
  528. TAU3 ='EVOL' 'MANU' 'T' PROG_T 'TAU3' PROG_TAU ;
  529.  
  530. *4eme transformation : 'FERR' --> 'AUST' parametres identiques a la premiere
  531. PEQ4 ='EVOL' 'MANU' 'T' PROG_T 'PEQ4' PROG_PEQ ;
  532. F4 ='EVOL' 'MANU' 'TPOI'PROG_TPO 'F4' PROG_F ;
  533. TAU4 ='EVOL' 'MANU' 'T' PROG_T 'TAU4' PROG_TAU ;
  534.  
  535. *5eme transformation : 'AUST' --> 'MART'
  536. MS5 = 380. ;
  537. KM5 = 0.0247 ;
  538.  
  539. *6eme transformation : 'AUST' --> 'BAIN'
  540. PEQ6 ='EVOL' 'MANU' 'T' ('PROG' 375 380 405 600)
  541. 'PEQ6' ('PROG' 0. 1. 1. 0. );
  542. F6 ='EVOL' 'MANU' 'TPOI' ('PROG' -100. -80. -60. -50. -40. -30. -25. -20. -18. -15. -12. -10. -9. -5. -1. -0.05 0.D0 1.D-6)
  543. 'F6' ('PROG' 0.005 1.573 2.857 3.417 3.982 4.583 4.833 5.26 5.472 6.033 7.675 11.4 18.45 17.1 0.328 0.00238 0.00238 0. ) ;
  544. TAU6 ='EVOL' 'MANU' 'T' ('PROG' 375 380)
  545. 'TAU6' ('PROG' 1.D6 20 );
  546.  
  547. *7eme transformation : 'AUST' --> 'FERR'
  548. PEQ7 ='EVOL' 'MANU' 'T' ('PROG' 625 630 730 735 )
  549. 'PEQ7' ('PROG' 0 1 1 0 );
  550. F7 ='EVOL' 'MANU' 'TPOI' ('PROG' -8.5 -6.2 -4.7 0. 1.D-6)
  551. 'F7' ('PROG' 0.001 0.13 1.5 1.5 0. );
  552. TAU7 ='EVOL' 'MANU' 'T' ('PROG' 625 630 )
  553. 'TAU7' ('PROG' 1.D6 5 );
  554. ************************************************************************
  555. * Definition de la metallurgie : FIN
  556. ************************************************************************
  557.  
  558. ************************************************************************
  559. * GRANDEURS initiales
  560. ************************************************************************
  561. *TEMPERATURE
  562. CHPTINI = MANU 'CHPO' MAILT 1 'T' TMIN 'NATU' 'DIFFUS' ;
  563.  
  564. CTYP ='CHAI' 'VARIABLES_INTERNES';
  565. CHPINI ='MANU' 'CHML' MODCP1 'MB ' MB_ini 'MART' MART_ini 'BAIN' BAIN_ini 'FERR' FERR_ini 'AUST' AUST_ini 'TYPE' CTYP 'NOEUD' ;
  566.  
  567. ************************************************************************
  568. * CARACTERISTIQUES MATERIAUX
  569. ************************************************************************
  570. MATPHAS = MCHK 'ET' MCHRHO 'ET' MCHC ;
  571. MATTHE ='MATE' MODTHE 'K' 0.D0 'RHO' 0.D0 'C' 0.D0 ;
  572.  
  573. MAMMB ='MATE' MOMMB 'YOUN' 180.E9 'NU' 0.28 'SIGY' 280.E6 'ALPH' EVALP1 'TREF' 20. 'TALP' 20. ;
  574. MAMMART ='MATE' MOMMART 'YOUN' 190.E9 'NU' 0.29 'SIGY' 290.E6 'ALPH' EVALP2 'TREF' 20. 'TALP' 20. ;
  575. MAMBAIN ='MATE' MOMBAIN 'YOUN' 200.E9 'NU' 0.30 'SIGY' 200.E6 'ALPH' EVALP3 'TREF' 20. 'TALP' 20. ;
  576. MAMFERR ='MATE' MOMFERR 'YOUN' 210.E9 'NU' 0.31 'SIGY' 210.E6 'ALPH' EVALP4 'TREF' 20. 'TALP' 20. ;
  577. MAMAUST ='MATE' MOMAUST 'YOUN' 220.E9 'NU' 0.32 'SIGY' 220.E6 'ALPH' EVALP5 'TREF' 450. 'TALP' 20. ;
  578.  
  579. MATMEC = MAMMB 'ET' MAMMART 'ET' MAMBAIN 'ET' MAMFERR 'ET' MAMAUST ;
  580.  
  581. MATCP1 ='MATE' MODCP1 'PEQ1' PEQ1 'TAU1' TAU1 'F1' F1
  582. 'PEQ2' PEQ2 'TAU2' TAU2 'F2' F2
  583. 'PEQ3' PEQ3 'TAU3' TAU3 'F3' F3
  584. 'PEQ4' PEQ4 'TAU4' TAU4 'F4' F4
  585. 'MS5' MS5 'KM5' KM5
  586. 'PEQ6' PEQ6 'TAU6' TAU6 'F6' F6
  587. 'PEQ7' PEQ7 'TAU7' TAU7 'F7' F7 ;
  588.  
  589. * Definition du materiau pour le modele de melange mecanique (les proportions de phase)
  590. MAMELMEC ='CHAN' 'CONS' CHPINI 'MEL1';
  591. MAMELMEC ='CHAN' MAMELMEC 'TYPE' 'CARACTERISTIQUES';
  592. MATTOT = MATTHE 'ET' MATCP1 'ET' MAMELMEC 'ET' MATMEC ;
  593.  
  594. ************************************************************************
  595. * CONDITIONS aux LIMITES
  596. ************************************************************************
  597. * TEMPERATURE IMPOSE PARTOUT
  598. CLTHE = BLOQ 'T' MAILT ;
  599. TIMPO = DEPI 1. CLTHE ;
  600.  
  601. * CHARGEMENT THERMIQUE 'T'
  602. TPS0 = 0.D0;
  603. TPS1 = TPS0 + ((TMAX-TMIN) / VCHAUFF);
  604. TPS2 = TPS1 + PALLIER ;
  605. TPS3 = TPS2 + ((TMIN-TMAX) / VREFROI);
  606.  
  607. LTPSCHA ='PROG' TPS0 TPS1 TPS2 TPS3 ;
  608. LTCHA ='PROG' TMIN TMIN TMAX TMIN ;
  609. EVT ='EVOL' 'MANU' LTPSCHA LTCHA ;
  610. CHAR1 ='CHAR' 'TIMP' TIMPO EVT ;
  611. 'DESS' EVT 'TITR' 'Chargement en temperature imposee au cours du temps';
  612.  
  613. * CHARGEMENT 'TPOI' (mis a jour dans la procedure UTILISATEUR PARATHER)
  614. LTPSCHA ='PROG' TPS0 TPS3;
  615. LTPOI ='PROG' 0. 0. ;
  616. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  617. TPOIN ='MANU' 'CHPO' MAILT 1 'TPOI' 1.D0 ; 'COMM' 'Le chargement vaut 1 * chargement(temps) partout !';
  618. CHAR2 ='CHAR' 'TPOI' TPOIN EVT ;
  619.  
  620. * BLOCAGE MECANIQUE
  621. CLMEC1 = BLOQ 'UZ' L1 ;
  622. CLMEC2 = BLOQ 'UR' L4 ;
  623. CLMEC = CLMEC1 'ET' CLMEC2;
  624.  
  625. *CHARGEMENT Total
  626. CHARTOT = CHAR1 'ET' CHAR2 ;
  627.  
  628. ************************************************************************
  629. * DEFINITION DE LA TABLE PASAPAS
  630. ************************************************************************
  631. LTCAL1 ='PROG' TPS0 'PAS' DT TPS2 ;
  632.  
  633. TPASAP ='TABL' ;
  634. TPASAP.'MODELE' = MODTOT ;
  635. TPASAP.'CARACTERISTIQUES' = MATTOT ;
  636. TPASAP.'BLOCAGES_THERMIQUES' = CLTHE ;
  637. TPASAP.'BLOCAGES_MECANIQUES' = CLMEC ;
  638. TPASAP.'CHARGEMENT' = CHARTOT ;
  639. TPASAP.'TEMPS_CALCULES' = LTCAL1 ;
  640.  
  641. TPASAP.'TEMPS' ='TABL' ;
  642. TPASAP.'TEMPS' . 0 ='EXTR' LTCAL1 1 ;
  643. TPASAP.'TEMPERATURES' ='TABL' ;
  644. TPASAP.'TEMPERATURES' . 0 = CHPTINI ;
  645. TPASAP.'PROPORTIONS_PHASES' ='TABL' ;
  646. TPASAP.'PROPORTIONS_PHASES' . 0 = CHPINI ;
  647.  
  648. * Indices divers
  649. TPASAP.'PROCESSEURS' ='MOT' 'MONO_PROCESSEUR';
  650. *TPASAP.'FTOL' = 1.D-5 ;
  651.  
  652. * PROCEDURES Utilisateurs
  653. TPASAP.'PROCEDURE_PARATHER' = VRAI ; 'COMM' 'MELANGE THERMIQUE a la MANO && Fabrication du CHARGEMENT TPOI' ;
  654. TPASAP.'PROCEDURE_REEV_THE' = VRAI ; 'COMM' 'Mise a jour des props de phases pour le MELANGE en MECANIQUE' ;
  655.  
  656. PASAPAS TPASAP ;
  657.  
  658. * Reprise de calcul pour verifier la dilatation THERMIQUE
  659. LTCAL1 ='PROG' TPS2 'PAS' DT TPS3 ;
  660. TPASAP.'TEMPS_CALCULES' = LTCAL1 ;
  661. PASAPAS TPASAP ;
  662.  
  663. ************************************************************************
  664. * POST-TRAITEMENT
  665. ************************************************************************
  666. fic_sauv ='CHAI' 'COUPLAGE_THERO-METALLURGIQUE-MECANIQUE.sauv' ;
  667. 'OPTI' 'SAUV' fic_sauv ;
  668. 'SAUV' ;
  669.  
  670. * Initialisations pour le POST-TRAITEMENT
  671. LISCOM ='EXTR' CHPINI 'COMP';
  672. NBCOMP ='DIME' LISCOM ;
  673. TABPHA ='TABL';
  674. 'REPE' SURPHA NBCOMP;
  675. TABPHA . &SURPHA ='VIDE' 'LISTREEL';
  676. 'FIN' SURPHA;
  677.  
  678. LTPS ='VIDE' 'LISTREEL';
  679. LVMI ='VIDE' 'LISTREEL';
  680. LUZ1 ='VIDE' 'LISTREEL';
  681. LT1 ='VIDE' 'LISTREEL';
  682. 'REPE' BLOC0 ('DIME' TPASAP.'TEMPS') ;
  683. I = &BLOC0 - 1 ;
  684. CHT = TPASAP.'TEMPERATURES' . I;
  685. CHPHA= TPASAP.'PROPORTIONS_PHASES' . I;
  686. CHSIG= TPASAP.'CONTRAINTES' . I;
  687. DEP1 = TPASAP.'DEPLACEMENTS' . I;
  688.  
  689. LTPS = LTPS 'ET' (TPASAP.'TEMPS' . I) ;
  690. VMI1 ='VMIS' MODTOT CHSIG ;
  691. LVMI = LVMI 'ET' ('EXTR' VMI1 'SCAL' 1 1 1) ;
  692. LUZ1 = LUZ1 'ET' ('EXTR' DEP1 'UZ' P3 ) ;
  693. LT1 = LT1 'ET' ('EXTR' CHT 'T' P3 ) ;
  694.  
  695. * Extraction pour chaque phase de la valeur courante
  696. 'REPE' SURPHA NBCOMP;
  697. NOMP ='EXTR' TPHASE.'PHASES' &SURPHA;
  698. TABPHA. &SURPHA = TABPHA. &SURPHA 'ET' ('EXTR' CHPHA NOMP 1 1 1);
  699. 'FIN' SURPHA;
  700. 'FIN' BLOC0 ;
  701.  
  702. *Reconstitution des EVOL
  703. EVTOTa ='VIDE' 'EVOLUTIO';
  704. EVOPHAS='VIDE' 'EVOLUTIO';
  705. CPPHAS ='CHAN' 'CHPO' CHPHA MODTOT;
  706.  
  707. 'REPE' SURPHA NBCOMP;
  708. NOMP ='EXTR' TPHASE.'PHASES' &SURPHA;
  709. ICOUL = @MOD &SURPHA NBCOUL;
  710. COUL1 ='EXTR' LESCOUL ICOUL;
  711. Lpi = TABPHA. &SURPHA ;
  712. TABPHA . &SURPHA ='EVOL' COUL1 'MANU' 'TEMP' LTPS NOMP Lpi;
  713. EVTOTa = EVTOTa 'ET' TABPHA . &SURPHA ;
  714. IMARQ = @MOD &SURPHA NBMARQ;
  715. LAMAR ='EXTR' IMARQ LESMARQ;
  716. EVOPHAS = EVOPHAS 'ET' ('EVOL' COUL1 'CHPO' CPPHAS NOMP L2);
  717. 'FIN' SURPHA;
  718.  
  719. EVTOTa = 'CHAN' 'NOMORD' EVTOTa 'PROP';
  720. 'DESS' EVTOTa 'LEGE' TDESS1 'TITR' ('CHAI' 'Evolution des Props en fonction du temps' ) 'YBOR' 0. 1. ;
  721.  
  722. EVOPHAS = 'CHAN' 'NOMORD' EVOPHAS 'PROP';
  723. 'DESS' EVOPHAS 'LEGE' TDESS1 'TITR' ('CHAI' 'Props a Temps final' ) 'YBOR' 0. 1. ;
  724.  
  725. ICOUL = ICOUL + 1 ;
  726. ICOUL = @MOD ICOUL NBCOUL ;
  727. COUL1 ='EXTR' LESCOUL ICOUL;
  728. EVOVMI ='EVOL' COUL1 'MANU' 'TEMP' LTPS 'VMIS' LVMI;
  729. 'DESS' EVOVMI 'TITR' ('CHAI' 'Evolution de VMIS en fonction du temps' ) ;
  730.  
  731. ICOUL = ICOUL + 1 ;
  732. ICOUL = @MOD ICOUL NBCOUL ;
  733. COUL1 ='EXTR' LESCOUL ICOUL;
  734. EVOUZ1 ='EVOL' COUL1 'MANU' 'TEMP' LTPS 'UZP3' LUZ1;
  735. 'DESS' EVOUZ1 'TITR' ('CHAI' 'Evolution de UZ au point P3 en fonction du temps' ) 'AXES' ;
  736.  
  737. ICOUL = ICOUL + 1 ;
  738. ICOUL = @MOD ICOUL NBCOUL ;
  739. COUL1 ='EXTR' LESCOUL ICOUL;
  740. EVOUZ2 ='EVOL' COUL1 'MANU' 'T' LT1 'EPZ' (LUZ1 / h0 * 100);
  741. 'DESS' EVOUZ2 'TITR' ('CHAI' 'Evolution de EPZ (%) au point P3 en fonction de la temperature' ) 'XBOR' 0. 1000. 'AXES';
  742.  
  743. 'TEMP' 'IMPR' 'PROC';
  744. 'TEMP' 'IMPR' 'BOUC';
  745.  
  746. FIN ;
  747.  
  748.  
  749.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales