Télécharger la plaquette Cast3M


fr en

Télécharger gatt_dp.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  gatt_dp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test gatt_dp.dgibi: Jeux de données            
  6. *     ---------------------------------------         
  7. * 
  8. 'OPTI' 'DIME' 2 'MODE' 'PLAN' 'DEFO' ;
  9. 'OPTI' 'ELEM' 'QUA8'                 ;
  10. 'OPTI' 'TRAC' 'PSC'                  ;
  11. 'TEMPS' 'ZERO'                       ;
  12. L = 'MOT' LIST ; F = 'MOT' FIN       ;
  13. *                                                                               
  14. *******************************************************          
  15. *                TEST DE VALIDATION                   *
  16. *                ------------------                   *
  17. *               MODELE GATT_MONERIE                   *
  18. *  UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE   *
  19. *                                                     *
  20. *  MAILLAGE:                                          *
  21. *     EPROUVETTE RECTANGULAIRE                        * 
  22. *                                                     *
  23. *  CHARGEMENT:                                        *
  24. *     DEPLACEMENT VERTICAL IMPOSE                     *
  25. *       TRACTION - COMPRESSION                        *
  26. *     TEMPERATURE CONSTANTE                           *
  27. *     DENSITE DE FISSIONS CONSTANTE                   *
  28. *     PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION      *
  29. *     DENSIFICATION - GONFLEMENT                      *
  30. *******************************************************          
  31. *
  32. * repertoire des fichiers "divers"
  33. DIVERS = VENV 'CASTEM_DIVERS';
  34. *
  35. GRAPH    = FAUX ;
  36. LISTCOUR = VRAI ;
  37. *
  38. NA   = 1                             ;
  39. NR   = 1                             ;
  40. H    = 6.2e-3                        ;
  41. D    = 5.e-3                         ;
  42. R    = D/2.                          ;
  43. HS2  = H/2.                          ;
  44. *
  45. OO   = 0.              0.            ;
  46. A1   = R               0.            ;
  47. A2   = R               HS2           ;
  48. A3   = 0.              HS2           ;
  49. *
  50. LB   = 'DROIT' NR  OO A1             ;
  51. LD   = 'DROIT' NA  A1 A2             ;
  52. LH   = 'DROIT' NR  A2 A3             ;
  53. LG   = 'DROIT' NA  A3 OO             ;
  54. *
  55. SU1  = 'DALL' LB  LD  LH  LG  'PLAN' ;
  56. *
  57. MODL1= MODE SU1 MECANIQUE ELASTIQUE
  58.   VISCOPLASTIQUE GATT_MONERIE        ;
  59. *
  60. * ----------------------*
  61. * Materiau GATT_MONERIE *
  62. * ----------------------*
  63. TE1  = 1400. + 273.  ;
  64. PO   = 4.52E-2       ;
  65. DF1  = 1.E18         ;
  66. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt') ;
  67. *
  68. * fluage primaire rendu significatif pour UO2 standard
  69.  TA.'KPUO'   = 1E3 * TA.'KPUO' ;
  70. *
  71. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ; 
  72. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ; 
  73. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  74. *
  75. MATR11 = 'MATE' MODL1  'YOUN' EE  'NU' 0.  'RHO' 10950.  'ALPH' 0. 'TALP' 0. 'TREF' 0. ;
  76. *
  77. MATR12 = 'MATE' MODL1 
  78.  'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DG')
  79.  'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1') 
  80.  'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2') 
  81.  'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA')
  82.  'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3')
  83.  'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  84. *
  85. MATR13 = 'MATE' MODL1 
  86.  'KP'   (TA.'KPUO')   'AP' (TA.'AP')  'BP'  (TA.'BP')  'QP'  (TA.'QP') ;
  87. * 
  88. MATR14 = 'MATE' MODL1 
  89.  'ADEN' TA.'ADEN' 'KGON' TA.'KGON'. 
  90.  'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI')  'EFIS' (TA.'EFIS') ;
  91. *
  92. * TYPE = 0. combustible UO2            sinon combustible AFA3GLAA
  93. * COMP = 0. combustible incompressible sinon compressible
  94. * DYN  = 0. couplage dynamique         sinon statique
  95. *
  96. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 ;
  97. *
  98. * -----------------------------------------------------*
  99. * Conditions aux limites + deplacement impose sur CLYH *
  100. * -----------------------------------------------------*
  101. CLYB = 'BLOQ' 'UY' LB                  ;
  102. CLYH = 'BLOQ' 'UY' LH                  ;
  103. CLXG = 'BLOQ' 'UX' LG                  ;
  104. CLT  = CLYB 'ET' CLYH 'ET' CLXG        ;
  105. *
  106. TMIL = 1.E6 ;
  107. TFIN = 2.E6 ;
  108. *
  109. RHO0 = 1. - TA.'POR0' ;
  110. AKBU = TA.'EFIS'*270./238./10950./RHO0*DF1 ;
  111. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT 
  112. TBU = (TA.'BUMI' / AKBU) - 1. ;
  113. TTBU = ('ENTI' (TBU/10000.)) * 10000. ;
  114. *-------------------*
  115. * Instants calcules *
  116. *-------------------*
  117. 'SI' LISTCOUR ;
  118. *--------------
  119. LIST1 = 'PROG' 0   'PAS' 50  300  'PAS' 100  1000 'PAS' 1000  10000
  120.                    'PAS' 10000. TTBU
  121.                    TBU (TTBU+10000.) (TTBU+20000.)      
  122.                    'PAS' 10000. TMIL ;
  123. 'SINON' ;
  124. *--------
  125. LIST1 = 'PROG' 0   'PAS' 50  300  'PAS' 100  1000 'PAS' 1000  10000
  126.                    'PAS' 10000. TTBU
  127.                    TBU (TTBU+10000.) (TTBU+20000.)      
  128.                    'PAS' 10000. TMIL 
  129.                    'PAS' 100. (TMIL + ((TFIN - TMIL) / 200.))
  130.                    'PAS' 1000. (TMIL + ((TFIN - TMIL) / 20.))
  131.                    'PAS' 2000. (TMIL + ((TFIN - TMIL) / 4.))
  132.                    'PAS' 10000. TFIN ;
  133. 'FINSI' ;
  134. *--------
  135. * --------------------------*
  136. * Chargement en temperature *
  137. * --------------------------*
  138. CHTEMP   = 'MANU' 'CHPO' SU1 1 'T' 1.           ;
  139. EVT      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  140.                          ('PROG' TE1 TE1)       ;
  141. CHARTEMP = 'CHAR' 'T' CHTEMP EVT                ;
  142. * ---------------------------------*
  143. * Chargement en densite de fission *
  144. * ---------------------------------*
  145. CHFISS   = 'MANU' 'CHPO' SU1 1 'DFIS' 1.        ;
  146. EVF      = 'EVOL' 'MANU' ('PROG' 0.  (2.*TFIN)) 
  147.                          ('PROG' DF1 DF1)       ;
  148. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF             ;
  149. * ---------------------------------*
  150. * Chargement en deplacement impose *
  151. * ---------------------------------*
  152. DEPZ     = 'DEPI' CLYH 1                                   ; 
  153. DELTAZ   = HS2/200.                                        ;
  154. EVEPS    = 'EVOL' 'MANU' ('PROG' 0. TMIL   TFIN (2.*TFIN))
  155.                       ('PROG' 0. DELTAZ 0.    0.)          ;
  156. CHARMECA = 'CHAR' 'DIMP' DEPZ EVEPS                        ;
  157. *
  158. CHARTOT  = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  159. * ---------------------------------------*
  160. * Variables internes initiales 'PORO'=PO *
  161. * ---------------------------------------*
  162. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  163. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO 
  164.                             'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  165. VAR0  = VAR00 + VAR01                                              ;
  166. *
  167. *
  168. TAB1 = TABLE                           ;
  169. TAB1.'TEMPERATURES' = TABLE            ;
  170. TAB1.'VARIABLES_INTERNES'= TABLE       ;
  171. TAB1.'BLOCAGES_MECANIQUES' = CLT       ;
  172. TAB1.'MODELE' = MODL1                  ;
  173. TAB1.'CHARGEMENT' = CHARTOT            ;
  174. TAB1.'TEMPERATURES' . 0 = CHTEMP       ;
  175. TAB1.'VARIABLES_INTERNES' . 0 = VAR0   ; 
  176. TAB1.'CARACTERISTIQUES' = MATR1        ;
  177. TAB1.'TEMPS_CALCULES' = LIST1          ;
  178. TAB1.'TEMPS_SAUVES' = LIST1            ;
  179. *
  180. TMASAU                   = TABLE       ;
  181. tab1 . 'MES_SAUVEGARDES' = TMASAU      ;
  182. TMASAU .'DEFTO' = VRAI                 ;
  183. TMASAU .'DEFIN' = VRAI                 ;
  184. *
  185. PASAPAS TAB1                           ;
  186. *
  187. AP    = TA.'AP'        ;
  188. BP    = TA.'BP'        ;
  189. N1    = TA.'N1'        ;
  190. N2    = TA.'N2'        ;
  191.  
  192. * Facteurs multiplicatifs dus au dopage par le Chrome
  193. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  194. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) )       ;
  195. CV  = 180. / PI                                  ;
  196. WC2 = 1. - ( 'COS' (CV * TA.'DG' / TA.'DG0') )   ;
  197. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2             ;
  198.  
  199. BUMI = TA.'BUMI' ;
  200. AKEVD = AKBU*TA.'KGON' ;
  201. ADEN = TA.'ADEN' ; 
  202. KGON = TA.'KGON' ;
  203. * -------------------------------------------------------------------*
  204. * Calcul de la cte AAAA intervenant ds le calcul de la def. de dens. *
  205. * -------------------------------------------------------------------*
  206. BUMAX0=60.D0*BUMI ;
  207. CRIT=1.D-10 ;
  208. 'REPE' BLOC 100 ;         
  209.   BUMAX = BUMI* ('EXP' (1. - (ADEN/(KGON*BUMAX0)))) ;
  210.   BUMAX = (0.2*BUMAX) + (0.8*BUMAX0) ;
  211.   TEST='ABS' ((BUMAX-BUMAX0)/BUMAX0) ;
  212.   'SI' ('<' TEST CRIT) ; 
  213.     'QUIT' BLOC ; 
  214.   'FINS' ;
  215.   BUMAX0=BUMAX ;
  216. 'FIN' BLOC ;
  217. AAAA = (-1.D0*RHO0*(ADEN-(KGON*BUMAX))) /
  218.                 ((1.D0+ADEN)*(LOG(BUMAX/BUMI)))  ;
  219. *
  220. * -----------------------*
  221. * Controle des resultats *
  222. * -----------------------*
  223. SS = TAB1 . 'CONTRAINTES'                   ;
  224. VV = TAB1 . 'VARIABLES_INTERNES'            ;
  225. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES'     ;
  226. NCONT = ('DIME' (TAB1 . 'CONTRAINTES')) - 1 ; 
  227. *
  228. T1     = 0.        ;
  229. SMYY1  = 0.        ;
  230. FF1    = TA.'POR0' ;
  231. ERMAX1 = 0.        ;
  232. ERMAX2 = 0.        ;
  233. *
  234. LTT     = 'PROG' ;
  235. LDFF    = 'PROG' ;
  236. LEVFF   = 'PROG' ;
  237. LEVP2   = 'PROG' ;
  238. LEVTH   = 'PROG' ;
  239. LEVCALC = 'PROG' ;
  240. * 
  241. 'REPE' BLOC NCONT ;
  242. *
  243. * -------------------------------------
  244. * VITESSE DE DEFORMATION THEORIQUE EVTH
  245. * -------------------------------------
  246.   T2   = 'EXTR' (TAB1.'TEMPS_SAUVES') (&BLOC + 1);
  247.   EVTH = DELTAZ / HS2 / TMIL                     ;
  248.   'SI' (> T2 (TMIL+0.1))                         ;
  249.     EVTH = -1. * DELTAZ / HS2 / (TFIN - TMIL)    ; 
  250.   'FINS'                                         ;
  251. * --------------------------------------------------------------
  252. * SMYY ET SMZZ SONT PREPONDERANTES DEVANT LES AUTRES CONTRAINTES
  253. * --------------------------------------------------------------
  254.   SMYY = 'MAXI' ('EXCO' (SS . &BLOC) 'SMYY') ;
  255.   SMZZ = 'MAXI' ('EXCO' (SS . &BLOC) 'SMZZ') ;
  256.   SSM  = (SMYY + SMZZ) / 3.                  ;
  257.   SSEQ = 
  258.          (1.5 * ((SSM*SSM) + ((SMYY-SSM)*(SMYY-SSM)) + 
  259.                              ((SMZZ-SSM)*(SMZZ-SSM)))) ** 0.5 ;
  260. * Deviateur des contraintes
  261.   SSPRIM1 =  -1. * SSM ;
  262.   SSPRIM2 = SMYY - SSM ;
  263.   SSPRIM3 = SMZZ - SSM ;
  264. * ---------------------------------------------
  265. * DEFORMATION VISCO-PLASTIQUE EQUIVALENTE EVPEQ
  266. * ---------------------------------------------
  267.   EVXX  = 'MAXI' ('EXCO' IN.&BLOC 'EIXX')                           ;
  268.   EVYY  = 'MAXI' ('EXCO' IN.&BLOC 'EIYY')                           ;
  269.   EVZZ  = 'MAXI' ('EXCO' IN.&BLOC 'EIZZ')                           ;
  270.   EVH   = (EVXX+EVYY+EVZZ) / 3.                                     ;
  271.   EVPEQ = ((EVXX - EVH)**2) + ((EVYY - EVH)**2) + ((EVZZ - EVH)**2) ;
  272.   EVPEQ = ((2./3.) * EVPEQ)**0.5                                    ;
  273. * ------------------------------------------
  274. * VITESSE DE DEFORMATION VISCO-PLASTIQUE EVP
  275. * ------------------------------------------
  276. *-- fluage primaire
  277. *
  278. 'SI' ('<' EVPEQ 1E-10) ; EVPEQ = 1E-10 ; 'FINSI' ;
  279. *
  280.   EVP01 = 1.5 * TA.'KPUO' * 
  281.   ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * 
  282.   ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM1 ;
  283. *
  284.   EVP02 = 1.5 * TA.'KPUO' * 
  285.   ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * 
  286.   ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM2 ;
  287. *
  288.   EVP03 = 1.5 * TA.'KPUO' * 
  289.   ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) * 
  290.   ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM3 ;
  291. *
  292. *-- fluage secondaire (2 mecanismes)
  293. *
  294.   PP = 'MAXI' ('EXCO' VV . &BLOC 'PORO') ;
  295. *
  296.   A1 = (N1* (PP**(-1./N1) - 1.)**(-2.*N1/(N1+1.)))      ;
  297.   B1 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N1/(N1+1.))) ;
  298.   AB1 = (9. * A1) / ( (4.*B1) + A1 )                     ;
  299.   BA1 = B1 / ( B1 + (A1/4.) )                            ;
  300. *
  301.   GSSEQ = ((BA1 * (SSEQ**2)) + (AB1 * (SSM**2))) ** 0.5  ;
  302. *
  303.   A2 = (N2* (PP**(-1./N2) - 1.)**(-2.*N2/(N2+1.))) ;
  304.   B2 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N2/(N2+1.))) ;
  305. *
  306.   EVP11 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  307.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  308.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  309.   ((A1*1.5*SSM) + (3.*B1*SSPRIM1))) ; 
  310. *
  311.   EVP21 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  312.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  313.   ((A2*1.5*SSM) + (3.*B2*SSPRIM1))) ; 
  314. *
  315.   EVP12 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  316.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  317.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  318.   ((A1*1.5*SSM) + (3.*B1*SSPRIM2))) ; 
  319. *
  320.   EVP22 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) * 
  321.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  322.   ((A2*1.5*SSM) + (3.*B2*SSPRIM2))) ; 
  323. *
  324.   EVP13 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  325.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  326.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  327.   ((A1*1.5*SSM) + (3.*B1*SSPRIM3))) ; 
  328. *
  329.   EVP23 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) * 
  330.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  331.   ((A2*1.5*SSM) + (3.*B2*SSPRIM3))) ; 
  332. *
  333.   PSI1 = TA.'K1' * WC1 * (TA.'DG'**TA.'M1')/(N1+1.) *
  334.   ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) * 
  335.   (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1+1.)/2.)) ;
  336. *
  337.   PSI2 = TA.'K2' * WC2/(N2+1.) * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  338.   (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2+1.)/2.)) ;
  339. *
  340.   EVPC1 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  341.   (GSSEQ**(-1.*TA.'Q' - 2.)) *
  342.       (1. -
  343.   (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q'))))  / TA.'H'))**2))
  344.    * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) +  (1.5*BA1*SSPRIM1) ) ;
  345. *
  346.   EVPC2 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  347.   (GSSEQ**(-1.*TA.'Q' - 2.)) *
  348.       (1. -
  349.   (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q'))))  / TA.'H'))**2))
  350.    * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) +  (1.5*BA1*SSPRIM2) ) ;
  351. *
  352.   EVPC3 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  353.   (GSSEQ**(-1.*TA.'Q' - 2.)) *
  354.       (1. -
  355.   (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q'))))  / TA.'H'))**2))
  356.    * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) +  (1.5*BA1*SSPRIM3) ) ;
  357. *
  358.   TETA = 0.5 * TA.'BETA' *
  359.       (1. + 
  360.       ('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))) ;
  361. *
  362.   EVP1 = EVP01 + ((1. - TETA) * EVP11) + (TETA * EVP21) + EVPC1 ; 
  363.   EVP2 = EVP02 + ((1. - TETA) * EVP12) + (TETA * EVP22) + EVPC2 ; 
  364.   EVP3 = EVP03 + ((1. - TETA) * EVP13) + (TETA * EVP23) + EVPC3 ;
  365. * -------------------------------------
  366. * VITESSE DE DEFORMATION ELASTIQUE EVEL
  367. * -------------------------------------
  368.   DSMYY = (SMYY - SMYY1) / (T2 - T1) ;
  369.   EVEL  = DSMYY / ('MAXI' EE)        ;
  370. * ----------------------------------
  371. * VITESSE DE DEFORMATION IRRADIATION
  372. * ----------------------------------
  373.   EVIR1 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  374.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM1 ;
  375.   EVIR2 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  376.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM2 ;
  377.   EVIR3 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) * 
  378.        ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM3 ;
  379. * ------------------------------------
  380. * VITESSE DE DEFORMATION DENSIFICATION
  381. * ------------------------------------
  382. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  383.   BU = AKBU * T2 ;
  384.   'SI' (BU '>' BUMI) ;
  385.     NUMER = (RHO0 * RHO0 * AKEVD) - (RHO0 * AAAA * AKEVD) +
  386.             (RHO0 * AAAA * AKEVD * ('LOG' (BU / BUMI))) -
  387.             (RHO0 * AAAA / T2) ; 
  388.     DENOM = (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) * 
  389.             (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) ;
  390.     EVD = -1. * (AKEVD - (NUMER/DENOM)) / 3. ;
  391.   'SINO' ;
  392.     EVD = 0. ;
  393.   'FINS' ;
  394. * --------------------------------- 
  395. * VITESSE DE DEFORMATION GONFLEMENT
  396. * ---------------------------------
  397. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  398.   EVG = AKEVD/3. ;
  399. * -------------------------------
  400. * VITESSE DE DEFORMATION SELON YY
  401. * -------------------------------
  402.   EVCALC = ((1.+(TA.'K'*DF1))*EVP2) + EVEL + EVIR2 + 
  403.                        EVD + EVG ;
  404.   ECART1 = (EVCALC - EVTH) / EVTH ;
  405.   ERMAX1 = 'MAXI' ('PROG' ('ABS' ECART1) ERMAX1) ;
  406. * -------------------
  407. * VITESSE DE POROSITE
  408. * -------------------
  409.   FF = 'MAXI' ('EXCO' (VV . &BLOC) 'PORO') ;
  410.   DFF = (FF - FF1) / (T2 - T1) ; 
  411.   EVFF = (3.*EVD) + 
  412.          ((1. - FF) * (1.+(TA.'K'*DF1))*(EVP1+EVP2+EVP3)) +
  413.          ((1. - FF) * (EVIR1 + EVIR2 + EVIR3)) ;
  414.   ECART2 = ('ABS' (DFF - EVFF)) / FF ; 
  415.   ERMAX2 = 'MAXI' ('PROG' ('ABS' ECART2) ERMAX2) ;
  416. *
  417.   LTT = LTT 'ET' ('PROG' T2) ;
  418.   LEVP2 = LEVP2 'ET' ('PROG' EVP2) ;
  419.   LEVCALC = LEVCALC 'ET' ('PROG' EVCALC) ;
  420.   LEVTH = LEVTH 'ET' ('PROG' EVTH) ;
  421.   LDFF = LDFF 'ET' ('PROG' DFF) ;
  422.   LEVFF = LEVFF 'ET' ('PROG' EVFF) ;
  423. *
  424.   FF1   = FF ;      
  425.   SMYY1 = SMYY ;
  426.   T1 = T2 ; 
  427. *
  428. 'FIN' BLOC ;
  429. *
  430. 'SI' ( ERMAX1 '&lt;EG' 0.05 );
  431.    'ERRE' 0;
  432. 'SINO';
  433.    'MESS' 'ERREUR MAXIMALE VITESSE DEFORMATION :' 
  434.            ERMAX1 '> 0.05 ' ; 
  435.    'ERRE' 5;
  436. 'FINS';
  437. *
  438. 'SI' ( ERMAX2 '&lt;EG' 0.05 );
  439.    'ERRE' 0;
  440. 'SINO';
  441.    'MESS' 'ERREUR MAXIMALE POROSITE :' 
  442.            ERMAX2 '> 0.05 ' ; 
  443.    'ERRE' 5;
  444. 'FINS';
  445. *
  446. 'SI' GRAPH ;
  447.   'TITR' 'Deformations planes : Vitesses de Deformation' ;
  448.   EVEVP  = 'EVOL' 'MANU' LTT 'Temps'   LEVP2   'Vitesse' ;
  449.   EVEVC  = 'EVOL' 'MANU' LTT 'Temps'   LEVCALC 'Vitesse' ;
  450.   EVEVTH = 'EVOL' 'MANU' LTT 'Temps'   LEVTH   'Vitesse' ;
  451.   TAD     = TABLE                                        ;
  452.   TAD . 1 = 'TIRC'                                       ;
  453.   TAD . 3 = 'TIRR'                                       ; 
  454.   TAD . 'TITRE' = TABLE                                  ;
  455.   TAD . 'TITRE' . 1 = 'Viscoplastique Analytique'        ;
  456.   TAD . 'TITRE' . 2 = 'Totale Calculee'                  ;
  457.   TAD . 'TITRE' . 3 = 'Totale Analytique'                ;
  458.   'DESS' (EVEVP 'ET' EVEVC 'ET' EVEVTH) TAD 'LEGE'       ;
  459. *
  460.   'TITR' 'Deformations planes : Vitesses de variation de la porosite' ;
  461.   EVDFF  = 'EVOL' 'MANU' LTT 'Temps' LDFF  'Vitesse'                  ;
  462.   EVEVFF = 'EVOL' 'MANU' LTT 'Temps' LEVFF 'Vitesse'                  ;
  463.   TAF     = TABLE                                                     ;
  464.   TAF . 2 = 'TIRR'                                                    ; 
  465.   TAF . 'TITRE' = TABLE                                               ;
  466.   TAF . 'TITRE' . 1 = 'Calculee'                                      ;
  467.   TAF . 'TITRE' . 2 =  'Analytique'                                   ;
  468.   'DESS' (EVDFF 'ET' EVEVFF) TAF 'LEGE'                               ;
  469. 'FINS' ;
  470. *
  471. 'FIN';
  472.  
  473.  
  474.  
  475.  
  476.  
  477.  
  478.  
  479.  
  480.  
  481.  
  482.  
  483.  
  484.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales