Télécharger metallurgie_06.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : metallurgie_06.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *__________________________________________________________________*
  6. * TEST METALLURGIE_14 *
  7. * *
  8. * CALCUL DES PROPORTIONS DE PHASE METALLURGIQUE *
  9. * *
  10. * Un MODELE thermo-metallurgique est cree et l'essai JOMINY *
  11. * est simule en 2D Axisymétrique *
  12. * *
  13. * Utilisation de PASAPAS et d'une procedure utilisateur : *
  14. * - Procédure PARATHER : Mise a jour du matériaux THERMIQUE *
  15. * avec la proportion de phase. *
  16. * Mise a jour du chargement 'TPOI' *
  17. * *
  18. * Le modèle métallurgique contient 5 phases ayant des cinétiques *
  19. * de transformation différentes *
  20. * - Metal de Base (MB) *
  21. * - Austénite *
  22. * - Martensite *
  23. * - Bainite *
  24. * - Ferrite *
  25. *__________________________________________________________________*
  26. * MAILLAGE : *
  27. * - Eprouvette cylindrique de hauteur 100mm et de rayon 12,5mm *
  28. * P4 _____ P3 *
  29. * | J | ^ *
  30. * | O | | *
  31. * | M | | *
  32. * | I | | h0 Y *
  33. * | N | | ^ *
  34. * | Y | | | *
  35. * P1 _____ P2 v o --> X *
  36. * *
  37. * <-----> r0 *
  38. * Origine du repere : P1 *
  39. * *
  40. * CHARGEMENT : *
  41. * - Montee lineaire en temperature depuis 25°C à 900°C en 1200s *
  42. * - Maintient à 900°C jusqu'a 3000s *
  43. * - Refroidissement par convection par la face cylindrique *
  44. * inférieure jusqu'à 3600s *
  45. * *
  46. * CL : *
  47. * - Blocage de la temperature (T imposee jusqu'a 3000s) *
  48. * - Convection de 3000s à 3600s avec h=0,1 [W.mm-2.K-1] *
  49. *__________________________________________________________________*
  50. OPTI DIME 2 MODE AXIS ELEM QUA4 ;
  51.  
  52. 'OPTI' 'TRAC' PSC 'EPTR' 10 ;
  53.  
  54. TMAX = 900.;
  55. TMIN = 25. ;
  56. HCON = 0.1 ;
  57.  
  58. ************************************************************************
  59. * Pour faire des beaux DESSINS
  60. ************************************************************************
  61. * LISTMOTS contenant les couleurs
  62. LESCOUL = 'MOTS' 'VIOL' 'VERT' 'CYAN' 'BRIQ' 'BOUT' 'JAUN' 'OLIV'
  63. 'ORAN' 'ROUG' 'BLEU' 'BRUN' 'CARA' 'GRIS' 'NOIR' ;
  64. NBCOUL = 'DIME' LESCOUL;
  65.  
  66. * LISTMOTS contenant les marques dans DESS
  67. LESMARQ = 'MOTS' 'CROI' 'PLUS' 'MOIN' 'BARR' 'ETOI' 'CARR'
  68. 'LOSA' 'ROND' 'TRID' 'TRIU' 'TRIL' 'TRIR';
  69. NBMARQ = 'DIME' LESMARQ;
  70. ************************************************************************
  71.  
  72. ************************************************************************
  73. * Debut de la procedure PARATHER
  74. ************************************************************************
  75. 'DEBP' PARATHER PRECED*'TABLE' TPS1*'FLOTTANT';
  76. ************************************************************************
  77. * PROCEDURE PARATHER :
  78. * DESCRIPTION :
  79. * -------------
  80. * Cette procedure permet de modifier le materiaux avant l'appel a
  81. * VARI 'NUAG' dans TRANSNON.
  82. * - Les composantes K, C et RHO sont une moyenne arithméthique
  83. * pondérée par la fraction de phase des Ki, Ci et RHOi
  84. * L'indice ETAB.'MAT_TOT' est remplacé
  85. * Cette procedure permet de modifier le chargement 'TPOI' avant
  86. * l'appel a VARI 'NUAG' dans TRANSNON.
  87. * L'indice ETAB . 'CHARGEMENT' est remplacé
  88. *
  89. * ENTREES :
  90. * ---------
  91. * - PRECED : TABLE complete de PASAPAS
  92. * - TPS1 : Temps courant
  93. *
  94. * SORTIES :
  95. * ---------
  96. * - Aucune
  97. *
  98. ************************************************************************
  99.  
  100. *I - Mise a jour du materiau Thermique avec les proportions de phases
  101. ETAB = PRECED.'WTABLE';
  102. MOD1 = ETAB.'MOD_TOT' ;
  103. T1 = ETAB.'THER_COURANT' ;
  104. T1 ='CHAN' 'CHAM' T1 MOD1 'RIGIDITE' 'CARACTERISTIQUES';
  105.  
  106. MAT_ORIG= ETAB.'MAT_TOT';
  107. COMPORIG='EXTR' MAT_ORIG 'COMP';
  108. NBCOMP ='DIME' COMPORIG;
  109.  
  110. MAT0 ='VIDE' 'MCHAML';
  111. REPE SURCOM NBCOMP;
  112. II = &SURCOM;
  113. LACOMP ='EXTR' COMPORIG II;
  114. SI(('NEG' LACOMP 'K' ) 'ET'
  115. ('NEG' LACOMP 'RHO') 'ET'
  116. ('NEG' LACOMP 'C' ));
  117. MAT0 = MAT0 'ET' ('EXCO' LACOMP MAT_ORIG);
  118. FINS;
  119. FIN SURCOM;
  120.  
  121. * Instanciation du matériaux de chaque phase
  122. MATPHAS ='REDU' MOD1 MATPHAS ;
  123. MAT2 ='VARI' 'NUAG' MOD1 MATPHAS T1 'RIGIDITE';
  124.  
  125. * On fait ensuite la moyenne qui nous interesse (Ponderation par la
  126. * proportion de phase)
  127. NPA ='DIME' PRECED.'TEMPS';
  128. SI ('EXIS' PRECED.'PROPORTIONS_PHASES' NPA ) ;
  129. MCHPHA = PRECED.'PROPORTIONS_PHASES' . NPA ;
  130. SINO ;
  131. MCHPHA = PRECED.'PROPORTIONS_PHASES' .(NPA - 1);
  132. PRECED.'PROPORTIONS_PHASES' . NPA = MCHPHA ;
  133. FINS ;
  134.  
  135. MCHPHA = 'CHAN' 'CONS' MCHPHA 'MAT1' ;
  136. MCHPHA = 'REDU' MCHPHA ETAB.'MOD_COND' ;
  137. MCHPHA ='CHAN' 'RIGIDITE' MCHPHA MOD1 ;
  138. MCHPHA ='CHAN' 'TYPE' MCHPHA 'CARACTERISTIQUES' ;
  139.  
  140. MOPROP1='EXTR' MCHPHA 'COMP' ;
  141. MOMAT2 ='EXTR' MAT2 'COMP' ;
  142.  
  143. MCHK ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  144. MCHR ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  145. MCHC ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  146.  
  147. * Boucle sur les phases
  148. NBPHA = 'DIME' MOPROP1;
  149. REPE SURP NBPHA;
  150. IP = &SURP ;
  151. PROPIP ='EXCO' MCHPHA ('EXTR' MOPROP1 IP) 'SCAL' ; 'COMM' 'Prop de la phase numero IP' ;
  152.  
  153. * Moyenne sur les K
  154. IB = IP;
  155. RATIO = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  156. MCHK = (PROPIP * RATIO) + MCHK ;
  157.  
  158. * Moyenne sur les RHO
  159. IB = IB + NBPHA;
  160. RATIO2 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  161. MCHR = (PROPIP * RATIO2) + MCHR ;
  162.  
  163. * Moyenne sur les CP
  164. IB = IB + NBPHA;
  165. RATIO3 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  166. MCHC = (PROPIP * RATIO3) + MCHC ;
  167. FIN SURP;
  168.  
  169. MCHK ='CHAN' 'COMP' 'K' MCHK ;
  170. MCHR ='CHAN' 'COMP' 'RHO' MCHR ;
  171. MCHC ='CHAN' 'COMP' 'C' MCHC ;
  172.  
  173. * REMPLACEMENT DU MATERIAUX
  174. ETAB.'MAT_TOT' = MCHK 'ET' MCHR 'ET' MCHC 'ET' MAT0 ;
  175.  
  176.  
  177. *II - Mise a jour du Chargement TPOI avec les champs de temperatures initiaux et finaux
  178.  
  179. * On recupere le modele complet : Conduction + Convection + Metallurgie :
  180. MODTOT = ETAB.'MOD_TOT';
  181.  
  182. ETAB = PRECED . 'WTABLE';
  183. CHARG = ETAB . 'CHARGEMENT';
  184.  
  185. * On modifie uniquement le chargement TPOI, on conserve les autres chargements.
  186. CHAR_T = 'ENLE' CHARG 'TPOI';
  187.  
  188. * On recupere tempINI et tempFIN
  189. NPA ='DIME' PRECED.'TEMPS';
  190. temps0 = PRECED.'TEMPS'.(NPA - 1);
  191. temps1 = TPS1 ;
  192.  
  193. * On recupere T_INI et T_FIN
  194. T_CHPO1 ='EXCO' PRECED.'CONTINUATION'.'TEMPERATURES' 'T' 'SCAL' ;
  195. T_CHPO2 ='EXCO' ETAB .'THER_COURANT' 'T' 'SCAL' ;
  196. T_CHAM1 ='CHAN' 'CHAM' T_CHPO1 MODTOT 'RIGIDITE';
  197. T_CHAM2 ='CHAN' 'CHAM' T_CHPO2 MODTOT 'RIGIDITE';
  198.  
  199. * Dependance temporelle du chargement TPOI :
  200. LTPSCHA ='PROG' temps0 temps1 ;
  201. LTPOI ='PROG' 1.D0 1.D0 ;
  202. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  203.  
  204. * Dependance spatiale du chargement TPOI :
  205. TPOIN = 'EXCO' ( ( T_CHPO2 - T_CHPO1 ) / (temps1 - temps0) ) 'SCAL' 'TPOI' ;
  206.  
  207. * Le chargement TPOI :
  208. CHAR_TPO ='CHAR' 'TPOI' TPOIN EVT ;
  209.  
  210. * Le chargement complet (TPOI + le reste) :
  211. CHAR_TOT = CHAR_T 'ET' CHAR_TPO ;
  212.  
  213. * Mise a jour du chargement :
  214. ETAB . 'CHARGEMENT' = CHAR_TOT ;
  215.  
  216. 'FINP';
  217. ************************************************************************
  218. * Fin de la procedure PARATHER
  219. ************************************************************************
  220.  
  221. *MAILLAGE
  222. h0 = 100. ; COMM 'hauteur du cylindre' ;
  223. r0 = 12.5 ; COMM 'rayon du cylindre' ;
  224. dens0 = 1. ; COMM 'densité maillage' ;
  225.  
  226. axes = @repere (0. 0.) ('PROG' 25. 25.) 'ROUG' ;
  227. P1 = POIN 0. 0. ;
  228. P2 = POIN r0 0. ;
  229. P3 = POIN r0 h0 ;
  230. P4 = POIN 0. h0 ;
  231.  
  232. L1 = DROI P1 P2 'DINI' dens0 'DFIN' dens0 ;
  233. L2 = DROI P2 P3 'DINI' dens0 'DFIN' dens0 ;
  234. L3 = DROI P3 P4 'DINI' dens0 'DFIN' dens0 ;
  235. L4 = DROI P4 P1 'DINI' dens0 'DFIN' dens0 ;
  236.  
  237. MAILT = (DALL L1 L2 L3 L4) COUL 'BLEU' ;
  238. ELIM MAILT 1.e-3 ;
  239. CONTT = CONT MAILT ;
  240. PTBAS = CONTT POIN 'DROIT' P1 P2 1.e-3 ;
  241. SURFBAS = CONTT ELEM 'APPUYE' 'STRICTEMENT' PTBAS ;
  242.  
  243. *MODELE
  244. MODTHE = MODE MAILT 'THERMIQUE' 'CONDUCTION' 'QUA4' 'CONS' 'MAT1' ;
  245. MODCON = MODE SURFBAS 'THERMIQUE' 'CONVECTION' 'SEG2';
  246. MODTHERM = MODTHE 'ET' MODCON;
  247.  
  248. ************************************************************************
  249. * Definition de la metallurgie : DEBUT
  250. ************************************************************************
  251. * 1- Métal de base 100% initialement
  252. * 2- Martensite
  253. * 3- Bainite
  254. * 4- Ferrite
  255. * 5- Austénite
  256.  
  257. * Evolution des proprietes thermiques pour les phases pures
  258. MCHK = VIDE 'MCHAML';
  259. MCHRHO = VIDE 'MCHAML';
  260. MCHC = VIDE 'MCHAML';
  261. CTYP = MOT 'CARACTERISTIQUES';
  262. ********************
  263. * 1- Métal de base *
  264. ********************
  265. IPAHS = 1;
  266. CPHAS = CHAI 'K' IPAHS;
  267. LTKP1 = PROG 0 55 113 162 191 243 293 392
  268. 457 507 605 655 756 795 840 856
  269. 900 950 1000 1101 1202 1303 1400 1500
  270. 1502 1600 ;
  271. LKP1 = PROG 0.0376 0.0389 0.0401 0.0407 0.0407 0.0404 0.0398 0.038
  272. 0.0364 0.0352 0.0329 0.0317 0.0291 0.0273 0.0252 0.0248
  273. 0.0253 0.0261 0.027 0.0283 0.0299 0.0314 0.0328 0.0343
  274. 0.05 0.05;
  275. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  276. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  277.  
  278. CPHAS = CHAI 'R' IPAHS;
  279. LTRHOP1= PROG 0 20 100 200 300 400
  280. 500 600 700 800 900 1440
  281. 2500 ;
  282. LRHOP1 = PROG 7852.D-9 7852.D-9 7815.D-9 7778.D-9 7741.D-9 7705.D-9
  283. 7668.D-9 7633.D-9 7595.D-9 7562.D-9 7527.D-9 7345.D-9
  284. 7011.D-9 ;
  285. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  286. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  287.  
  288. CPHAS = CHAI 'C' IPAHS;
  289. LTCP1 = PROG 21 50 150 200 250 300 350 450 550
  290. 650 700 750 850 1000 1200 1300 1400 1440
  291. 1465 1490 1540 1590 1615 1640 2500 ;
  292. LCP1 = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 661.4 749.3
  293. 845.6 1431.6 950.2 900 845.6 800 815 840 850
  294. 1210 1840 2470 1840 1210 840 707 ;
  295. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  296. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  297.  
  298. *****************
  299. * 2- Martensite *
  300. *****************
  301. IPAHS = 2;
  302. CPHAS = CHAI 'K' IPAHS;
  303. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  304. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  305.  
  306. CPHAS = CHAI 'R' IPAHS;
  307. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  308. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  309.  
  310. CPHAS = CHAI 'C' IPAHS;
  311. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  312. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  313.  
  314. **************
  315. * 3- Bainite *
  316. **************
  317. IPAHS = 3;
  318. CPHAS = CHAI 'K' IPAHS;
  319. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  320. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  321.  
  322. CPHAS = CHAI 'R' IPAHS;
  323. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  324. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  325.  
  326. CPHAS = CHAI 'C' IPAHS;
  327. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  328. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  329.  
  330. **************
  331. * 4- Ferrite *
  332. **************
  333. IPAHS = 4;
  334. CPHAS = CHAI 'K' IPAHS;
  335. EVKP1 = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  336. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  337.  
  338. CPHAS = CHAI 'R' IPAHS;
  339. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  340. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  341.  
  342. CPHAS = CHAI 'C' IPAHS;
  343. EVCP1 = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  344. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  345.  
  346. ****************
  347. * 5- Austénite *
  348. ****************
  349. IPAHS = 5;
  350. CPHAS = CHAI 'K' IPAHS;
  351. LTKP5 = PROG 0 20 100 200 400 600 800 856
  352. 900 1000 1200 1500 1502 1600 ;
  353. LKP5 = PROG 0.0121 0.0124 0.0136 0.015 0.018 0.021 0.0239 0.0248
  354. 0.0254 0.0269 0.0298 0.0343 0.05 0.05;
  355. EVKP5 = EVOL 'MANU' 'T' LTKP5 CPHAS LKP5;
  356. MCHK = MCHK ET (MANU 'CHML' MODTHE CPHAS EVKP5 'TYPE' CTYP) ;
  357.  
  358. CPHAS = CHAI 'R' IPAHS;
  359. LTRHOP5= PROG 0 20 100 200 300 400
  360. 500 600 700 800 900 1440
  361. 2500 ;
  362. LRHOP5 = PROG 7852.D-9 7841.D-9 7794.D-9 7736.D-9 7680.D-9 7624.D-9
  363. 7569.D-9 7514.D-9 7458.D-9 7408.D-9 7356.D-9 7087.D-9
  364. 6613.D-9 ;
  365. EVRHOP5 = EVOL 'MANU' 'T' LTRHOP5 CPHAS LRHOP5;
  366. MCHRHO = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP5 'TYPE' CTYP);
  367.  
  368.  
  369. CPHAS = CHAI 'C' IPAHS;
  370. LTCP5 = PROG 21 50 150 200 250 300 350 475 575 675 800
  371. 950 1000 1100 1200 1300 1400 1440 1465 1490 1540 1590
  372. 1615 1640 2500 ;
  373. LCP5 = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 652 671 685 715
  374. 742 750 774 795 815 840 850 1210 1840 2470 1840
  375. 1210 840 707 ;
  376. EVCP5 = EVOL 'MANU' 'T' LTCP5 CPHAS LCP5;
  377. MCHC = MCHC ET (MANU 'CHML' MODTHE CPHAS EVCP5 'TYPE' CTYP) ;
  378.  
  379.  
  380. TPHASE = TABL;
  381. * Liste des transformations existantes dans un LISTENTIE
  382. TPHASE . 'PHASES' = MOTS 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' ;
  383. TPHASE . 'REACTIFS' = MOTS 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' 'AUST' 'AUST' ;
  384. TPHASE . 'PRODUITS' = MOTS 'AUST' 'AUST' 'AUST' 'AUST' 'MART' 'BAIN' 'FERR' ;
  385. TPHASE . 'TYPE' = MOTS 'LEBL' 'LEBL' 'LEBL' 'LEBL' 'KOIS' 'LEBL' 'LEBL' ;
  386.  
  387. MODCP1 = MODE MAILT 'METALLURGIE' 'PHASES' (TPHASE . 'PHASES')
  388. 'REACTIFS' (TPHASE . 'REACTIFS')
  389. 'PRODUITS' (TPHASE . 'PRODUITS')
  390. 'TYPE' (TPHASE . 'TYPE')
  391. 'QUA4' ;
  392.  
  393. PROG_T = 'PROG' 716. 802. ;
  394. PROG_TPO = 'PROG' -1.D-6 0. ;
  395. PROG_PEQ = 'PROG' 0. 1. ;
  396. PROG_F = 'PROG' 0. 1. ;
  397. PROG_TAU = 'PROG' 12. 0.5 ;
  398.  
  399. *1ere transformation :
  400. PEQ1 = EVOL 'MANU' 'T' PROG_T 'PEQ1' PROG_PEQ ;
  401. F1 = EVOL 'MANU' 'TPOI'PROG_TPO 'F1' PROG_F ;
  402. TAU1 = EVOL 'MANU' 'T' PROG_T 'TAU1' PROG_TAU ;
  403. *2eme transformation : parametres identiques a la premiere
  404. PEQ2 = EVOL 'MANU' 'T' PROG_T 'PEQ2' PROG_PEQ ;
  405. F2 = EVOL 'MANU' 'TPOI'PROG_TPO 'F2' PROG_F ;
  406. TAU2 = EVOL 'MANU' 'T' PROG_T 'TAU2' PROG_TAU ;
  407. *3eme transformation : parametres identiques a la premiere
  408. PEQ3 = EVOL 'MANU' 'T' PROG_T 'PEQ3' PROG_PEQ ;
  409. F3 = EVOL 'MANU' 'TPOI'PROG_TPO 'F3' PROG_F ;
  410. TAU3 = EVOL 'MANU' 'T' PROG_T 'TAU3' PROG_TAU ;
  411. *4eme transformation : parametres identiques a la premiere
  412. PEQ4 = EVOL 'MANU' 'T' PROG_T 'PEQ4' PROG_PEQ ;
  413. F4 = EVOL 'MANU' 'TPOI'PROG_TPO 'F4' PROG_F ;
  414. TAU4 = EVOL 'MANU' 'T' PROG_T 'TAU4' PROG_TAU ;
  415. *5eme transformation
  416. MS5 = 380. ;
  417. KM5 = 0.0247 ;
  418.  
  419. *6eme transformation
  420. PEQ6 = EVOL 'MANU' 'T' (PROG 375 380 405 600)
  421. 'PEQ6' (PROG 0. 1. 1. 0. );
  422.  
  423. F6 = 'EVOL' 'MANU' 'TPOI' (PROG -100. -80. -60. -50. -40. -30. -25. -20. -18. -15. -12. -10. -9. -5. -1. -0.05 0.D0 1.D-6)
  424. 'F6' (PROG 0.005 1.573 2.857 3.417 3.982 4.583 4.833 5.26 5.472 6.033 7.675 11.4 18.45 17.1 0.328 0.00238 0.00238 0.) ;
  425.  
  426. TAU6 = EVOL 'MANU' 'T' (PROG 375 380)
  427. 'TAU6' (PROG 1.D6 20 );
  428.  
  429. *7eme transformation
  430. PEQ7 = 'EVOL' 'MANU' 'T' (PROG 625 630 730 735 )
  431. 'PEQ7' (PROG 0 1 1 0 );
  432.  
  433. F7 = 'EVOL' 'MANU' 'TPOI' (PROG -8.5 -6.2 -4.7 0. 1.D-6)
  434. 'F7' (PROG 0.001 0.13 1.5 1.5 0. );
  435.  
  436. TAU7 = EVOL 'MANU' 'T' (PROG 625 630 )
  437. 'TAU7' (PROG 1.D6 5 );
  438.  
  439. MATCP1 = 'MATE' MODCP1 'PEQ1' PEQ1 'TAU1' TAU1 'F1' F1
  440. 'PEQ2' PEQ2 'TAU2' TAU2 'F2' F2
  441. 'PEQ3' PEQ3 'TAU3' TAU3 'F3' F3
  442. 'PEQ4' PEQ4 'TAU4' TAU4 'F4' F4
  443. 'MS5' MS5 'KM5' KM5
  444. 'PEQ6' PEQ6 'TAU6' TAU6 'F6' F6
  445. 'PEQ7' PEQ7 'TAU7' TAU7 'F7' F7;
  446.  
  447. ************************************************************************
  448. * Definition de la metallurgie : FIN
  449. ************************************************************************
  450.  
  451. MODTOT = MODTHE 'ET' MODCP1 'ET' MODCON ;
  452.  
  453. ************************************************************************
  454. * Phase 1 et 2 :
  455. * Rampe de temperature jusqu'à 900°C d'une durée de 20min
  456. * Palier isotherme à 900°C d'une durée de 30min
  457. ************************************************************************
  458.  
  459. *TEMPERATURE INITIALE
  460. CHPTINI = MANU 'CHPO' MAILT 1 'T' TMIN 'NATU' 'DIFFUS' ;
  461.  
  462. CTYP ='CHAI' 'VARIABLES_INTERNES';
  463. MCHPHA = MANU 'CHML' MODCP1 'MB ' 0.1 'MART' 0.2 'BAIN' 0.3
  464. 'FERR' 0.4 'AUST' 0.0
  465. 'TYPE' CTYP 'NOEUD' ;
  466.  
  467. *MATERIAUX
  468. MATPHAS = MCHK 'ET' MCHRHO 'ET' MCHC ;
  469. MATCONV ='MATE' MODCON 'H' 0.D0 ;
  470. MATCOND ='MATE' MODTHE 'K' 0.D0 'RHO' 0.D0 'C' 0.D0;
  471. MATTOT = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  472.  
  473.  
  474. ************************************************************************
  475. * Fabrication du diagramme TRC (Pour vérification de la mise en donnee)
  476. ************************************************************************
  477. * Calcul automatique de la liste des vitesses de refroidissement
  478. VIT1 = 250. ;
  479. VIT2 = 1. ;
  480. NBVI = 50 ;
  481. VLOG1 = 'LOG' VIT1;
  482. VLOG2 = 'LOG' VIT2;
  483.  
  484. PASLOG = (VLOG2 - VLOG1) / (NBVI - 1);
  485. LRELOG ='PROG' VLOG1 'PAS' PASLOG VLOG2;
  486. LISTVIT='EXP' LRELOG;
  487.  
  488. * Liste manuelle des vitesses de refroidissement
  489. LISTVIT = PROG 250. 50. 10. 7. 4. ;
  490. ************************************************************************
  491.  
  492. *CLs
  493. *TEMPERATURE IMPOSE EN BAS
  494. CLTOT = BLOQ 'T' MAILT ;
  495. TIMPO = DEPI 1. CLTOT ;
  496.  
  497. * CHARGEMENT Thermque 'T'
  498. LTPSCHA = PROG 0. 1200. 3000. ;
  499. LTCHA = PROG TMIN TMAX TMAX ;
  500. EVT = EVOL 'MANU' LTPSCHA LTCHA;
  501. CHAR1 = CHAR 'TIMP' TIMPO EVT ;
  502.  
  503. * CHARGEMENT 'TPOI'. Ce chargement est mis a jour dans PARATHER
  504. TPS0 = 0.D0 ;
  505. TPS1 = 3000.D0 ;
  506. VREFROI= 10 ;
  507. VREFROI= ( TMAX - TMIN ) / (1200. - 0.) ;
  508.  
  509. VITESSE = -1 * VREFROI ;
  510. LTPSCHA ='PROG' 0. 1200. 1201. 3000. ;
  511. LTPOI ='PROG' VITESSE VITESSE 0. 0. ;
  512. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  513. TPOIN ='MANU' 'CHPO' MAILT 1 'TPOI' 1.D0 ; 'COMM' 'Le chargement vaut 1 * chargement(temps) partout !';
  514. CHAR2 ='CHAR' 'TPOI' TPOIN EVT ;
  515.  
  516. *CHARGEMENT Total
  517. CHARTOT = CHAR1 'ET' CHAR2 ;
  518.  
  519. *TEMPS_CALCULES
  520. LTCAL1 = PROG 0. 'PAS' 300. 3000. ;
  521.  
  522. *PASAPAS
  523. TPASAP ='TABL' ;
  524. TPASAP.'MODELE' = MODTOT ;
  525. TPASAP.'CARACTERISTIQUES' = MATTOT ;
  526. TPASAP.'BLOCAGES_THERMIQUES' = CLTOT ;
  527. TPASAP.'CHARGEMENT' = CHARTOT ;
  528. TPASAP.'TEMPS_CALCULES' = LTCAL1 ;
  529.  
  530. TPASAP.'TEMPS' ='TABL' ;
  531. TPASAP.'TEMPERATURES' ='TABL' ;
  532. TPASAP.'PROPORTIONS_PHASES' ='TABL' ;
  533. TPASAP.'TEMPS' . 0 ='EXTR' LTCAL1 1;
  534. TPASAP.'TEMPERATURES' . 0 = CHPTINI ;
  535. TPASAP.'PROPORTIONS_PHASES' . 0 = MCHPHA ;
  536. TPASAP.'PROCESSEURS' ='MOT' 'MONO_PROCESSEUR';
  537.  
  538. * PROCEDURES Utilisateurs
  539. TPASAP.'PROCEDURE_PARATHER' = VRAI ;
  540.  
  541. PASAPAS TPASAP ;
  542.  
  543. ************************************************************************
  544. * Phase 3 :
  545. * Refroidissement par convection sur un des bords
  546. ************************************************************************
  547. * MATERIAU
  548. MATCONV ='MATE' MODCON 'H' HCON ;
  549. MATTOT = MATCOND 'ET' MATCONV ;
  550.  
  551. MATTOT = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  552.  
  553. * CHARGEMENT Thermque 'T'
  554. LTPSCHA = PROG 0.D0 1.D6 ;
  555. LTCHA = PROG 1.D0 1.D0 ;
  556. EVTECO = EVOL 'MANU' LTPSCHA LTCHA;
  557. CHPTECO ='MANU' 'CHPO' SURFBAS 1 'T' 20. ;
  558. CHAR1 = CHAR 'TECO' CHPTECO EVTECO ;
  559.  
  560. * CHARGEMENT 'TPOI'. Ce chargement est mis a jour dans PARATHER
  561. VITESSE =-1 * VREFROI ;
  562. LTPSCHA ='PROG' 0.D0 1.D6 ;
  563. LTPOI ='PROG' 0. 0. ;
  564. EVT ='EVOL' 'MANU' LTPSCHA LTPOI ;
  565. TPOIN ='MANU' 'CHPO' MAILT 1 'TPOI' 1.D0 ;
  566. CHAR2 ='CHAR' 'TPOI' TPOIN EVT ;
  567.  
  568. *CHARGEMENT Total
  569. CHARTOT = CHAR1 'ET' CHAR2 ;
  570.  
  571. *TEMPS_CALCULES
  572. MTPS1 ='MAXI' LTCAL1 ;
  573. MTPS2 = MTPS1 + 600. ;
  574. LTCAL2 ='PROG' 3000. 'PAS' 1. 3040. 'PAS' 4. 3160. 'PAS' 8. 3320. 'PAS' 16. MTPS2 ;
  575.  
  576. * Remplacement des indices dans la TABLE TPASAP
  577. TPASAP.'BLOCAGES_THERMIQUES'='VIDE' 'RIGIDITE';
  578. TTPS = TPASAP.'TEMPS';
  579. ID_IND=('DIME' TTPS) - 1;
  580. MCHPHA= TPASAP.'PROPORTIONS_PHASES' . ID_IND ;
  581. ID2 = ID_IND + 1 ;
  582.  
  583. TPASAP.'CARACTERISTIQUES' = MATTOT ;
  584. TPASAP.'CHARGEMENT' = CHARTOT;
  585. TPASAP.'TEMPS_CALCULES' = LTCAL2 ;
  586. TPASAP.'PROPORTIONS_PHASES' . ID2 = MCHPHA ;
  587.  
  588. PASAPAS TPASAP ;
  589.  
  590. ************************************************************************
  591. * POST-TRAITEMENT des résultats
  592. ************************************************************************
  593. fic_sauv = 'CHAI' 'JOMINY.sauv' ;
  594. OPTI SAUV fic_sauv ;
  595.  
  596. * Initialisations pour le POST-TRAITEMENT
  597. LISCOM ='EXTR' MCHPHA 'COMP' ;
  598. NBCOMP ='DIME' LISCOM ;
  599. TABPHA ='TABL';
  600. REPE SURPHA NBCOMP;
  601. IPH = &SURPHA;
  602. TABPHA . IPH ='VIDE' 'LISTREEL' ;
  603. FIN SURPHA;
  604. LTPS ='VIDE' 'LISTREEL';
  605.  
  606. REPE BLOC0 ('DIME' TPASAP.'TEMPS') ;
  607. I = &BLOC0 - 1 ;
  608. CHT = TPASAP.'TEMPERATURES' . I ;
  609. CHPHA = TPASAP.'PROPORTIONS_PHASES'. I ;
  610. LTPS = LTPS 'ET' (TPASAP.'TEMPS' . I) ;
  611.  
  612. * Extraction pour chaque phase de la valeur courante
  613. REPE SURPHA NBCOMP;
  614. IPH = &SURPHA;
  615. NOMP='EXTR' LISCOM IPH;
  616. Pi ='EXTR' CHPHA NOMP 1 1 1 ;
  617. TABPHA . IPH = TABPHA . IPH 'ET' Pi;
  618. FIN SURPHA;
  619. FIN BLOC0 ;
  620.  
  621. *Reconstitution des EVOL
  622. EVTOTa ='VIDE' 'EVOLUTIO';
  623. TDESS1 ='TABL' ;
  624. TDESS1 . 'TITRE' ='TABL' ;
  625. EVOPHAS ='VIDE' 'EVOLUTIO';
  626. CPPHAS ='CHAN' 'CHPO' CHPHA MODTOT;
  627.  
  628. REPE SURPHA NBCOMP;
  629. IPH = &SURPHA;
  630. NOMP ='EXTR' LISCOM IPH;
  631. ICOUL = @MOD IPH NBCOUL;
  632. COUL1 ='EXTR' LESCOUL ICOUL;
  633. Lpi = TABPHA. IPH ;
  634. TABPHA . IPH ='EVOL' COUL1 'MANU' 'TEMP' LTPS NOMP Lpi;
  635. EVTOTa = EVTOTa 'ET' TABPHA . IPH ;
  636. IMARQ = @MOD IPH NBMARQ;
  637. LAMAR ='EXTR' IMARQ LESMARQ;
  638. TDESS1 . 'TITRE' . IPH = NOMP;
  639. * TDESS1 . IPH ='CHAI' 'MARQ ' LAMAR ' REGU';
  640. EVOPHAS = EVOPHAS 'ET' ('EVOL' COUL1 'CHPO' CPPHAS NOMP L2);
  641. FIN SURPHA;
  642.  
  643. EVTOTa = 'CHAN' 'NOMORD' EVTOTa 'PROP';
  644. 'DESS' EVTOTa 'LEGE' TDESS1 'TITR' ('CHAI' 'Evolution des Props en fonction du temps' ) 'YBOR' 0. 1. ;
  645.  
  646. EVOPHAS = 'CHAN' 'NOMORD' EVOPHAS 'PROP';
  647. 'DESS' EVOPHAS 'LEGE' TDESS1 'TITR' ('CHAI' 'Props a Temps final' ) 'YBOR' 0. 1. ;
  648.  
  649. FIN ;
  650.  
  651.  
  652.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales