Télécharger hart2trac.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : hart2trac.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE HART-SMITH INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION BIAXIALE DANS LE PLAN X,Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' ;
  24. option epsilon utilisateur ;
  25. *
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = FAUX ;
  28. *GRAPH = VRAI ;
  29. title = 'CHAINE' 'HART-SMITH - ' 'TRACTION BIAXIALE XY' ;
  30.  
  31. *======================================================================*
  32. * Geometrie - Maillage *
  33. *======================================================================*
  34. * Longueur (direction x) de la plaque/membrane :
  35. Lg_x = 1. ;
  36. * Largeur (direction y) de la plaque/membrane :
  37. Lg_y = 0.5 ;
  38. * Nombre d'elements selon les directions x et y :
  39. Nel_x = 3 ;
  40. Nel_y = 2 ;
  41. *
  42. *
  43. 'OPTION' 'ELEM' 'QUA8' ;
  44. *
  45. P1 = 0. 0. ;
  46. P2 = Lg_x 0. ;
  47. P3 = Lg_x Lg_y ;
  48. P4 = 0. Lg_y ;
  49. *
  50. L1 = 'DROITE' Nel_x P1 P2 ;
  51. L2 = 'DROITE' Nel_y P2 P3 ;
  52. L3 = 'DROITE' Nel_x P3 P4 ;
  53. L4 = 'DROITE' Nel_y P4 P1 ;
  54. *
  55. SU = 'DALLER' L1 L2 L3 L4 ;
  56. 'SI' GRAPH ;
  57. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  58. 'FINSI' ;
  59.  
  60. *======================================================================*
  61. * Modele - Materiau - Caracteristiques (en MPa) *
  62. *======================================================================*
  63. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  64. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  65. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  66. 'ERREUR' 5 ;
  67. 'FINSI' ;
  68. *
  69. * Ne pas oublier de definir les parametres lies a l'elasticite.
  70. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  71. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  72. *
  73. LCMAT = MOTS 'YOUN' 'NU ' 'G' 'K1' 'K2' ;
  74. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  75. 'NON_LINEAIRE' 'UTILISATEUR'
  76. 'NUME_LOI' 34 'C_MATERIAU' LCMAT ;
  77. * Calcul du Module d'Young
  78. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  79. C1 = 0.183 ; C2 = 0.0034 ;
  80. *
  81. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  82. * du fait de l'incompressibilite inherente au modele.
  83. * Le module de Young YOU est alors connu, car, pour ce modele, le
  84. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  85. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  86. * de la traction. En fonction du niveau de deformation atteinte en
  87. * traction, il faut augmenter cette valeur afin de pouvoir faire
  88. * converger les calculs. Prendre des valeurs superieures n'entraine pas
  89. * de modification des resultats, cela modifie seulement le nombre
  90. * d'iterations mecaniques.
  91. * Par ex. : pour 1000 %, il faut multiplier par 30 la valeur initiale.
  92. * Si l'on se contente de 10., les calculs s'arretent vers 900 %.
  93. *
  94. XNU = 0.499 ;
  95. YOUini = 3.*(2.*(C1+C2)) ; YOU = 1000. * YOUini ;
  96. *
  97. *Parametres du modèle HS : essais Treloar/Kawabata MPa
  98. G = 0.175 ;
  99. K1 = 2.86E-4 ;
  100. K2 = 0.311 ;
  101. *
  102. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'G' G 'K1' K1 'K2' K2 ;
  103.  
  104. *======================================================================*
  105. * Conditions aux limites - Chargement bi-axe *
  106. *======================================================================*
  107. BL1 = 'BLOQUER' 'UY ' L1 ;
  108. BL2 = 'BLOQUER' 'UY ' L3 ;
  109. BL4 = 'BLOQUER' 'UX ' L4 ;
  110. BL3 = 'BLOQUER' 'UX ' L2 ;
  111. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  112. *
  113. * Definition des instants du chargement :
  114. t_deb = 0. ; t_fin = 10. ;
  115. L_tps = 'PROG' t_deb t_fin ;
  116. * Deplacement suivant X :
  117. FF_x = 'DEPIMP' BL3 1. ;
  118. L_UX = 'PROG' 0. (5. * Lg_x) ;
  119. EV_x = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMX' L_UX ;
  120. CHAR_x = 'CHARGEMENT' 'DIMP' FF_x EV_x ;
  121. * Deplacement suivant Y :
  122. L_UY = 'PROG' 0. ( 2. * Lg_y) ;
  123. L_UY = 'PROG' 0. ( 5. * Lg_y) ;
  124. FF_y = 'DEPIMP' BL2 1. ;
  125. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  126. CHAR_y = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  127. *
  128. CHARTOT = CHAR_x 'ET' CHAR_y ;
  129.  
  130. *======================================================================*
  131. * Initialisation de la table pour appel a PASAPAS *
  132. *======================================================================*
  133. TAB1 = 'TABLE' ;
  134. TAB1.'MODELE' = MO ;
  135. TAB1.'CARACTERISTIQUES' = MA ;
  136. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  137. TAB1.'CHARGEMENT' = CHARTOT ;
  138. **** LG
  139. *TAB1.'PRECISION' = 1.E-6 ;
  140. *TAB1.'FTOL' = 1.E-5 ;
  141. *TAB1.'MTOL' = 1.E-5 ;
  142. *
  143. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  144. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  145. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  146. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  147. *
  148. L_abs = TAB1.'TEMPS_SAUVES' ;
  149. n_abs = 'DIMENSION' L_abs ;
  150. *
  151. PASAPAS TAB1 ;
  152. *
  153. * Quelques traces de controle apres calculs
  154. 'SI' GRAPH ;
  155. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  156. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  157. 'TRACER' (Defo_0 'ET' Defo_1)
  158. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  159. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  160. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  161. 'FINSI' ;
  162. *
  163. *======================================================================*
  164. * Construction de la solution analytique *
  165. *======================================================================*
  166. * Definitions :
  167. * - Allongement selon direction x : Lamx = 1 + (UX/Lg_x)
  168. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  169. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  170. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  171. * Dans le cas du modele de HART-SMITH :
  172. * dW/dI1 = G * exp (k1 * (I1 - 3)**2) et dW/dI2 = G * k2 * 1 / I2
  173. *
  174. * Les contraintes de Cauchy sont calculables analytiquement :
  175. * - SCxx = 2.(Lamx**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamy**2.dW/dI2)
  176. * - SCyy = 2.(Lamy**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamx**2.dW/dI2)
  177. * - SCxy = 0 (pas de cisaillement)
  178. * - SCzz = 0 (hypothese des contraintes planes)
  179. *
  180. L_Un = 'PROG' n_abs '*' 1. ;
  181. Lamx = L_Un + (('IPOL' L_abs L_tps L_UX) / Lg_X) ;
  182. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  183. *
  184. L_z1 = Lamx * Lamx ; L_z2 = Lamy * Lamy ;
  185. L_z3 = L_z1 - ((L_z1*L_z2)**-1) ;
  186. L_z4 = L_z2 - ((L_z1*L_z2)**-1) ;
  187. *LG
  188. L_tr = L_Un * 3.;
  189. I1 = L_z1 + L_z2 + ((L_z1*L_z2)**-1);
  190. I2 =(L_z1 * L_z2) + (L_z1**-1) + (L_z2**-1);
  191. **********************************************************************
  192. dWI1= G * (exp (k1 *((I1 - L_tr)**2)));
  193. dWI2= G * k2 * L_Un / I2;
  194. **********************************************************************
  195. SCxx_th = L_z3 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  196. SCyy_th = L_z4 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z1)) ;
  197. SCxy_th = 0. * L_Un ;
  198. *PK1
  199. L_z1 = Lamx ; L_z2 = Lamy ;
  200. L_z3 = L_z1 - (((L_z1**3)*(L_z2**2))**-1) ;
  201. L_z4 = L_z2 - (((L_z2**3)*(L_z1**2))**-1) ;
  202. *
  203. PCxx_th = L_z3 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  204. PCyy_th = L_z4 * ((2.*dWI1*L_Un) + (2.*dWI2*L_z1)) ;
  205.  
  206. *======================================================================*
  207. * Comparaison des resultats avec la solution analytique *
  208. *======================================================================*
  209. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  210. * calculees et les solutions analytiques correspondantes.
  211. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  212. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  213. *
  214. TabD = TAB1.'DEPLACEMENTS' ;
  215. TabS = TAB1.'CONTRAINTES' ;
  216. Confini = 'FORM' ;
  217. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  218. *
  219. SCxx = 'PROG' 0. ;
  220. SCyy = 'PROG' 0. ;
  221. SCxy = 'PROG' 0. ;
  222. 'REPETER' Boucle (n_abs - 1) ;
  223. 'FORM' (TabD.&Boucle) ;
  224. VolSU = 'INTG' MO ChmUn ;
  225. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  226. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  227. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  228. 'FORM' Confini ;
  229. 'FIN' Boucle ;
  230. *
  231. * LG lamb
  232. L_abs = Lamy;
  233. *
  234. 'SI' GRAPH ;
  235. tlege = 'TABLE' ;
  236. tlege. 1 = 'MARQ CROI' ;
  237. tlege.'TITRE' = 'TABLE' ;
  238. tlege.'TITRE'. 1 = 'Numerique' ;
  239. tlege.'TITRE'. 2 = 'Analytique' ;
  240. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  241. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  242. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  243. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  244. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  245. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  246. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  247. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  248. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  249. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  250. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  251. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  252. *PK1
  253. Ev_t2 = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' PCxx_th ;
  254. Ev_t3 = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' PCyy_th ;
  255. 'DESSIN' (Ev_t2 'ET' Ev_t3) 'LEGE' tlege
  256. 'TITRE' ('CHAINE' title ' - CONTRAINTE PK1 XX (MPa)') ;
  257. @EXCEL1 Ev_t2 'hartsmith-th' ;
  258. 'FINSI' ;
  259. *
  260. * Tests de bon fonctionnement :
  261. *
  262. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  263. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  264. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  265. *
  266. MESS ' RESULTATS : ' title ;
  267. MESS ' ------------------------------------------------ ';
  268. 'SAUTER' 1 'LIGNE' ;
  269. 'MESS' ' Tests de bon fonctionnement :' ;
  270. 'MESS' ' -------------------------------' ;
  271. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  272. 'MESS' ' Ecart maximal en valeur absolue entre la valeur moyenne '
  273. 'calculee' ;
  274. 'MESS' ' et la '
  275. 'solution analytique associee' ;
  276. 'MESS' ' Composante XX : ' r_xx ' MPa' ;
  277. 'MESS' ' Composante YY : ' r_yy ' MPa' ;
  278. 'MESS' ' Composante XY : ' r_xy ' MPa' ;
  279. 'SAUTER' 1 'LIGNE' ;
  280. * Ecart maximal tolere sur la contrainte (en MPa)
  281. Sigref = 1.E-3 ;
  282. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  283. 'MESS' ' ---------------------' ;
  284. 'MESS' ' ECHEC DU CAS-TEST !' ;
  285. 'MESS' ' ---------------------' ;
  286. 'ERREUR' 5 ;
  287. 'SINON' ;
  288. 'MESS' ' ----------------------' ;
  289. 'MESS' ' SUCCES DU CAS-TEST !' ;
  290. 'MESS' ' ----------------------' ;
  291. 'FINSI' ;
  292. 'SAUTER' 1 'LIGNE' ;
  293.  
  294. 'FIN' ;
  295.  
  296.  
  297.  
  298.  
  299.  
  300.  
  301.  
  302.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales