Télécharger huit2tract.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : huit2tract.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE 8 Chaines INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION BIAXIALE DANS LE PLAN X,Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. option epsilon 'UTILISATEUR';
  25. *
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = VRAI ;
  28. GRAPH = FAUX;
  29.  
  30. title = 'CHAINE' '8 Chaines - ' 'TRACTION BIAXIALE XY' ;
  31.  
  32. *======================================================================*
  33. * Geometrie - Maillage *
  34. *======================================================================*
  35. * Longueur (direction x) de la plaque/membrane :
  36. Lg_x = 1. ;
  37. * Largeur (direction y) de la plaque/membrane :
  38. Lg_y = 0.5 ;
  39. * Nombre d'elements selon les directions x et y :
  40. Nel_x = 30 ;
  41. Nel_y = 10 ;
  42. *
  43. Nel_x = 3 ;
  44. Nel_y = 1 ;
  45. 'OPTION' 'ELEM' 'QUA8' ;
  46. *
  47. P1 = 0. 0. ;
  48. P2 = Lg_x 0. ;
  49. P3 = Lg_x Lg_y ;
  50. P4 = 0. Lg_y ;
  51. *
  52. L1 = 'DROITE' Nel_x P1 P2 ;
  53. L2 = 'DROITE' Nel_y P2 P3 ;
  54. L3 = 'DROITE' Nel_x P3 P4 ;
  55. L4 = 'DROITE' Nel_y P4 P1 ;
  56. *
  57. SU = 'DALLER' L1 L2 L3 L4 ;
  58. 'SI' GRAPH ;
  59. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  60. 'FINSI' ;
  61.  
  62. *======================================================================*
  63. * Modele - Materiau - Caracteristiques (en Pa) *
  64. *======================================================================*
  65. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  66. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  67. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  68. 'ERREUR' 5 ;
  69. 'FINSI' ;
  70. * Calcul du Module d'Young
  71. * Ne pas oublier de definir les parametres lies a l'elasticite.
  72. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  73. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  74. *
  75. LCMAT = MOTS 'YOUN' 'NU ' 'NKT' 'VN ' ;
  76. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  77. 'NON_LINEAIRE' 'UTILISATEUR'
  78. 'NUME_LOI' 36 'C_MATERIAU' LCMAT ;
  79. *
  80. * Pour calculer le module d'Young, on utilise les
  81. * Coefficients du modele de Mooney-Rivlin (en MPa) : Pourquoi Pas !
  82. *
  83. C1 = 0.183 ; C2 = 0.0034 ;
  84. *
  85. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  86. * du fait de l'incompressibilite inherente au modele.
  87. * Le module de Young YOU est alors connu, car, pour ce modele, le
  88. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  89. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  90. * de la traction. En fonction du niveau de deformation atteinte en
  91. * traction, il faut augmenter cette valeur afin de pouvoir faire
  92. * converger les calculs (module tangent en fin de calculs).
  93. * Prendre des valeurs superieures n'entraine pas de modification des
  94. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  95. *
  96. XNU = 0.499 ;
  97. YOUini = 3.*(2.*(C1+C2)) ; YOU = 1000. * YOUini ;
  98. *Parametres du modèle 8chaines : essais Treloar/Kawabata MPa
  99. xnkt = 0.28;
  100. xvn = 25.4;
  101. * 'DIM3' 1.
  102. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'NKT' xnkt 'VN' xvn ;
  103. *
  104. *
  105. *======================================================================*
  106. * Conditions aux limites - Chargement bi-axe *
  107. *======================================================================*
  108. BL1 = 'BLOQUER' 'UY ' L1 ;
  109. BL2 = 'BLOQUER' 'UY ' L3 ;
  110. BL4 = 'BLOQUER' 'UX ' L4 ;
  111. BL3 = 'BLOQUER' 'UX ' L2 ;
  112. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  113. *
  114. * Definition des instants du chargement :
  115. t_deb = 0. ; t_fin = 10. ;
  116. L_tps = 'PROG' t_deb t_fin ;
  117. * Deplacement suivant X :
  118. FF_x = 'DEPIMP' BL3 1. ;
  119. L_UX = 'PROG' 0. (10. * Lg_x) ;
  120. EV_x = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMX' L_UX ;
  121. CHAR_x = 'CHARGEMENT' 'DIMP' FF_x EV_x ;
  122. * Deplacement suivant Y :
  123. L_UY = 'PROG' 0. ( 2. * Lg_y) ;
  124. FF_y = 'DEPIMP' BL2 1. ;
  125. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  126. CHAR_y = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  127. *
  128. CHARTOT = CHAR_x 'ET' CHAR_y ;
  129.  
  130. *======================================================================*
  131. * Initialisation de la table pour appel a PASAPAS *
  132. *======================================================================*
  133. TAB1 = 'TABLE' ;
  134. TAB1.'MODELE' = MO ;
  135. TAB1.'CARACTERISTIQUES' = MA ;
  136. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  137. TAB1.'CHARGEMENT' = CHARTOT ;
  138. *TAB1.'PRECISION' = 1.E-6 ;
  139. *TAB1.'FTOL' = 1.E-5 ;
  140. *TAB1.'MTOL' = 1.E-5 ;
  141. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  142. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  143. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  144. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  145. *
  146. L_abs = TAB1.'TEMPS_SAUVES' ;
  147. n_abs = 'DIMENSION' L_abs ;
  148. *
  149. PASAPAS TAB1 ;
  150. *
  151. * Quelques traces de controle apres calculs
  152. 'SI' GRAPH ;
  153. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  154. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  155. 'TRACER' (Defo_0 'ET' Defo_1)
  156. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  157. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  158. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  159. 'FINSI' ;
  160. *
  161. *======================================================================*
  162. * Construction de la solution analytique *
  163. *======================================================================*
  164. * Definitions :
  165. * - Allongement selon direction x : Lamx = 1 + (UX/Lg_x)
  166. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  167. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  168. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  169. * Dans le cas du modele de 8 Chaines :
  170. * W = , soit dW/dI1 = et dW/dI2 = 0
  171. *
  172. * Les contraintes de Cauchy sont calculables analytiquement :
  173. * - SCxx = 2.(Lamx**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamy**2.dW/dI2)
  174. * - SCyy = 2.(Lamy**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamx**2.dW/dI2)
  175. * - SCxy = 0 (pas de cisaillement)
  176. * - SCzz = 0 (hypothese des contraintes planes)
  177. *
  178. *
  179. L_Un = 'PROG' n_abs '*' 1. ;
  180. Lamx = L_Un + (('IPOL' L_abs L_tps L_UX) / Lg_X) ;
  181. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  182. *
  183. L_z1 = Lamx * Lamx ; L_z2 = Lamy * Lamy ;
  184. L_z3 = L_z1 - ((L_z1*L_z2)**-1) ;
  185. L_z4 = L_z2 - ((L_z1*L_z2)**-1) ;
  186. *LG
  187. L_tr = L_Un * 3.;
  188. I1 = L_z1 + L_z2 + ((L_z1*L_z2)**-1);
  189. I2 =(L_z1 * L_z2) + (L_z1**-1) + (L_z2**-1);
  190. *********** modele 8 chaines ******************************************
  191. ufj = L_Un*xnkt*0.5;
  192. alp = xnkt*(0.1/xvn)*(L_Un * I1 );
  193. xop = xnkt*((33./(1050.*(xvn**2)))*((L_Un * (I1 **2))));
  194. lmp = xnkt*((19.*4./(7000.*(xvn**3)))*((L_Un * (I1 **3))));
  195. mpo = xnkt*((519.*5./(673750.*(xvn**4)))*((L_Un * (I1 **4))));
  196. dWI1= ufj+alp+xop+lmp+mpo;
  197. dWI2= L_Un*0.;
  198. ***********************************************************************
  199. SCxx_th = L_z3 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  200. SCyy_th = L_z4 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z1)) ;
  201. SCxy_th = 0. * L_Un ;
  202.  
  203. *======================================================================*
  204. * Comparaison des resultats avec la solution analytique *
  205. *======================================================================*
  206. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  207. * calculees et les solutions analytiques correspondantes.
  208. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  209. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  210. *
  211. TabD = TAB1.'DEPLACEMENTS' ;
  212. TabS = TAB1.'CONTRAINTES' ;
  213. Confini = 'FORM' ;
  214. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  215. *
  216. SCxx = 'PROG' 0. ;
  217. SCyy = 'PROG' 0. ;
  218. SCxy = 'PROG' 0. ;
  219. 'REPETER' Boucle (n_abs - 1) ;
  220. 'FORM' (TabD.&Boucle) ;
  221. VolSU = 'INTG' MO ChmUn ;
  222. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  223. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  224. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  225. 'FORM' Confini ;
  226. 'FIN' Boucle ;
  227. *
  228. 'SI' GRAPH ;
  229. tlege = 'TABLE' ;
  230. tlege. 1 = 'MARQ CROI' ;
  231. tlege.'TITRE' = 'TABLE' ;
  232. tlege.'TITRE'. 1 = 'Numerique' ;
  233. tlege.'TITRE'. 2 = 'Analytique' ;
  234. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  235. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  236. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  237. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  238. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  239. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  240. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  241. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  242. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  243. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  244. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  245. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  246. 'FINSI' ;
  247. *
  248. * Tests de bon fonctionnement :
  249. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  250. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  251. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  252. *
  253. MESS ' RESULTATS : ' title ;
  254. MESS ' ------------------------------------------------ ';
  255. 'SAUTER' 1 'LIGNE' ;
  256. 'MESS' ' Tests de bon fonctionnement :' ;
  257. 'MESS' ' -------------------------------' ;
  258. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  259. 'MESS' ' Ecart maximal en valeur absolue entre la valeur moyenne '
  260. 'calculee' ;
  261. 'MESS' ' et la '
  262. 'solution analytique associee' ;
  263. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  264. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  265. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  266. 'SAUTER' 1 'LIGNE' ;
  267. * Ecart maximal tolere sur la contrainte (en Pa)
  268. Sigref = 1.E-3 ;
  269. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  270. 'MESS' ' ---------------------' ;
  271. 'MESS' ' ECHEC DU CAS-TEST !' ;
  272. 'MESS' ' ---------------------' ;
  273. 'ERREUR' 5 ;
  274. 'SINON' ;
  275. 'MESS' ' ----------------------' ;
  276. 'MESS' ' SUCCES DU CAS-TEST !' ;
  277. 'MESS' ' ----------------------' ;
  278. 'FINSI' ;
  279. 'SAUTER' 1 'LIGNE' ;
  280.  
  281. 'FIN' ;
  282.  
  283.  
  284.  
  285.  
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales