Télécharger lapnvf3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : lapnvf3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. ********************* cas test lapnvf3.dgibi *********************
  6. *
  7. *-----------------------------------------------------------------
  8. * Cas Test pour l'operateur LAPN version VF
  9. *-----------------------------------------------------------------
  10. * On cherche la solution stationnaire d'un problème de diffusion
  11. * thermique sur un disque où on impose une température T1 sur le
  12. * disque de rayon r1 et T2 à l'exterieur du disque de rayon r2.
  13. *
  14. * La solution analytique ne dépend que du rayon r, soit :
  15. *
  16. * T2 log (r/r1) - T1 log (r/r2)
  17. * T(r) = -----------------------------
  18. * log r2 - log r1
  19. *
  20. * On effectue un calcul 3D en maillant le pb 2D plan
  21. *
  22. *-----------------------------------------------------------------
  23. * Auteurs : J.CREUZIL et F.DABBENE (TTMF) 12/97
  24. *-----------------------------------------------------------------
  25. *
  26. *- Options
  27. *
  28. 'OPTI' 'DIME' 3 'ELEM' 'CUB8' 'ECHO' 0 ;
  29. 'OPTI' 'TRAC' 'PS' ;
  30. GRAPH = 'N' ;
  31. *
  32. *- Données du problème
  33. *
  34. R1 = 3.0 ; R2 = 9.0 ;
  35. T1 = 200.0 ; T2 = 100.0 ;
  36. *
  37. *- Maillage
  38. *
  39. R0 = R1 - 0.5 ;
  40. R3 = R2 + 0.5 ;
  41. MR0 = -1.D0 * R0 ;
  42. MR1 = -1.D0 * R1 ;
  43. MR2 = -1.D0 * R2 ;
  44. MR3 = -1.D0 * R3 ;
  45. *
  46. PC = 0.0 0.0 0.0 ;
  47. P0 = R0 0.0 0.0 ;
  48. P1 = R1 0.0 0.0 ;
  49. P2 = R2 0.0 0.0 ;
  50. P3 = R3 0.0 0.0 ;
  51. P4 = 0.0 R0 0.0 ;
  52. P5 = 0.0 R1 0.0 ;
  53. P6 = 0.0 R2 0.0 ;
  54. P7 = 0.0 R3 0.0 ;
  55. P8 = MR0 0.0 0.0 ;
  56. P9 = MR1 0.0 0.0 ;
  57. P10 = MR2 0.0 0.0 ;
  58. P11 = MR3 0.0 0.0 ;
  59. *
  60. N = 12 ;
  61. N1 = 10 ;
  62. P0P1 = P0 'DROI' 2 P1 ;
  63. P1P2 = P1 'DROI' N P2 ;
  64. P2P3 = P2 'DROI' 2 P3 ;
  65. P4P5 = P4 'DROI' 2 P5 ;
  66. P5P6 = P5 'DROI' N P6 ;
  67. P6P7 = P6 'DROI' 2 P7 ;
  68. P9P8 = P9 'DROI' 2 P8 ;
  69. P10P9 = P10 'DROI' N P9 ;
  70. P11P10 = P11 'DROI' 2 P10;
  71. P5P4 = 'INVE' P4P5 ;
  72. P6P5 = 'INVE' P5P6 ;
  73. P7P6 = 'INVE' P6P7 ;
  74. P4P0 = 'CERC' N1 P4 PC P0 ;
  75. P5P1 = 'CERC' N1 P5 PC P1 ;
  76. P1P5 = 'INVE' P5P1 ;
  77. P2P6 = 'CERC' N1 P2 PC P6 ;
  78. P6P2 = 'INVE' P2P6 ;
  79. P3P7 = 'CERC' N1 P3 PC P7 ;
  80. P8P4 = 'CERC' N1 P8 PC P4 ;
  81. P5P9 = 'CERC' N1 P5 PC P9 ;
  82. P9P5 = 'INVE' P5P9 ;
  83. P6P10 = 'CERC' N1 P6 PC P10;
  84. P10P6 = 'INVE' P6P10 ;
  85. P7P11 = 'CERC' N1 P7 PC P11;
  86. P4P7 = P4P5 'ET' P5P6 'ET' P6P7 ;
  87. 'OPTI' 'ELEM' 'TRI3' ;
  88. M00 = 'DALL' P0P1 P1P5 P5P4 P4P0 'PLAN' ;
  89. M10 = 'DALL' P1P2 P2P6 P6P5 P5P1 'PLAN' ;
  90. M20 = 'DALL' P2P3 P3P7 P7P6 P6P2 'PLAN' ;
  91. 'OPTI' 'ELEM' 'QUA4' ;
  92. M30 = 'DALL' P9P8 P8P4 P4P5 P5P9 'PLAN' ;
  93. M40 = 'DALL' P10P9 P9P5 P5P6 P6P10 'PLAN' ;
  94. M50 = 'DALL' P11P10 P10P6 P6P7 P7P11 'PLAN' ;
  95. M2D = M00 'ET' M10 'ET' M20 'ET' M30 'ET' M40 'ET' M50 ;
  96. 'OPTI' 'ELEM' 'CUB8' ;
  97. VEC1 = 0. 0. 5. ;
  98. M = M2D 'VOLU' 5 'TRAN' VEC1 ;
  99. M1 = (M00 'ET' M30) 'VOLU' 5 'TRAN' VEC1 ;
  100. M3 = (M20 'ET' M50) 'VOLU' 5 'TRAN' VEC1 ;
  101. M2 = (M10 'ET' M40) 'VOLU' 5 'TRAN' VEC1 ;
  102. 'ELIM' 0.001 (M 'ET' M1 'ET' M2 'ET' M3) ;
  103. COT1 = 'ENVE' M ;
  104. *
  105. *- Tables domaines
  106. *
  107. $M = 'DOMA' M ;
  108. $M1 = 'DOMA' M1 'INCL' $M;
  109. $M2 = 'DOMA' M2 'INCL' $M;
  110. $M3 = 'DOMA' M3 'INCL' $M;
  111. $D1 = 'DOMA' P4P7 'INCL' $M;
  112. *
  113. *- Resolution du probleme
  114. *
  115. CHP1 = 'MANU' 'CHPO' $M1.'CENTRE' 1 'SCAL' T1 ;
  116. CHP2 = 'MANU' 'CHPO' $M3.'CENTRE' 1 'SCAL' T2 ;
  117. CHP3 = 'KCHT' $M 'SCAL' 'CENTRE' 0. CHP1 CHP2 ;
  118. CHP4 = 'MANU' 'CHPO' $M2.'CENTRE' 1 'SCAL' 0. ;
  119. *
  120. RV = EQEX $M 'ITMA' 2
  121. 'OPTI' 'VF' 'IMPL' 'CENTREE'
  122. 'ZONE' $M 'OPER' 'DFDT' 1.D0 'CNM' 'DT' 'INCO' 'CN'
  123. 'ZONE' $M 'OPER' 'LAPN' 'DIFF' 'INCO' 'CN'
  124. 'CLIM' 'CN' 'TIMP' $M1.'CENTRE' T1
  125. 'CLIM' 'CN' 'TIMP' $M3.'CENTRE' T2
  126. ;
  127. RV . 'INCO' = TABLE 'INCO' ;
  128. RV . 'INCO' . 'CN' = 'KCHT' $M 'SCAL' 'CENTRE' 0. ;
  129. RV . 'INCO' . 'CNM' = 'KCHT' $M 'SCAL' 'CENTRE' 0. ;
  130. RV . 'INCO' . 'DIFF' = 'KCHT' $M 'SCAL' 'CENTRE' 2. ;
  131. RV . 'INCO' . 'DT' = 40. ;
  132. *
  133. EXEC RV ;
  134. *
  135. *- Solution analytique
  136. *
  137. XC YC ZC = 'COOR' $M.'CENTRE' ;
  138. SOL0 = 'LOG' ( R1 / R2 ) ;
  139. SOL1 = 'LOG' ( R1 ** T2 / (R2 ** T1)) ;
  140. RC = XC*XC + (YC*YC) ** 0.5 ;
  141. SS1 = 'MANU' 'CHPO' $M.'CENTRE' 1 'SCAL' (SOL1 / SOL0) ;
  142. SS2 = (T1 - T2) / SOL0 * (LOG RC) ;
  143. SS4 = 'MANU' 'CHPO' $M1.'CENTRE' 1 'SCAL' T1 ;
  144. SS5 = 'MANU' 'CHPO' $M3.'CENTRE' 1 'SCAL' T2 ;
  145. SS3 = 'KCHT' $M 'SCAL' 'CENTRE' (SS2 + SS1) SS4 SS5 ;
  146. *
  147. *- Tracé des résultats
  148. *
  149. ERR1 = 'ABS' ((RV.INCO.'CN') - SS3) ;
  150. 'SI' ('NEG' GRAPH 'N') ;
  151. MOD1 = 'MODE' M 'THERMIQUE' ;
  152. CHAM1 = 'KCHA' $M 'CHAM' (RV.INCO.'CN') ;
  153. 'TRAC' MOD1 CHAM1 'TITR' 'Solution' ;
  154. MERR1 = ( 'KCHA' $M 'CHAM' ERR1) ;
  155. 'TRAC' MOD1 MERR1 'TITR' 'Erreur relative' ;
  156. 'FINSI' ;
  157. *
  158. *- Gestion des erreurs
  159. *
  160. MAXE1 = 'MAXI' ERR1 ;
  161. 'MESS' 'Erreur Absolue : ' MAXE1 ;
  162. 'SI' (MAXE1 '>' 7.) ;
  163. 'ERRE' 5 ;
  164. 'SINO' ;
  165. 'ERRE' 0 ;
  166. 'FINS' ;
  167. *
  168. FIN;
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  
  176.  
  177.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales