Télécharger gdep2_boucle.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gdep2_boucle.dgibi
  2. ******************************************************************
  3. * anneau sous pression non uniforme
  4. ******************************************************************
  5. *
  6. * position du probleme
  7. * --------------------
  8. * il s agit de determiner la deformee d un anneau
  9. * sous pression non uniforme suiveuse en grands
  10. * deplacements
  11. * reference:
  12. * ----------
  13. * Argyris J., Mlejnek H. P., Dynamics of structure, North Holland
  14. * 1991, p545
  15. ******************************************************************
  16.  
  17. option echo 1;
  18. option dime 2 elem seg2 ;
  19. opti mode 'PLAN' 'CONT' ;
  20.  
  21. graph = faux ;
  22.  
  23. *-------------------------------
  24. * definition de la geometrie
  25. *-------------------------------
  26.  
  27. r = 100 ;
  28. a = 0 0 ;
  29. b = 100 0 ;
  30. c = 0 100 ;
  31. lig1 = b cerc 18 a c ;
  32.  
  33. *--------------------------------------
  34. * definition des conditions aux limites
  35. *--------------------------------------
  36. cl1 = bloq rota (b et c) ;
  37. cl2 = bloq uy b ;
  38. cl3 = bloq ux c ;
  39. cl = cl1 et cl2 et cl3 ;
  40.  
  41. *---------------------------------------------------------
  42. * definition du modele, du materiau et des caracteristiques
  43. *---------------------------------------------------------
  44.  
  45. valyoun = 2.1e7 ;
  46. mo1 = modele lig1 mecanique elastique isotrope coq2 ;
  47. ma = mate mo1 youn valyoun nu 0. rho 7.8e3 ;
  48. ep1 = 1. ;
  49. ca = cara mo1 epai ep1 ;
  50. ma = ma et ca;
  51.  
  52. *-----------------------------
  53. * calcul de l objet chargement
  54. *-----------------------------
  55.  
  56. lf = prog 0 1000. ;
  57. lt = prog 0 1000. ;
  58. ls = prog 0 pas 0.025 1. pas 0.0125 3. ;
  59.  
  60. p0bar = r * r * r * 12 / valyoun ;
  61. chx1 = lig1 coor 1 ;
  62. chp1 = chx1 ** 2 / r / r * 2. / p0bar ;
  63. chp1 = chp1 nomc pr ;
  64. *
  65. * Modele Chargement de pression
  66. MOPRE = 'MODE' LIG1 'CHARGEMENT' 'PRESSION' 'COQ2' ;
  67. CHMZ = pres mopre (chan cham mopre chp1) ;
  68. *
  69. TTPS = 'TABL' ; TTPS. 0 = 0. ; TTPS. 1 = 1000. ;
  70. TPRE = 'TABL' ; TPRE. 0 = 0.*CHMZ ; TPRE. 1 = 1000.*CHMZ ;
  71. CHAA = 'CHAR' 'PRES' TTPS TPRE ;
  72. *
  73. *------------------------------
  74. * calcul non lineaire
  75. *------------------------------
  76.  
  77. tab2 = table ;
  78. tab2.grands_deplacements = vrai ;
  79. tab2.blocages_mecaniques = cl;
  80. tab2.modele = MO1 'ET' MOPRE ;
  81. tab2.caracteristiques = MA ;
  82. tab2.chargement = CHAA ;
  83. tab2.temps_calcules = ls;
  84. tab2.'PRECISION'= 1e-8;
  85.  
  86.  
  87.  
  88.  
  89.  
  90. pasapas tab2 ;
  91. *------------------------------
  92. * comparaison avec la reference
  93. *------------------------------
  94.  
  95. xxx = peche tab2 deplacements;
  96. uxb = (extr xxx ux b) ;
  97. uxbth = -86. ;
  98. err = (abs ((uxbth - uxb)/uxbth))*100 ;
  99. mess 'deplacement du point b, p0 = 3 ' ;
  100. mess 'reference 'uxbth 'castem' uxb '%erreur' err ;
  101.  
  102. si (err < 2) ;
  103. erre 0 ;
  104. sinon ;
  105. erre 5 ;
  106. finsi ;
  107.  
  108. si(graph) ;
  109. defo0 = defo lig1 xxx 0. VERT ;
  110. defo1 = defo lig1 xxx 1. ROUG ;
  111. trac (defo0 et defo1) ;
  112. finsi ;
  113.  
  114. fin ;
  115.  
  116.  
  117.  
  118.  
  119.  
  120.  
  121.  
  122.  
  123.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales