Télécharger injN2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : injairAC.dgibi
  2. *
  3. * Enceinte 2D Axisymetrique
  4. * Injection d'air en non adiabatique
  5. * Comparaison Castem 2D axi / Cathare / Solution analytique
  6. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  7. 'OPTI' 'MODE' 'AXIS' ;
  8. opti trace 'X';
  9. opti EPTR 10 ;
  10.  
  11. COMPLET= VRAI ;
  12. COMPLET= FAUX ;
  13. GRAPH = VRAI ;
  14. GRAPH = FAUX ;
  15.  
  16. Si COMPLET;
  17. DTC=0.;
  18. n1=5 ;
  19. n2=10;
  20. n3=20;
  21. nf1=4;
  22. nf2=20;
  23. nf3=20;
  24. Sinon;
  25. DTC=2.;
  26. n1=3;
  27. n2=3;
  28. n3=3;
  29. nf1=2;
  30. nf2=5;
  31. nf3=5;
  32. Finsi;
  33.  
  34. *=======================================================================
  35. * Feuille inox de protection
  36. e4=(2.36-2.3588)/2.;
  37. lb4=15.5;
  38. *lb4=17.;
  39. ROCP4=35.325e5;
  40. h4i=e4/lb4;
  41. * Isolant
  42. e1=(2.46-2.36)/2.;
  43. lb1=0.025;
  44. ROCP1=2.392e5;
  45. h1i=e1/lb1;
  46. * paroi inox Riva
  47. e3=0.02;
  48. lb3=18.;
  49. *lb3=19.;
  50. ROCP3=35.325e5;
  51. h3i=e3/lb3;
  52. * Echange interne
  53. Hint=15.;
  54. * Echange externe
  55. hext=10.;
  56. Text=tetai;
  57. * H equivalent
  58. Heq=(h4i + h1i + h3i + (1./hext)+(1./Hint))**(-1.);
  59. mess 'Heq=' Heq;
  60.  
  61. *=======================================================================
  62.  
  63. *=======================================================================
  64. * Solution analytique
  65. DEBPROC SOREF Tmax*'FLOTTANT' DT0*'FLOTTANT' QM*'FLOTTANT' Vr*'FLOTTANT'
  66. Sr*'FLOTTANT' Pnm*'FLOTTANT' tetai*'FLOTTANT' INCOND*'MOT'
  67. HEXT*'FLOTTANT' TEXT*'FLOTTANT' COL*'MOT';
  68. * Les températures son en °C
  69.  
  70. Tps=0.;
  71. nbit = 50000;
  72.  
  73. Si('EGA' INCOND 'AIR');
  74. a1 a2 a3 a4 a5 a6 Cp=calcp tetai ;
  75. Rinc=287.1;
  76. SINON;
  77. Si('EGA' INCOND 'N2');
  78. a1 a2 a3 Cp a5 a6 a7=calcp tetai ;
  79. Rinc=296.9;
  80. SINON;
  81. mess ' Incondensable inconnu';
  82. QUITTER SOREF;
  83. FINSI;
  84. FINSI;
  85. * Rinc=292.; Valeur pour faire mieux fiter la solution analytique avec
  86. * cathare en air.
  87.  
  88. mess ' Incondensable R=' Rinc;
  89. Rhonm=Pnm/Rinc/(tetai + 273.15);
  90. a=Cp/Rinc-1.;
  91.  
  92. Lrho= prog Rhonm;
  93. Ltps= prog Tps ;
  94. Lp = prog Pnm ;
  95. LT = prog tetai;
  96.  
  97. repeter BLOC nbit;
  98. tps=tps + dt0;
  99. Si (tps > Tmax); quitter Bloc ; Finsi ;
  100. Rhon=Rhonm + (DT0*Qm/Vr);
  101. Fd=(Qm**3.)/(Rhon**2.)/(Vr**(10./3.));
  102.  
  103. A = Cp/Rinc - 1. ;
  104. Alfa = Sr*hext/Rhon/Rinc;
  105. Beta = Sr*hext*(Text + 273.15) ;
  106. AA = DT0/(Alfa*DT0+A) ;
  107.  
  108. Pn = (A*DT0/(A/DT0 + Alfa)*Pnm) + (AA/Vr*Qm*Cp*(tetai + 273.15))
  109. + (AA*Beta);
  110.  
  111. **Pn =Pnm + (DT0*Qm/Vr*(Rinc*Cp)/(Cp-Rinc)*(tetai + 273.15));
  112.  
  113. Tn =(Pn/Rhon/Rinc) - 273.15;
  114.  
  115. Si('EGA' INCOND 'AIR');
  116. a1 a2 a3 a4 a5 a6 Cp=calcp tn;
  117. Finsi;
  118. Si('EGA' INCOND 'N2');
  119. a1 a2 a3 Cp a5 a6 a7=calcp tn;
  120. FINSI;
  121.  
  122. Lrho= Lrho et (prog Rhon);
  123. Ltps= Ltps et (prog Tps) ;
  124. Lp = Lp et (prog Pn) ;
  125. LT = LT et (prog Tn) ;
  126. Rhonm = Rhon;
  127. Pnm = pn;
  128.  
  129. Fin BLOC;
  130.  
  131. evrho1 = (evol manu ltps lrho) coul col ;
  132. evp1 = (evol manu ltps lp) coul col ;
  133. evt1 = (evol manu ltps lt) coul col ;
  134. evmair1= evrho1* Vr ;
  135. FINPROC evp1 evt1 evrho1 evmair1 ;
  136.  
  137. Tmax=500.;
  138. DT0=1. ;
  139. Qm=0.2 ;
  140. Vr=17.4;
  141. Sr=35.914;
  142. Pnm=1.e5;
  143. tetai=300. - 273.15;
  144.  
  145. hexteq=0.; Text = 0.;
  146. evpa evta evrhoa evmaira = SOREF Tmax DT0 QM Vr Sr Pnm tetai 'N2'
  147. HEXTeq TEXT 'ROUGE';
  148.  
  149. hexteq=Heq; Text = tetai;
  150. evp1 evt1 evrho1 evmair1 = SOREF Tmax DT0 QM Vr Sr Pnm tetai 'N2'
  151. HEXTeq TEXT 'VERT';
  152.  
  153.  
  154. *=======================================================================
  155. Si GRAPH;
  156. TAB1 =TABLE ;
  157. TAB1.'TITRE'=TABLE ;
  158. tab1 . 1 = 'MOT' 'MARQ CROI REGU ';
  159. tab1 . 'TITRE' . 1 = 'Sol Ref adia';
  160. tab1 . 'TITRE' . 2 = 'Sol Ref non adia' ;
  161.  
  162. tit= chai 'Pression enceinte' ;
  163. dess (evpa et evp1) titr tit
  164. 'GRIL' titx 's' tity 'Pa' lege tab1;
  165.  
  166. tit= chai 'Température enceinte' ;
  167. dess (evta et evt1) titr tit
  168. 'GRIL' titx 's' tity '°C' lege tab1;
  169.  
  170. tit = chai 'Densité moyenne enceinte';
  171. dess (evrhoa et evrho1) titr tit
  172. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  173.  
  174. tit = chai 'Masse d air';
  175. dess (evmaira et evmair1) titr tit
  176. 'GRIL' titx 's' tity 'kg' lege tab1;
  177. Finsi;
  178.  
  179.  
  180. epsi=1.e-8;
  181.  
  182. episo=0.044;
  183. db=0.1 ;
  184. R1=1.2 ;
  185. R1=1.2 - episo;
  186. h1=1.605;
  187. h2=2.342 - episo;
  188. hb=0.835;
  189. PA0=R1 0.;
  190. PAb=PA0 moins (0. hb);
  191. PAbm=PAb moins ((R1/2.) 0.);
  192. PA1=R1 h1;
  193. PB1=R1 ((-1.)*h1);
  194. PA1b=PA1 moins (0. hb);
  195. CA1=0. 0.275 ;
  196. CA2=(0.33*R1) H1 ;
  197. PAX2=0. h2;
  198. PA20= PAX2 tour -5. CA1;
  199. PA2= PA20 tour -15. CA1;
  200. p0=0 0 ;
  201. paxb= p0 moins (0. hb);
  202. p2=db 0. ;
  203. p2b=p2 moins (0. hb);
  204. breche = paxb 'DROI' n1 p2b ;
  205. bas= p2b 'DROI' dini (db/n1) dfin (R1/10.) PABM
  206. 'DROI' dini (R1/10.) dfin (db/n1) PAB;
  207. n2= nbel bas;
  208. plaf0 = PAX2 C n1 CA1 PA20;
  209. plaf1 = PA20 C (n2/2) CA1 PA2;
  210. plaf2 = PA1 C (n2/2) CA2 PA2;
  211.  
  212. plaf =plaf0 et plaf1 et (inve plaf2);
  213. axeh = PAX2 'DROI' n3 paxb ;
  214. PAXM=(PAX2 plus PAXB)*0.5;
  215.  
  216. axeh = PAX2 DROI dini (h2/n3/4.) dfin (h1/n3) PAXM
  217. DROI dini (h1/n3) dfin (h2/n3/4.) PAXB;
  218. n3n= nbel axeh ;
  219. paroih=PAb d n3n PA1;
  220.  
  221. pla=plaf et (inve paroih) ;
  222. pla = pla et (syme pla droit p0 pax2);
  223. Si GRAPH;
  224. trace (pla et ca1 et ca2 et PA1);
  225. trace (plaf et paroih et axeh et breche et bas
  226. et ca1);
  227. Finsi;
  228. mth= 'DALLER' (breche 'ET' bas) paroih plaf axeh;
  229.  
  230. entb = breche plus (0. 0.);
  231. DEPL entb tour 15. P2b;
  232. pbx2= pax2 syme 'DROITE' P0 PA0;
  233. p0b= poin 1 entb ;
  234. axeb = PBX2 'DROI' n3 p0b;
  235. paroib =pab d n3 pb1;
  236. fond = plaf SYME 'DROITE' P0 PA0;
  237. elim (entb 'ET' bas et paroib et fond et axeb) epsi;
  238. mtb= 'DALLER' (entb 'ET' bas) paroib fond axeb;
  239. axe=axeb et axeh;
  240. mt = mth et mtb ;
  241. elim (mtb et bas et entb et bas) epsi;
  242. Parois = paroib et paroih et plaf et fond et entb ;
  243. parext = plaf et (inve paroih) et paroib et (inve fond);
  244.  
  245. parexp = parext plus (0. 0.);
  246. debproc crec parexp*'MAILLAGE' e1*'FLOTTANT' n1*'ENTIER' col*'MOT';
  247. cq= vide maillage;
  248. tt=table;
  249. repeter BLOC (nbel parexp);
  250. ei= elem &bloc parexp;
  251. p1=point 1 ei ;
  252. p2=point 2 ei;
  253. p1p2=p2 moins p1 ;
  254. a = norm p1p2;
  255. p1p2=p1p2*(e1/a);
  256. pp2=p1 plus p1p2;
  257. p3= pp2 tour 90. p1;
  258. tt.&bloc=p3;
  259. Si(Ega &bloc 1);
  260. p0=p3;
  261. sinon;
  262. cq = cq et (p0 d 1 p3);
  263. p0 = p3;
  264. finsi;
  265. *trace ( parexp et cq) 'NCLK';
  266. fin bloc;
  267. pp2= p2 moins p1p2;
  268. p2= pp2 tour (-90.) p2;
  269. cq = cq et (p3 d 1 p2);
  270. cq = elem cq 'SEG2';
  271. mcq= parexp regle n1 cq;
  272. mcq= mcq coul col ;
  273. finproc cq mcq ;
  274.  
  275.  
  276. cq1 mcq1 = crec parexp e4 nf1 rouge;
  277. cq2 mcq2 = crec cq1 e1 nf2 vert;
  278. cq3 mcq3 = crec cq2 e3 nf3 TURQ;
  279.  
  280. mtp= (mcq1 et mcq2 et mcq3);
  281.  
  282. Si Graph;
  283. trace mtp;
  284. trace (elim ((mt et mtp) et (syme (mt et mtp) 'DROIT' P0 pax2)) epsi);
  285. Finsi;
  286.  
  287. ************************************************************************
  288. * Petite disgression pour calculer la surface de l'enceinte
  289. Si FAUX;
  290.  
  291. la= prog;
  292. ln=prog;
  293. nn=25;
  294. repeter BLOC 40;
  295. a= rota parext nn 90. pax2 pbx2;
  296. sa=((mesu a 'SURF' ) * 4.);
  297. la = la et (prog sa);
  298. ln = ln et (prog nn);
  299. nn= nn + 25;
  300. fin bloc;
  301. evmes= evol manu ln la ;
  302. dess evmes GRIL TITR ' Surface interne de l enceinte RIVA';
  303. opti donn 5;
  304. Finsi ;
  305. ************************************************************************
  306.  
  307. rxt = 'TABLE' ;
  308. rxt.'vtf'=mt ;
  309. rxt.'axe' = axe ;
  310. rxt.'breche'=breche ;
  311. rxt.'diru1'=0. 1. ;
  312. rxt.'epsi'= epsi ;
  313. rxt.'pi' = 0.5 0.5 ;
  314. rxt.'DT0' = (maxi (prog DT0 DTC));
  315. rxt.'DETMAT'= VRAI ;
  316. rxt.'RENU' = 'RIEN' ;
  317. rxt.'DISCR'= 'LINE';
  318. rxt.'KPRE' = 'MSOMMET';
  319. rxt.'N2' = VRAI ;
  320. rxt.'MODTURB' = 'LMEL' ;
  321. rxt.'LMEL' = 0.01 ;
  322. rxt.'GRAPH' = GRAPH ;
  323.  
  324. *rxt.'THERCO'=VRAI ;
  325. rxt.'PAROIS'=table;
  326. rxt.'PAROIS'.'Feuille'=table ;
  327. rxt.'PAROIS'.'Feuille'.'vtp'=mcq1;
  328. rxt.'PAROIS'.'Feuille'.'LAMBDA'=LB4;
  329. rxt.'PAROIS'.'Feuille'.'ROCP'=ROCP4;
  330. rxt.'PAROIS'.'Feuille'.'Tp0'=tetai;
  331.  
  332. rxt.'PAROIS'.'Isolant'=table ;
  333. rxt.'PAROIS'.'Isolant'.'vtp'=mcq2;
  334. rxt.'PAROIS'.'Isolant'.'LAMBDA'=LB1;
  335. rxt.'PAROIS'.'Isolant'.'ROCP'=ROCP1;
  336. rxt.'PAROIS'.'Isolant'.'Tp0'=tetai;
  337.  
  338. rxt.'PAROIS'.'Inox'=table ;
  339. rxt.'PAROIS'.'Inox'.'vtp'=mcq3;
  340. rxt.'PAROIS'.'Inox'.'LAMBDA'=LB3;
  341. rxt.'PAROIS'.'Inox'.'ROCP'=ROCP3;
  342. rxt.'PAROIS'.'Inox'.'Tp0'=tetai;
  343.  
  344. rxt.'ECHEXT' = VRAI;
  345. rxt.'parext' = cq3 ;
  346. rxt.'HEXT' = HEXT ;
  347. rxt.'TPEXT' = TEXT ;
  348.  
  349. rxt.'ECHAN' = Hint ;
  350.  
  351. rxt.'Yn20' = 0. ;
  352. rxt.'TF0' = tetai ;
  353. rxt.'PT0' = 1.0e5 ;
  354.  
  355. Qinc = Qm ;
  356. rxt.'scenario' = table ;
  357. rxt.'scenario'.'t' = prog 0.0 1000. ;
  358. rxt.'scenario'.'qair' = prog 0. 0. ;
  359. rxt.'scenario'.'qn2' = prog Qinc Qinc ;
  360. rxt.'scenario'.'tinj' = prog tetai tetai ;
  361.  
  362. rxt.'GRAPH' = FAUX ;
  363. execrxt 0 rxt ;
  364.  
  365. Si COMPLET;
  366. rxt.'TBT'.'RTF'.'1TSCA'.'KOPT'.'CMD'=0.;
  367. Finsi;
  368.  
  369. Diag=rxt.'GEO'.'Diag';
  370. mess ' Volume de RIVA ' (somt diag);
  371. rxt.'GRAPH' = GRAPH ;
  372.  
  373. nbit = ENTI (Tmax / rxt.'DT0') ;
  374. execrxt nbit rxt ;
  375.  
  376. TAB1 =TABLE ;
  377. TAB1.'TITRE'=TABLE ;
  378. tab1 . 1 = 'MOT' 'MARQ CROI REGU ';
  379. tab1 . 2 = 'MOT' 'MARQ CARR REGU TIRC';
  380. tab1 . 3 = 'MOT' 'MARQ LOSA REGU TIRC';
  381. tab1 . 4 = 'MOT' 'MARQ TRIU REGU TIRC';
  382. tab1 . 5 = 'MOT' 'MARQ TRID REGU TIRC';
  383. tab1 . 'TITRE' . 1 = 'Sol Ref non adia';
  384. tab1 . 'TITRE' . 2 = 'Nautilus CFD';
  385. *.................................................................
  386. evrho2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'Rhom');
  387. evp2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'PT');
  388. evt2= evol manu (rxt.'TIC'.'LTPS') (rxt.'TIC'. 'Tfm');
  389. evmair2=evrho2 * Vr;
  390.  
  391. Si GRAPH;
  392. tit= chai 'Pression enceinte' ;
  393. dess (evp1 et evp2) titr tit
  394. 'GRIL' titx 's' tity 'Pa' lege tab1;
  395.  
  396. tit= chai 'Température moyenne enceinte';
  397. dess (evt1 et evt2) titr tit
  398. 'GRIL' titx 's' tity '°C' lege tab1;
  399.  
  400. tit= chai 'Densité moyenne enceinte ' ;
  401. dess (evrho1 et evrho2) titr tit
  402. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  403.  
  404. tit= chai 'Masse d air ' ;
  405. dess (evmair1 et evmair2) titr tit
  406. 'GRIL' titx 's' tity 'kg/m3' lege tab1;
  407.  
  408. tp= rxt.tic.'TP';
  409. tf= rxt.tic.'TF';
  410. $vtp = rxt.geo.'$vtp';
  411. $vtf = rxt.geo.'$vtf';
  412. vtp = doma $vtp maillage;
  413. vtf = doma $vtf maillage;
  414. a1 = elem vtp 'APPUYE' 'LARGEMENT' parexp ;
  415. vtp1= diff vtp a1;
  416. tp1 = redu tp vtp1;
  417. trace (tp1 et tf) (vtp1 et vtf) titr 'Isothermes';
  418.  
  419. Finsi;
  420.  
  421. devp=evp1 - evp2 abs;
  422. erp= maxi (extr devp 'ORDO');
  423. mess ' ERP =' ERP;
  424. Si (ERP '>' 30000. ) ; erreur 5 ; Finsi ;
  425.  
  426.  
  427. FIN ;
  428.  
  429.  
  430. opti donn 5 ;
  431.  
  432. un=rxt.'TIC'.'UN';
  433. tf =rxt.'TIC'.'TF' ;
  434.  
  435. $vtf=rxt.'GEO'.'$vtf' ;
  436. vtf=doma $vtf maillage;
  437. rho=rxt.'TIC'.'RHO' ;
  438. un =rxt.'TIC'.'UN';
  439.  
  440. ixe=inve axe ;
  441. evauz = evol chpo (exco un 'UY') ixe ;
  442. evarh = evol chpo rho ixe ;
  443. evatf = evol chpo tf ixe ;
  444. evair = evol chpo rair ixe ;
  445.  
  446.  
  447. Si GRAPH ;
  448.  
  449. dess evauz 'TITRE' 'Vitesse sur l axe';
  450. dess evarh 'TITRE' 'Densite melange sur l axe';
  451. dess evatf 'TITRE' 'Temperature sur l axe';
  452.  
  453. ung= vect un 0.1 ux uy jaune;
  454. trace ung vtf;
  455. opti isov suli ;
  456. trace rho vtf 'TITRE' ' Rho' ;
  457. *trace rh2 vtf 'TITRE' ' Rh2' ;
  458. *trace rco vtf 'TITRE' ' Rco' ;
  459. trace tf vtf 'TITRE' ' Tf ' ;
  460. Finsi ;
  461.  
  462. * FIN ;
  463.  
  464.  
  465.  
  466.  
  467.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales