Télécharger joi_ama.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : joi_ama.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. GRAPH = 'N' ;
  5. SAUT PAGE ;
  6. ********************************************************************
  7. MESS ' ';
  8. MESS ' ';
  9. MESS ' ';
  10. MESS ' ';
  11. MESS ' TEST AVEC UN JOINT (2D) POUR LE MODELE DE AMADEI-SAEB ';
  12. MESS ' ';
  13. MESS ' LA SURFACE DE HAUT DU JOINT EST SOUMISE A UN DEPL. IMPOSE ';
  14. MESS ' SELON LA DIRECTION TANGENTIELLE ET A UNE FORCE CONSTANTE ';
  15. MESS ' SELON LA DIRETION NORMALE ';
  16. MESS ' ';
  17. MESS ' ';
  18. MESS ' ';
  19. MESS ' ';
  20. MESS ' ';
  21. MESS ' ';
  22. MESS ' A _______________ H ';
  23. MESS ' | | ';
  24. MESS ' |_______________| ';
  25. MESS ' G D ';
  26. MESS ' ';
  27. MESS ' ';
  28. MESS ' ';
  29. MESS ' ';
  30. MESS ' ';
  31. MESS ' JOINT FORME DES NOEUDS DG-HA ';
  32. MESS ' ';
  33. MESS ' CONDITIONS AUX LIMITES : ';
  34. MESS ' - DG BLOQUEE EN UX ET EN UY ';
  35. MESS ' ';
  36. MESS ' CHARGEMENT : ';
  37. MESS ' - DEPLACEMENT IMPOSE ET FORCE SUR HA ';
  38. MESS ' ';
  39. MESS ' ';
  40. MESS ' ';
  41. MESS ' DANS CET ESSAI ON COMPARE LA CONTRAINTE TANGENTIELLE ET ';
  42. MESS ' LE DEPLACEMENT NORMAL AUX QUANTITES CORRESPONDANTES ';
  43. MESS ' CALCULEES ANALYTIQUEMENT. ';
  44. MESS ' ';
  45. MESS ' ';
  46. MESS ' ';
  47. ********************************************************************
  48. *
  49. *
  50. OPTION ECHO 1 DIME 2 ;
  51. OPTION ELEM SEG2 MODE PLAN CONT ;
  52. TEMPS ;
  53. *
  54. *------------------------------------------------
  55. * --------- DEFINITION DE LA GEOMETRIE ----------
  56. *------------------------------------------------
  57. *
  58. A = 0.00 0.00 ;
  59. H = 1.00 0.00 ;
  60. *
  61. G = 0.00 0.00 ;
  62. D = 1.00 0.00 ;
  63. *
  64. HA = H DROIT 1 A ;
  65. *
  66. DG = D DROIT 1 G ;
  67. *
  68. *-----------------------------------------------------
  69. * -------------- DEFINITION DU MAILLAGE --------------
  70. *-----------------------------------------------------
  71. *
  72. OPTION ELEM RAC2 ;
  73. *
  74. JOINT = RACC 0.001 (INVE HA) (INVE DG) ;
  75. *
  76. *------------------------------------------------------------------
  77. * -------------- DEFINITION DES CONDITIONS AUX LIMITES ------------
  78. *------------------------------------------------------------------
  79. *
  80. CL1 = BLOQ DG UX UY ;
  81. *
  82. CL5 = BLOQ HA UX ;
  83. *
  84. CLTOT = CL1 ET CL5 ;
  85. *
  86. *-----------------------------------------------------------------
  87. * -------------- DEFINITION DU MODELE E DU MATERIAU --------------
  88. *-----------------------------------------------------------------
  89. *
  90. MODJOI = MODE JOINT 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE'
  91. 'AMADEI' JOI2 ;
  92. *
  93. MAJOI = MATE MODJOI KS 5. KN 20. RHO 0. ALPN 0. FIMU 30.
  94. SGMT -20. I0 10. S0 6.5 B0 0.7 UR 14.
  95. UP 4. KNI 6. FI0 23. VM 1. ;
  96. *
  97. *--------------------------------------------------------------
  98. * ------------------- DEFINITION DU CHARGEMENT ----------------
  99. *--------------------------------------------------------------
  100. *
  101. DEP6 = FORCE FY -10.0 HA ;
  102. DEP5 = DEPI CL5 20.0 ;
  103. *
  104. L56 = PROG 0.0 1.0 1.0 ;
  105. L55 = PROG 0.0 0.0 1.0 ;
  106. L50 = PROG 0.0 1.0 2.0 ;
  107. *
  108. EV5 = EVOL MANU X L50 Y L55 ;
  109. EV6 = EVOL MANU X L50 Y L56 ;
  110. *
  111. CAR5 = CHAR 'DIMP' DEP5 EV5 ;
  112. CAR6 = CHAR 'MECA' DEP6 EV6 ;
  113. CART = CAR5 ET CAR6 ;
  114.  
  115. *
  116. *-------------------------------------------------------
  117. * --------------------- RESOLUTION ---------------------
  118. *-------------------------------------------------------
  119. *
  120. TAB = TABLE ;
  121. LIS1 = PROG 0.0 PAS 0.05 2.0 ;
  122. TAB.'BLOCAGES_MECANIQUES' = CLTOT;
  123. TAB.'MODELE' = MODJOI;
  124. TAB.'CHARGEMENT' = CART;
  125. TAB.'TEMPS_CALCULES' = LIS1;
  126. TAB.'CARACTERISTIQUES' = MAJOI;
  127. *
  128. TMASAU=table;
  129. tab . 'MES_SAUVEGARDES'=TMASAU;
  130. TMASAU .'DEFTO'=VRAI;
  131. TMASAU .'DEFIN'=VRAI;
  132. PASAPAS TAB ;
  133. *
  134. *--------------------------------------
  135. * ---------- POST TRAITEMENT ----------
  136. *--------------------------------------
  137. *
  138. sig1 = prog ; sig2 = prog ; var1 = prog ; var2 = prog ;
  139. var3 = prog ; var4 = prog ; var5 = prog ; var6 = prog ;
  140. dep1 = prog ; dep2 = prog ; tem0 = prog ; tem1 = prog ;
  141. *
  142. dtab1=index(tab.deplacements) ;
  143. *
  144. ndime=dime dtab1 ;
  145. *
  146. *
  147. i=0 ;
  148. *
  149. REPETER BOU1 ndime ;
  150. *
  151. i=i+1 ;
  152. *
  153. d=dtab1.i ;
  154. *
  155. dep0 = tab.deplacements.d ;
  156. sig0 = tab.contraintes.d ;
  157. var0 = tab.variables_internes.d ;
  158. def0 = tab.deformations_inelastiques.d ;
  159. *
  160. DEPJOI = REDU DEP0 JOINT ;
  161. SIGJOI = REDU SIG0 JOINT ;
  162. VARJOI = REDU VAR0 JOINT ;
  163. DEFJOI = REDU DEF0 JOINT ;
  164. *
  165. tau1 = extr SIGJOI 'SMSN' 1 1 1 ;
  166. tau2 = extr SIGJOI 'SMN' 1 1 1 ;
  167. *
  168. sor1 = extr VARJOI 'EPSE' 1 1 1 ;
  169. sor2 = extr VARJOI 'EPOU' 1 1 1 ;
  170. sor3 = extr VARJOI 'STAT' 1 1 1 ;
  171. sor4 = extr VARJOI 'UEQU' 1 1 1 ;
  172. sor5 = extr VARJOI 'EPS1' 1 1 1 ;
  173. sor6 = extr VARJOI 'EPS2' 1 1 1 ;
  174. *
  175. pla1 = extr DEFJOI 'FRSN' 1 1 1 ;
  176. pla2 = extr DEFJOI 'FRN' 1 1 1 ;
  177. *
  178. sig1 = inse sig1 i tau1 ;
  179. sig2 = inse sig2 i tau2 ;
  180. *
  181. var1 = inse var1 i sor1 ;
  182. var2 = inse var2 i sor2 ;
  183. var3 = inse var3 i sor3 ;
  184. var4 = inse var4 i sor4 ;
  185. var5 = inse var5 i sor5 ;
  186. var6 = inse var6 i sor6 ;
  187. *
  188. tem0 = inse tem0 i d ;
  189. *
  190. dep1 = inse dep1 i pla1 ;
  191. dep2 = inse dep2 i pla2 ;
  192. *
  193. fin bou1 ;
  194. *
  195. si ( NEG graph 'N' ) ;
  196. *
  197. gra1 = evol manu U var5 T sig1 ;
  198. gra2 = evol manu V var6 S sig2 ;
  199. gra3 = evol manu t0 tem0 EPSE var1 ;
  200. gra4 = evol manu t0 tem0 UEQU var4 ;
  201. gra5 = evol manu t0 tem0 STAT var3 ;
  202. gra6 = evol comp t0 tem0 U_DRS var5 dep1 ;
  203. gra7 = evol manu t0 tem0 DRN dep2 ;
  204. *
  205. dess gra1 ;
  206. dess gra2 ;
  207. dess gra3 ;
  208. dess gra4 ;
  209. dess gra5 ;
  210. dess gra6 ;
  211. dess gra7 ;
  212. *
  213. finsi ;
  214. *
  215. *-------------------------------------------------------------
  216. *------------------ CODE DE FONCTIONNEMENT -------------------
  217. *-------------------------------------------------------------
  218. *
  219. *
  220. * listreel de la contrainte tangentielle de repère en fonction du temps *
  221. *
  222. pro1 = prog
  223. 2.2599 4.5197 6.7796 9.0394 8.9038 8.7682 8.6327 8.4971 8.3615
  224. 8.2259 8.0903 7.9547 7.8191 7.6835 7.6835 7.6835 7.6835 7.6835
  225. 7.6835 7.6835 ;
  226. *
  227. *
  228. ***** listreel du déplacement normal de repère en fonction du temps *****
  229. *
  230. pro2 = prog
  231. -7.6984E-02 -.1430 -.2001 -.2501 -.2943 -.3335 -.3686
  232. -.4002 -.4288 -.4548 -.4785 -.5003 -.5203 -.5388 -.5558
  233. -.5717 -.5866 -.6003 -.6132 -.6252 ;
  234. *
  235. j1 = 21 ;
  236. j2 = 1 ;
  237. ii0 = 0 ;
  238. num1 = 0. ;
  239. num2 = 0. ;
  240. den1 = 0. ;
  241. den2 = 0. ;
  242. *
  243. repeter bou2 20 ;
  244. *
  245. j1 = j1 + 1 ;
  246. j2 = j2 + 1 ;
  247. ii0 = ii0 + 1 ;
  248. *
  249. ttt1 = extr sig1 j1 ;
  250. vvv1 = extr var6 j2 ;
  251. ttt0 = extr pro1 ii0 ;
  252. vvv0 = extr pro2 ii0 ;
  253. *
  254. num1 = num1 + ((ttt1 - ttt0) * (ttt1 - ttt0)) ;
  255. num2 = num2 + ((vvv1 - vvv0) * (vvv1 - vvv0)) ;
  256. den1 = den1 + (ttt0 * ttt0) ;
  257. den2 = den2 + (vvv0 * vvv0) ;
  258. *
  259. fin bou2 ;
  260. *
  261. err0 = (num1/den1) * 100. ;
  262. err1 = (num2/den2) * 100. ;
  263. *
  264. si ((err0 < 5.) et (err1 < 5.)) ;
  265. *
  266. ERRE 0 ;
  267. *
  268. sinon ;
  269. *
  270. ERRE 5 ;
  271. *
  272. finsi ;
  273. *
  274. fin;
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  
  281.  
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales