Télécharger metallurgie_05.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : metallurgie_05.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * TEST METALLURGIE_05 *
  7. * *
  8. * CALCUL D'UN DIAGRAMME T.R.C. SUR UNE MISE EN DONNEES *
  9. * METALLURGIQUE COMPLETE : ACIER 16MND5 *
  10. * REF : A. Bonaventure, « Évaluation expérimentale et numérique des *
  11. * contraintes résiduelles dans des structures soudées en *
  12. * multipasse », PhD Theses, 2012 *
  13. * *
  14. * Appel a la PROCEDURE TRC.PROCEDUR qui genere automatiquement le *
  15. * diagramme T.R.C. *
  16. ************************************************************************
  17.  
  18. 'OPTI' 'TRAC' PSC 'EPTR' 10 ;
  19. 'OPTI' 'DIME' 2 'ELEM' 'TRI3';
  20.  
  21. * Temperatures initiales et finales
  22. TINI = 900.;
  23. TFIN = 20. ;
  24.  
  25. *Calcul automatique de la liste des vitesses de refroidissement
  26. NBVI = 30. ;
  27. VIT1 = 250. ;
  28. VIT2 = 1. ;
  29. VLOG1 ='LOG' VIT1 ;
  30. VLOG2 ='LOG' VIT2 ;
  31. PASLOG =(VLOG2 - VLOG1) / (NBVI - 1);
  32. LRELOG ='PROG' VLOG1 'PAS' PASLOG VLOG2;
  33. LISTREF='EXP' LRELOG;
  34.  
  35. * MAILLAGE
  36. P1 = 0. 0. ;
  37. P2 = 1. 0. ;
  38. P3 = 0. 1. ;
  39.  
  40. MAILT ='MANU' 'TRI3' P1 P2 P3 ;
  41.  
  42. * MODELE
  43. LISTPHA ='MOTS' 'AUST' 'MART' 'BAIN' 'FERR' 'MB ' ;
  44. LISTREAC ='MOTS' 'MB ' 'MART' 'BAIN' 'FERR' 'AUST' 'AUST' 'AUST' ;
  45. LISTPROD ='MOTS' 'AUST' 'AUST' 'AUST' 'AUST' 'MART' 'BAIN' 'FERR' ;
  46. LISTTYPE ='MOTS' 'LEBL' 'LEBL' 'LEBL' 'LEBL' 'KOIS' 'LEBL' 'LEBL' ;
  47. NOMCONS ='16MND5';
  48.  
  49. MODCP1 ='MODE' MAILT 'METALLURGIE' 'PHASES' LISTPHA
  50. 'REACTIFS' LISTREAC
  51. 'PRODUITS' LISTPROD
  52. 'TYPE' LISTTYPE
  53. 'CONS' NOMCONS ;
  54.  
  55. * Materiaux - caracteristiques
  56.  
  57. * 1ere transformation :
  58. PEQ1 ='EVOL' 'MANU' 'T' ('PROG' 716. 802. )
  59. 'PEQ1' ('PROG' 0. 1. );
  60. F1 ='EVOL' 'MANU' 'TPOI' ('PROG' -1.D-6 0. )
  61. 'F1' ('PROG' 0. 1. );
  62. TAU1 ='EVOL' 'MANU' 'T' ('PROG' 716. 802. )
  63. 'TAU1' ('PROG' 12. 0.5 );
  64.  
  65. * 2eme transformation : parametres identiques a la premiere
  66. PEQ2 ='CHAN' 'NOMORD' PEQ1 1 'PEQ2';
  67. F2 ='CHAN' 'NOMORD' F1 1 'F2' ;
  68. TAU2 ='CHAN' 'NOMORD' TAU1 1 'TAU2';
  69.  
  70. * 3eme transformation : parametres identiques a la premiere
  71. PEQ3 ='CHAN' 'NOMORD' PEQ1 1 'PEQ3';
  72. F3 ='CHAN' 'NOMORD' F1 1 'F3' ;
  73. TAU3 ='CHAN' 'NOMORD' TAU1 1 'TAU3';
  74.  
  75. * 4eme transformation : parametres identiques a la premiere
  76. PEQ4 ='CHAN' 'NOMORD' PEQ1 1 'PEQ4';
  77. F4 ='CHAN' 'NOMORD' F1 1 'F4' ;
  78. TAU4 ='CHAN' 'NOMORD' TAU1 1 'TAU4';
  79.  
  80. * 5eme transformation
  81. MS5 = 380. ;
  82. KM5 = 0.0247 ;
  83.  
  84. * 6eme transformation
  85. PEQ6 ='EVOL' 'MANU' 'T' ('PROG' 375 380 405 600 )
  86. 'PEQ6' ('PROG' 0. 1. 1. 0. );
  87.  
  88. F6 ='EVOL' 'MANU' 'TPOI' ('PROG' -100. -80. -60. -50. -40. -30. -25. -20. -18. -15. -12. -10. -9. -5. -1. -0.05 0.D0 1.D-6)
  89. 'F6' ('PROG' 0.005 1.573 2.857 3.417 3.982 4.583 4.833 5.26 5.472 6.033 7.675 11.4 18.45 17.1 0.328 0.00238 0.00238 0.) ;
  90.  
  91. TAU6 ='EVOL' 'MANU' 'T' ('PROG' 375 380)
  92. 'TAU6' ('PROG' 1.D6 20 );
  93.  
  94. * 7eme transformation
  95. PEQ7 ='EVOL' 'MANU' 'T' ('PROG' 625 630 730 735 )
  96. 'PEQ7' ('PROG' 0 1 1 0 );
  97.  
  98. F7 ='EVOL' 'MANU' 'TPOI' ('PROG' -8.5 -6.2 -4.7 0. 1.D-6)
  99. 'F7' ('PROG' 0.001 0.13 1.5 1.5 0. );
  100.  
  101. TAU7 ='EVOL' 'MANU' 'T' ('PROG' 625 630 )
  102. 'TAU7' ('PROG' 1.D6 5 );
  103.  
  104. MATCP1 ='MATE' MODCP1 'PEQ1' PEQ1 'TAU1' TAU1 'F1' F1
  105. 'PEQ2' PEQ2 'TAU2' TAU2 'F2' F2
  106. 'PEQ3' PEQ3 'TAU3' TAU3 'F3' F3
  107. 'PEQ4' PEQ4 'TAU4' TAU4 'F4' F4
  108. 'MS5' MS5 'KM5' KM5
  109. 'PEQ6' PEQ6 'TAU6' TAU6 'F6' F6
  110. 'PEQ7' PEQ7 'TAU7' TAU7 'F7' F7;
  111.  
  112. * Appel a la procedure TRC.procedur
  113. TRC MODCP1 MATCP1 TINI TFIN LISTREF ;
  114.  
  115. FIN ;
  116.  
  117.  
  118.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales