Télécharger lyre3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : lyre3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * CAS TEST DU 91/06/13 PROVENANCE : TEST
  5.  
  6. *******************************************
  7. * Test lyre3.dgibi: jeux de données *
  8. * --------------------------------- *
  9. *******************************************
  10.  
  11. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  12. * SINON SI GRAPH DIFFERENT DE N TOUS
  13. * LES GRAPHIQUES SONT AFFICHES
  14.  
  15. GRAPH = 'N' ;
  16.  
  17. SAUT PAGE;
  18. SI (NEG GRAPH 'N') ;
  19. OPTI ECHO 1 ;
  20. OPTI TRAC PSC ;
  21. SINO ;
  22. OPTI ECHO 0 ;
  23. FINSI ;
  24.  
  25. SAUT PAGE;
  26.  
  27. *******************************************
  28. * *
  29. * LYRE-VICTUS 3 *
  30. * *
  31. * ESSAI ELEMENT TUYAU (DROIT ET COUDE) *
  32. * *
  33. * description : *
  34. * ----------- *
  35. * Test en statique lineaire, chargement *
  36. * thermique. *
  37. * La structure est constituee d'elements*
  38. * TUYAU : *
  39. * - 7 portions de tuyau droit, *
  40. * - 6 portions de tuyau coude. *
  41. * *
  42. * Proprietes du materaiux : *
  43. * - Module d'Young : YOUN = 2.e11 *
  44. * - Coefficient de Poisson : NU = 0.3 *
  45. * - Dilatabilite thermique : ALPH = 18.e-6*
  46. * *
  47. * Conditions aux limites : *
  48. * Encastrement aux extremites *
  49. * (P1 et P14) *
  50. * *
  51. * Chargement : *
  52. * Chargement thermique : Elevation de *
  53. * temperature de 400 degres Celcius. *
  54. * Le poids propre est neglige. *
  55. * Test corrig‚ le 10/09/92 *
  56. *******************************************
  57.  
  58. OPTI ELEM SEG2;
  59. *+++++++++++++++++++++++++++++++++++++++++*
  60. * GEOMETRIE : MAILLAGE *
  61. *+++++++++++++++++++++++++++++++++++++++++*
  62.  
  63. OEIL = 100 -100 100;
  64.  
  65. P1 = 0. 0. 0.;
  66. P2 = 0.79 0. 0.;
  67. P3 = 1.095 -.305 0.;
  68. P4 = 1.095 -1.155 0.;
  69. P5 = 1.400 -1.460 0.;
  70. P6 = 2.480 -1.460 0.;
  71. P7 = 2.785 -1.460 .305;
  72. P8 = 2.785 -1.460 1.155;
  73. P9 = 2.785 -1.155 1.460;
  74. P10 = 2.785 -.305 1.460;
  75. P11 = 2.785 0. 1.155;
  76. P12 = 2.785 0. 0.305;
  77. P13 = 3.090 0. 0.;
  78. P14 = 3.880 0. 0.;
  79.  
  80. T = TABL;
  81. T.1 = P1 DROI 10 P2;
  82. T.2 = P3 DROI 11 P4;
  83. T.3 = P5 DROI 14 P6;
  84. T.4 = P7 DROI 11 P8;
  85. T.5 = P9 DROI 11 P10;
  86. T.6 = P11 DROI 11 P12;
  87. T.7 = P13 DROI 12 P14;
  88.  
  89. C = TABL;
  90. C1 = 0.79 -0.305 0.;
  91. C2 = 1.4 -1.155 0.;
  92. C3 = 2.48 -1.460 0.305;
  93. C4 = 2.885 -1.155 1.155;
  94. C5 = 2.885 -0.305 1.155;
  95. C6 = 3.190 0.0 0.305;
  96.  
  97. C.1 = P2 CERC 12 C1 P3;
  98. C.2 = P4 CERC 12 C2 P5;
  99. C.3 = P6 CERC 12 C3 P7;
  100. C.4 = P8 CERC 12 C4 P9;
  101. C.5 = P10 CERC 12 C5 P11;
  102. C.6 = P12 CERC 12 C6 P13;
  103.  
  104. SUR1 = T.7;
  105. I = 0;
  106. REPETER BLOC1 6;
  107. I = I + 1;
  108. SUR1 = SUR1 ET T.I ET C.I;
  109. FIN BLOC1;
  110.  
  111. SI (NEG GRAPH 'N');
  112. TITR 'LYRE3 : MAILLAGE';
  113. TRAC OEIL 'QUAL' SUR1;
  114. FINSI;
  115.  
  116. *+++++++++++++++++++++++++++++++++++++++++*
  117. * CALCUL DE LA RIGIDITE *
  118. *+++++++++++++++++++++++++++++++++++++++++*
  119. VECT1 = TABL;
  120.  
  121. VECT1.1 = ( 0. 0. -1.);
  122. VECT1.2 = ( 0. 0. 1.);
  123. VECT1.3 = ( 0. -1. 0.);
  124. VECT1.4 = (-1. 0. 0.);
  125. VECT1.5 = (-1. 0. 0.);
  126. VECT1.6 = ( 0. -1. 0.);
  127.  
  128. MODL1 = MODE T.7 MECANIQUE ELASTIQUE
  129. ISOTROPE TUYA;
  130. MATR1 = MATE MODL1 YOUN 2.E11 NU 0.3
  131. ALPH 18.E-6
  132. EPAI 8.18E-3
  133. RAYON 109.59E-3;
  134. RIGI1 = RIGI MODL1 MATR1;
  135.  
  136. I = 0;
  137. REPETER BLOC2 6;
  138. I = I + 1;
  139.  
  140. MODL2 = MODE T.I MECANIQUE ELASTIQUE
  141. ISOTROPE TUYA;
  142. MATR2 = MATE MODL2 YOUN 2.E11 NU 0.3
  143. ALPH 18.E-6
  144. EPAI 8.18E-3
  145. RAYON 109.59E-3;
  146. RIGI2 = RIGI MODL2 MATR2;
  147.  
  148. MODL3 = MODE C.I MECANIQUE ELASTIQUE
  149. ISOTROPE TUYA;
  150. MATR3 = MATE MODL3 YOUN 2.E11 NU 0.3
  151. ALPH 18.E-6
  152. EPAI 8.18E-3
  153. RAYON 109.59E-3
  154. RACO 305.E-3 VECT VECT1.I;
  155. RIGI3 = RIGI MODL3 MATR3;
  156.  
  157. MODL1 = MODL1 ET MODL2 ET MODL3;
  158. MATR1 = MATR1 ET MATR2 ET MATR3;
  159. RIGI1 = RIGI1 ET RIGI2 ET RIGI3;
  160.  
  161. FIN BLOC2;
  162.  
  163. *+++++++++++++++++++++++++++++++++++++++++*
  164. * RESOLUTION : CALCUL ELASTIQUE *
  165. *+++++++++++++++++++++++++++++++++++++++++*
  166.  
  167. * Conditions aux limites
  168. CL1 = BLOQ DEPL ROTA P1;
  169. CL2 = BLOQ DEPL ROTA P14;
  170. RIGI1 = RIGI1 ET CL1 ET CL2;
  171.  
  172. * Chargement thermique
  173. CHPOTEMP = MANU CHPO SUR1 1 'T' 400.;
  174. SIGM1 = THET MODL1 MATR1 CHPOTEMP;
  175. CHAR1 = BSIG MODL1 SIGM1 MATR1;
  176.  
  177. * Resolution
  178. DEPL1 = RESO RIGI1 CHAR1;
  179.  
  180. * Trace
  181. SI (NEG GRAPH 'N');
  182.  
  183. TITR 'LYRE3 : DEFORMEE';
  184. DEF0 = DEFO SUR1 DEPL1 0. NOIR;
  185. DEF1 = DEFO SUR1 DEPL1 1. BLEU;
  186. TRAC OEIL (DEF0 ET DEF1);
  187. FINSI;
  188.  
  189. *+++++++++++++++++++++++++++++++++++++++++*
  190. * extraction des resultats *
  191. *+++++++++++++++++++++++++++++++++++++++++*
  192. V1P6 = -1.374E-2;
  193. V2P6 = EXTR DEPL1 UY P6;
  194. ERG1 = 100. * (ABS ((V1P6 - V2P6) / V1P6));
  195.  
  196. U1P7 = 1.070E-2;
  197. U2P7 = EXTR DEPL1 UX P7;
  198. ERG2 = 100. * (ABS ((U1P7 - U2P7) / U1P7));
  199.  
  200. W1P9 = 1.301E-2;
  201. W2P9 = EXTR DEPL1 UZ P9;
  202. ERG3 = 100. * (ABS ((W1P9 - W2P9) / W1P9));
  203.  
  204. *+++++++++++++++++++++++++++++++++++++++++*
  205. * affichage des resultats *
  206. *+++++++++++++++++++++++++++++++++++++++++*
  207. MESS 'RESULTATS : TEST LYRE VICTUS 3 ';
  208. MESS '------------------------------ ';
  209.  
  210. MESS ' Deplacement v (m) du point P6 ';
  211. MESS ' ----------------------------- ';
  212. MESS ' Valeur theorique : ' V1P6 'm';
  213. MESS ' Valeur calculee : ' V2P6 'm';
  214. MESS ' Ecart : ' ERG1 '%';
  215.  
  216. MESS ' Deplacement u (m) du point P7 ';
  217. MESS ' ----------------------------- ';
  218. MESS ' Valeur theorique : ' U1P7 'm';
  219. MESS ' Valeur calculee : ' U2P7 'm';
  220. MESS ' Ecart : ' ERG2 '%';
  221.  
  222. MESS ' Deplacement w (m) du point P9 ';
  223. MESS ' ----------------------------- ';
  224. MESS ' Valeur theorique : ' W1P9 'm';
  225. MESS ' Valeur calculee : ' W2P9 'm';
  226. MESS ' Ecart : ' ERG3 '%';
  227.  
  228. *+++++++++++++++++++++++++++++++++++++++++*
  229. * Code de fonctionnement *
  230. *+++++++++++++++++++++++++++++++++++++++++*
  231. ERGMAX = MAXI (PROG ERG1 ERG2 ERG3);
  232.  
  233. SI (ERGMAX <EG 3.);
  234. ERRE 0;
  235. SINON;
  236. ERRE 5;
  237. FINSI;
  238.  
  239. TEMPS;
  240.  
  241. FIN;
  242.  
  243.  
  244.  
  245.  
  246.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales