Télécharger injair.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : injairAC.dgibi
  2. *
  3. * Enceinte 2D Axisymetrique
  4. * Injection d'air en non adiabatique
  5. * Comparaison Castem 2D axi / Cathare / Solution analytique
  6. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  7. 'OPTI' 'MODE' 'AXIS' ;
  8. opti trace 'X';
  9. opti EPTR 10 ;
  10.  
  11. COMPLET= VRAI ;
  12. COMPLET= FAUX ;
  13. GRAPH = VRAI ;
  14. GRAPH = FAUX ;
  15.  
  16. Tmax=500.;
  17.  
  18. Si COMPLET;
  19. DTC=0.;
  20. n1=5 ;
  21. n2=10;
  22. n3=20;
  23. nf1=4;
  24. nf2=20;
  25. nf3=20;
  26. Sinon;
  27. DTC=2.;
  28. n1=3;
  29. n2=3;
  30. n3=3;
  31. nf1=2;
  32. nf2=5;
  33. nf3=5;
  34. Finsi;
  35.  
  36. *=======================================================================
  37. * Feuille inox de protection
  38. e4=(2.36-2.3588)/2.;
  39. lb4=15.5;
  40. *lb4=17.;
  41. ROCP4=35.325e5;
  42. h4i=e4/lb4;
  43. * Isolant
  44. e1=(2.46-2.36)/2.;
  45. lb1=0.025;
  46. ROCP1=2.392e5;
  47. h1i=e1/lb1;
  48. * paroi inox Riva
  49. e3=0.02;
  50. lb3=18.;
  51. *lb3=19.;
  52. ROCP3=35.325e5;
  53. h3i=e3/lb3;
  54. * Echange externe
  55. hext=10.;
  56. Text=tetai;
  57. * H equivalent
  58. Heq=(h4i + h1i + h3i + (1./hext))**(-1.);
  59. mess 'Heq=' Heq;
  60.  
  61. *=======================================================================
  62. *=======================================================================
  63. * Solution analytique
  64. DEBPROC SOREF Tmax*'FLOTTANT' DT0*'FLOTTANT' QM*'FLOTTANT' Vr*'FLOTTANT'
  65. Sr*'FLOTTANT' Pnm*'FLOTTANT' tetai*'FLOTTANT' INCOND*'MOT'
  66. HEXT*'FLOTTANT' TEXT*'FLOTTANT' COL*'MOT';
  67. * Les températures son en °C
  68.  
  69. Tps=0.;
  70. nbit = 50000;
  71.  
  72. Si('EGA' INCOND 'AIR');
  73. a1 a2 a3 a4 a5 a6 Cp=calcp tetai ;
  74. Rinc=287.1;
  75. SINON;
  76. Si('EGA' INCOND 'N2');
  77. a1 a2 a3 Cp a5 a6 a7=calcp tetai ;
  78. Rinc=296.9;
  79. SINON;
  80. mess ' Incondensable inconnu';
  81. QUITTER SOREF;
  82. FINSI;
  83. FINSI;
  84. * Rinc=292.; Valeur pour faire mieux fiter la solution analytique avec
  85. * cathare en air.
  86.  
  87. mess ' Incondensable R=' Rinc;
  88. Rhonm=Pnm/Rinc/(tetai + 273.15);
  89. a=Cp/Rinc-1.;
  90.  
  91. Lrho= prog Rhonm;
  92. Ltps= prog Tps ;
  93. Lp = prog Pnm ;
  94. LT = prog tetai;
  95.  
  96. repeter BLOC nbit;
  97. tps=tps + dt0;
  98. Si (tps > Tmax); quitter Bloc ; Finsi ;
  99. Rhon=Rhonm + (DT0*Qm/Vr);
  100. Fd=(Qm**3.)/(Rhon**2.)/(Vr**(10./3.));
  101.  
  102. A = Cp/Rinc - 1. ;
  103. Alfa = Sr*hext/Rhon/Rinc;
  104. Beta = Sr*hext*(Text + 273.15) ;
  105. AA = DT0/(Alfa*DT0+A) ;
  106.  
  107. Pn = (A*DT0/(A/DT0 + Alfa)*Pnm) + (AA/Vr*Qm*Cp*(tetai + 273.15))
  108. + (AA*Beta);
  109.  
  110. **Pn =Pnm + (DT0*Qm/Vr*(Rinc*Cp)/(Cp-Rinc)*(tetai + 273.15));
  111.  
  112. Tn =(Pn/Rhon/Rinc) - 273.15;
  113.  
  114. Si('EGA' INCOND 'AIR');
  115. a1 a2 a3 a4 a5 a6 Cp=calcp tn;
  116. Finsi;
  117. Si('EGA' INCOND 'N2');
  118. a1 a2 a3 Cp a5 a6 a7=calcp tn;
  119. FINSI;
  120.  
  121. Lrho= Lrho et (prog Rhon);
  122. Ltps= Ltps et (prog Tps) ;
  123. Lp = Lp et (prog Pn) ;
  124. LT = LT et (prog Tn) ;
  125. Rhonm = Rhon;
  126. Pnm = pn;
  127.  
  128. Fin BLOC;
  129.  
  130. evrho1 = (evol manu ltps lrho) coul col ;
  131. evp1 = (evol manu ltps lp) coul col ;
  132. evt1 = (evol manu ltps lt) coul col ;
  133. evmair1= evrho1* Vr ;
  134. FINPROC evp1 evt1 evrho1 evmair1 ;
  135.  
  136. DT0=1. ;
  137. Qm=0.2 ;
  138. Vr=17.4;
  139. Sr=35.914;
  140. Pnm=1.e5;
  141. tetai=300. - 273.15;
  142.  
  143. hexteq=0.; Text = 0.;
  144. evpa evta evrhoa evmaira = SOREF Tmax DT0 QM Vr Sr Pnm tetai 'AIR'
  145. HEXTeq TEXT 'ROUGE';
  146.  
  147. hexteq=Heq; Text = tetai;
  148. evp1 evt1 evrho1 evmair1 = SOREF Tmax DT0 QM Vr Sr Pnm tetai 'AIR'
  149. HEXTeq TEXT 'VERT';
  150.  
  151.  
  152. *=======================================================================
  153. Si GRAPH;
  154. TAB1 =TABLE ;
  155. TAB1.'TITRE'=TABLE ;
  156. tab1 . 1 = 'MOT' 'MARQ CROI REGU ';
  157. tab1 . 'TITRE' . 1 = 'Sol Ref adia';
  158. tab1 . 'TITRE' . 2 = 'Sol Ref non adia' ;
  159.  
  160. tit= chai 'Pression enceinte' ;
  161. dess (evpa et evp1) titr tit
  162. 'GRIL' titx 's' tity 'Pa' lege tab1;
  163.  
  164. tit= chai 'Température enceinte' ;
  165. dess (evta et evt1) titr tit
  166. 'GRIL' titx 's' tity '°C' lege tab1;
  167.  
  168. tit = chai 'Densité moyenne enceinte';
  169. dess (evrhoa et evrho1) titr tit
  170. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  171.  
  172. tit = chai 'Masse d air';
  173. dess (evmaira et evmair1) titr tit
  174. 'GRIL' titx 's' tity 'kg' lege tab1;
  175. Finsi;
  176.  
  177.  
  178. epsi=1.e-8;
  179.  
  180. episo=0.044;
  181. db=0.1 ;
  182. R1=1.2 ;
  183. R1=1.2 - episo;
  184. h1=1.605;
  185. h2=2.342 - episo;
  186. hb=0.835;
  187. PA0=R1 0.;
  188. PAb=PA0 moins (0. hb);
  189. PAbm=PAb moins ((R1/2.) 0.);
  190. PA1=R1 h1;
  191. PB1=R1 ((-1.)*h1);
  192. PA1b=PA1 moins (0. hb);
  193. CA1=0. 0.275 ;
  194. CA2=(0.33*R1) H1 ;
  195. PAX2=0. h2;
  196. PA20= PAX2 tour -5. CA1;
  197. PA2= PA20 tour -15. CA1;
  198. p0=0 0 ;
  199. paxb= p0 moins (0. hb);
  200. p2=db 0. ;
  201. p2b=p2 moins (0. hb);
  202. breche = paxb 'DROI' n1 p2b ;
  203. bas= p2b 'DROI' dini (db/n1) dfin (R1/10.) PABM
  204. 'DROI' dini (R1/10.) dfin (db/n1) PAB;
  205. n2= nbel bas;
  206. plaf0 = PAX2 C n1 CA1 PA20;
  207. plaf1 = PA20 C (n2/2) CA1 PA2;
  208. plaf2 = PA1 C (n2/2) CA2 PA2;
  209.  
  210. plaf =plaf0 et plaf1 et (inve plaf2);
  211. axeh = PAX2 'DROI' n3 paxb ;
  212. PAXM=(PAX2 plus PAXB)*0.5;
  213.  
  214. axeh = PAX2 DROI dini (h2/n3/4.) dfin (h1/n3) PAXM
  215. DROI dini (h1/n3) dfin (h2/n3/4.) PAXB;
  216. n3n= nbel axeh ;
  217. paroih=PAb d n3n PA1;
  218.  
  219. pla=plaf et (inve paroih) ;
  220. pla = pla et (syme pla droit p0 pax2);
  221. Si GRAPH;
  222. trace (pla et ca1 et ca2 et PA1);
  223. trace (plaf et paroih et axeh et breche et bas
  224. et ca1);
  225. Finsi;
  226. mth= 'DALLER' (breche 'ET' bas) paroih plaf axeh;
  227.  
  228. entb = breche plus (0. 0.);
  229. DEPL entb tour 15. P2b;
  230. pbx2= pax2 syme 'DROITE' P0 PA0;
  231. p0b= poin 1 entb ;
  232. axeb = PBX2 'DROI' n3 p0b;
  233. paroib =pab d n3 pb1;
  234. fond = plaf SYME 'DROITE' P0 PA0;
  235. elim (entb 'ET' bas et paroib et fond et axeb) epsi;
  236. mtb= 'DALLER' (entb 'ET' bas) paroib fond axeb;
  237. axe=axeb et axeh;
  238. mt = mth et mtb ;
  239. elim (mtb et bas et entb et bas) epsi;
  240. Parois = paroib et paroih et plaf et fond et entb ;
  241. parext = plaf et (inve paroih) et paroib et (inve fond);
  242.  
  243. parexp = parext plus (0. 0.);
  244. debproc crec parexp*'MAILLAGE' e1*'FLOTTANT' n1*'ENTIER' col*'MOT';
  245. cq= vide maillage;
  246. tt=table;
  247. repeter BLOC (nbel parexp);
  248. ei= elem &bloc parexp;
  249. p1=point 1 ei ;
  250. p2=point 2 ei;
  251. p1p2=p2 moins p1 ;
  252. a = norm p1p2;
  253. p1p2=p1p2*(e1/a);
  254. pp2=p1 plus p1p2;
  255. p3= pp2 tour 90. p1;
  256. tt.&bloc=p3;
  257. Si(Ega &bloc 1);
  258. p0=p3;
  259. sinon;
  260. cq = cq et (p0 d 1 p3);
  261. p0 = p3;
  262. finsi;
  263. *trace ( parexp et cq) 'NCLK';
  264. fin bloc;
  265. pp2= p2 moins p1p2;
  266. p2= pp2 tour (-90.) p2;
  267. cq = cq et (p3 d 1 p2);
  268. cq = elem cq 'SEG2';
  269. mcq= parexp regle n1 cq;
  270. mcq= mcq coul col ;
  271. finproc cq mcq ;
  272.  
  273.  
  274. cq1 mcq1 = crec parexp e4 nf1 rouge;
  275. cq2 mcq2 = crec cq1 e1 nf2 vert;
  276. cq3 mcq3 = crec cq2 e3 nf3 TURQ;
  277.  
  278. mtp= (mcq1 et mcq2 et mcq3);
  279.  
  280. Si Graph;
  281. trace mtp;
  282. trace (elim ((mt et mtp) et (syme (mt et mtp) 'DROIT' P0 pax2)) epsi);
  283. Finsi;
  284.  
  285. ************************************************************************
  286. * Petite disgression pour calculer la surface de l'enceinte
  287. Si FAUX;
  288.  
  289. la= prog;
  290. ln=prog;
  291. nn=25;
  292. repeter BLOC 40;
  293. a= rota parext nn 90. pax2 pbx2;
  294. sa=((mesu a 'SURF' ) * 4.);
  295. la = la et (prog sa);
  296. ln = ln et (prog nn);
  297. nn= nn + 25;
  298. fin bloc;
  299. evmes= evol manu ln la ;
  300. dess evmes GRIL TITR ' Surface interne de l enceinte RIVA';
  301. opti donn 5;
  302. Finsi ;
  303. ************************************************************************
  304.  
  305. rxt = 'TABLE' ;
  306. rxt.'vtf'=mt ;
  307. rxt.'axe' = axe ;
  308. rxt.'breche'=breche ;
  309. rxt.'diru1'=0. 1. ;
  310. rxt.'epsi'= epsi ;
  311. rxt.'pi' = 0.5 0.5 ;
  312. rxt.'DT0' = (maxi (prog DT0 DTC));
  313. rxt.'DETMAT'= VRAI ;
  314. rxt.'RENU' = 'RIEN' ;
  315. rxt.'DISCR'= 'LINE';
  316. rxt.'KPRE' = 'MSOMMET';
  317. rxt.'MODTURB' = 'LMEL' ;
  318. rxt.'LMEL' = 0.01 ;
  319. rxt.'GRAPH' = GRAPH ;
  320.  
  321. *rxt.'THERCO'=VRAI ;
  322. rxt.'PAROIS'=table;
  323. rxt.'PAROIS'.'Feuille'=table ;
  324. rxt.'PAROIS'.'Feuille'.'vtp'=mcq1;
  325. rxt.'PAROIS'.'Feuille'.'LAMBDA'=LB4;
  326. rxt.'PAROIS'.'Feuille'.'ROCP'=ROCP4;
  327. rxt.'PAROIS'.'Feuille'.'Tp0'=tetai;
  328.  
  329. rxt.'PAROIS'.'Isolant'=table ;
  330. rxt.'PAROIS'.'Isolant'.'vtp'=mcq2;
  331. rxt.'PAROIS'.'Isolant'.'LAMBDA'=LB1;
  332. rxt.'PAROIS'.'Isolant'.'ROCP'=ROCP1;
  333. rxt.'PAROIS'.'Isolant'.'Tp0'=tetai;
  334.  
  335. rxt.'PAROIS'.'Inox'=table ;
  336. rxt.'PAROIS'.'Inox'.'vtp'=mcq3;
  337. rxt.'PAROIS'.'Inox'.'LAMBDA'=LB3;
  338. rxt.'PAROIS'.'Inox'.'ROCP'=ROCP3;
  339. rxt.'PAROIS'.'Inox'.'Tp0'=tetai;
  340.  
  341. rxt.'ECHEXT' = VRAI;
  342. rxt.'parext' = cq3 ;
  343. rxt.'HEXT' = HEXT ;
  344. rxt.'TPEXT' = TEXT ;
  345.  
  346. rxt.'ECHAN' = 100.;
  347.  
  348. rxt.'TF0' = tetai ;
  349. rxt.'PT0' = 1.0e5 ;
  350.  
  351. Qinc = Qm ;
  352. rxt.'scenario' = table ;
  353. rxt.'scenario'.'t' = prog 0.0 1000. ;
  354. rxt.'scenario'.'qair' = prog Qinc Qinc ;
  355. rxt.'scenario'.'tinj' = prog tetai tetai ;
  356.  
  357. rxt.'GRAPH' = FAUX ;
  358. execrxt 0 rxt ;
  359.  
  360. Si COMPLET;
  361. rxt.'TBT'.'RTF'.'1TSCA'.'KOPT'.'CMD'=0.;
  362. Finsi;
  363.  
  364. Diag=rxt.'GEO'.'Diag';
  365. mess ' Volume de RIVA ' (somt diag);
  366. rxt.'GRAPH' = GRAPH ;
  367.  
  368. nbit = ENTI (Tmax / rxt.'DT0') ;
  369. execrxt nbit rxt ;
  370.  
  371. TAB1 =TABLE ;
  372. TAB1.'TITRE'=TABLE ;
  373. tab1 . 1 = 'MOT' 'MARQ CROI REGU ';
  374. tab1 . 2 = 'MOT' 'MARQ CARR REGU TIRC';
  375. tab1 . 3 = 'MOT' 'MARQ LOSA REGU TIRC';
  376. tab1 . 4 = 'MOT' 'MARQ TRIU REGU TIRC';
  377. tab1 . 5 = 'MOT' 'MARQ TRID REGU TIRC';
  378. tab1 . 'TITRE' . 1 = 'Sol Ref non adia';
  379. tab1 . 'TITRE' . 2 = 'Nautilus CFD';
  380. *.................................................................
  381. evrho2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'Rhom');
  382. evp2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'PT');
  383. evt2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'Tfm');
  384. evmair2=evrho2 * Vr;
  385.  
  386. Si GRAPH;
  387. tit= chai 'Pression enceinte' ;
  388. dess (evp1 et evp2) titr tit
  389. 'GRIL' titx 's' tity 'Pa' lege tab1;
  390.  
  391. tit= chai 'Température moyenne enceinte';
  392. dess (evt1 et evt2) titr tit
  393. 'GRIL' titx 's' tity '°C' lege tab1;
  394.  
  395. tit= chai 'Densité moyenne enceinte ' ;
  396. dess (evrho1 et evrho2) titr tit
  397. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  398.  
  399. tit= chai 'Masse d air ' ;
  400. dess (evmair1 et evmair2) titr tit
  401. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  402.  
  403. tp= rxt.tic.'TP';
  404. tf= rxt.tic.'TF';
  405. $vtp = rxt.geo.'$vtp';
  406. $vtf = rxt.geo.'$vtf';
  407. vtp = doma $vtp maillage;
  408. vtf = doma $vtf maillage;
  409. a1 = elem vtp 'APPUYE' 'LARGEMENT' parexp ;
  410. vtp1= diff vtp a1;
  411. tp1 = redu tp vtp1;
  412. trace (tp1 et tf) (vtp1 et vtf) titr 'Isothermes';
  413.  
  414. Finsi;
  415.  
  416. devp=evp1 - evp2 abs;
  417. erp= maxi (extr devp 'ORDO');
  418. mess ' ERP =' ERP;
  419. Si (ERP '>' 13000. ) ; erreur 5 ; Finsi ;
  420.  
  421.  
  422. FIN ;
  423.  
  424.  
  425. un=rxt.'TIC'.'UN';
  426.  
  427. tf =rxt.'TIC'.'TF' ;
  428.  
  429. $vtf=rxt.'GEO'.'$vtf' ;
  430. vtf=doma $vtf maillage;
  431. rho=rxt.'TIC'.'RHO' ;
  432. un =rxt.'TIC'.'UN';
  433.  
  434. ixe=inve axe ;
  435. evauz = evol chpo (exco un 'UY') ixe ;
  436. evarh = evol chpo rho ixe ;
  437. evatf = evol chpo tf ixe ;
  438. evair = evol chpo rair ixe ;
  439.  
  440.  
  441.  
  442. dess evauz 'TITRE' 'Vitesse sur l axe';
  443. dess evarh 'TITRE' 'Densite melange sur l axe';
  444. dess evatf 'TITRE' 'Temperature sur l axe';
  445.  
  446. ung= vect un 0.1 ux uy jaune;
  447. trace ung vtf;
  448. opti isov suli ;
  449. trace rho vtf 'TITRE' ' Rho' ;
  450. *trace rh2 vtf 'TITRE' ' Rh2' ;
  451. *trace rco vtf 'TITRE' ' Rco' ;
  452. trace tf vtf 'TITRE' ' Tf ' ;
  453.  
  454. FIN ;
  455.  
  456.  
  457.  
  458.  
  459.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales