Télécharger guionnet_tra.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : guionnet_tra.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Guionnet_tra.dgibi: Jeux de données *
  5. * ---------------------------------------- *
  6. * *
  7. **************************************************
  8. * *
  9. * TEST DE VALIDATION D'UNE LOI DE COMPORTEMENT *
  10. * -------------------------------------------- *
  11. * DE MATERIAU *
  12. * ----------- *
  13. * *
  14. * LOI DE COMPORTEMENT VISCOPLASTIQUE DE : *
  15. * GUIONNET *
  16. * *
  17. * COMPARAISON DE CALCULS SUR DES ELEMENTS: *
  18. * - COQUE EPAISSE ( MFR=5 ) *
  19. * - MASSIF 3D ( MFR=1 ) *
  20. * *
  21. * STRUCTURE : UNE PLAQUE CARREE *
  22. * - COTE : 1. M *
  23. * - EPAISSEUR : 0.01 M *
  24. * *
  25. * CHARGEMENT : DEPLACEMENTS IMPOSES *
  26. * ESSAI DE TRACTION *
  27. * *
  28. **************************************************
  29. opti echo 0 dime 3 elem cub8 ;
  30. *
  31. * Maillage
  32. *
  33. l1 = 1. ;
  34. l2 = 1. ;
  35. ep0 = .01 ;
  36. p1 = 0. 0. 0. ;
  37. p2 = ep0 0. 0. ;
  38. p3 = ep0 l2 0. ;
  39. p4 = 0. l2 0. ;
  40. p10 = 0. 0. l1 ;
  41. p20 = ep0 0. l1 ;
  42. p30 = ep0 l2 l1 ;
  43. p40 = 0. l2 l1 ;
  44. li1 = d p1 1 p2 ;
  45. li2 = d p2 1 p3 ;
  46. li3 = d p3 1 p4 ;
  47. li4 = d p4 1 p1 ;
  48. li10 = d p10 1 p20 ;
  49. li20 = d p20 1 p30 ;
  50. li30 = d p30 1 p40 ;
  51. li40 = d p40 1 p10 ;
  52. sur1 = 'DALL' li1 li2 li3 li4 ;
  53. sur10 = 'DALL' li10 li20 li30 li40 ;
  54. mail1 = sur1 'VOLU' 1 sur10 ;
  55. *
  56. * Modele
  57. *
  58. youn0 = 2.1E11 ;
  59. nu0 = .3 ;
  60. mod0 = 'MODE' mail1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  61. 'VISCOPLASTIQUE' 'GUIONNET' ;
  62. mat0 = MATE mod0 'YOUN' 192500. 'NU ' 0.3 'N ' 24
  63. 'K ' 200. 'CK ' 0. 'R0 ' 25.
  64. 'CD ' 0. 'M ' 0.8 'A ' 24000.
  65. 'A1 ' 3.3E5 'C ' 180. 'C1 ' 40.
  66. 'G ' 0. 'R ' 0. 'NN ' 0.005
  67. 'C2 ' 40. 'Q ' 1.466 'G1 ' 0. 'R1 ' 0.
  68. 'BETA' 1.1 'C0 ' 180. 'P1M0' 0.00333 ;
  69.  
  70. *
  71. * Conditions aux limites
  72. *
  73. cl1 = 'BLOQ' sur1 'UZ' ;
  74. cl2 = 'BLOQ' ( li1 'ET' li10 ) 'UY' ;
  75. cl3 = 'BLOQ' ( li2 'ET' li20 ) 'UX' ;
  76. cl4 = 'BLOQ' sur10 'UZ' ;
  77. cl0 = cl1 'ET' cl2 'ET' cl3 'ET' cl4 ;
  78. *
  79. * Chargement
  80. *
  81. depmax = .1 ;
  82. dep0 = 'DEPI' cl4 depmax ;
  83. ev0 = 'EVOL' 'MANU' temps ( 'PROG' 0. 1000. )
  84. y ( 'PROG' 0. 1. ) ;
  85. cha0 = 'CHAR' 'MECA' dep0 ev0 ;
  86. *
  87. dt0 = 10. ;
  88. tfin0 = 100. ;
  89. pro0 = 'PROG' 0. 'PAS' dt0 tfin0 ;
  90. *
  91. * Appel à PASAPAS
  92. *
  93. ta1 = 'TABLE' ;
  94. ta1 .'MODELE' = mod0 ;
  95. ta1 .'CARACTERISTIQUES' = mat0 ;
  96. ta1 .'CHARGEMENT' = cha0 ;
  97. ta1 .'BLOCAGES_MECANIQUES' = cl0 ;
  98. ta1 .'TEMPS_CALCULES' = pro0 ;
  99. *
  100. PASAPAS ta1 ;
  101. *
  102. * Post traitement
  103. *
  104. dim0 = 'DIME' ta1 .'TEMPS' ;
  105. *
  106. * Résultats calculés
  107. *
  108. reac0 = ta1 .'REACTIONS'.( dim0 - 1 ) ;
  109. depl0 = ta1 .'DEPLACEMENTS'.( dim0 - 1 ) ;
  110. temp0 = ta1 .'TEMPS'.( dim0 - 1 ) ;
  111. sigm0 = ta1 .'CONTRAINTES'.(dim0 - 1 ) ;
  112. eps0 = 'EPSI' mod0 depl0 ;
  113. *
  114. defo0 = 'DEFO' mail1 depl0 0. ;
  115. defo1 = 'DEFO' mail1 depl0 10. 'ROUG' ;
  116. *titr ' deformee finale' ;
  117. *trace ( defo0 'ET' defo1 ) ;
  118. *
  119. sigm0 = 'CHAN' 'CHPO' sigm0 mod0 ;
  120. *titr ' Contraintes suivant X' ;
  121. *trace ( 'EXCO' sigm0 'SMXX' ) mail1 ;
  122. *titr ' Contraintes suivant Y' ;
  123. *trace ( 'EXCO' sigm0 'SMYY' ) mail1 ;
  124. *titr ' Contraintes suivant Z' ;
  125. *trace ( 'EXCO' sigm0 'SMZZ' ) mail1 ;
  126. *titr ' Contraintes d cisaillement suivant YZ' ;
  127. *trace ( 'EXCO' sigm0 'SMYZ' ) mail1 ;
  128. reac0 = 'REDU' reac0 sur10 ;
  129. reac0 = 'EXCO' reac0 'FZ' 'SCAL' ;
  130. chp1 = 'MANU' 'CHPO' sur10 1 'SCAL' 1. ;
  131. reac1 = 'XTY' reac0 chp1 ( 'MOTS' 'SCAL' )
  132. ( 'MOTS' 'SCAL' ) ;
  133. *
  134. opti echo 0 dime 3 elem qua8 ;
  135. *
  136. * Maillage
  137. *
  138. p1 = 0. 0. 0. ;
  139. p4 = 0. l2 0. ;
  140. p10 = 0. 0. l1 ;
  141. p40 = 0. l2 l1 ;
  142. li1 = d p1 1 p4 ;
  143. li2 = d p4 1 p40 ;
  144. li3 = d p40 1 p10 ;
  145. li4 = d p10 1 p1 ;
  146. mail1 = 'DALL' li1 li2 li3 li4 ;
  147. *titr ' Maillage' ;
  148. *trace mail1 ;
  149. *
  150. * Modele
  151. *
  152. mod0 = 'MODE' mail1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  153. 'VISCOPLASTIQUE' 'GUIONNET' 'COQ8' ;
  154. mat0 = MATE mod0 'YOUN' 192500. 'NU ' 0.3
  155. 'N ' 24 'K ' 200. 'CK ' 0. 'A ' 24000.
  156. 'R0 ' 25. 'CD ' 0. 'M ' 0.8
  157. 'A1 ' 3.3E5 'C ' 180. 'C1 ' 40. 'G ' 0.
  158. 'R ' 0. 'NN ' 0.005 'C2 ' 40.
  159. 'Q ' 1.466 'G1 ' 0. 'R1 ' 0. 'BETA' 1.1
  160. 'C0 ' 180. 'P1M0' 0.00333 ;
  161. car0 = 'CARA' mod0 'EPAI' ep0 ;
  162. *
  163. * Conditions aux limites
  164. *
  165. cl1 = 'BLOQ' li1 'UZ' ;
  166. cl2 = 'BLOQ' li4 'UY' ;
  167. cl3 = 'BLOQ' mail1 'UX' ;
  168. cl4 = 'BLOQ' li3 'UZ' ;
  169. cl0 = cl1 'ET' cl2 'ET' cl3 'ET' cl4 ;
  170. *
  171. * Chargement
  172. *
  173. dep0 = 'DEPI' cl4 depmax ;
  174. ev0 = 'EVOL' 'MANU' temps ( 'PROG' 0. 1000. )
  175. y ( 'PROG' 0. 1. ) ;
  176. cha0 = 'CHAR' 'DIMP' dep0 ev0 ;
  177. *
  178. * Appel à PASAPAS
  179. *
  180. ta1 = 'TABLE' ;
  181. ta1 .'MODELE' = mod0 ;
  182. ta1 .'CARACTERISTIQUES' = mat0 'ET' car0 ;
  183. ta1 .'CHARGEMENT' = cha0 ;
  184. ta1 .'BLOCAGES_MECANIQUES' = cl0 ;
  185. ta1 .'TEMPS_CALCULES' = pro0 ;
  186. *
  187. PASAPAS ta1 ;
  188. *
  189. * Post traitement
  190. *
  191. dim0 = 'DIME' ta1 .'TEMPS' ;
  192. *
  193. * Résultats calculés
  194. *
  195. reac0 = ta1 .'REACTIONS'.( dim0 - 1 ) ;
  196. depl0 = ta1 .'DEPLACEMENTS'.( dim0 - 1 ) ;
  197. temp0 = ta1 .'TEMPS'.( dim0 - 1 ) ;
  198. sigm0 = ta1 .'CONTRAINTES'.( dim0 - 1 ) ;
  199. eps0 = 'EPSI' mod0 depl0 car0 ;
  200. *
  201. defo0 = 'DEFO' mail1 depl0 0. ;
  202. defo1 = 'DEFO' mail1 depl0 10. 'ROUG' ;
  203. *titr ' deformee finale' ;
  204. *trace ( defo0 'ET' defo1 ) ;
  205. *
  206. sigm0 = 'CHAN' 'CHPO' sigm0 mod0 ;
  207. *titr ' Contraintes suivant Y' ;
  208. *trace ( 'EXCO' sigm0 'SMSS' ) mail1 ;
  209. *titr ' Contraintes suivant Z' ;
  210. *trace ( 'EXCO' sigm0 'SMTT' ) mail1 ;
  211. *titr ' Contraintes d cisaillement suivant YZ' ;
  212. *trace ( 'EXCO' sigm0 'SMST' ) mail1 ;
  213. reac0 = 'REDU' reac0 li3 ;
  214. reac0 = 'EXCO' reac0 'FZ' 'SCAL' ;
  215. chp1 = 'MANU' 'CHPO' li3 1 'SCAL' 1. ;
  216. reac2 = 'XTY' reac0 chp1 ( 'MOTS' 'SCAL' )
  217. ( 'MOTS' 'SCAL' ) ;
  218. *
  219. 'MESS' ' Réaction au sommet de la structure
  220. , calcul massif ='
  221. reac1 ;
  222. 'MESS' ' Réaction au sommet de la structure
  223. , calcul coque épaisse ='
  224. reac2 ;
  225. 'SI' ( reac1 '>' 0. ) ;
  226. err1 = ( 'ABS' ( reac1 -reac2 ) ) / reac1 ;
  227. err1 = err1 * 100. ;
  228. 'SINON' ;
  229. err1 = 0. ;
  230. 'FINSI' ;
  231. 'MESS' ' Erreur obtenue en % =' err1 ;
  232. *
  233. 'SI' ( err1 '>' 0.03 ) ;
  234. 'ERRE' 5 ;
  235. 'SINON' ;
  236. 'ERRE' 0 ;
  237. 'FINSI' ;
  238. *
  239. 'FIN' ;
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales