Télécharger joi1_lie_2.dgibi

Retour à la liste

Numérotation des lignes :

  1. 'OPTI' 'ECHO' 0 ;
  2. ************************************************************************
  3. ************************************************************************
  4. itrac = FAUX ;
  5.  
  6. ************************************************************************
  7. * Cas test sur la mise a jour des vecteurs orientant les elements JOI1 *
  8. * avec FORM *
  9. * *
  10. * On modelise le contact entre deux poutres a section annulaires *
  11. * lorsque l'une d'elles est flechie et vient toucher l'autre. *
  12. * *
  13. * Les poutres sont sont modelisees avec des elements TUYA. *
  14. * Le contact est modelise par des elements JOI1 *
  15. * La mise a jour du repere local des joints, au cours du calcul, *
  16. * permet de gerer le contact lorsque sa direction change *
  17. * *
  18. * *
  19. * _________________________ *
  20. * | *
  21. * | *
  22. * | Deplacement UX impose au sommet *
  23. * | de la poutre A *
  24. * | ____ *
  25. * | B .' `. *
  26. * | / \ *
  27. * A | | B | | *
  28. * | ____ \ / *
  29. * | Z A .' `. `.____.' *
  30. * | | / \ *
  31. * | ---X | ---> | Y *
  32. * | \ / | *
  33. * | `.____.' ---X *
  34. * __________|______________ *
  35. * *
  36. * *
  37. * - element joint, liaison, JOI1 *
  38. * - grands deplacements *
  39. * - PASAPAS *
  40. * *
  41. ************************************************************************
  42.  
  43.  
  44.  
  45.  
  46. ** Parametres geometriques des poutres (section annulaire)
  47. * hauteur, rayon, epaisseur, entraxe, angle
  48. h = 0.5 ;
  49. re = 1.2E-2 ;
  50. ep = 1.E-3 ;
  51. dt = 3.E-2 ;
  52. alpha = 30. ;
  53.  
  54.  
  55. ** Hauteur du maillage de contact (par des joints)
  56. hc = 0.01 ;
  57.  
  58.  
  59. ** Valeur du deplacement impose au sommet de la poutre 1
  60. uimp = 2. * dt ;
  61.  
  62.  
  63. ** Verification qu'il y aura bien contact
  64. de = 2. * re ;
  65. a = (uimp / 1.)**2 ;
  66. b = -2. * dt * (COS alpha) * uimp / 1. ;
  67. c = (dt**2) - (de**2) ;
  68. delta = (b**2) - (4. * a * c) ;
  69. SI (delta < 0.) ;
  70. MESS ;
  71. MESS '***** Aucun contact possible avec ce jeu de parametres' ;
  72. MESS '***** ECHEC du cas test !' ;
  73. MESS ;
  74. ERREUR 5 ;
  75. FINSI ;
  76.  
  77.  
  78. ** Options generales
  79. OPTI 'DIME' 3 'ELEM' 'SEG2' ;
  80.  
  81.  
  82. ** Maillage des poutres
  83. p1b = 0. 0. 0. ;
  84. p1h = 0. 0. h ;
  85. l1 = DROI 40 p1b p1h ;
  86. p1hb = l1 POIN 'PROC' (0. 0. (h - hc)) ;
  87. z1b = COOR 3 p1hb ;
  88. l2 = l1 PLUS ((dt * (COS alpha)) (dt * (SIN alpha)) z1b) ;
  89. p2b = l2 POIN 'INIT' ;
  90. p2h = l2 POIN 'FINA' ;
  91. p2bb = l2 POIN 'PROC' p1h ;
  92. ltot = l1 ET l2 ;
  93.  
  94.  
  95. ** Maillage des joints sur la zone ou les poutres peuvent se toucher
  96. l1c = l1 ELEM 'COMP' p1hb p1h ;
  97. mp1 = CHAN 'POI1' l1c ;
  98. j = VIDE 'MAILLAGE'/'SEG2' ;
  99. REPE b1 (NBEL mp1) ;
  100. p11 = mp1 POIN &b1 ;
  101. p22 = l2 POIN 'PROC' p11 ;
  102. j = j ET (DROI 1 p11 p22) ;
  103. FIN b1 ;
  104.  
  105.  
  106. ** Modele et materiau
  107. mo = MODE ltot 'MECANIQUE' 'ELASTIQUE' 'TUYA' 'CONS' 'AIGUILLES' ;
  108. ma = MATE mo 'YOUN' 200.E9 'NU' 0.3 'EPAI' ep 'RAYO' re ;
  109. moj = MODE j 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE'
  110. 'PLASTIQUE' 'COULOMB'
  111. 'JOI1' 'CONS' 'JOINTS' 'LIE' ;
  112. maj = MATE moj 'KN' 1.E6 'KS1' 1. 'KS2' 1.
  113. 'QN' 1. 'QS1' 1. 'QS2' 1.
  114. 'FNE' 1.E30 'QT' 0. 'COHE' 0. 'FRIC' 0. 'TYPE' 1
  115. 'DIRECTION' ((COS alpha) (SIN alpha) 0.) (0. 0. 1.) ;
  116.  
  117.  
  118. ** Conditions aux limites (encastrement des extremites et
  119. * deplacement impose au sommet de la poutre 1)
  120. bl1 = BLOQ 'DEPL' 'ROTA' (p1b ET p2h) ;
  121. bl2 = BLOQ 'UY' 'UZ' p1h ;
  122. bl3 = BLOQ 'UX' p1h ;
  123. f1 = DEPI bl3 uimp ;
  124. ev1 = EVOL 'MANU' (PROG 0. 1.E-9 1.) (PROG 0. 0. 1.) ;
  125. cha1 = CHAR 'DIMP' f1 ev1 ;
  126.  
  127.  
  128. ** Chargement de deformation impose dans les joints pour
  129. * represener le jeu initial
  130. jeu0 = dt - (2. * re) ;
  131. exx = MANU 'CHML' moj 'EXX' (-1. * jeu0) 'TYPE' 'DEFORMATIONS'
  132. 'STRESSES' ;
  133. e1 = (ZERO (mo ET moj) 'DEFORMATIONS') + exx ;
  134. ev2 = EVOL 'MANU' (PROG 0. 1.E-9 1.) (PROG 0. 1. 1.) ;
  135. cha2 = CHAR 'DEFI' e1 ev2 ;
  136.  
  137.  
  138. ** Trace du maillage
  139. SI itrac ;
  140. TRAC (ltot ET (j COUL 'VERT')) 'TITR' 'Maillage' ;
  141. FINSI ;
  142.  
  143.  
  144. ** Calcul avec PASAPAS
  145. * on fait 1 premier pas de temps tres petit pour la mise en place
  146. * du jeu initial sous forme de deformation imposee dans les joints
  147. xpas = 0.01 ;
  148. tab = TABL ;
  149. tab . 'MODELE' = mo ET moj ;
  150. tab . 'CARACTERISTIQUES' = ma ET maj ;
  151. tab . 'BLOCAGES_MECANIQUES' = bl1 ET bl2 ET bl3 ;
  152. tab . 'CHARGEMENT' = cha1 ET cha2 ;
  153. tab . 'TEMPS_CALCULES' = PROG 1.E-9 xpas PAS xpas 1. ;
  154. tab . 'GRANDS_DEPLACEMENTS' = VRAI ;
  155. PASAPAS tab ;
  156.  
  157.  
  158.  
  159.  
  160. ** Verification du bon comportement
  161. * - la distance entre les deux tuyaux doit rester superieure
  162. * au diametre exterieur
  163. * - le premier instant du contact doit etre egal a la valeur theorique
  164. * - la poutre 2 doit toujours flechir dans la direction du contact
  165.  
  166.  
  167. ** Cercles pour visualiser les sections sur le maillage deforme
  168. SI itrac ;
  169. pcer = re 0. 0. ;
  170. cer0 = CERC 10 pcer (0. 0. 0.) (0. re 0.) ;
  171. cer0 = CERC 10 cer0 (0. 0. 0.) ((-1. * re) 0. 0.) ;
  172. cer0 = CERC 10 cer0 (0. 0. 0.) (0. (-1. * re) 0.) ;
  173. cer0 = CERC 10 cer0 (0. 0. 0.) pcer ;
  174. FINSI ;
  175.  
  176.  
  177. ** Calcul des indicateurs de post-traitement
  178. tt = tab . 'TEMPS' ;
  179. tu = tab . 'DEPLACEMENTS' ;
  180. ts = tab . 'CONTRAINTES' ;
  181. n1 = 'DIME' tt ;
  182. tdc = 0. ;
  183. tfc = 1. ;
  184. logdc = FAUX ;
  185. logfc = FAUX ;
  186. ltps = PROG ;
  187. leffx = PROG ;
  188. lvu2 = PROG ;
  189. ldir1 = PROG ;
  190. ldir2 = PROG ;
  191. conf0 = FORM ;
  192. ld12 = PROG ;
  193. REPE b1 n1 ;
  194. i1 = &b1 - 1 ;
  195. tps1 = tt . i1 ;
  196. SI (EGA tps1 1.E-9) ;
  197. ITER b1 ;
  198. FINSI ;
  199. ltps = ltps ET tps1 ;
  200. u1 = tu . i1 ;
  201. FORM u1 ;
  202. * distance entre les points de contact au sommet
  203. p12 = p2bb MOIN p1h ;
  204. ld12 = ld12 ET (NORM p12) ;
  205. * reaction au contact
  206. s1 = REDU (ts . i1) moj ;
  207. effx1 = 0. ;
  208. REPE b2 (NBEL j) ;
  209. effx1 = effx1 + (ABS (EXTR s1 'EFFX' 1 &b2 1)) ;
  210. FIN b2 ;
  211. leffx = leffx ET effx1 ;
  212. * detection de l'instant ou debute le contact
  213. SI ((NON logdc) ET (effx1 > 1.E-1)) ;
  214. logdc = VRAI ;
  215. tdc = 0.5 * (tps1 + (tt . (i1 - 1))) ;
  216. FINSI ;
  217. * detection de l'instant ou fini le contact
  218. SI (logdc ET (NON logfc) ET (effx1 &lt;EG 1.E-1)) ;
  219. logfc = VRAI ;
  220. tfc = 0.5 * (tps1 + (tt . (i1 - 1))) ;
  221. FINSI ;
  222. * direction du contact (angle d'orientation du bipoint)
  223. dir1 = ATG (COOR 2 p12) (COOR 1 p12) ;
  224. ldir1 = ldir1 ET dir1 ;
  225. * amplitude du deplacement du point "esclave"
  226. up12 = REDU u1 (p1h ET p2bb) ;
  227. ux2 = EXTR up12 'UX' p2bb ;
  228. uy2 = EXTR up12 'UY' p2bb ;
  229. uz2 = EXTR up12 'UZ' p2bb ;
  230. vu2 = ((ux2**2) + (uy2**2) + (uz2**2))**0.5 ;
  231. lvu2 = lvu2 ET vu2 ;
  232. * direction du deplacement du point "esclave"
  233. vu22 = ((ux2**2) + (uy2**2))**0.5 ;
  234. SI ((vu22 &lt;EG 1.E-6) OU (NON logdc) OU logfc) ;
  235. dir2 = 0. ;
  236. SINON ;
  237. dir2 = ATG uy2 ux2 ;
  238. FINSI ;
  239. ldir2 = ldir2 ET dir2 ;
  240. * trace de la deformee
  241. SI itrac ;
  242. vec1 = VECT up12 'DEPL' 1. 'VERT' ;
  243. tit1 = CHAI 'Deformee a l instant ' tps1 ;
  244. cer1 = ((cer0 PLUS p1h) ET (cer0 PLUS p1hb)) COUL 'ROUG' ;
  245. cer2 = ((cer0 PLUS p2b) ET (cer0 PLUS p2bb)) COUL 'JAUN' ;
  246. TRAC vec1 (ltot ET cer1 ET cer2) 'TITR' tit1 ;
  247. FINSI ;
  248. FORM conf0 ;
  249. FIN b1 ;
  250.  
  251. MESS '***** LE CONTACT A LIEU ENTRE LES INSTANTS :' ;
  252. MESS tdc ;
  253. MESS tfc ;
  254.  
  255. SI itrac ;
  256. evd12 = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Distance' ld12 ;
  257. DESS evd12 'TITR' 'Distance points A--B vs Temps' ;
  258. FINSI ;
  259.  
  260.  
  261. ** Test1 : premier instant de contact
  262. MESS '***** TEST 1 : INSTANT DU PREMIER CONTACT' ;
  263. tdcthe = ((-1. * b) - (delta**0.5)) / (2. * a) ;
  264. err1 = ABS ((tdc - tdcthe) / xpas) ;
  265. MESS '- Instant de contact theorique =' tdcthe ;
  266. MESS '- Instant de contact calcule =' tdc ;
  267. MESS '- Ecart en nombre de pas de temps =' err1 ;
  268. SI itrac ;
  269. eveffx = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Effort' leffx ;
  270. DESS eveffx 'TITR' 'Resultante de l effort de contact vs Temps' ;
  271. FINSI ;
  272. SI (err1 > 1.5) ;
  273. MESS '***** ECHEC du cas test !' ;
  274. MESS ;
  275. ERREUR 5 ;
  276. SINON ;
  277. MESS '***** OK !' ;
  278. FINSI ;
  279.  
  280.  
  281. ** Test 2 : la poutre 2 doit se deplacer dans la direction du contact
  282. MESS '***** TEST 2 : DEPLACEMENT DE LA POUTRE 2' ;
  283. err2m = 0. ;
  284. tps2m = 0. ;
  285. err3m = 0. ;
  286. tps3m = 0. ;
  287. REPE b1 (DIME ltps) ;
  288. tps1 = EXTR ltps &b1 ;
  289. * hors du contact, on regarde l'amplitude du deplacement
  290. SI ((tps1 < tdc) OU (tps1 > tfc)) ;
  291. v2 = EXTR lvu2 &b1 ;
  292. SI (v2 > err3m) ;
  293. err3m = v2 ;
  294. tps3m = tps1 ;
  295. FINSI ;
  296. * pendant le contact, on regarde la direction du deplacement
  297. SINON ;
  298. dir1 = EXTR ldir1 &b1 ;
  299. dir2 = EXTR ldir2 &b1 ;
  300. err2 = ABS (dir2 - dir1) ;
  301. SI (err2 > err2m) ;
  302. err2m = err2 ;
  303. tps2m = tps1 ;
  304. FINSI ;
  305. FINSI ;
  306. FIN b1 ;
  307. MESS '- [Pendant le contact] ecart d angle max =' err2m ;
  308. MESS '- [ Hors du contact] amplitude max =' err3m ;
  309. SI ((err2m > 3.) OU (err3m > (0.1 * uimp))) ;
  310. MESS '***** ECHEC du cas test !' ;
  311. MESS '***** instant de l ecart max d angle = ' tps2m ;
  312. MESS '***** instant de l amplitude max = ' tps3m ;
  313. MESS ;
  314. ERREUR 5 ;
  315. SINON ;
  316. MESS '***** OK !' ;
  317. FINSI ;
  318. SI itrac ;
  319. evd1 = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Direction' ldir1 ;
  320. evd2 = EVOL 'VERT' 'MANU' 'Temps' ltps 'Direction' ldir2 ;
  321. DESS (evd1 ET evd2) 'TITR'
  322. 'Direction du deplacement (v) et du contact (r) vs Temps' ;
  323. evu2 = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Apmplitude' lvu2 ;
  324. DESS evu2 'TITR' 'Amplitude du deplacement vs Temps' ;
  325. FINSI ;
  326.  
  327.  
  328. FIN ;
  329.  
  330.  
  331.  
  332.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales