Télécharger jetaxi.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : jetaxi.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. GRAPH = FAUX ;
  5. COMPLET = FAUX ;
  6.  
  7. DISCR = 'MACRO';
  8. KPRESS = 'CENTRE';
  9. BETA = 1.;
  10.  
  11. ************************************************************************
  12. * JETAXI.DGIBI : jet turbulent monophasique axisymétrique *
  13. ************************************************************************
  14. * FICHE DE VALIDATION DU K-EPSILON INCOMPRESSIBLE + FILTRE *
  15. * FORMULATION EF QUA8 *
  16. * P. CORNET SEMT/TTMF DECEMBRE 1998 *
  17. ** modifie le 15/06/2014 passage EQPR -> EQEX *
  18. ************************************************************************
  19.  
  20. SI ( COMPLET) ;
  21. NITER = 40000 ;
  22. SINON ;
  23. NITER = 20 ;
  24. FINSI ;
  25.  
  26. *--------------------------- maillage ----------------------------------
  27.  
  28. TITRE 'JET' ;
  29. OPTI MODE AXIS ;
  30. OPTI DIME 2 ELEM QUA8 ;
  31. *
  32. DJ = 2.e-2 ; RJ = DJ/2. ; RM = 50.*RJ ;
  33.  
  34. * points :
  35. P00=0. 0.; PJ0=RJ 0.; PR0=RM 0.; PJ5=RJ (50.*DJ);
  36. P02=0. (20.*DJ); P03=0. (30.*DJ); P04=0. (40.*DJ); P05=0. (50.*DJ);
  37. PR2=RM (20.*DJ); PR3=RM (30.*DJ); PR4=RM (40.*DJ); PR5=RM (50.*DJ);
  38.  
  39. * segments verticaux :
  40. A02 = DROI -20 P00 P02 dini (0.5*DJ) dfin (1.25*DJ) ;
  41. A23 = DROI -6 P02 P03 dini (0.9*DJ) dfin (1.25*DJ) ;
  42. A34 = DROI 4 P03 P04 ;
  43. A45 = DROI -3 P04 P05 dini (1.25*DJ) dfin (2.*DJ) ;
  44.  
  45. B02 = DROI -20 PR0 PR2 dini (0.5*DJ) dfin (1.25*DJ) ;
  46. B23 = DROI -6 PR2 PR3 dini (0.9*DJ) dfin (1.25*DJ) ;
  47. B34 = DROI 4 PR3 PR4 ;
  48. B45 = DROI -3 PR4 PR5 dini (1.25*DJ) dfin (2.*DJ) ;
  49.  
  50. AXE = A02 ET A23 ET A34 ET A45 ;
  51. BORD= B02 ET B23 ET B34 ET B45 ;
  52.  
  53. * segments horizontaux :
  54. JET = DROI 2 P00 PJ0 ;
  55. BAS2 = DROI PJ0 PR0 dini (RJ/2.) dfin (10.*RJ) ; BAS = JET ET BAS2 ;
  56.  
  57. HAU1 = DROI 2 P05 PJ5 ;
  58. HAU2 = DROI PJ5 PR5 dini (RJ/2.) dfin (10.*RJ) ; HAUT=HAU1 ET HAU2 ;
  59.  
  60. * domaine total :
  61. MT = DALL BAS BORD (inve HAUT) (inve AXE) 'PLAN' ;
  62. CMT = cont MT ;
  63.  
  64. Mmt = 'CHAN' mt 'QUAF';
  65. Mjet = 'CHAN' jet 'QUAF';
  66. Mbord = 'CHAN' bord 'QUAF';
  67. Mbas2 = 'CHAN' bas2 'QUAF';
  68. Mbas = 'CHAN' bas 'QUAF';
  69. Mhaut = 'CHAN' haut 'QUAF';
  70. Maxe = 'CHAN' axe 'QUAF';
  71.  
  72. ELIM (Mmt et Mjet et Mbord et Mbas2 et Mbas et Mhaut et Maxe) 1.e-5;
  73.  
  74.  
  75. * tables domaine :
  76. $MT = 'MODE' MMT 'NAVIER_STOKES' DISCR;
  77. $JET = 'MODE' MJET 'NAVIER_STOKES' DISCR;
  78. $BORD = 'MODE' MBORD 'NAVIER_STOKES' DISCR;
  79. $BAS2 = 'MODE' MBAS2 'NAVIER_STOKES' DISCR;
  80. $BAS = 'MODE' MBAS 'NAVIER_STOKES' DISCR;
  81. $HAUT = 'MODE' MHAUT 'NAVIER_STOKES' DISCR;
  82. $AXE = 'MODE' MAXE 'NAVIER_STOKES' DISCR;
  83. DOMA $MT 'IMPR' ;
  84. MT = 'DOMA' $MT 'MAILLAGE' ;
  85. jet = 'DOMA' $jet 'MAILLAGE' ;
  86. bord = 'DOMA' $bord 'MAILLAGE' ;
  87. bas2 = 'DOMA' $bas2 'MAILLAGE' ;
  88. bas = 'DOMA' $bas 'MAILLAGE' ;
  89. haut = 'DOMA' $haut 'MAILLAGE' ;
  90. axe = 'DOMA' $axe 'MAILLAGE' ;
  91.  
  92.  
  93. *------------------------ donnees physiques ----------------------------
  94. *
  95. NUF = 1.5E-5 ;
  96. REJ = 1.e4 ;
  97. UJ = REJ*NUF/DJ ;
  98.  
  99. KJ = 1.E-3 ;
  100. EJ = 6.E-3 ;
  101. NUTj = 0.09*KJ*KJ/EJ ;
  102. KA = 1.E-7 ;
  103. EA = 1.E-5 ;
  104. L0 = 25.*DJ ;
  105.  
  106. *-------------------------- equations ----------------------------------
  107.  
  108. RV = EQEX $MT 'DUMP' 'ITMA' NITER 'ALFA' 0.9
  109. 'ZONE' $MT 'OPER' 'FILTREKE' UJ L0 'INCO' 'KN' 'EN'
  110. 'ZONE' $MT 'OPER' 'NSKE' NUF 'NUT' 'INCO' 'UN' 'KN' 'EN'
  111. 'CLIM' 'UN' UIMP JET 0. 'UN' VIMP JET UJ
  112. 'UN' VIMP BAS2 0. 'UN' UIMP AXE 0.
  113. 'KN' TIMP JET KJ 'EN' TIMP JET EJ
  114. 'KN' TIMP BORD KA 'EN' TIMP BORD EA ;
  115.  
  116. RV=EQEX RV OPTI EFM1 'CENTREE'
  117. 'ZONE' $MT 'OPER' 'DFDT' 1. 'UN' 'DELTAT' 'INCO' 'UN'
  118. 'ZONE' $MT 'OPER' 'DFDT' 1. 'KN' 'DELTAT' 'INCO' 'KN'
  119. 'ZONE' $MT 'OPER' 'DFDT' 1. 'EN' 'DELTAT' 'INCO' 'EN'
  120. ;
  121.  
  122. RVP = EQEX 'OPTI' 'EF' KPRESS
  123. 'ZONE' $MT OPER KBBT -1. beta INCO 'UN' 'PRES'
  124. ;
  125.  
  126. rvp.'METHINV'.TYPINV=1 ;
  127. rvp.'METHINV'.IMPINV=0 ;
  128. rvp.'METHINV'.NITMAX=300;
  129. rvp.'METHINV'.PRECOND=3 ;
  130. rvp.'METHINV'.RESID =1.e-8 ;
  131. rvp.'METHINV' . 'FCPRECT'=100 ;
  132. rvp.'METHINV' . 'FCPRECI'=100 ;
  133.  
  134. RV.'PROJ' =RVP ;
  135.  
  136.  
  137. *------------------------ initialisations ------------------------------
  138.  
  139. RV.INCO = TABLE 'INCO' ;
  140. RV.'INCO'.'UN' = KCHT $MT VECT SOMMET (1.E-7 1.E-7) ;
  141. RV.'INCO'.'PRES' = KCHT $MT SCAL KPRESS 0. ;
  142. RV.'INCO'.'KN' = KCHT $MT SCAL SOMMET 1.E-7 ;
  143. RV.'INCO'.'EN' = KCHT $MT SCAL SOMMET 1.E-5 ;
  144. RV.'INCO'.'NUT' = KCHT $MT SCAL CENTRE 1.E-6 ;
  145.  
  146. *------------------------ historiques ----------------------------------
  147.  
  148. P11 = MT POIN 'PROC' ((25.*RJ) (10.*DJ));
  149. P12 = MT POIN 'PROC' ((25.*RJ) (20.*DJ));
  150. P14 = MT POIN 'PROC' ((25.*RJ) (40.*DJ));
  151. P15 = MT POIN 'PROC' ((25.*RJ) (50.*DJ));
  152. LH = P02 et P03 et P04 et P05 et P11 et P12 et P14 et P15 ;
  153. HIS = KHIS 'UN' 1 LH 'UN' 2 LH 'KN' LH 'EN' LH ;
  154. RV.'HIST' = HIS ;
  155.  
  156. *------------------------ résolution -----------------------------------
  157.  
  158. EXEC RV ;
  159.  
  160. *------------------------ post-traitement ------------------------------
  161. SI GRAPH ;
  162.  
  163. opti 'ISOV' 'LIGNE' ;
  164. un = rv.INCO.'UN' ;
  165. unn = un/uj ;
  166. kn = rv.INCO.'KN' ;
  167. en = rv.INCO.'EN' ;
  168. nut= rv.INCO.'NUT' ;
  169. nut= elno $mt nut ;
  170. nur= (1./nuf)*nut ;
  171. pn = rv.pression.'PRESSION' ;
  172. pe = elno $mt pn ;
  173.  
  174. *----------------------------- isovaleurs ------------------------------
  175.  
  176. UNV = VECT (RV.'INCO'.'UN') 5.E-3 UX UY vert ;
  177. TRAC UNV CMT TITRE 'VITESSES ' ;
  178. TRAC NUR MT CMT TITRE 'NUT/NU' ;
  179.  
  180. *------------------------- U sur l'axe ---------------------------------
  181.  
  182. uz = exco uy un uy ;
  183. uzn = exco uy unn uy ;
  184. uzne = evol chpo uzn uy axe ;
  185. uzno = extr uzne ordo ;
  186. zz = extr uzne absc ; zn = zz/DJ ;
  187. uznn = evol manu 'Z/Dj' zn 'Vaxe/Vj' uzno ;
  188.  
  189. *------------------------ valeurs experimentales de U ------------------
  190.  
  191. ue = 5.8 * (zn**(-1)) ;
  192. uzne = evol manu 'Z/Dj' zn 'Vaxe/Vj' ue ;
  193. tabu = table ;
  194. tabu . 1 = 'REGU MARQ CARR ' ;
  195. tabu . 2 = 'REGU MARQ ETOI ' ;
  196. tabu.'TITRE' = table ;
  197. tabu.'TITRE' . 1 = MOT 'CASTEM' ;
  198. tabu.'TITRE' . 2 = MOT 'THEORIE' ;
  199.  
  200. titr 'VITESSE SUR L AXE' ;
  201. dess (uznn et uzne) lege tabu xbord 0. 50. ybord 0.0 1.1 ;
  202.  
  203. *------------------------- u' sur l'axe --------------------------------
  204.  
  205. kn = abs kn ;
  206. up = kn*2./3. ; up = up**0.5 ;
  207. upaxe = evol chpo up scal axe ;
  208. uz1 = nomc scal uz ;
  209. upu = up/uz1 ;
  210. upue = evol chpo upu scal axe ;
  211. upuo = extr upue ordo ;
  212. zz = extr upue absc ; zn = zz/DJ ;
  213. upun = evol manu 'Z/Dj' zn 'u/Vaxe' upuo ;
  214.  
  215. *------------------------ valeurs experimentales de u' -----------------
  216. * Panchapakesan & Lumley 1993, et Wygnanski & Fiedler 1969
  217.  
  218. lzz = prog 30. 35. 40. 45. 50. ;
  219. lup = prog 0.222 0.2245 0.2265 0.2283 0.230 ;
  220. lvp = prog 0.177 0.178 0.179 0.1796 0.180 ;
  221. upe = evol manu 'Z/D' lzz 'Uprime/Umoyen' lup ;
  222. vpe = evol manu 'Z/D' lzz 'Uprime/Umoyen' lvp ;
  223. lz1 = prog 40. ; up1 = prog 0.268 ;
  224. lz2 = prog 30. 40. 50. ;
  225. vp2 = prog 0.183 0.1975 0.211 ;
  226. wp2 = prog 0.188 0.2035 0.2075 ;
  227. u1e = evol manu 'Z/D' lz1 'Uprime/Umoyen' up1 ;
  228. v1e = evol manu 'Z/D' lz2 'Uprime/Umoyen' vp2 ;
  229. w1e = evol manu 'Z/D' lz2 'Uprime/Umoyen' wp2 ;
  230.  
  231. tabp = table ;
  232. tabp.1 = ' REGU ' ;
  233. tabp.2 = 'MARQ PLUS NOLI ' ;
  234. tabp.3 = 'MARQ CROI NOLI ' ;
  235. tabp.4 = 'MARQ TRIA NOLI ' ;
  236. tabp.5 = 'MARQ LOSA NOLI ' ;
  237. tabp.6 = 'MARQ CARR NOLI ' ;
  238. tabp.'TITRE' = table ;
  239. tabp.'TITRE' . 1 = MOT 'CASTEM' ;
  240. tabp.'TITRE' . 2 = MOT 'u/V P&L' ;
  241. tabp.'TITRE' . 3 = MOT 'v/V P&L' ;
  242. tabp.'TITRE' . 4 = MOT 'u/V W&F' ;
  243. tabp.'TITRE' . 5 = MOT 'v/V W&F' ;
  244. tabp.'TITRE' . 6 = MOT 'w/V W&F' ;
  245.  
  246. titre 'FLUCTUATIONS DE VITESSE SUR L AXE' ;
  247. dess (upun et upe et vpe et u1e et v1e et w1e) lege tabp ;
  248.  
  249. *------------------------------- les rayons ---------------------------
  250.  
  251. P01 = MT poin proc (0. (10.*DJ));
  252. PJ1 = MT poin proc (RJ (10.*DJ));
  253. PR1 = MT poin proc ((50.*DJ) (10.*DJ)) ;
  254. * ordonnee de p01 = 0.2035 si RJ = 0.01 m
  255. l101 = droi 2 P01 PJ1 ;
  256. l102 = droi PJ1 PR1 dini (RJ/2.) dfin (10.*RJ) ;
  257. L10 = l101 et l102 ; elim mt l10 1.e-5 ;
  258.  
  259. PJ2 = RJ (20.*DJ) ;
  260. l201 = droi 2 P02 PJ2 ;
  261. l202 = droi PJ2 PR2 dini (RJ/2.) dfin (10.*RJ) ;
  262. L20 = l201 et l202 ; elim mt l20 1.e-5 ;
  263.  
  264. PJ3 = RJ (30.*DJ) ;
  265. l301 = droi 2 P03 PJ3 ;
  266. l302 = droi PJ3 PR3 dini (RJ/2.) dfin (10.*RJ) ;
  267. L30 = l301 et l302 ; elim mt l30 1.e-5 ;
  268.  
  269. PJ4 = RJ (40.*DJ) ;
  270. l401 = droi 2 P04 PJ4 ;
  271. l402 = droi PJ4 PR4 dini (RJ/2.) dfin (10.*RJ) ;
  272. L40 = l401 et l402 ; elim mt l40 1.e-5 ;
  273.  
  274. PJ5 = RJ (50.*DJ) ;
  275. l501 = droi 2 P05 PJ5 ;
  276. l502 = droi PJ5 PR5 dini (RJ/2.) dfin (10.*RJ) ;
  277. L50 = l501 et l502 ; elim mt l50 1.e-5 ;
  278.  
  279. *---------------------------- U sur les rayons -------------------------
  280.  
  281. uz20 = evol chpo uz l20 ;
  282. u20 = extr uz20 ordo ; uzn20 = u20/(maxi u20) ;
  283. r20 = extr uz20 absc ; rn20 = r20/(20.*DJ) ;
  284. un20 = evol manu 'R/Z' rn20 'V/Vaxe' uzn20 ;
  285.  
  286. uz30 = evolchpo uz l30 ;
  287. u30 = extr uz30 ordo ; uzn30 = u30/(maxi u30) ;
  288. r30 = extr uz30 absc ; rn30 = r30/(30.*DJ) ;
  289. un30 = evol manu 'R/Z' rn30 'Uz/Uzmax' uzn30 ;
  290.  
  291. uz40 = evol chpo uz l40 ;
  292. u40 = extr uz40 ordo ; uzn40 = u40/(maxi u40) ;
  293. r40 = extr uz40 absc ; rn40 = r40/(40.*DJ) ;
  294. un40 = evol manu 'R/Z' rn40 'Uz/Uzmax' uzn40 ;
  295.  
  296. *------------------- valeurs experimentales ----------------------------
  297. * ut=formule de Tollmien, ue=valeurs exp de Trupel
  298.  
  299. lz=prog 0.000 0.009 0.018 0.027 0.036 0.045 0.054 0.063 0.072 0.081
  300. 0.090 0.099 0.108 0.117 0.126 0.135 0.144 0.153 0.162 0.171
  301. 0.180 0.189 0.198 0.207 0.216 0.225 0.234 0.243 0.252 0.261
  302. 0.270 0.279 0.288 0.297 0.306 ;
  303. ut=prog 1.000 0.984 0.958 0.922 0.884 0.843 0.795 0.748 0.700 0.653
  304. 0.605 0.555 0.510 0.470 0.425 0.378 0.340 0.300 0.265 0.230
  305. 0.198 0.169 0.140 0.117 0.094 0.075 0.059 0.046 0.034 0.024
  306. 0.017 0.011 0.007 0.003 0. ;
  307. ue=prog 1.000 0.991 0.965 0.936 0.898 0.864 0.809 0.762 0.707 0.700
  308. 0.612 0.562 0.517 0.475 0.425 0.374 0.342 0.298 0.268 0.228
  309. 0.196 0.171 0.138 0.119 0.096 0.075 0.056 0.046 0.035 0.025
  310. 0.017 0.012 0.009 0.004 0. ;
  311. uze = evol MANU 'R/Z' lz 'U/Umax' ue ;
  312. uzt = evol MANU 'R/Z' lz 'U/Umax' ut ;
  313.  
  314. tabv = table ;
  315. tabv.1 = 'MARQ TRIA REGU ' ;
  316. tabv.2 = 'MARQ LOSA REGU ' ;
  317. tabv.3 = 'MARQ CARR REGU ' ;
  318. tabv.4 = 'MARQ CROI NOLI ' ;
  319. tabv.5 = 'MARQ PLUS NOLI ' ;
  320. tabv.'TITRE' = table ;
  321. tabv.'TITRE' . 1 = MOT 'CASTEM Z=20Dj' ;
  322. tabv.'TITRE' . 2 = MOT 'CASTEM Z=30Dj' ;
  323. tabv.'TITRE' . 3 = MOT 'CASTEM Z=40Dj' ;
  324. tabv.'TITRE' . 4 = MOT 'THEORIE' ;
  325. tabv.'TITRE' . 5 = MOT 'EXPERIENCE' ;
  326.  
  327. titr 'PROFILS RADIAUX DE VITESSE MOYENNE AXIALE' ;
  328. dess (un20 et un30 et un40 et uzt et uze)
  329. lege tabv ybord 0. 1. xbor 0. 0.3 ;
  330.  
  331. *---------------------------- historiques ------------------------------
  332.  
  333. titre 'HISTORIQUE DE LA VITESSE RADIALE' ;
  334. dess rv.hist.'1UN' ;
  335. titre 'HISTORIQUE DE LA VITESSE AXIALE' ;
  336. dess rv.hist.'2UN' ;
  337.  
  338. FINSI ;
  339. *----------------test sur le débit total -------------------------------
  340.  
  341. debent= DBIT $bas RV.INCO.'UN' ;
  342. debsor= DBIT $haut RV.INCO.'UN' ;
  343. debbor= DBIT $bord RV.INCO.'UN' ;
  344. debtot= debent + debbor - debsor ;
  345.  
  346. SI ( (ABS debtot) > 1.e-10 ) ;
  347. ERREUR 5 ;
  348. FINSI ;
  349.  
  350. FIN ;
  351.  
  352.  
  353.  
  354.  
  355.  
  356.  
  357.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales