Télécharger harttrac3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : harttrac3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE HART-SMITH QUASI-INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE INCOMPRESSIBLE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  24. *opti trac PSC;
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = VRAI ;
  27. GRAPH=FAUX;
  28. * Mettre 1 ou 2 selon le type de calcul voulu
  29. ICALCUL = 2;
  30. *
  31. 'SI' ('>' ICALCUL 2) ;
  32. 'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  33. 'ERREUR' 5 ;
  34. 'FINSI' ;
  35.  
  36. title = 'CHAINE' 'HART-SMITH- ' 'TRACTION UNIAXIALE Z' ;
  37.  
  38. *======================================================================*
  39. * Geometrie - Maillage *
  40. *======================================================================*
  41. * Longueur (direction x) du pave :
  42. Lg_x = 1. ;
  43. * Largeur (direction y) du pave :
  44. Lg_y = 1. ;
  45. * Hauteur (direction z) du pave :
  46. Lg_z = 1. ;
  47. * Nombre d'elements selon les directions x, y et z :
  48. 'SI' ('EGA' ICALCUL 1) ;
  49. Nel_x = 2 ;
  50. Nel_y = 2 ;
  51. Nel_z = 2 ;
  52. * 'TET4' 'PRI6' 'PYR5' 'TET4' 'CUB8'
  53. 'OPTION' 'ELEM' 'CUB8' ;
  54. 'FINSI' ;
  55. 'SI' ('EGA' ICALCUL 2) ;
  56. Nel_x = 3 ;
  57. Nel_y = 3 ;
  58. Nel_z = 3 ;
  59. *CU20
  60. 'OPTION' 'ELEM' 'CUB8';
  61. 'FINSI' ;
  62. *'CU20'
  63. P1 = 0. 0. 0. ;
  64. P2 = Lg_x 0. 0. ;
  65. P3 = Lg_x Lg_y 0. ;
  66. P4 = 0. Lg_y 0. ;
  67. *
  68. L1 = 'DROITE' Nel_x P1 P2 ;
  69. L2 = 'DROITE' Nel_y P2 P3 ;
  70. L3 = 'DROITE' Nel_x P3 P4 ;
  71. L4 = 'DROITE' Nel_y P4 P1 ;
  72. *
  73. SBas = 'DALLER' L1 L2 L3 L4 ;
  74. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  75. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  76. 'SI' GRAPH ;
  77. 'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') 'CACH' ;
  78. 'FINSI' ;
  79.  
  80. *======================================================================*
  81. * Modele - Materiau - Caracteristiques (en MPa) *
  82. *======================================================================*
  83. * Ne pas oublier de definir les parametres lies a l'elasticite.
  84. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  85. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  86. *
  87. LCMAT = MOTS 'YOUN' 'NU ' 'G' 'K1' 'K2' 'D ';
  88. MO = MODE Pave 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  89. 'NON_LINEAIRE' 'UTILISATEUR'
  90. 'NUME_LOI' 34 'C_MATERIAU' LCMAT ;
  91. *
  92. * Pour calculer le module d'Young, on utilise les
  93. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  94. *
  95. C1 = 0.183 ; C2 = 0.0034 ;
  96. *
  97. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  98. * du fait de l'incompressibilite inherente au modele.
  99. * Le module de Young YOU est alors connu, car, pour ce modele, le
  100. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  101. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  102. * de la traction. En fonction du niveau de deformation atteinte en
  103. * traction, il faut augmenter cette valeur afin de pouvoir faire
  104. * converger les calculs (module tangent en fin de calculs).
  105. * Prendre des valeurs superieures n'entraine pas de modification des
  106. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  107. *XNU = 0.497 ;
  108. YOUini = 3.*(2.*(C1+C2)) ;
  109. *
  110. 'SI' ('EGA' ICALCUL 1) ;
  111. XNU = 0.497 ;
  112. CoeD = 1.E-4 ;
  113. YOU = 10000. * YOUini ;
  114. 'FINSI' ;
  115. 'SI' ('EGA' ICALCUL 2) ;
  116. XNU = 0.497;
  117. CoeD = 1.E-4 ;
  118. * YOU = 50000. * YOUini ;
  119. YOU = 10000. * YOUini ;
  120. 'FINSI' ;
  121. *
  122. *Parametres du modèle HS : essais Treloar/Kawabata MPa
  123. G = 0.175 ;
  124. K1 = 2.86E-4 ;
  125. K2 = 0.311 ;
  126. *
  127. *
  128. *
  129. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'G' G 'K1' K1 'K2' K2
  130. 'D ' CoeD ;
  131. *==================================================================*
  132. * Conditions aux limites *
  133. *==================================================================*
  134. BL1 = 'BLOQUER' 'UZ ' Shau ;
  135. BL2 = 'BLOQUER' 'UZ ' Sbas ;
  136. BL3 = 'BLOQUER' 'UX ' L4 ;
  137. BL4 = 'BLOQUER' 'UY ' L1 ;
  138. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  139. *
  140. * Definition des instants du chargement :
  141. t_deb = 0. ; t_fin = 10. ;
  142. L_tps = 'PROG' t_deb t_fin ;
  143. * Deplacement suivant Z :
  144. L_UZ = 'PROG' 0. (6. * Lg_z) ;
  145. FF_z = 'DEPIMP' BL1 1. ;
  146. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMZ' L_UZ ;
  147. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  148. *======================================================================*
  149. * Initialisation de la table pour appel a PASAPAS *
  150. *======================================================================*
  151. TAB1 = 'TABLE' ;
  152. TAB1.'MODELE' = MO ;
  153. TAB1.'CARACTERISTIQUES' = MA ;
  154. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  155. TAB1.'CHARGEMENT' = CHARTOT ;
  156. *TAB1.'PAS_AJUSTE'= VRAI;
  157. *TAB1.'PRECISION' = 1.E-7 ;
  158. *TAB1.'FTOL' = 1.E-5 ;
  159. *TAB1.'MTOL' = 1.E-5 ;
  160. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  161. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  162. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  163. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  164. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  165. TAB1.'REAC_GRANDS'=500.;
  166. *
  167. L_abs = TAB1.'TEMPS_SAUVES' ;
  168. n_abs = 'DIMENSION' L_abs ;
  169. *
  170. PASAPAS TAB1 ;
  171. *
  172. * Quelques traces de controle apres calculs
  173. 'SI' GRAPH ;
  174. Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  175. Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  176. 'TRACER' (Defo_0 'ET' Defo_1)
  177. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  178. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  179. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  180. 'FINSI' ;
  181. *
  182. *======================================================================*
  183. * Construction de la solution analytique INCOMPRESSIBLE *
  184. *======================================================================*
  185. * Definitions :
  186. * - Allongement selon direction y : Lamz = 1 + (UY/Lg_y)
  187. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  188. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  189. * Dans le cas du modele de HART-SMITH : Incompressible
  190. * dW/dI1 = G * exp (k1 * (I1 - 3)**2) et dW/dI2 = G * k2 * 1 / I2
  191. * Les contraintes de Cauchy sont calculables analytiquement :
  192. * - SCzz = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  193. *
  194. L_Un = 'PROG' n_abs '*' 1. ;
  195. Lamz = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  196. *
  197. SCxx_th = 0. * L_Un ;
  198. SCyy_th = 0. * L_Un ;
  199. L_z1 = Lamz * Lamz ; L_z2 = L_Un / Lamz ;
  200. L_tr = L_Un * 3.;
  201. I1 = L_z1 + (2. * L_z2);
  202. I2 = (2. * Lamz) + ( L_Un / L_z1 );
  203. ************************************************************************
  204. dWI1= G * (exp (k1 *((I1 - L_tr)**2)));
  205. dWI2= G * k2 * L_Un / I2;
  206. ************************************************************************
  207. SCzz_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  208. SCxy_th = 0. * L_Un ;
  209. SCxz_th = 0. * L_Un ;
  210. SCyz_th = 0. * L_Un ;
  211. *
  212. *======================================================================*
  213. * Comparaison des resultats avec la solution analytique *
  214. *======================================================================*
  215. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  216. * calculees et les solutions analytiques correspondantes.
  217. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  218. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  219. *
  220. TabD = TAB1.'DEPLACEMENTS' ;
  221. TabS = TAB1.'CONTRAINTES' ;
  222. Confini = 'FORM' ;
  223. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  224. *
  225. SCxx = 'PROG' 0. ;
  226. SCyy = 'PROG' 0. ;
  227. SCzz = 'PROG' 0. ;
  228. SCxy = 'PROG' 0. ;
  229. SCxz = 'PROG' 0. ;
  230. SCyz = 'PROG' 0. ;
  231. 'REPETER' Boucle (n_abs - 1) ;
  232. 'FORM' (TabD.&Boucle) ;
  233. VolSU = 'INTG' MO ChmUn ;
  234. * mess ' volsu ' volsu;
  235. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  236. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  237. SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  238. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  239. SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  240. SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  241. 'FORM' Confini ;
  242. 'FIN' Boucle ;
  243. *
  244. * LG lamb
  245. L_abs = Lamz;
  246. *
  247. 'SI' GRAPH ;
  248. tlege = 'TABLE' ;
  249. tlege. 1 = 'MARQ CROI' ;
  250. tlege.'TITRE' = 'TABLE' ;
  251. tlege.'TITRE'. 1 = 'Numerique' ;
  252. tlege.'TITRE'. 2 = 'Analytique' ;
  253. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  254. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  255. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  256. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  257. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  258. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  259. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  260. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  261. Evzz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  262. Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  263. 'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  264. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  265. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  266. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  267. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  268. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  269. Evxz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  270. Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  271. 'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  272. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  273. Evyz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  274. Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  275. 'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  276. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  277. 'FINSI' ;
  278. *
  279. * Tests de bon fonctionnement :
  280. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  281. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  282. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  283. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  284. uu= ('ABS' (SCzz - SCzz_th)) / Smaxref;
  285. list sczz; list SCzz_th; list uu;
  286. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  287. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  288. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  289. *
  290. MESS ' RESULTATS : ' title ;
  291. MESS ' ------------------------------------------------- ';
  292. 'SAUTER' 1 'LIGNE' ;
  293. 'MESS' ' Tests de bon fonctionnement :' ;
  294. 'MESS' ' -------------------------------' ;
  295. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  296. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  297. 'MESS' ' et la solution analytique' ;
  298. 'MESS' ' Composante XX : ' r_xx ;
  299. 'MESS' ' Composante YY : ' r_yy ;
  300. 'MESS' ' Composante ZZ : ' r_zz ;
  301. 'MESS' ' Composante XY : ' r_xy ;
  302. 'MESS' ' Composante XZ : ' r_xz ;
  303. 'MESS' ' Composante YZ : ' r_yz ;
  304. 'SAUTER' 1 'LIGNE' ;
  305. * Ecart relatif maximal tolere
  306. 'SI' ('EGA' ICALCUL 1) ;
  307. Sigref = 1.E-3 ;
  308. 'FINSI' ;
  309. 'SI' ('EGA' ICALCUL 2) ;
  310. Sigref = 1.E-2 ;
  311. 'FINSI' ;
  312. *
  313. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  314. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  315. 'MESS' ' ---------------------' ;
  316. 'MESS' ' ECHEC DU CAS-TEST !' ;
  317. 'MESS' ' ---------------------' ;
  318. 'ERREUR' 5 ;
  319. 'SINON' ;
  320. 'MESS' ' ----------------------' ;
  321. 'MESS' ' SUCCES DU CAS-TEST !' ;
  322. 'MESS' ' ----------------------' ;
  323. 'FINSI' ;
  324. 'SAUTER' 1 'LIGNE' ;
  325. 'FIN' ;
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  
  340.  
  341.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales