Télécharger konv_resi_dem_shocktube_12.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : konv_resi_dem_shocktube_12.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ***********************************************************
  5. **** APPROCHE VF "Cell-Centred Formulation" pour la ****
  6. **** solution des ****
  7. **** Equations d'Euler pour un gaz parfait ****
  8. **** Approche DEM pour la combustion ****
  9. **** OPERATEURS PRET, KONV ****
  10. **** ****
  11. **** We verify the global conservativity of the method.****
  12. **** Left state = phase 1 ****
  13. **** Right state = phase 2 ****
  14. **** ****
  15. **** Methodes: SS, VLH ****
  16. **** ****
  17. **** A. BECCANTINI DM2S/SFME/LTMF DECEMBRE 2009 ****
  18. ***********************************************************
  19.  
  20.  
  21. 'OPTION' 'DIME' 2 ;
  22. 'OPTION' 'ELEM' QUA4 ;
  23. 'OPTION' 'ECHO' 1 ;
  24. 'OPTION' 'TRAC' 'X' ;
  25.  
  26. *
  27. *** GRAPH
  28. *
  29.  
  30. GRAPH = FAUX ;
  31. * GRAPH = VRAI ;
  32.  
  33. **** Cas homogene : la table proprieté de gaz
  34.  
  35. *************************************************
  36. **** The table for the properties of the gas ****
  37. *************************************************
  38. *
  39. PGAS = 'TABLE' ;
  40. *
  41. **** Order of the polynomial order for cv = cv(T)
  42. * For T > TMAX, cv(T) = cv(Tmax)
  43. *
  44. PGAS . 'TMAX' = 6000.0 ;
  45. PGAS . 'NORD' = 4 ;
  46. *
  47. **** Species involved in the mixture (before or after
  48. * the chemical reaction)
  49. *
  50. PGAS . 'SPECIES' = 'MOTS' 'H2 ' 'O2 ' 'H2O ' 'N2 ' ;
  51. *
  52. *
  53. **** Coefficient of the chemical reaction.
  54. * Note that for the first species this coefficient should be positive
  55. * Normal, we take it equal to 1.
  56. *
  57. * H2 '+' 0.5 O2 ---> H2O
  58. *
  59. PGAS . 'CHEMCOEF' = 'PROG' 1.0 0.5 -1.0 0.0 ;
  60. *
  61. **** Mass fraction of the first species before and after the combustion
  62. * Final mass fractions of the species with positive coefficients.
  63. * Final mass fractions of the species with non-positive coefficient.
  64. * The mass fraction of the last species is not given.
  65. *
  66. PGAS . 'MASSFRA' = 'PROG' 0.285219E-01 0.964039E-11 0.765104E-10
  67. 0.127442E-10 ;
  68. PGAS . 'MASSFRA' = 'PROG' 0.285219E-01 0.964039E-11 0.765104E-10
  69. 0.127442E-10 ;
  70. *
  71. **** Coef with the gas properties
  72. *
  73. PGAS . 'H2 ' = 'TABLE' ;
  74. PGAS . 'H2O ' = 'TABLE' ;
  75. PGAS . 'N2 ' = 'TABLE' ;
  76. PGAS . 'O2 ' = 'TABLE' ;
  77. *
  78. **** Runiv (J/mole/K)
  79. *
  80. PGAS . 'RUNIV' = 8.31441 ;
  81. *
  82. **** W (kg/mole). Gas constant (J/kg/K = Runiv/W)
  83. *
  84. PGAS . 'H2 ' . 'W' = 2.016E-3 ;
  85. PGAS . 'O2 ' . 'W' = 31.999E-3 ;
  86. PGAS . 'H2O ' . 'W' = 18.0155E-3 ;
  87. PGAS . 'N2 ' . 'W' = 28.013E-3 ;
  88. *
  89. **** Polynomial coefficients
  90. *
  91. PGAS . 'H2 ' . 'A' = 'PROG' 9834.91866 0.54273926 0.000862203836
  92. -2.37281455E-07 1.84701105E-11 ;
  93. PGAS . 'H2O ' . 'A' = 'PROG' 1155.95625 0.768331151 -5.73129958E-05
  94. -1.82753232E-08 2.44485692E-12 ;
  95. PGAS . 'N2 ' . 'A' = 'PROG' 652.940766 0.288239099 -7.80442298E-05
  96. 8.78233606E-09 -3.05514485E-13 ;
  97. PGAS . 'O2 ' . 'A' = 'PROG' 575.012333 0.350522002 -0.000128294865
  98. 2.33636971E-08 -1.53304905E-12;
  99. *
  100. **** Formation enthalpies (energies) at 0K (J/Kg)
  101. *
  102. PGAS . 'H2 ' . 'H0K' = -4.195D6 ;
  103. PGAS . 'H2O ' . 'H0K' = -1.395D7 ;
  104. PGAS . 'N2 ' . 'H0K' = -2.953D5 ;
  105. PGAS . 'O2 ' . 'H0K' = -2.634D5 ;
  106.  
  107.  
  108. ***************************
  109. ***** DOMAINE SPATIAL ****
  110. ***************************
  111.  
  112. A1 = 0.0D0 0.01D0;
  113. A2 = 1.011D0 0.21D0;
  114. A3 = 2.12D0 0.021D0;
  115. A4 = 2.11D0 1.09D0;
  116. A5 = 1.023D0 1.132D0;
  117. A6 = 0.098D0 1.199D0;
  118.  
  119. L12 = A1 'DROIT' 1 A2;
  120. L23 = A2 'DROIT' 1 A3;
  121. L34 = A3 'DROIT' 1 A4;
  122. L45 = A4 'DROIT' 1 A5;
  123. L56 = A5 'DROIT' 1 A6;
  124. L61 = A6 'DROIT' 1 A1;
  125. L25 = A2 'DROIT' 1 A5;
  126.  
  127. DOM10 = 'DALL' L12 L25 L56 L61
  128. 'PLANE';
  129. DOM20 = 'DALL' L23 L34 L45 ('INVERSE' L25)
  130. 'PLANE';
  131.  
  132. *
  133. *** Point ou on controlle la consistence
  134. *
  135.  
  136. P10 = 1.0 0.5;
  137.  
  138. *
  139. EPS = 1.0D-16 ;
  140. K0 = 10.0 ;
  141. *
  142. *******************************************
  143. *** Etats gauche et droite ****************
  144. *******************************************
  145. *
  146. *
  147. tg1 = 293.16 ;
  148. td1 = 293.16 ;
  149. pg1 = 1.023e5 ;
  150. pd1 = 1.023e5 ;
  151. ung1 = -122.0 ;
  152. und1 = -122.0 ;
  153. utg1 = 101.0 ;
  154. utd1 = 101.0 ;
  155. * utg1 = 0.0 ;
  156. * utd1 = 0.0 ;
  157. tg2 = 2800.15 ;
  158. td2 = 2800.15 ;
  159. pg2 = 1.023e5 ;
  160. pd2 = 1.023e5 ;
  161. ung2 = -150.0 ;
  162. und2 = -150.0 ;
  163. utg2 = 160.0 ;
  164. utd2 = 160.0 ;
  165.  
  166. TN1 = 'PROG' tg1 td1 ;
  167. TN2 = 'PROG' tg2 td2 ;
  168. PN1 = 'PROG' pg1 pd1 ;
  169. PN2 = 'PROG' pg2 pd2 ;
  170. UN1 = 'PROG' ung1 und1 ;
  171. UN2 = 'PROG' ung2 und2 ;
  172. UT1 = 'PROG' utg1 utd1 ;
  173. UT2 = 'PROG' utg2 utd2 ;
  174. ALPHA1 = 'PROG' 1.0 0.0 ;
  175. ALPHA2 = ('PROG' ('DIME' ALPHA1) '*' 1.0) '-' ALPHA1 ;
  176.  
  177. *
  178. * ETHER = int_0^T cv(T') dT' T < TMAX
  179. * = int_0^TMAX cv(T') dT' '+'
  180. * cv(TMAX) T >= TMAX
  181. *
  182.  
  183. ESP1 = 'EXTRAIRE' (PGAS . 'SPECIES') 1 ;
  184. * DY1 = y_i - y_f for the species 1
  185. DY1 = (('EXTRAIRE' (PGAS . 'MASSFRA') 1) '-'
  186. ('EXTRAIRE' (PGAS . 'MASSFRA') 2)) ;
  187. COEF1 = ('EXTRAIRE' (PGAS . 'CHEMCOEF') 1) '*'
  188. (PGAS . ESP1 . 'W') ;
  189. YFINPH1 = 1.0 ;
  190. YFINPH2 = 1.0 ;
  191. 'SI' (COEF1 > 0) ;
  192. YPH2 = 'EXTRAIRE' (PGAS . 'MASSFRA') 2 ;
  193. YPH1 = YPH2 '+' DY1 ;
  194. 'SINON' ;
  195. YPH1 = 'EXTRAIRE' (PGAS . 'MASSFRA') 2 ;
  196. YPH2 = YPH1 '-' DY1 ;
  197. 'FINSI' ;
  198. YFINPH1 = YFINPH1 '-' YPH1 ;
  199. YFINPH2 = YFINPH2 '-' YPH2 ;
  200. PRYPH1 = 'PROG' YPH1 ;
  201. PRYPH2 = 'PROG' YPH2 ;
  202. 'REPETER' BLESP (('DIME' (PGAS . 'SPECIES')) '-' 2) ;
  203. ESP = 'EXTRAIRE' (PGAS . 'SPECIES') (&BLESP '+' 1) ;
  204. COEF = ('EXTRAIRE' (PGAS . 'CHEMCOEF') (&BLESP '+' 1))
  205. '*' (PGAS . ESP . 'W') ;
  206. DY = (DY1 * (COEF '/' COEF1)) ;
  207. 'SI' (COEF > 0) ;
  208. YPH2 = 'EXTRAIRE' (PGAS . 'MASSFRA') (&BLESP '+' 2) ;
  209. YPH1 = YPH2 '+' DY ;
  210. 'SINON' ;
  211. YPH1 = 'EXTRAIRE' (PGAS . 'MASSFRA') (&BLESP '+' 2) ;
  212. YPH2 = YPH1 '-' DY ;
  213. 'FINSI' ;
  214. PRYPH1 = PRYPH1 'ET' ('PROG' YPH1) ;
  215. PRYPH2 = PRYPH2 'ET' ('PROG' YPH2) ;
  216. YFINPH1 = YFINPH1 '-' YPH1 ;
  217. YFINPH2 = YFINPH2 '-' YPH2 ;
  218. 'FIN' BLESP ;
  219. PRYPH1 = PRYPH1 'ET' ('PROG' YFINPH1) ;
  220. PRYPH2 = PRYPH2 'ET' ('PROG' YFINPH2) ;
  221. 'LISTE' PRYPH1 ;
  222. 'LISTE' PRYPH2 ;
  223. *
  224. TMAX = ('PROG' ('DIME' ALPHA1) '*' (PGAS . 'TMAX')) ;
  225. * TCAL1 = MIN TN1, TMAX
  226. TCAL1 = 0.5D0 '*' ((TMAX '+' TN1) '-' ('ABS' (TN1 '-' TMAX))) ;
  227. DTN1 = TN1 '-' TCAL1 ;
  228. * TCAL1 = MIN TN1, TMAX
  229. TCAL2 = 0.5D0 '*' ((TMAX '+' TN2) '-' ('ABS' (TN2 '-' TMAX))) ;
  230. DTN2 = TN2 '-' TCAL2 ;
  231. *
  232. * Internal energy (J/kg in SI)
  233. *
  234. ETHER1 = ('PROG' ('DIME' ALPHA1) '*' 0.0) ;
  235. CV1 = ('PROG' ('DIME' ALPHA1) '*' 0.0) ;
  236. ETHER2 = ('PROG' ('DIME' ALPHA1) '*' 0.0) ;
  237. CV2 = ('PROG' ('DIME' ALPHA1) '*' 0.0) ;
  238. FUNTN1 = ('PROG' ('DIME' ALPHA1) '*' 1.0) ;
  239. FUNTN2 = ('PROG' ('DIME' ALPHA1) '*' 1.0) ;
  240. 'REPETER' BLPO ((PGAS . 'NORD') '+' 1) ;
  241. 'REPETER' BLESP ('DIME' (PGAS . 'SPECIES')) ;
  242. ESP = 'EXTRAIRE' (PGAS . 'SPECIES') &BLESP ;
  243. YCEL1 = 'EXTRAIRE' PRYPH1 &BLESP ;
  244. YCEL2 = 'EXTRAIRE' PRYPH2 &BLESP ;
  245. AA = 'EXTRAIRE' (PGAS . ESP . 'A') &BLPO ;
  246. DCV1 = (AA * YCEL1 * FUNTN1) ;
  247. DCV2 = (AA * YCEL2 * FUNTN2) ;
  248. CV1 = CV1 '+' DCV1 ;
  249. CV2 = CV2 '+' DCV2 ;
  250. ETHER1 = ETHER1 '+' (DCV1 * TCAL1 '/' (&BLPO)) ;
  251. ETHER2 = ETHER2 '+' (DCV2 * TCAL2 '/' (&BLPO)) ;
  252. 'FIN' BLESP ;
  253. FUNTN1 = FUNTN1 '*' TCAL1 ;
  254. FUNTN2 = FUNTN2 '*' TCAL2 ;
  255. 'FIN' BLPO ;
  256. ETHER1 = ETHER1 '+' (CV1 '*' DTN1) ;
  257. ETHER2 = ETHER2 '+' (CV2 '*' DTN2) ;
  258. *
  259. * Formation energy/enthalpy (J/kg in SI) and gas constant (J/kg/K)
  260. *
  261. EFORM1 = 0.0 ;
  262. EFORM2 = 0.0 ;
  263. RGAS1 = 0.0 ;
  264. RGAS2 = 0.0 ;
  265. 'REPETER' BLESP ('DIME' (PGAS . 'SPECIES')) ;
  266. ESP = 'EXTRAIRE' (PGAS . 'SPECIES') &BLESP ;
  267. YCEL1 = 'EXTRAIRE' PRYPH1 &BLESP ;
  268. YCEL2 = 'EXTRAIRE' PRYPH2 &BLESP ;
  269. EFORM1 = EFORM1 '+' (YCEL1 * (PGAS . ESP . 'H0K')) ;
  270. EFORM2 = EFORM2 '+' (YCEL2 * (PGAS . ESP . 'H0K')) ;
  271. RGAS1 = RGAS1 '+' (YCEL1 * (PGAS . 'RUNIV') '/'
  272. (PGAS . ESP . 'W')) ;
  273. RGAS2 = RGAS2 '+' (YCEL2 * (PGAS . 'RUNIV') '/'
  274. (PGAS . ESP . 'W')) ;
  275. 'FIN' BLESP ;
  276. EFORM1 = 'PROG' ('DIME' ETHER1) '*' EFORM1 ;
  277. EFORM2 = 'PROG' ('DIME' ETHER2) '*' EFORM2 ;
  278.  
  279. *
  280. * Computation of the conservative variables
  281. *
  282. RN1 = PN1 '/' (RGAS1 '*' TN1) ;
  283. RN2 = PN2 '/' (RGAS2 '*' TN2) ;
  284. GNX1 = RN1 * UN1 ;
  285. GNY1 = RN1 * UT1 ;
  286. GNX2 = RN2 * UN2 ;
  287. GNY2 = RN2 * UT2 ;
  288. ECIN1 = 0.5D0 '*' ('PROG' ((ung1 * ung1) '+' (utg1 * utg1))
  289. ((und1 * und1) '+' (utd1 * utd1)));
  290. ECIN2 = 0.5D0 '*' ('PROG' ((ung2 * ung2) '+' (utg2 * utg2))
  291. ((und2 * und2) '+' (utd2 * utd2)));
  292. RETN1 = RN1 '*' (ETHER1 '+' ECIN1 '+' EFORM1) ;
  293. RETN2 = RN2 '*' (ETHER2 '+' ECIN2 '+' EFORM2) ;
  294. *
  295. * Computation of the resi contribution in (n,t)
  296. *
  297. retg1 = MAXI RETN1 ;
  298. rhog1 = 'MAXIMUM' RN1 ;
  299. f1gd = ung1 '*' rhog1 ;
  300. f2gd = (f1gd '*' ung1) '+' pg1 ;
  301. f3gd = f1gd '*' utg1 ;
  302. f4gd = ung1 '*' (retg1 '+' pg1);
  303.  
  304. ****************************************************
  305. ****************************************************
  306. ******** Boucle sur les angles *********
  307. ****************************************************
  308. ****************************************************
  309.  
  310. DANGLE = 360 '/' 7.15;
  311. ANGLE = 11.3 ;
  312.  
  313. 'REPETER' BLOC 8;
  314.  
    *
  315. *** Rotation
  316. *
  317.  
  318. ANGLE = ANGLE '+' DANGLE;
  319. ORIG = 0.0D0 0.0D0;
  320.  
  321. 'MESSAGE' ;
  322. 'MESSAGE' (CHAIN 'Angle de rotation= ' ANGLE);
  323. 'MESSAGE' ;
  324.  
  325. DOM1 = DOM10 'TOURNER' ANGLE ORIG;
  326. DOM2 = DOM20 'TOURNER' ANGLE ORIG;
  327. P1FAC = P10 'TOURNER' ANGLE ORIG;
  328.  
  329. DOMTOT = DOM1 ET DOM2;
  330. 'ELIMINATION' DOMTOT 1D-6;
  331.  
  332. $DOMTOT = 'MODELISER' DOMTOT 'EULER';
  333. $DOM1 = 'MODELISER' DOM1 'EULER';
  334. $DOM2 = 'MODELISER' DOM2 'EULER';
  335. TDOMTOT = 'DOMA' $DOMTOT 'VF';
  336. TDOM1 = 'DOMA' $DOM1 'VF';
  337. TDOM2 = 'DOMA' $DOM2 'VF';
  338. MDOM1 = TDOM1 . 'QUAF' ;
  339. MDOM2 = TDOM2 . 'QUAF' ;
  340. MDOMTOT = TDOMTOT . 'QUAF' ;
  341.  
  342. 'ELIM' (MDOMTOT 'ET' MDOM1 'ET' MDOM2) 1.E-6 ;
  343.  
  344. GRALP1 = 'NOMC' ('MOTS' 'UX' 'UY') ('DOMA' $DOMTOT 'XXNORMAF')
  345. ('MOTS' 'P1DX' 'P1DY') ;
  346.  
  347. *
  348. VINF = 'MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' 100. ;
  349. *
  350. **** Redefinition de P1FAC dans $DOMTOT 'FACE'
  351. *
  352.  
  353. P1FAC = ('DOMA' $DOMTOT 'FACE') 'POIN' 'PROC' P1FAC ;
  354. XSURF = 'EXTRAIRE' ('DOMA' $DOMTOT 'XXSURFAC') P1FAC 'SCAL' ;
  355. NX = 'EXTRAIRE' ('DOMA' $DOMTOT 'XXNORMAF') P1FAC 'UX' ;
  356. NY = 'EXTRAIRE' ('DOMA' $DOMTOT 'XXNORMAF') P1FAC 'UY' ;
  357. TX = -1 * NY ;
  358. TY = NX ;
  359.  
  360. GEOPC = ('DOMA' $DOMTOT 'FACEL') 'ELEM' 'APPUYE' 'LARGEMENT'
  361. P1FAC ;
  362. AA = 'CHANGER' GEOPC 'POI1' ;
  363. PC1 = 'POIN' 1 AA ;
  364. P2 = 'POIN' 1 ('DOMA' $DOMTOT 'CENTRE') ;
  365. PC2 = 'POIN' 3 AA ;
  366. * Si P3 n'existe pas, probleme en FACEL.
  367. 'SI' ('NEG' PC1 P2) ;
  368. ORIENT = -1 ;
  369. PCD = PC1 ;
  370. PCG = PC2 ;
  371. XVOLD = 'MAXIMUM' (TDOM1 . 'XXVOLUM') ;
  372. XVOLG = 'MAXIMUM' (TDOM2 . 'XXVOLUM') ;
  373. 'SINON' ;
  374. ORIENT = 1 ;
  375. PCD = PC2 ;
  376. PCG = PC1 ;
  377. XVOLG = 'MAXIMUM' (TDOM1 . 'XXVOLUM') ;
  378. XVOLD = 'MAXIMUM' (TDOM2 . 'XXVOLUM') ;
  379. 'FINSI' ;
  380.  
  381. uxg1 = ((ung1 '*' NX) '+' (utg1 '*' TX)) '*' ORIENT ;
  382. uyg1 = ((ung1 '*' NY) '+' (utg1 '*' TY)) '*' ORIENT ;
  383. uxg2 = ((ung2 '*' NX) '+' (utg2 '*' TX)) '*' ORIENT ;
  384. uyg2 = ((ung2 '*' NY) '+' (utg2 '*' TY)) '*' ORIENT ;
  385. uxd1 = ((und1 '*' NX) '+' (utd1 '*' TX)) '*' ORIENT ;
  386. uyd1 = ((und1 '*' NY) '+' (utd1 '*' TY)) '*' ORIENT ;
  387. uxd2 = ((und2 '*' NX) '+' (utd2 '*' TX)) '*' ORIENT ;
  388. uyd2 = ((und2 '*' NY) '+' (utd2 '*' TY)) '*' ORIENT ;
  389.  
  390. 'SI' GRAPH;
  391. 'TRACER' (('DOMA' $DOMTOT 'MAILLAGE') 'ET'
  392. ('COULEUR' ('DOMA' $DOMTOT 'FACEL') 'ROUGE') 'ET' P1FAC)
  393. 'TITRE' 'Domaine et FACEL';
  394. 'FINSI' ;
  395.  
  396. MAILIM = 'DIFF' ('DOMA' $DOMTOT 'FACE') ('MANUEL' 'POI1' P1FAC) ;
  397.  
  398. ***********************
  399. **** Les CHPOINTs ****
  400. ***********************
  401.  
  402. CHRN1 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' RN1) ;
  403. CHRN2 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' RN2) ;
  404.  
  405. CHVN1 = ('MANUEL' 'CHPO' (TDOM1 . 'CENTRE') 2 'UX' uxg1
  406. 'UY' uyg1) '+'
  407. ('MANUEL' 'CHPO' (TDOM2 . 'CENTRE') 2 'UX' uxd1
  408. 'UY' uyd1) ;
  409. CHVN2 = ('MANUEL' 'CHPO' (TDOM1 . 'CENTRE') 2 'UX' uxg2
  410. 'UY' uyg2) '+'
  411. ('MANUEL' 'CHPO' (TDOM2 . 'CENTRE') 2 'UX' uxd2
  412. 'UY' uyd2) ;
  413.  
  414. CHGN1 = CHRN1 '*' CHVN1 ;
  415. CHGN2 = CHRN2 '*' CHVN2 ;
  416.  
  417. CHRET1 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' RETN1) ;
  418. CHRET2 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' RETN2) ;
  419.  
  420. CHTN1 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' TN1) ;
  421. CHTN2 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' TN2) ;
  422.  
  423. CHAL1 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' ALPHA1) ;
  424. CHAL2 = ('MANUEL' 'CHPO' (TDOMTOT . 'CENTRE') 1 'SCAL' ALPHA2) ;
  425.  
  426. R1 R2 V1 V2 P1 P2 T1 T2 = 'PRIM' 'DEM' PGAS CHAL1 CHAL2
  427. (CHAL1 * CHRN1) (CHAL2 * CHRN2) (CHAL1 * CHGN1)
  428. (CHAL2 * CHGN2) (CHAL1 * CHRET1) (CHAL2 * CHRET2)
  429. CHTN1 CHTN2 EPS ;
  430.  
  431. GRADAL1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  432. 'P1DX' 0.0 'P1DY' 0.0 ;
  433. GRADAL2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  434. 'P1DX' 0.0 'P1DY' 0.0 ;
  435. LIMAL1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 1
  436. 'P1' 0.0 ;
  437. LIMAL2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 1
  438. 'P1' 0.0 ;
  439. GRADR1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  440. 'P1DX' 0.0 'P1DY' 0.0 ;
  441. GRADR2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  442. 'P1DX' 0.0 'P1DY' 0.0 ;
  443. LIMR1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 1
  444. 'P1' 0.0 ;
  445. LIMR2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 1
  446. 'P1' 0.0 ;
  447. GRADV1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 4
  448. 'P1DX' 0.0 'P1DY' 0.0 'P2DX' 0.0 'P2DY' 0.0 ;
  449. GRADV2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 4
  450. 'P1DX' 0.0 'P1DY' 0.0 'P2DX' 0.0 'P2DY' 0.0 ;
  451. LIMV1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  452. 'P1' 0.0 'P2' 0.0 ;
  453. LIMV2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  454. 'P1' 0.0 'P2' 0.0 ;
  455. GRADP1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  456. 'P1DX' 0.0 'P1DY' 0.0 ;
  457. GRADP2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 2
  458. 'P1DX' 0.0 'P1DY' 0.0 ;
  459. LIMP1 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 1
  460. 'P1' 0.0 ;
  461. LIMP2 = 'MANU' 'CHPO' (TDOMTOT . 'CENTRE') 1
  462. 'P1' 0.0 ;
  463.  
  464. *
  465. **** L'operateur 'PRET'
  466. *
  467.  
  468. CHFAL1 CHFAL2 CHFRN1 CHFRN2 CHFVN1 CHFVN2 CHFPN1 CHFPN2 =
  469. 'PRET' 'DEM' $DOMTOT
  470. CHAL1 (0.0 * GRADAL1) LIMAL1
  471. CHAL2 (0.0 * GRADAL2) LIMAL2
  472. R1 (0.0 * GRADR1) LIMR1
  473. R2 (0.0 * GRADR2) LIMR2
  474. V1 (0.0 * GRADV1) LIMV1
  475. V2 (0.0 * GRADV2) LIMV2
  476. P1 (0.0 * GRADP1) LIMP1
  477. P2 (0.0 * GRADP2) LIMP2 ;
  478.  
  479.  
  480. *
  481. **** L'operateur 'KONV'
  482. *
  483.  
  484. 'REPETER' BLMETO 3 ;
  485.  
  486. 'SI' ('EGA' &BLMETO 1) ;
  487. METO = 'SS' ;
  488. 'FINSI' ;
  489. 'SI' ('EGA' &BLMETO 2) ;
  490. METO = 'VLH' ;
  491. 'FINSI' ;
  492. 'SI' ('EGA' &BLMETO 3) ;
  493. METO = 'AUSMPUP' ;
  494. 'FINSI' ;
  495.  
  496. 'MESSAGE' ('CHAINE' 'METO = ' METO) ;
  497. LISTINC1 = ('MOTS' 'ALF1' 'RN1' 'RNX1' 'RUY1' 'RET1'
  498. 'ALF2' 'RN2' 'RUX2' 'RUY2' 'RET2') ;
  499.  
  500. SI ('EGA' METO 'AUSMPUP') ;
  501. CHPRES DT SURF = 'KONV' 'VF' 'DEM' 'RESI' METO 'CONS'
  502. $DOMTOT PGAS LISTINC1 CHAL1 CHAL2 CHFAL1 CHFAL2 CHFRN1 CHFRN2
  503. CHFVN1 CHFVN2 CHFPN1 CHFPN2 K0 GRALP1 EPS MAILIM VINF VINF ;
  504. 'SINON' ;
  505. CHPRES DT SURF = 'KONV' 'VF' 'DEM' 'RESI' METO 'CONS'
  506. $DOMTOT PGAS LISTINC1 CHAL1 CHAL2 CHFAL1 CHFAL2 CHFRN1 CHFRN2
  507. CHFVN1 CHFVN2 CHFPN1 CHFPN2 K0 GRALP1 EPS MAILIM ;
  508. 'FINSI' ;
  509.  
  510.  
  511. * 'LISTE' ('CHAINE' 'FORMAT' '(E16.10)' ('EXTRAIRE' ETHER1 1)) ;
  512. * 'LISTE' ('CHAINE' 'FORMAT' '(E16.10)' ('EXTRAIRE' ECIN1 1)) ;
  513. * 'LISTE' ('CHAINE' 'FORMAT' '(E16.10)' ('EXTRAIRE' EFORM1 1)) ;
  514. * 'LISTE' ('CHAINE' 'FORMAT' '(E16.10)' (pg1)) ;
  515. * 'LISTE' ('CHAINE' 'FORMAT' '(E16.10)' ('EXTRAIRE' RN1 1)) ;
  516. * 'LISTE' ('CHAINE' 'FORMAT' '(E16.10)' (ung1)) ;
  517. *
  518. * We verify the global conservativity of the approach
  519. *
  520. RA11 = 'EXCO' ('EXTRAIRE' LISTINC1 1) CHPRES ;
  521. RA12 = 'EXCO' ('EXTRAIRE' LISTINC1 2) CHPRES ;
  522. RA13X = 'EXCO' ('EXTRAIRE' LISTINC1 3) CHPRES ;
  523. RA13Y = 'EXCO' ('EXTRAIRE' LISTINC1 4) CHPRES ;
  524. RA13N = (RA13X '*' NX) '+' (RA13Y * NY);
  525. RA13T = (RA13X '*' TX) '+' (RA13Y * TY);
  526. RA14 = 'EXCO' ('EXTRAIRE' LISTINC1 5) CHPRES ;
  527. *
  528. RA21 = 'EXCO' ('EXTRAIRE' LISTINC1 6) CHPRES ;
  529. RA22 = 'EXCO' ('EXTRAIRE' LISTINC1 7) CHPRES ;
  530. RA23X = 'EXCO' ('EXTRAIRE' LISTINC1 8) CHPRES ;
  531. RA23Y = 'EXCO' ('EXTRAIRE' LISTINC1 9) CHPRES ;
  532. RA23N = (RA23X '*' NX) '+' (RA23Y * NY);
  533. RA23T = (RA23X '*' TX) '+' (RA23Y * TY);
  534. RA24 = 'EXCO' ('EXTRAIRE' LISTINC1 10) CHPRES ;
  535. *
  536. dRA11 = 'EXTRAIRE' RA11 'SCAL' PCD ;
  537. gRA11 = 'EXTRAIRE' RA11 'SCAL' PCG ;
  538. dRA21 = 'EXTRAIRE' RA21 'SCAL' PCD ;
  539. gRA21 = 'EXTRAIRE' RA21 'SCAL' PCG ;
  540. ERRO = 1D-8 *
  541. (('MAXIMUM' ('PROG' dRA11 gRA11 dRA21 gRA21)) 'ABS') ;
  542. HORROR = ((dRA11 '+' dRA21) * XVOLD) 'ABS' ;
  543. LOGI1 = HORROR < ERRO ;
  544. HORROR = ((gRA11 '+' gRA21) * XVOLG) 'ABS' ;
  545. LOGI2 = HORROR < ERRO ;
  546. SI ('NON' LOGI2) ;
  547. 'MESSAGE' HORROR ;
  548. 'ERREUR' 21 ;
  549. 'FINSI' ;
  550. LOGI1 = LOGI1 'ET' LOGI2;
  551. *
  552. dRA12 = 'EXTRAIRE' RA12 'SCAL' PCD ;
  553. gRA12 = 'EXTRAIRE' RA12 'SCAL' PCG ;
  554. dRA22 = 'EXTRAIRE' RA22 'SCAL' PCD ;
  555. gRA22 = 'EXTRAIRE' RA22 'SCAL' PCG ;
  556. ERRO = 1D-8 *
  557. (('MAXIMUM' ('PROG' dRA12 gRA12 dRA22 gRA22)) 'ABS') ;
  558. HORROR = (((dRA12 '+' dRA22) * XVOLD) '+'
  559. ((gRA12 '+' gRA22) * XVOLG)) ;
  560. LOGI2 = HORROR < ERRO ;
  561. SI ('NON' LOGI2) ;
  562. 'MESSAGE' HORROR ;
  563. 'ERREUR' 21 ;
  564. 'FINSI' ;
  565. LOGI1 = LOGI1 'ET' LOGI2;
  566. *
  567. dRA13N = 'EXTRAIRE' RA13N 'SCAL' PCD ;
  568. gRA13N = 'EXTRAIRE' RA13N 'SCAL' PCG ;
  569. dRA23N = 'EXTRAIRE' RA23N 'SCAL' PCD ;
  570. gRA23N = 'EXTRAIRE' RA23N 'SCAL' PCG ;
  571. ERRO = 1D-8 *
  572. (('MAXIMUM' ('PROG' dRA13N gRA13N dRA23N gRA23N)) 'ABS') ;
  573. HORROR = (((dRA13N '+' dRA23N) * XVOLD) '+'
  574. ((gRA13N '+' gRA23N) * XVOLG)) ;
  575. LOGI2 = HORROR < ERRO ;
  576. SI ('NON' LOGI2) ;
  577. 'MESSAGE' HORROR ;
  578. 'ERREUR' 21 ;
  579. 'FINSI' ;
  580. LOGI1 = LOGI1 'ET' LOGI2;
  581. *
  582. dRA13T = 'EXTRAIRE' RA13T 'SCAL' PCD ;
  583. gRA13T = 'EXTRAIRE' RA13T 'SCAL' PCG ;
  584. dRA23T = 'EXTRAIRE' RA23T 'SCAL' PCD ;
  585. gRA23T = 'EXTRAIRE' RA23T 'SCAL' PCG ;
  586. ERRO = 1D-8 *
  587. (('MAXIMUM' ('PROG' dRA13T gRA13T dRA23T gRA23T)) 'ABS') ;
  588. HORROR = (((dRA13T '+' dRA23T) * XVOLD) '+'
  589. ((gRA13T '+' gRA23T) * XVOLG)) ;
  590. LOGI2 = HORROR < ERRO ;
  591. SI ('NON' LOGI2) ;
  592. 'MESSAGE' HORROR ;
  593. 'ERREUR' 21 ;
  594. 'FINSI' ;
  595. LOGI1 = LOGI1 'ET' LOGI2;
  596. *
  597. dRA14 = 'EXTRAIRE' RA14 'SCAL' PCD ;
  598. gRA14 = 'EXTRAIRE' RA14 'SCAL' PCG ;
  599. dRA24 = 'EXTRAIRE' RA24 'SCAL' PCD ;
  600. gRA24 = 'EXTRAIRE' RA24 'SCAL' PCG ;
  601. ERRO = 1D-8 *
  602. (('MAXIMUM' ('PROG' dRA14 gRA14 dRA24 gRA24)) 'ABS') ;
  603. HORROR = (((dRA14 '+' dRA24) * XVOLD) '+'
  604. ((gRA14 '+' gRA24) * XVOLG)) ;
  605. LOGI2 = HORROR < ERRO ;
  606. SI ('NON' LOGI2) ;
  607. 'MESSAGE' HORROR ;
  608. 'ERREUR' 21 ;
  609. 'FINSI' ;
  610. LOGI1 = LOGI1 'ET' LOGI2;
  611.  
  612. 'SI' ('NON' LOGI1);
  613. 'MESSAGE' ;
  614. 'MESSAGE' 'OPERATEUR KONV';
  615. 'MESSAGE' ('CHAINE' METO);
  616. 'MESSAGE' ;
  617. 'ERREUR' 5 ;
  618. 'FINSI' ;
  619.  
  620. 'FIN' BLMETO ;
  621.  
  622. ****************************************************
  623. ****************************************************
  624. ******** Fin boucle sur les angles *********
  625. ****************************************************
  626. ****************************************************
  627.  
  628. 'FIN' BLOC;
  629.  
  630. 'FIN' ;
  631.  
  632.  
  633.  
  634.  
  635.  
  636.  
  637.  
  638.  
  639.  
  640.  
  641.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales