Télécharger injN2A.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : injN2.dgibi
  2. *
  3. * Enceinte 2D Axisymetrique
  4. * Injection d'azote en adiabatique
  5. * Comparaison Castem 2D axi / Cathare / Solution analytique
  6. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  7. 'OPTI' 'MODE' 'AXIS' ;
  8. opti trace 'X';
  9. opti EPTR 10 ;
  10.  
  11. COMPLET= VRAI ;
  12. COMPLET= FAUX ;
  13. GRAPH = VRAI ;
  14. GRAPH = FAUX ;
  15.  
  16.  
  17. Si COMPLET;
  18. DTC=0.;
  19. n1=5 ;
  20. n2=10;
  21. n3=20;
  22. Sinon;
  23. DTC=2.;
  24. n1=3;
  25. n2=3;
  26. n3=3;
  27. Finsi;
  28.  
  29.  
  30. *=======================================================================
  31. * Feuille inox de protection
  32. e4=(2.36-2.3588)/2.;
  33. lb4=17.;
  34. h4i=e4/lb4;
  35. * Isolant
  36. e1=(2.46-2.36)/2.;
  37. lb1=0.025;
  38. h1i=e1/lb1;
  39. * paroi inox Riva
  40. e3=0.02;
  41. lb3=18.;
  42. h3i=e3/lb3;
  43. * Echange externe
  44. hext=10.;
  45. Text=20.;
  46. * H equivalent
  47. Heq=(h4i + h1i + h3i + (1./hext))**(-1.);
  48. mess 'Heq=' Heq;
  49.  
  50. *=======================================================================
  51. *=======================================================================
  52. * Solution analytique
  53. DEBPROC SOREF Tmax*'FLOTTANT' DT0*'FLOTTANT' QM*'FLOTTANT' Vr*'FLOTTANT'
  54. Sr*'FLOTTANT' Pnm*'FLOTTANT' tetai*'FLOTTANT' INCOND*'MOT'
  55. HEXT*'FLOTTANT' TEXT*'FLOTTANT' ;
  56. * Les températures son en °C
  57.  
  58. Tps=0.;
  59. nbit = 50000;
  60.  
  61. Si('EGA' INCOND 'AIR');
  62. a1 a2 a3 a4 a5 a6 Cp=calcp tetai ;
  63. Rinc=287.1;
  64. SINON;
  65. Si('EGA' INCOND 'N2');
  66. a1 a2 a3 Cp a5 a6 a7=calcp tetai ;
  67. Rinc=296.9;
  68. SINON;
  69. mess ' Incondensable inconnu';
  70. QUITTER SOREF;
  71. FINSI;
  72. FINSI;
  73. * Rinc=292.; Valeur pour faire mieux fiter la solution analytique avec
  74. * cathare en air.
  75.  
  76. mess ' Incondensable R=' Rinc;
  77. Rhonm=Pnm/Rinc/(tetai + 273.15);
  78. a=Cp/Rinc-1.;
  79.  
  80. Lrho= prog Rhonm;
  81. Ltps= prog Tps ;
  82. Lp = prog Pnm ;
  83. LT = prog tetai;
  84.  
  85. repeter BLOC nbit;
  86. tps=tps + dt0;
  87. Si (tps > Tmax); quitter Bloc ; Finsi ;
  88. Rhon=Rhonm + (DT0*Qm/Vr);
  89. Fd=(Qm**3.)/(Rhon**2.)/(Vr**(10./3.));
  90. Pn =Pnm + (DT0*Qm/Vr*(Rinc*Cp)/(Cp-Rinc)*(tetai + 273.15));
  91. dpdt = Qm/Vr*(Rinc*Cp)/(Cp-Rinc)*(tetai + 273.15);
  92. Tn =(Pn/Rhon/Rinc) - 273.15;
  93.  
  94. Si('EGA' INCOND 'AIR');
  95. a1 a2 a3 a4 a5 a6 Cp=calcp tn;
  96. Finsi;
  97. Si('EGA' INCOND 'N2');
  98. a1 a2 a3 Cp a5 a6 a7=calcp tn;
  99. FINSI;
  100.  
  101. Lrho= Lrho et (prog Rhon);
  102. Ltps= Ltps et (prog Tps) ;
  103. Lp = Lp et (prog Pn) ;
  104. LT = LT et (prog Tn) ;
  105. Rhonm = Rhon;
  106. Pnm = pn;
  107.  
  108. Fin BLOC;
  109.  
  110. evrho1 = (evol manu ltps lrho) coul rouge;
  111. evp1 = (evol manu ltps lp) coul rouge ;
  112. evt1 = (evol manu ltps lt) coul rouge ;
  113. evmair1= evrho1* Vr ;
  114. FINPROC evp1 evt1 evrho1 evmair1 ;
  115.  
  116. Tmax=500.;
  117. DT0=1. ;
  118. Qm=0.2 ;
  119. Vr=17.4;
  120. Sr=35.914;
  121. Pnm=1.e5;
  122. tetai=300. - 273.15;
  123. hext=0.; Text = 0.;
  124. *hext=Heq; Text = 20.;
  125. evp1 evt1 evrho1 evmair1 = SOREF Tmax DT0 QM Vr Sr Pnm tetai 'N2'
  126. HEXT TEXT ;
  127.  
  128.  
  129. *=======================================================================
  130.  
  131. epsi=1.e-5;
  132.  
  133. episo=0.044;
  134. db=0.1 ;
  135. R1=1.2 ;
  136. R1=1.2 - episo;
  137. h1=1.605;
  138. h2=2.342 - episo;
  139. hb=0.835;
  140. PA0=R1 0.;
  141. PAb=PA0 moins (0. hb);
  142. PAbm=PAb moins ((R1/2.) 0.);
  143. PA1=R1 h1;
  144. PB1=R1 ((-1.)*h1);
  145. PA1b=PA1 moins (0. hb);
  146. CA1=0. 0.275 ;
  147. CA2=(0.33*R1) H1 ;
  148. PAX2=0. h2;
  149. PA20= PAX2 tour -5. CA1;
  150. PA2= PA20 tour -15. CA1;
  151. p0=0 0 ;
  152. paxb= p0 moins (0. hb);
  153. p2=db 0. ;
  154. p2b=p2 moins (0. hb);
  155. breche = paxb 'DROI' n1 p2b ;
  156. bas= p2b 'DROI' dini (db/n1) dfin (R1/10.) PABM
  157. 'DROI' dini (R1/10.) dfin (db/n1) PAB;
  158. n2= nbel bas;
  159. plaf0 = PAX2 C n1 CA1 PA20;
  160. plaf1 = PA20 C (n2/2) CA1 PA2;
  161. plaf2 = PA1 C (n2/2) CA2 PA2;
  162.  
  163. plaf =plaf0 et plaf1 et plaf2;
  164. axeh = PAX2 'DROI' n3 paxb ;
  165. PAXM=(PAX2 plus PAXB)*0.5;
  166.  
  167. axeh = PAX2 DROI dini (h2/n3/4.) dfin (h1/n3) PAXM
  168. DROI dini (h1/n3) dfin (h2/n3/4.) PAXB;
  169. n3n= nbel axeh ;
  170. paroih=PAb d n3n PA1;
  171.  
  172. pla=plaf et paroih ;
  173. pla = pla et (syme pla droit p0 pax2);
  174. Si GRAPH;
  175. trace (pla et ca1 et ca2 et PA1);
  176. trace (plaf et paroih et axeh et breche et bas
  177. et ca1);
  178. Finsi;
  179. mth= 'DALLER' (breche 'ET' bas) paroih plaf axeh;
  180.  
  181. entb = breche plus (0. 0.);
  182. DEPL entb tour 15. P2b;
  183. pbx2= pax2 syme 'DROITE' P0 PA0;
  184. p0b= poin 1 entb ;
  185. axeb = PBX2 'DROI' n3 p0b;
  186. paroib =pab d n3 pb1;
  187. fond = plaf SYME 'DROITE' P0 PA0;
  188. elim (entb 'ET' bas et paroib et fond et axeb) epsi;
  189. mtb= 'DALLER' (entb 'ET' bas) paroib fond axeb;
  190. axe=axeb et axeh;
  191. mt = mth et mtb ;
  192. elim (mtb et bas et entb et bas) epsi;
  193. Parois = paroib et paroih et plaf et fond et entb ;
  194. parext = paroib et paroih et plaf et fond ;
  195. Si Graph;
  196. trace (elim (mt et (syme mt 'DROIT' P0 pax2)) epsi);
  197. Finsi;
  198. ************************************************************************
  199. * Petite disgression pour calculer la surface de l'enceinte
  200. Si FAUX;
  201.  
  202. la= prog;
  203. ln=prog;
  204. nn=25;
  205. repeter BLOC 40;
  206. a= rota parext nn 90. pax2 pbx2;
  207. sa=((mesu a 'SURF' ) * 4.);
  208. la = la et (prog sa);
  209. ln = ln et (prog nn);
  210. nn= nn + 25;
  211. fin bloc;
  212. evmes= evol manu ln la ;
  213. dess evmes GRIL TITR ' Surface interne de l enceinte RIVA';
  214. *opti donn 5;
  215. Finsi ;
  216. ************************************************************************
  217.  
  218. rxt = 'TABLE' ;
  219. rxt.'vtf'=mt ;
  220. rxt.'axe' = axe ;
  221. rxt.'breche'=breche ;
  222. rxt.'diru1'=0. 1. ;
  223. rxt.'epsi'= 1.e-4 ;
  224. rxt.'pi' = 0.5 0.5 ;
  225. rxt.'DT0' = (maxi (prog DT0 DTC));
  226. rxt.'DETMAT'= VRAI ;
  227. rxt.'RENU' = 'RIEN' ;
  228. rxt.'DISCR'= 'LINE';
  229. rxt.'KPRE' = 'MSOMMET';
  230. rxt.'N2' = VRAI ;
  231. rxt.'MODTURB' = 'LMEL' ;
  232. rxt.'LMEL' = 0.01 ;
  233. rxt.'GRAPH' = GRAPH ;
  234.  
  235.  
  236. TF0 = Tetai ;
  237. rxt.'TF0' = TF0 ;
  238. rxt.'PT0' = 1.0e5 ;
  239. rxt.'Yn20' = 0. ;
  240.  
  241. Qinc = Qm ;
  242. rxt.'scenario' = table ;
  243. rxt.'scenario'.'t' = prog 0.0 1000. ;
  244. rxt.'scenario'.'qair' = prog 0. 0. ;
  245. rxt.'scenario'.'qn2' = prog Qinc Qinc ;
  246. rxt.'scenario'.'tinj' = prog TF0 TF0 ;
  247.  
  248. rxt.'GRAPH' = FAUX ;
  249. execrxt 0 rxt ;
  250.  
  251. Si COMPLET;
  252. rxt.'TBT'.'RTF'.'1TSCA'.'KOPT'.'CMD'=0.;
  253. Finsi;
  254.  
  255. Diag=rxt.'GEO'.'Diag';
  256. mess ' Volume de RIVA ' (somt diag);
  257. rxt.'GRAPH' = GRAPH ;
  258.  
  259. nbit = ENTI (Tmax / rxt.'DT0') ;
  260. execrxt nbit rxt ;
  261.  
  262. TAB1 =TABLE ;
  263. TAB1.'TITRE'=TABLE ;
  264. tab1 . 1 = 'MOT' 'MARQ CROI REGU ';
  265. tab1 . 2 = 'MOT' 'MARQ CARR REGU TIRC';
  266. tab1 . 3 = 'MOT' 'MARQ LOSA REGU TIRC';
  267. tab1 . 4 = 'MOT' 'MARQ TRIU REGU TIRC';
  268. tab1 . 5 = 'MOT' 'MARQ TRID REGU TIRC';
  269. tab1 . 'TITRE' . 1 = 'Sol Ref';
  270. tab1 . 'TITRE' . 2 = 'Nautilus CFD';
  271. *.................................................................
  272. evrho2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'Rhom');
  273. evp2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'PT');
  274. evt2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'Tfm');
  275. evmair2=evrho2 * Vr;
  276.  
  277. Si GRAPH;
  278. tit= chai 'Pression enceinte' ;
  279. dess (evp1 et evp2) titr tit
  280. 'GRIL' titx 's' tity 'Pa' lege tab1;
  281.  
  282. tit= chai 'Température moyenne enceinte';
  283. dess (evt1 et evt2) titr tit
  284. 'GRIL' titx 's' tity '°C' lege tab1;
  285.  
  286. tit= chai 'Densité moyenne enceinte ' ;
  287. dess (evrho1 et evrho2) titr tit
  288. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  289.  
  290. tit= chai 'Masse d air ' ;
  291. dess (evmair1 et evmair2) titr tit
  292. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  293. Finsi;
  294.  
  295.  
  296. devp=evp1 - evp2 abs;
  297. erp= maxi (extr devp 'ORDO');
  298. mess ' ERP =' ERP;
  299. Si (ERP '>' 8000. ) ; erreur 5 ; Finsi ;
  300.  
  301. devt=evt1 - evt2 abs;
  302. ert= maxi (extr devt 'ORDO');
  303. mess ' ERT =' ERT;
  304. Si (ERT '>' 2. ) ; erreur 5 ; Finsi ;
  305.  
  306. FIN ;
  307.  
  308.  
  309.  
  310.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales