Télécharger joi1_coul_plas.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : joi1_coul_plas.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. f = mot fin; l = mot list; tr = mot trac;
  6. 'OPTI' 'ECHO' 1 ;
  7.  
  8. 'OPTI' 'ELEM' 'SEG2' 'DIME' 3 'MODE' 'TRID' ;
  9. 'OPTI' 'EPSILON' 'LINEAIRE' ;
  10.  
  11. GRAPH = FAUX ;
  12.  
  13. P1 = 0 0 0 ;
  14. P2 = 0 0 0 ;
  15.  
  16. jo = P1 P2 'DROIT' 1 ;
  17.  
  18. ************************************************************************
  19. * Début: MODELE *
  20. ************************************************************************
  21. mo = MODE jo 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE'
  22. 'PLASTIQUE' 'COULOMB' 'JOI1' ;
  23.  
  24. ************************************************************************
  25. * Fin: MODELE *
  26. ************************************************************************
  27.  
  28.  
  29. ************************************************************************
  30. * Début: MATERIAU *
  31. ************************************************************************
  32. kn = 100. ;
  33. ks1 = 50. ;
  34. ks2 = ks1 ;
  35.  
  36. qn = 40. ;
  37. qs1 = 20. ;
  38. qs2 = 30. ;
  39. *
  40. phi = 45. ;
  41.  
  42. kt = kn/10. ;
  43. fne = 15. ;
  44. *fne = 150. ;
  45.  
  46.  
  47. ma = 'MATE' mo 'DIRECTION' (1 0 0) (0 1 0)
  48. 'KN ' kn 'KS1 ' ks1 'KS2 ' ks2
  49. 'QN ' qn 'QS1 ' qs1 'QS2 ' qs2
  50. 'TYPE' 1. 'FRIC' phi
  51. 'QT ' kt 'FNE ' fne 'COHE' 0. ;
  52.  
  53. ************************************************************************
  54. * Fin: MATERIAU *
  55. ************************************************************************
  56.  
  57. ************************************************************************
  58. * Début: CL & CHARGEMENT *
  59. ************************************************************************
  60. cl1 = 'BLOQ' 'DEPL' 'ROTA' P1 ;
  61. cl2 = 'BLOQ' 'UX' P2 ;
  62. cl3 = 'BLOQ' 'UY' P2 ;
  63. cl = cl1 'ET' cl2 'ET' cl3 ;
  64.  
  65. vdpi = 0.1 ;
  66. dpi = 'DEPI' cl2 vdpi ;
  67. lt = 'PROG' 0 2 4 6 7 ;
  68. lc = 'PROG' 0 -2 -2 -2 -1 ;
  69. ev = 'EVOL' 'MANU' 't' lt 'coef' lc ;
  70.  
  71. cha1 = 'CHAR' 'DIMP' dpi ev ;
  72.  
  73.  
  74. vdpi2 = 0.1 ;
  75. dpi2 = 'DEPI' cl3 vdpi2 ;
  76. lt2 = 'PROG' 0 2 4 6 7 ;
  77. lc2 = 'PROG' 0 0 3.1 5 5 ;
  78. ev2 = 'EVOL' 'MANU' 't' lt2 'coef' lc2 ;
  79.  
  80. cha2 = 'CHAR' 'DIMP' dpi2 ev2 ;
  81.  
  82.  
  83. cha = cha1 et cha2 ;
  84. *opti donn 5;
  85. ************************************************************************
  86. * Fin: CL & CHARGEMENT *
  87. ************************************************************************
  88. dt1 = 0.10 ;
  89. dt2 = 0.05 ;
  90. lt = 'PROG' 0.1 pas dt1 7 ;
  91.  
  92.  
  93. tab = 'TABLE' ;
  94. tab.'MODELE' = mo ;
  95. tab.'CARACTERISTIQUES' = ma ;
  96. tab.'BLOCAGES_MECANIQUES' = cl ;
  97. tab.'CHARGEMENT' = cha ;
  98. tab.'TEMPS_CALCULES' = lt ;
  99. tab.'FTOL' = 1E-3 ;
  100.  
  101. PASAPAS tab ;
  102.  
  103.  
  104. time=tab.'TEMPS';
  105. ntime = 'DIME' time ;
  106. n=ntime - 1 ;
  107.  
  108. progt = 'PROG' ;
  109. prN = 'PROG' ;
  110. prFY = 'PROG' ;
  111. prepse = 'PROG' ;
  112. prouv = 'PROG' ;
  113. prlam1 = 'PROG' ;
  114. prlam3 = 'PROG' ;
  115. prpla1 = 'PROG' ;
  116. prpla3 = 'PROG' ;
  117. prepco = 'PROG' ;
  118. pretat = 'PROG' ;
  119. ouv = 0. ;
  120. ************************************************************************
  121. * RESULTATS CALCULES *
  122. ************************************************************************
  123. REPETER contro ntime ;
  124. i = &contro - 1 ;
  125. t = time.i ;
  126. progt = progt 'ET' ('PROG' t) ;
  127. *-
  128. sig = tab.'CONTRAINTES'.i ;
  129. prN = prN 'ET' ('PROG' ('EXTR' sig 'EFFX' 1 1 1)) ;
  130. prFY = prFY 'ET' ('PROG' ('EXTR' sig 'EFFY' 1 1 1)) ;
  131. *-
  132. vi = tab.'VARIABLES_INTERNES'.i ;
  133. prepse = prepse 'ET' ('PROG' ('EXTR' vi 'EPSE' 1 1 1)) ;
  134. ouv = ouv + ('EXTR' vi 'EPOU' 1 1 1) ;
  135. prouv = prouv 'ET' ('PROG' ouv) ;
  136. prlam1 = prlam1 'ET' ('PROG' ('EXTR' vi 'LAM1' 1 1 1)) ;
  137. prlam3 = prlam3 'ET' ('PROG' ('EXTR' vi 'LAM3' 1 1 1)) ;
  138. prpla1 = prpla1 'ET' ('PROG' ('EXTR' vi 'PLA1' 1 1 1)) ;
  139. prpla3 = prpla3 'ET' ('PROG' ('EXTR' vi 'PLA3' 1 1 1)) ;
  140. prepco = prepco 'ET' ('PROG' ('EXTR' vi 'EPCO' 1 1 1)) ;
  141. pretat = pretat 'ET' ('PROG' ('EXTR' vi 'STAT' 1 1 1)) ;
  142. FIN contro ;
  143. *-----------------------------------------------------------------------
  144. evN = evol manu 't' progt 'N' prN ;
  145. evepco = evol manu 't' progt 'EPCO' prepco ;
  146. evlam3 = evol manu 't' progt 'LAM3' prlam3 ;
  147. evouv = evol manu 't' progt 'EPOU' prouv ;
  148. evlam1 = evol manu 't' progt 'LAM1' prlam1 ;
  149. evpla3 = evol manu 't' progt 'PLA3' prpla3 ;
  150. evepse = evol manu 't' progt 'EPSE' prepse ;
  151. evFY = evol manu 't' progt 'FY' prFY ;
  152. evpla1 = evol manu 't' progt 'PLA1' prpla1 ;
  153. evetat = evol manu 't' progt 'STAT' pretat ;
  154.  
  155. ************************************************************************
  156. * RESULTATS THEORIQUES *
  157. ************************************************************************
  158. tg=tan phi ;
  159.  
  160. *- Elasticité en compression (0 à t_0)
  161. * ------------------------------------
  162. t_0 = 1.5 ;
  163. epse_0 = -1*fne/kn ;
  164. eps_0 = epse_0 ;
  165. N_0 = -1*fne ;
  166. epco_0 = 0. ;
  167. lam3_0 = 0. ;
  168. ouv_0 = 0. ;
  169. lam1_0 = 0. ;
  170. pla3_0 = 0. ;
  171. p_0 = 0. ;
  172. Fy_0 = 0. ;
  173. pla1_0 = 0. ;
  174. etat_0 = 2 ;
  175.  
  176. *- Plasticité en compression (t_0 à t_1)
  177. * -------------------------------------
  178. t_1 = 2. ;
  179. eps_1 = -0.2 ;
  180. N_1 = (kt*eps_1) + (fne*((kt/kn) - 1.)) ;
  181. epse_1 = N_1/kn ;
  182. epco_1 = eps_1 - epse_1 ;
  183. lam3_1 = abs epco_1 ;
  184. ouv_1 = 0. ;
  185. lam1_1 = 0. ;
  186. pla3_1 = epco_1 ;
  187. p_1 = abs pla3_1 ;
  188. Fy_1 = 0. ;
  189. pla1_1 = 0. ;
  190. etat_1 = 3 ;
  191.  
  192. *- Cisaillement élastique à effort de compression constant (t_1 à t_2)
  193. * -------------------------------------------------------------------
  194. t_2 = 4. ;
  195. eps_2 = -0.2 ;
  196. N_2 = N_1 ;
  197. epse_2 = N_2/kn ;
  198. epco_2 = epco_1 ;
  199. lam3_2 = lam3_1 ;
  200. ouv_2 = 0. ;
  201. lam1_2 = 0. ;
  202. pla3_2 = pla3_1 ;
  203. p_2 = p_1 ;
  204. gy_2 = 0.31 ;
  205. Fy_2 = ks1*gy_2 ;
  206. pla1_2 = 0. ;
  207. etat_2 = 3 ;
  208.  
  209. *- Cisaillement Coulomb à effort de compression constant (t_2 à t_3)
  210. * -----------------------------------------------------------------
  211. t_3 = 6. ;
  212. eps_3 = -0.2 ;
  213. N_3 = N_2 ;
  214. epse_3 = N_3/kn ;
  215. epco_3 = epco_2 ;
  216. lam3_3 = lam3_2 ;
  217. ouv_3 = 0. ;
  218. lam1_3 = 0. ;
  219. pla3_3 = eps_3 - epse_3 ;
  220. gy_3 = 0.5 ;
  221. Fy_3 = -1*tg*N_3 ;
  222. gye_3 = Fy_3/ks1 ;
  223. pla1_3 = gy_3 - gye_3 ;
  224. p_3 = p_2 + (abs (pla1_3-pla1_2)) ;
  225. etat_3 = 3 ;
  226.  
  227. *- Décharge élast. de l'effort normal et cisail. Coulomb (t_3 à t_4)
  228. * -----------------------------------------------------------------
  229. t_4 = 7. ;
  230. eps_4 = -0.1 ;
  231. N_4 = N_1 + (kn*(eps_4-eps_1)) ;
  232. epse_4 = N_4/kn ;
  233. epco_4 = epco_3 ;
  234. lam3_4 = lam3_3 ;
  235. ouv_4 = 0. ;
  236. lam1_4 = 0. ;
  237. pla3_4 = eps_4 - epse_4 ;
  238. gy_4 = gy_3 ;
  239. Fy_4 = -1*tg*N_4 ;
  240. gye_4 = Fy_4/ks1 ;
  241. pla1_4 = gy_4 - gye_4 ;
  242. p_4 = p_3 + (abs (pla1_4-pla1_3)) ;
  243. etat_4 = 2 ;
  244.  
  245.  
  246. pt = prog 0 t_0 t_1 t_2 t_3 t_4 ;
  247.  
  248. ptN = prog 0. N_0 N_1 N_2 N_3 N_4 ;
  249. ptepco = prog
  250. 0. epco_0 epco_1 epco_2 epco_3 epco_4 ;
  251. ptlam3 = prog
  252. 0. lam3_0 lam3_1 lam3_2 lam3_3 lam3_4 ;
  253. ptouv = prog
  254. 0. ouv_0 ouv_1 ouv_2 ouv_3 ouv_4 ;
  255. ptlam1 = prog
  256. 0. lam1_0 lam1_1 lam1_2 lam1_3 lam1_4 ;
  257. ptpla3 = prog
  258. 0. pla3_0 pla3_1 pla3_2 pla3_3 pla3_4 ;
  259. ptepse = prog
  260. 0. p_0 p_1 p_2 p_3 p_4 ;
  261. ptFy = prog
  262. 0. Fy_0 Fy_1 Fy_2 Fy_3 Fy_4 ;
  263. ptpla1 = prog
  264. 0. pla1_0 pla1_1 pla1_2 pla1_3 pla1_4 ;
  265.  
  266. tt = prog 0 dt1 (t_0-dt1) t_0 (t_0+dt1) (t_1-dt1) ;
  267. ptetat = prog 0 etat_0 etat_0 etat_1 etat_1 etat_1 ;
  268.  
  269. tt = tt et (prog t_1 (t_1+dt1)) ;
  270. ptetat = ptetat et (prog etat_1 etat_2) ;
  271.  
  272. tt = tt et (prog (t_2-dt2) t_2 (t_2+dt2)) ;
  273. ptetat = ptetat et (prog etat_2 etat_2 etat_3) ;
  274.  
  275. tt = tt et (prog (t_3-dt1) t_3 (t_3+dt1) t_4) ;
  276. ptetat = ptetat et (prog etat_3 etat_3 etat_4 etat_4);
  277.  
  278.  
  279.  
  280. tN = evol roug manu 't' pt 'N' ptN ;
  281. tepco = evol roug manu 't' pt 'EPCO' ptepco ;
  282. tlam3 = evol roug manu 't' pt 'LAM3' ptlam3 ;
  283. touv = evol roug manu 't' pt 'EPOU' ptouv ;
  284. tlam1 = evol roug manu 't' pt 'LAM1' ptlam1 ;
  285. tpla3 = evol roug manu 't' pt 'PLA3' ptpla3 ;
  286. tepse = evol roug manu 't' pt 'EPSE' ptepse ;
  287. tetat = evol roug manu 't' tt 'STAT' ptetat ;
  288. tFy = evol roug manu 't' pt 'FY' ptFy ;
  289. tpla1 = evol roug manu 't' pt 'PLA1' ptpla1 ;
  290.  
  291.  
  292.  
  293. t = 'TABLE' ;
  294. t . 1 = 'MOT' 'MARQ CROI' ;
  295. t . 2 = 'MOT' 'MARQ LOSA' ;
  296. t.'TITRE' = 'TABLE' ;
  297. t.'TITRE' . 1 = 'Theorie' ;
  298. t.'TITRE' . 2 = 'Calcul' ;
  299.  
  300.  
  301. 'SI' GRAPH ;
  302. 'DESS' (tN et evN) 'TITR' 'Effort normal' t 'LEGE';
  303. 'DESS' (tepco et evepco) 'TITR' 'Def. plas. de compression' t 'LEGE';
  304. 'DESS' (tlam3 et evlam3) 'TITR' 'Mult. plas. / compression' t 'LEGE';
  305. 'DESS' (touv et evouv) 'TITR' 'Def. plas. en ouverture' t 'LEGE';
  306. 'DESS' (tlam1 et evlam1) 'TITR' 'Mult. plas. / traction' t 'LEGE';
  307. 'DESS' (tpla3 et evpla3) 'TITR' 'Def. plas. normale' t 'LEGE';
  308. 'DESS' (tepse et evepse) 'TITR' 'Def. plas. cumulee' t 'LEGE';
  309. 'DESS' (tFy 'ET' evFY) 'TITR' 'Effort de glissement' t 'LEGE';
  310. 'DESS' (tpla1 et evpla1) 'TITR' 'Def. plas. de glissement' t 'LEGE';
  311. 'DESS' (tetat et evetat) 'TITR' 'Etat du joint' t 'LEGE';
  312. 'FINSI' ;
  313.  
  314.  
  315. *
  316. * ---------- CODE DE FONCTIONNEMENT ----------
  317. *
  318. dif_N = 'MAXI' ('ABS' ('EXTR' (tN - evN) 'ORDO')) ;
  319. dif_Fy = 'MAXI' ('ABS' ('EXTR' (tFy - evFY) 'ORDO')) ;
  320. dif_pla1 = 'MAXI' ('ABS' ('EXTR' (tpla1 - evpla1) 'ORDO')) ;
  321. dif_pla3 = 'MAXI' ('ABS' ('EXTR' (tpla3 - evpla3) 'ORDO')) ;
  322.  
  323. test = 'MAXI' ('PROG' dif_N dif_Fy dif_pla1 dif_pla3) ;
  324.  
  325.  
  326. 'SI' (test '<EG' 1E-6 ) ;
  327. 'ERRE' 0 ;
  328. 'SINO';
  329. 'ERRE' 5 ;
  330. 'FINSI' ;
  331. 'FIN' ;
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  
  340.  
  341.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales