Télécharger liai_ar1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : liai_ar1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test liai_ar1.dgibi: Jeux de donnees
  6. * ------------------------------------
  7. **********************************************************
  8. * TEST DE VALIDATION *
  9. * ------------------ *
  10. * MODELE PLASTIQUE BILIN_EFFX *
  11. * SIMULATION DE LA LIAISON CRAYON/GRILLE *
  12. * *
  13. * MAILLAGE: *
  14. * CRAYON = POUTRES ELASTIQUES *
  15. * 1 CELLULE DE GRILLE = PLAQUE EQUIVALENTE *
  16. * ELASTIQUE EN COQ4 *
  17. * 1 LIAISON CRAYON/CELLULE = 1 POUTRE AVEC MODELE *
  18. * PLASTIQUE BILIN_EFFX *
  19. * *
  20. * CHARGEMENT: *
  21. * FORCE DE TRACTION AXIALE SUR L'EXTREMITE *
  22. * SUPERIEURE DU CRAYON: CHARGE PUIS DECHARGE *
  23. * *
  24. * CONDITIONS AUX LIMITES: *
  25. * CELLULE DE GRILLE ENCASTREE SUR SES 4 COTES *
  26. * *
  27. * COMPARAISON / SOLUTION ANALYTIQUE: *
  28. * RAIDEUR AU CENTRE EN FLEXION DE LA *
  29. * PLAQUE EQUIVALENTE PAR CALCUL ANNEXE *
  30. **********************************************************
  31.  
  32. * ::::::::::::::::::::::::::::::::::::::::::::::::
  33. * DEFINITION DES PROCEDURES POUR POST TRAITEMENT :
  34. * ::::::::::::::::::::::::::::::::::::::::::::::::
  35. 'DEBP' FEPS mo*'MMODEL' mat*'MCHAML' n*'ENTIER'
  36. dep*'TABLE' sig*'TABLE'
  37. mot1*'MOT' mot2*'MOT' P*'POINT' ;
  38. ************************************************************************
  39. prx = prog ;
  40. pry = prog ;
  41.  
  42. repe stru n ;
  43. *-
  44. i = &stru-1 ;
  45. eps = 'EPSI' mo mat dep.i ;
  46. eps = 'CHAN' 'CHPO' mo eps ;
  47. x = 'EXTR' eps mot1 P ;
  48. prx = prx 'ET' (prog x) ;
  49. sg = sig.i ;
  50. sg = 'CHAN' 'CHPO' mo sg ;
  51. y = 'EXTR' sg mot2 P ;
  52. pry = pry 'ET' (prog y) ;
  53. ev = 'EVOL' 'MANU' mot1 prx mot2 pry ;
  54. *-
  55. fin stru ;
  56. ************************************************************************
  57. 'FINP' ev ;
  58. ************************************************************************
  59.  
  60. ************************************************************************
  61. 'DEBP' FTEMPS mo*'MMODEL' mat*'MCHAML' n*'ENTIER'
  62. tab1*'TABLE' tab2*'TABLE'
  63. mot1*'MOT' P*'POINT' ;
  64. ************************************************************************
  65. prx = prog ;
  66. pry = prog ;
  67.  
  68. repe stru n ;
  69. *-
  70. i = &stru-1 ;
  71. x = tab1.i ;
  72. prx = prx 'ET' (prog x) ;
  73. y = 'EXTR' tab2.i mot1 P ;
  74. pry = pry 'ET' (prog y) ;
  75. ev = 'EVOL' 'MANU' 'temps' prx mot1 pry ;
  76. *-
  77. fin stru ;
  78. ************************************************************************
  79. 'FINP' ev ;
  80. ************************************************************************
  81.  
  82. ************************************************************************
  83. 'DEBP' SOLEFFX
  84. F*'FLOTTANT' Fseuil*'FLOTTANT' k*'FLOTTANT'
  85. l1*'FLOTTANT' A1*'FLOTTANT' E1*'FLOTTANT' E1T*'FLOTTANT'
  86. l2*'FLOTTANT' A2*'FLOTTANT' E2*'FLOTTANT' Fa/'FLOTTANT';
  87. ************************************************************************
  88. k1 = E1 * A1 ;
  89. k1T = E1T * A1 ;
  90. k2 = E2 * A2 ;
  91.  
  92. pr1 = prog 0 l1 ; pr1un = prog (dime pr1)*1 ;
  93. pr2 = prog l1 (l1+l2) ; pr2un = prog (dime pr2)*1 ;
  94.  
  95. 'SI' ('NON' ('EXIS' Fa)) ;
  96. *- Charge
  97. 'SI' (F '<EG' Fseuil) ;
  98. *- Solution élastique pour la liaison
  99. epsg = F/k1 ;
  100. u2b = (F*l1)/k1 ;
  101. 'SINON' ;
  102. *- Solution plastique pour la liaison
  103. eps1 = Fseuil*(1-(E1T/E1)) ;
  104. epsg = (F - eps1) / k1T ;
  105. u2b = epsg*l1 ;
  106. 'FINSI' ;
  107. 'SINON' ;
  108. *- Décharge
  109. eps1 = (Fa-Fseuil)*(1-(E1/E1T)) ;
  110. epsg = (F - eps1) / k1 ;
  111. u2b = epsg*l1 ;
  112. 'FINSI' ;
  113.  
  114. u1 = epsg*pr1 + (F *(pr1un/k)) ;
  115. ev1 = 'EVOL' 'MANU' 'ABSC' pr1 'DEPL' u1 ;
  116.  
  117. u2a = (F/k2) * (pr2 - (l1*pr2un)) ;
  118. u2 = u2a + ((u2b +(F/k))*pr2un) ;
  119. ev2 = 'EVOL' 'MANU' 'ABSC' pr2 'DEPL' u2 ;
  120.  
  121. ev = 'CONCAT' ev1 ev2 ;
  122.  
  123. ************************************************************************
  124. 'FINP' ev ;
  125. ************************************************************************
  126. * ajout de option epsilon lineaire pour la precision des test!
  127. OPTION epsilon lineaire;
  128. * :::::::::::::
  129. * DEBUT DU PB :
  130. * :::::::::::::
  131.  
  132. 'OPTI' 'DIME' 3 ;
  133.  
  134. *'OPTI' 'TRAC' 'PSC' ;
  135. 'TEMPS' 'ZERO' ;
  136.  
  137. DESSI = faux ;
  138.  
  139. lcel = 12.595E-3 ;
  140. long = 0.15 ;
  141. l1 = long / 10 ;
  142.  
  143. ************
  144. *- CRAYON -*
  145. ************
  146. 'OPTI' 'ELEM' 'SEG2' ;
  147.  
  148. p1 = 0 0 0 ;
  149. p3 = 0 0 l1 ;
  150. p2 = 0 0 long ;
  151. q3 = 0 0 (-1*l1) ;
  152. q2 = 0 0 (-1*long) ;
  153.  
  154. nelt = 10 ;
  155. n1 = 1 ;
  156. n2 = nelt-n1 ;
  157.  
  158. geo1 = p1 p3 'DROI' n1 ;
  159. geo2 = p3 p2 'DROI' n2 ;
  160. geo3 = p1 q3 'DROI' n1 ;
  161. geo4 = q3 q2 'DROI' n2 ;
  162. geo = geo1 'ET' geo2 'ET' geo3 'ET' geo4 ;
  163.  
  164. ************
  165. *- GRILLE -*
  166. ************
  167. 'OPTI' 'ELEM' 'QUA4' ;
  168.  
  169. r1 = (-1*lcel) (-1*lcel) 0 ;
  170. r2 = lcel (-1*lcel) 0 ;
  171. r3 = lcel lcel 0 ;
  172. r4 = (-1*lcel) lcel 0 ;
  173.  
  174. n3 = 4 ;
  175.  
  176. lplac1 = r1 r2 'DROIT' n3 ;
  177. lplac2 = r2 r3 'DROIT' n3 ;
  178. lplac3 = r3 r4 'DROIT' n3 ;
  179. lplac4 = r4 r1 'DROIT' n3 ;
  180. plac = lplac1 lplac2 lplac3 lplac4 'DALLER' 'PLAN' ;
  181. r0 = plac 'POIN' 'PROC' p1 ;
  182.  
  183. *************
  184. *- LIAISON -*
  185. *************
  186. 'OPTI' 'ELEM' 'SEG2' ;
  187.  
  188. lien = 'COUL' (r0 p3 'DROIT' 1) 'ROUG' ;
  189.  
  190. ****************
  191. *- ASSEMBLAGE -*
  192. ****************
  193. mailtot = geo 'ET' plac 'ET' lien ;
  194.  
  195. *************
  196. *- MODELES -*
  197. *************
  198. moc = 'MODE' geo 'MECANIQUE' 'ELASTIQUE' 'POUTRE';
  199. mop = 'MODE' plac 'MECANIQUE' 'ELASTIQUE' 'COQ4' ;
  200. mol = 'MODE' lien 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE'
  201. 'BILIN_EFFX' 'POUTRE';
  202. mo = moc 'ET' mop 'ET' mol ;
  203.  
  204.  
  205. youn_M5 = 0.984E11 ;
  206. nu_M5 = 0.368 ;
  207. yp = youn_M5 / 10000.;
  208. fseuilx = 6. ;
  209.  
  210. mac = 'MATE' moc 'YOUN' youn_M5 'NU' nu_M5 ;
  211. map = 'MATE' mop 'YOUN' youn_M5 'NU' nu_M5 ;
  212. mal = 'MATE' mol 'YOUN' youn_M5 'NU' nu_M5 'ETAN' yp 'YIEF' fseuilx ;
  213. ma = mac 'ET' map 'ET' mal ;
  214.  
  215. *ep_plaq = 0.425E-3 ;
  216. ep_plaq = 2.879E-3 ;
  217. ep_cray = 0.57E-3 ;
  218. Dext = 9.5E-3 ;
  219. Dint = 8.36E-3 ;
  220.  
  221. air = (pi/4) * ((Dext**2)-(Dint**2)) ;
  222. iy = (pi/64) * ((Dext**4)-(Dint**4)) ;
  223. iz = iy ;
  224. ix = 2*iy ;
  225. sr1 = (Dint/Dext)/(1+((Dint/Dext)**2));
  226. sr2 = 6./(7.+(20.*(sr1**2))) ;
  227. sry = sr2*air ;
  228. srz = sry ;
  229.  
  230. cac = 'CARA' moc 'TORS' ix 'INRY' iy 'INRZ' iz 'SECT' air
  231. 'SECY' sry 'SECZ' srz ;
  232. cap = 'CARA' mop 'EPAI' ep_plaq ;
  233. cal = 'CARA' mol 'TORS' ix 'INRY' iy 'INRZ' iz 'SECT' air
  234. 'SECY' sry 'SECZ' srz ;
  235. ca = cac 'ET' cap 'ET' cal ;
  236.  
  237. mat = ma 'ET' ca ;
  238.  
  239.  
  240. cl = bloq 'DEPL' 'ROTA' (lplac1 et lplac2 et lplac3 et lplac4) ;
  241.  
  242. valfo = 1. ;
  243. fo = 'FORCE' 'FZ' valfo p2 ;
  244. evfo = 'EVOL' 'MANU' ('PROG' 0 12 24) ('PROG' 0 12 0) ;
  245. cha = 'CHAR' fo evfo ;
  246.  
  247. lisc = 'PROG' 1 pas 1 24;
  248. *lisc = 'PROG' 1 pas 1 6 pas 1 7 pas 1 12 pas 1 13 pas 1 24 ;
  249. *pas 0.1 13 pas 1 24 ; yp = youn_M5 / 100. ;
  250.  
  251. tab = 'TABLE' ;
  252. tab.'MODELE' = mo ;
  253. tab.'CARACTERISTIQUES' = mat ;
  254. tab.'CHARGEMENT' = cha ;
  255. tab.'BLOCAGES_MECANIQUES' = cl ;
  256. *tab.deltaiter= 20;
  257. tab.maxdefor=5.e-5;
  258. tab.'TEMPS_CALCULES' = lisc ;
  259. tab.'TEMPS_SAUVES' = lisc ;
  260.  
  261. PASAPAS tab ;
  262.  
  263. time = tab.TEMPS ;
  264. ntime = 'DIME' time ;
  265. n = ntime-1 ;
  266.  
  267. dep = tab.'DEPLACEMENTS' ;
  268. sig = tab.'CONTRAINTES' ;
  269. vi = tab.'VARIABLES_INTERNES' ;
  270.  
  271. titr 'P2' ;
  272. FXEPS_P2 = FEPS mo mat ntime dep sig 'EPS' 'EFFX' P2 ;
  273. FXt_P2 = FTEMPS mo mat ntime time dep 'UZ' P2 ;
  274. 'SI' DESSI; dess FXEPS_P2 ; dess FXt_P2 ; 'FINSI' ;
  275.  
  276. titr 'P3' ;
  277. FXEPS_P3 = FEPS mo mat ntime dep sig 'EPS' 'EFFX' P3 ;
  278. FXt_P3 = FTEMPS mo mat ntime time dep 'UZ' P3 ;
  279. 'SI' DESSI; dess FXEPS_P3 ; dess FXt_P3 ; 'FINSI' ;
  280.  
  281. titr 'R0' ;
  282. FXEPS_R0 = FEPS mo mat ntime dep sig 'EPS' 'EFFX' R0 ;
  283. FXt_R0 = FTEMPS mo mat ntime time dep 'UZ' R0 ;
  284. 'SI' DESSI; dess FXEPS_R0 ; dess FXt_R0 ; 'FINSI' ;
  285.  
  286. titr 'Q2' ;
  287. FXEPS_Q2 = FEPS mo mat ntime dep sig 'EPS' 'EFFX' Q2 ;
  288. FXt_Q2 = FTEMPS mo mat ntime time dep 'UZ' Q2 ;
  289. 'SI' DESSI; dess FXEPS_Q2 ; dess FXt_Q2 ; 'FINSI' ;
  290.  
  291. titr 'Q3' ;
  292. FXEPS_Q3 = FEPS mo mat ntime dep sig 'EPS' 'EFFX' Q3 ;
  293. FXt_Q3 = FTEMPS mo mat ntime time dep 'UZ' Q3 ;
  294. 'SI' DESSI; dess FXEPS_Q3 ; dess FXt_Q3 ; 'FINSI' ;
  295.  
  296. tdes = 'TABLE' ;
  297. tdes.'TITRE' = 'TABLE' ;
  298. tdes . 1 = 'MARQ ETOI' ;
  299. tdes . 2 = 'MARQ CARR' ;
  300. tdes . 3 = 'MARQ TRIA' ;
  301. tdes . 4 = 'MARQ TRIB' ;
  302. tdes.'TITRE' . 1 = 'MOT' 'P2' ;
  303. tdes.'TITRE' . 2 = 'MOT' 'P3' ;
  304. tdes.'TITRE' . 3 = 'MOT' 'Q2' ;
  305. tdes.'TITRE' . 4 = 'MOT' 'Q3' ;
  306.  
  307. titr 'UX(t)' ;
  308. 'SI' DESSI ; dess (FXt_P2 et FXt_P3 et FXt_Q2 et FXt_Q3) LEGE tdes ;
  309. 'FINSI' ;
  310.  
  311. ni = 6 ;
  312. titr 'UX le long de la poutre t=' time.ni ;
  313. evUXgeo = 'EVOL' 'CHPO' dep.ni 'UZ' (inve geo) ;
  314. 'SI' DESSI; dess evUXgeo ; 'FINSI' ;
  315.  
  316. geolien = lien et geo2 ;
  317. titr 'UX le long de la liaison t=' time.ni ;
  318. evUXlien = 'EVOL' 'CHPO' dep.ni 'UZ' geolien ;
  319. evUXliey = extr evUXlien 'ORDO' ;
  320. evUXliex = (extr evUXlien 'ABSC')+(prog (dime evUXliey)*long) ;
  321. evUXlie = 'EVOL' 'MANU' evUXliex evUXliey ;
  322. 'SI' DESSI; dess (evUXlie et evUXgeo) ; 'FINSI' ;
  323.  
  324. def = 'DEFO' dep.ni mailtot 100. 'ROUG' ;
  325. def0 = 'DEFO' dep.ni mailtot 0. ;
  326. 'SI' DESSI; trac (def0 et def) ; 'FINSI' ;
  327.  
  328. l2 = long-l1 ;
  329. k1 = (youn_M5 * air) / l1 ;
  330. k2 = (youn_M5 * air) / l2 ;
  331. k = k1 / 2. ;
  332.  
  333. *- pour ep_plaq = 0.425E-3
  334. *k = 1./(4.26698E-6) ;
  335.  
  336. PREXABSO = 1E-6 ;
  337.  
  338. pinstant = 'PROG' 6. 7. 12. 12.5 18. 24. ;
  339. instants = 'LECT' ;
  340. 'REPE' boc00 ('DIME' pinstant) ;
  341. tinstant = 'EXTR' pinstant &boc00 ;
  342. 'REPE' boc0 ntime ;
  343. nt = &boc0 - 1 ;
  344. t = time.nt ;
  345. 'SI' (t 'NEG' 0.) ;
  346. test = (time.nt - tinstant) / tinstant ;
  347. test = 'ABS' test ;
  348. 'SI' (test '<EG' 1E-4) ;
  349. instants = instants 'ET' ('LECT' nt) ;
  350. 'FINSI' ;
  351. 'FINSI' ;
  352. 'FIN' boc0 ;
  353. 'FIN' boc00 ;
  354.  
  355. 'REPE' boc1 ('DIME' instants) ;
  356.  
  357. ti = 'EXTR' instants &boc1 ;
  358. t = time.ti ;
  359. ft = 'MAXI' ('TIRE' cha t) ;
  360. 'SI' (t '<EG' 12.) ;
  361. evUXsol = SOLEFFX ft fseuilx k
  362. l1 air youn_M5 yp
  363. l2 air youn_M5 ;
  364. fa=ft ;
  365. 'SINON' ;
  366. evUXsol = SOLEFFX ft fseuilx k
  367. l1 air youn_M5 yp
  368. l2 air youn_M5 fa ;
  369. 'FINSI' ;
  370. evUXlien = 'EVOL' 'CHPO' dep.ti 'UZ' geolien ;
  371.  
  372. evUXsolx = 'EXTR' evUXsol 'ABSC' ;
  373. evUXsoly = 'EXTR' evUXsol 'ORDO' ;
  374. evUXlenx = 'EXTR' evUXlien 'ABSC' ;
  375. evUXleny = 'EXTR' evUXlien 'ORDO' ;
  376. evUXleny = 'IPOL' evUXsolx evUXlenx evUXleny ;
  377. test = 'ABS' (evUXsoly - evUXleny) ;
  378. test = 'MAXI' test ;
  379. 'SI' ('<' test PREXABSO) ;
  380. 'ERRE' 0 ;
  381. 'SINON' ;
  382. 'MESS' 'ERREUR DEPLACEMENT AXIAL a t= ' t
  383. test ' > ' PREXabso ;
  384. mess ' evuxsoly'; list evuxsoly;
  385. mess ' evuxleny'; list evuxleny;
  386. mess ' evuxsolx'; list evuxsolx;
  387. * 'ERRE' 5 ;
  388. 'FINSI' ;
  389.  
  390.  
  391. tdes = 'TABLE' ;
  392. tdes.'TITRE' = 'TABLE' ;
  393. tdes . 1 = 'MARQ ETOI' ;
  394. tdes . 2 = 'MARQ CARR' ;
  395. tdes.'TITRE' . 1 = 'MOT' 'Solution' ;
  396. tdes.'TITRE' . 2 = 'MOT' 'Calcul' ;
  397. titr 'UX le long de la poutre t=' t ;
  398. 'SI' DESSI;
  399. dess (evUXsol et evUXlien) tdes LEGE ;
  400. 'FINSI' ;
  401.  
  402. 'FIN' boc1 ;
  403.  
  404. 'FIN' ;
  405.  
  406.  
  407.  
  408.  
  409.  
  410.  
  411.  
  412.  
  413.  
  414.  
  415.  
  416.  
  417.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales