Télécharger gdtract3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gdtract3d.dgibi
  2. *======================================================================*
  3. * MODELE HYPERELASTIQUE GORNET-DESMORAT QUASI-INCOMPRESSIBLE *
  4. * EN GRANDES TRANSFORMATIONS *
  5. * *
  6. * TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z *
  7. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE INCOMPRESSIBLE *
  8. * *
  9. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  10. *======================================================================*
  11. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  12. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  13. *======================================================================*
  14. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  15. * *
  16. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  17. * ne peut contenir que des modeles de type UMAT. On ne peut *
  18. * pas melanger les derivees objectives et les modeles de C3m. *
  19. *======================================================================*
  20.  
  21. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  22. option epsilon 'UTILISATEUR';
  23. *opti trac PSC;
  24. * Mettre VRAI si l'on souhaite divers traces.
  25. GRAPH = VRAI ;
  26. GRAPH = Faux;
  27. * Mettre 1 ou 2 selon le type de calcul voulu
  28. ICALCUL = 1;
  29. *
  30. 'SI' ('>' ICALCUL 2) ;
  31. 'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  32. 'ERREUR' 5 ;
  33. 'FINSI' ;
  34.  
  35. title = 'CHAINE' 'GORNET-DESMORAT - ' 'TRACTION UNIAXIALE Z' ;
  36.  
  37. *======================================================================*
  38. * Geometrie - Maillage *
  39. *======================================================================*
  40. * Longueur (direction x) du pave :
  41. Lg_x = 1. ;
  42. * Largeur (direction y) du pave :
  43. Lg_y = 1. ;
  44. * Hauteur (direction z) du pave :
  45. Lg_z = 1. ;
  46. * Nombre d'elements selon les directions x, y et z :
  47. 'SI' ('EGA' ICALCUL 1) ;
  48. Nel_x = 2 ;
  49. Nel_y = 2 ;
  50. Nel_z = 2 ;
  51. * 'TET4' 'PRI6' 'PYR5' 'TET4' 'CUB8'
  52. 'OPTION' 'ELEM' 'CUB8' ;
  53. 'FINSI' ;
  54. 'SI' ('EGA' ICALCUL 2) ;
  55. Nel_x = 3 ;
  56. Nel_y = 3 ;
  57. Nel_z = 3 ;
  58. *CU20
  59. 'OPTION' 'ELEM' 'CUB8';
  60. 'FINSI' ;
  61. *'CU20'
  62. P1 = 0. 0. 0. ;
  63. P2 = Lg_x 0. 0. ;
  64. P3 = Lg_x Lg_y 0. ;
  65. P4 = 0. Lg_y 0. ;
  66. *
  67. L1 = 'DROITE' Nel_x P1 P2 ;
  68. L2 = 'DROITE' Nel_y P2 P3 ;
  69. L3 = 'DROITE' Nel_x P3 P4 ;
  70. L4 = 'DROITE' Nel_y P4 P1 ;
  71. *
  72. SBas = 'DALLER' L1 L2 L3 L4 ;
  73. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  74. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  75. 'SI' GRAPH ;
  76. 'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') 'CACH' ;
  77. 'FINSI' ;
  78.  
  79. *======================================================================*
  80. * Modele - Materiau - Caracteristiques (en MPa) *
  81. *======================================================================*
  82. * Ne pas oublier de definir les parametres lies a l'elasticite.
  83. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  84. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  85. *
  86. LCMAT = MOTS 'YOUN' 'NU ' 'H1' 'H2' 'H3' 'D ';
  87. MO = MODE Pave 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  88. 'NON_LINEAIRE' 'UTILISATEUR'
  89. 'NUME_LOI' 33 'C_MATERIAU' LCMAT ;
  90. *
  91. * Pour calculer le module d'Young, on utilise les
  92. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  93. *
  94. C1 = 0.183 ; C2 = 0.0034 ;
  95. *
  96. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  97. * du fait de l'incompressibilite inherente au modele.
  98. * Le module de Young YOU est alors connu, car, pour ce modele, le
  99. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  100. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  101. * de la traction. En fonction du niveau de deformation atteinte en
  102. * traction, il faut augmenter cette valeur afin de pouvoir faire
  103. * converger les calculs (module tangent en fin de calculs).
  104. * Prendre des valeurs superieures n'entraine pas de modification des
  105. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  106.  
  107.  
  108. *XNU = 0.497 ;
  109. YOUini = 3.*(2.*(C1+C2)) ;
  110. *
  111. 'SI' ('EGA' ICALCUL 1) ;
  112. XNU = 0.497 ;
  113. CoeD = 1.E-4 ;
  114. YOU = 10000. * YOUini ;
  115. 'FINSI' ;
  116. 'SI' ('EGA' ICALCUL 2) ;
  117. XNU = 0.497;
  118. CoeD = 1.E-4 ;
  119. * YOU = 50000. * YOUini ;
  120. YOU = 10000. * YOUini ;
  121. 'FINSI' ;
  122. *
  123. *Parametres du modèle GD : essais Treloar/Kawabata MPa
  124. H1 = 0.142236 ;
  125. H2 = 1.5854659E-2 ;
  126. H3 = 3.4946541E-4 ;
  127. *
  128. *
  129. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'H1' H1 'H2' H2
  130. 'H3' H3 'D ' CoeD ;
  131. *==================================================================*
  132. * Conditions aux limites *
  133. *==================================================================*
  134. BL1 = 'BLOQUER' 'UZ ' Shau ;
  135. BL2 = 'BLOQUER' 'UZ ' Sbas ;
  136. BL3 = 'BLOQUER' 'UX ' L4 ;
  137. BL4 = 'BLOQUER' 'UY ' L1 ;
  138. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  139. *
  140. * Definition des instants du chargement :
  141. t_deb = 0. ; t_fin = 10. ;
  142. L_tps = 'PROG' t_deb t_fin ;
  143. * Deplacement suivant Z :
  144. L_UZ = 'PROG' 0. (6. * Lg_z) ;
  145. FF_z = 'DEPIMP' BL1 1. ;
  146. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMZ' L_UZ ;
  147. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  148.  
  149. *======================================================================*
  150. * Initialisation de la table pour appel a PASAPAS *
  151. *======================================================================*
  152. TAB1 = 'TABLE' ;
  153. TAB1.'MODELE' = MO ;
  154. TAB1.'CARACTERISTIQUES' = MA ;
  155. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  156. TAB1.'CHARGEMENT' = CHARTOT ;
  157. *TAB1.'PAS_AJUSTE'= VRAI;
  158. *TAB1.'PRECISION' = 1.E-7 ;
  159. *TAB1.'FTOL' = 1.E-5 ;
  160. *TAB1.'MTOL' = 1.E-5 ;
  161. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  162. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  163. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  164. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  165. tab1.reac_grands= 500.;
  166. *
  167. L_abs = TAB1.'TEMPS_SAUVES' ;
  168. n_abs = 'DIMENSION' L_abs ;
  169. *
  170. PASAPAS TAB1 ;
  171. *
  172. * Quelques traces de controle apres calculs
  173. 'SI' GRAPH ;
  174. Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  175. Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  176. 'TRACER' (Defo_0 'ET' Defo_1)
  177. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  178. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  179. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  180. 'FINSI' ;
  181. *
  182. *======================================================================*
  183. * Construction de la solution analytique INCOMPRESSIBLE *
  184. *======================================================================*
  185. * Definitions :
  186. * - Allongement selon direction y : Lamz = 1 + (UY/Lg_y)
  187. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  188. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  189. * Dans le cas du modele GD : Incompressible
  190. * Les contraintes de Cauchy sont calculables analytiquement :
  191. * - SCzz = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  192. *
  193. L_Un = 'PROG' n_abs '*' 1. ;
  194. Lamz = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  195. *
  196. SCxx_th = 0. * L_Un ;
  197. SCyy_th = 0. * L_Un ;
  198. L_z1 = Lamz * Lamz ; L_z2 = L_Un / Lamz ;
  199. L_tr = L_Un * 3.;
  200. I1 = L_z1 + (2. * L_z2);
  201. I2 = (2. * Lamz) + ( L_Un / L_z1 );
  202. ************************************************************************
  203. dWI1= H1 * (exp (H3 *((I1 - L_tr)**2)));
  204. dWI2= 3. * H2 * L_Un / (I2**0.5);
  205. ************************************************************************
  206. SCzz_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  207. SCxy_th = 0. * L_Un ;
  208. SCxz_th = 0. * L_Un ;
  209. SCyz_th = 0. * L_Un ;
  210. *
  211. *======================================================================*
  212. * Comparaison des resultats avec la solution analytique *
  213. *======================================================================*
  214. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  215. * calculees et les solutions analytiques correspondantes.
  216. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  217. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  218. *
  219. TabD = TAB1.'DEPLACEMENTS' ;
  220. TabS = TAB1.'CONTRAINTES' ;
  221. Confini = 'FORM' ;
  222. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  223. *
  224. SCxx = 'PROG' 0. ;
  225. SCyy = 'PROG' 0. ;
  226. SCzz = 'PROG' 0. ;
  227. SCxy = 'PROG' 0. ;
  228. SCxz = 'PROG' 0. ;
  229. SCyz = 'PROG' 0. ;
  230. 'REPETER' Boucle (n_abs - 1) ;
  231. 'FORM' (TabD.&Boucle) ;
  232. VolSU = 'INTG' MO ChmUn ;
  233. * mess ' volsu ' volsu;
  234. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  235. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  236. SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  237. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  238. SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  239. SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  240. 'FORM' Confini ;
  241. 'FIN' Boucle ;
  242. *
  243. * LG lamb
  244. L_abs = Lamz;
  245. *
  246. 'SI' GRAPH ;
  247. tlege = 'TABLE' ;
  248. tlege. 1 = 'MARQ CROI' ;
  249. tlege.'TITRE' = 'TABLE' ;
  250. tlege.'TITRE'. 1 = 'Numerique' ;
  251. tlege.'TITRE'. 2 = 'Analytique' ;
  252. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  253. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  254. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  255. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  256. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  257. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  258. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  259. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  260. Evzz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  261. Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  262. 'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  263. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  264. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  265. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  266. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  267. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  268. Evxz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  269. Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  270. 'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  271. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  272. Evyz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  273. Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  274. 'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  275. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  276. 'FINSI' ;
  277. *
  278. * Tests de bon fonctionnement :
  279. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  280. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  281. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  282. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  283. uu= ('ABS' (SCzz - SCzz_th)) / Smaxref;
  284. list sczz; list SCzz_th; list uu;
  285. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  286. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  287. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  288. *
  289. MESS ' RESULTATS : ' title ;
  290. MESS ' ------------------------------------------------- ';
  291. 'SAUTER' 1 'LIGNE' ;
  292. 'MESS' ' Tests de bon fonctionnement :' ;
  293. 'MESS' ' -------------------------------' ;
  294. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  295. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  296. 'MESS' ' et la solution analytique' ;
  297. 'MESS' ' Composante XX : ' r_xx ;
  298. 'MESS' ' Composante YY : ' r_yy ;
  299. 'MESS' ' Composante ZZ : ' r_zz ;
  300. 'MESS' ' Composante XY : ' r_xy ;
  301. 'MESS' ' Composante XZ : ' r_xz ;
  302. 'MESS' ' Composante YZ : ' r_yz ;
  303. 'SAUTER' 1 'LIGNE' ;
  304. * Ecart relatif maximal tolere
  305. 'SI' ('EGA' ICALCUL 1) ;
  306. Sigref = 1.E-3 ;
  307. 'FINSI' ;
  308. 'SI' ('EGA' ICALCUL 2) ;
  309. Sigref = 1.E-2 ;
  310. 'FINSI' ;
  311. *
  312. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  313. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  314. 'MESS' ' ---------------------' ;
  315. 'MESS' ' ECHEC DU CAS-TEST !' ;
  316. 'MESS' ' ---------------------' ;
  317. 'ERREUR' 5 ;
  318. 'SINON' ;
  319. 'MESS' ' ----------------------' ;
  320. 'MESS' ' SUCCES DU CAS-TEST !' ;
  321. 'MESS' ' ----------------------' ;
  322. 'FINSI' ;
  323. 'SAUTER' 1 'LIGNE' ;
  324. 'FIN' ;
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales