Télécharger gatt_axi.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : gatt_axi.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. * Test gatt_axi.dgibi: Jeux de données
  6. * ---------------------------------------
  7. *
  8. 'OPTI' 'DIME' 2 'MODE' 'AXIS' ;
  9. 'OPTI' 'ELEM' 'QUA8' ;
  10. 'OPTI' 'TRAC' 'PSC' ;
  11. 'TEMPS' 'ZERO' ;
  12. L = 'MOT' LIST ; F = 'MOT' FIN ;
  13. *
  14. *******************************************************
  15. * TEST DE VALIDATION *
  16. * ------------------ *
  17. * MODELE GATT_MONERIE *
  18. * UO2 DOPE CHROME Cr=0.15% TAILLE DE GRAIN=7 µm *
  19. * COMPRESSIBLE AVEC COUPLAGE STATIQUE *
  20. * *
  21. * MAILLAGE: *
  22. * EPROUVETTE RECTANGULAIRE *
  23. * *
  24. * CHARGEMENT: *
  25. * DEPLACEMENT VERTICAL IMPOSE *
  26. * TRACTION - COMPRESSION *
  27. * TEMPERATURE CONSTANTE *
  28. * DENSITE DE FISSIONS CONSTANTE *
  29. * PRIMAIRE - MECANISMES 1 ET 2 - IRRADIATION *
  30. * DENSIFICATION - GONFLEMENT *
  31. *******************************************************
  32. *
  33. GRAPH = FAUX ;
  34. LISTCOUR = VRAI ;
  35. *
  36. NA = 1 ;
  37. NR = 1 ;
  38. H = 6.2e-3 ;
  39. D = 5.e-3 ;
  40. R = D/2. ;
  41. HS2 = H/2. ;
  42. *
  43. OO = 0. 0. ;
  44. A1 = R 0. ;
  45. A2 = R HS2 ;
  46. A3 = 0. HS2 ;
  47. *
  48. LB = 'DROIT' NR OO A1 ;
  49. LD = 'DROIT' NA A1 A2 ;
  50. LH = 'DROIT' NR A2 A3 ;
  51. LG = 'DROIT' NA A3 OO ;
  52. *
  53. SU1 = 'DALL' LB LD LH LG 'PLAN' ;
  54. *
  55. MODL1= MODE SU1 MECANIQUE ELASTIQUE VISCOPLASTIQUE GATT_MONERIE ;
  56. *
  57. * ----------------------*
  58. * Materiau GATT_MONERIE *
  59. * ----------------------*
  60. TE1 = 1400. + 273. ;
  61. PO = 4.52E-2 ;
  62. DF1 = 1.E18 ;
  63. TA = @GATTPAR '/u2/castem/divers/fichier_gatt' ;
  64. *
  65. * fluage primaire rendu significatif pour UO2 standard
  66. TA.'KPUO' = 1E12 * TA.'KPUO' ;
  67. *
  68. TA.'DG' = TA.'DG0' ;
  69. TA.'CR' = 0.15E-2 ;
  70. *
  71. MATREE = MATE MODL1 'YOUN' (TA.'YOUN') ;
  72. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  73. EE = 'VARI' 'NUAG' MODL1 MATREE PP ;
  74. *
  75. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' 0.3 'RHO' 10950. 'ALPH' 0. ;
  76. *
  77. MATR12 = 'MATE' MODL1
  78. 'R' (TA.'R') 'DG0' (TA.'DG0') 'DG' (TA.'DG')
  79. 'K1' (TA.'K1') 'M1' (TA.'M1') 'Q1' (TA.'Q1') 'N1' (TA.'N1')
  80. 'K2' (TA.'K2') 'M2' (TA.'M2') 'Q2' (TA.'Q2') 'N2' (TA.'N2')
  81. 'OMEG' (TA.'OMEG') 'H' (TA.'H') 'Q' (TA.'Q') 'BETA' (TA.'BETA')
  82. 'K' (TA.'K') 'A' (TA.'A') 'Q3' (TA.'Q3') 'N3' (TA.'N3')
  83. 'CR' (TA.'CR') 'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3' (TA.'CR3');
  84. *
  85. MATR13 = 'MATE' MODL1
  86. 'KP' (TA.'KPUO') 'AP' (TA.'AP') 'BP' (TA.'BP') 'QP' (TA.'QP') ;
  87. *
  88. MATR14 = 'MATE' MODL1
  89. 'ADEN' TA.'ADEN' 'KGON' TA.'KGON'.
  90. 'POR0' (TA.'POR0') 'BUMI' (TA.'BUMI') 'EFIS' (TA.'EFIS') ;
  91. *
  92. * TYPE = 0. combustible UO2 sinon combustible AFA3GLAA
  93. * COMP = 0. combustible compressible sinon incompressible
  94. * DYN = 0. couplage statique sinon dynamique
  95. *
  96. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 ;
  97. *
  98. * -----------------------------------------------------*
  99. * Conditions aux limites + deplacement impose sur CLZH *
  100. * -----------------------------------------------------*
  101. CLZB = 'BLOQ' 'UZ' LB ;
  102. CLZH = 'BLOQ' 'UZ' LH ;
  103. CLO = 'BLOQ' 'UR' OO ;
  104. CLT = CLZB 'ET' CLZH 'ET' CLO ;
  105. *
  106. TMIL = 1.E6 ;
  107. TFIN = 2.E6 ;
  108. *
  109. RHO0 = 1. - TA.'POR0' ;
  110. AKBU = TA.'EFIS'*270./238./10950./RHO0*DF1 ;
  111. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  112. TBU = (TA.'BUMI' / AKBU) - 1. ;
  113. TTBU = ('ENTI' (TBU/10000.)) * 10000. ;
  114. *-------------------*
  115. * Instants calcules *
  116. *-------------------*
  117. 'SI' LISTCOUR ;
  118. *--------------
  119. LIST1 = 'PROG' 0 'PAS' 0.01 1 'PAS' 10 100
  120. 'PAS' 100 1000 'PAS' 500 20000
  121. 'PAS' 2000 TBU 'PAS' 1000 (TTBU+10000.) ;
  122. 'SINON' ;
  123. *--------
  124. LIST1 = 'PROG' 0 'PAS' 0.01 1 'PAS' 10 100
  125. 'PAS' 100 1000 'PAS' 500 20000
  126. 'PAS' 2000 TBU 'PAS' 1000 (TTBU+10000.) ;
  127. LIST1 = LIST1 ET (PROG
  128. 'PAS' 1000. TMIL
  129. 'PAS' 1000. (TMIL + ((TFIN - TMIL) / 200.))
  130. 'PAS' 1000. (TMIL + ((TFIN - TMIL) / 20.))
  131. 'PAS' 2000. (TMIL + ((TFIN - TMIL) / 4.))
  132. 'PAS' 2000. TFIN) ;
  133. 'FINSI' ;
  134. *--------
  135. * --------------------------*
  136. * Chargement en temperature *
  137. * --------------------------*
  138. CHTEMP = 'MANU' 'CHPO' SU1 1 'T' 1. ;
  139. EVT = 'EVOL' 'MANU' ('PROG' 0. (2.*TFIN))
  140. ('PROG' TE1 TE1) ;
  141. CHARTEMP = 'CHAR' 'T' CHTEMP EVT ;
  142. * ---------------------------------*
  143. * Chargement en densite de fission *
  144. * ---------------------------------*
  145. CHFISS = 'MANU' 'CHPO' SU1 1 'DFIS' 1. ;
  146. EVF = 'EVOL' 'MANU' ('PROG' 0. (2.*TFIN))
  147. ('PROG' DF1 DF1) ;
  148. CHARFISS = 'CHAR' 'DFIS' CHFISS EVF ;
  149. * ---------------------------------*
  150. * Chargement en deplacement impose *
  151. * ---------------------------------*
  152. DEPZ = 'DEPI' CLZH 1 ;
  153. DELTAZ = HS2/200. ;
  154. EVEPS = 'EVOL' 'MANU'
  155. ('PROG' 0. TMIL TFIN (2.*TFIN))
  156. ('PROG' 0. DELTAZ 0. 0.) ;
  157. CHARMECA = 'CHAR' 'DIMP' DEPZ EVEPS ;
  158. *
  159. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS ;
  160. * ---------------------------------------*
  161. * Variables internes initiales 'PORO'=PO *
  162. * ---------------------------------------*
  163. VAR00 = 'ZERO' MODL1 'VARINTER' ;
  164. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO
  165. 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  166. VAR0 = VAR00 + VAR01 ;
  167. *
  168. TAB1 = TABLE ;
  169. TAB1.'TEMPERATURES' = TABLE ;
  170. TAB1.'VARIABLES_INTERNES'= TABLE ;
  171. TAB1.'BLOCAGES_MECANIQUES' = CLT ;
  172. TAB1.'MODELE' = MODL1 ;
  173. TAB1.'CHARGEMENT' = CHARTOT ;
  174. TAB1.'TEMPERATURES' . 0 = CHTEMP ;
  175. TAB1.'VARIABLES_INTERNES' . 0 = VAR0 ;
  176. TAB1.'CARACTERISTIQUES' = MATR1 ;
  177. TAB1.'TEMPS_CALCULES' = LIST1 ;
  178. TAB1.'TEMPS_SAUVES' = LIST1 ;
  179. *
  180. TMASAU = TABLE ;
  181. tab1 . 'MES_SAUVEGARDES' = TMASAU ;
  182. TMASAU .'DEFTO' = VRAI ;
  183. TMASAU .'DEFIN' = VRAI ;
  184. *
  185. PASAPAS TAB1 ;
  186. *
  187. AP = TA.'AP' ;
  188. BP = TA.'BP' ;
  189. N1 = TA.'N1' ;
  190. N2 = TA.'N2' ;
  191.  
  192. * Facteurs multiplicatifs dus au dopage par le Chrome
  193. WC1 = 'TANH' ( (TA.'CR' - TA.'CR2') / TA.'CR3' ) ;
  194. WC1 = 1. + ( 0.5 * TA.'CR1' * (1. + WC1) ) ;
  195. CV = 180. / PI ;
  196. WC2 = 1. - ( 'COS' (CV * TA.'DG' / TA.'DG0') ) ;
  197. WC2 = 2. * (TA.'DG0'**TA.'M2') * WC2 ;
  198.  
  199. BUMI = TA.'BUMI' ;
  200. AKEVD = AKBU*TA.'KGON' ;
  201. ADEN = TA.'ADEN' ;
  202. KGON = TA.'KGON' ;
  203. * -------------------------------------------------------------------*
  204. * Calcul de la cte AAAA intervenant ds le calcul de la def. de dens. *
  205. * -------------------------------------------------------------------*
  206. BUMAX0=60.D0*BUMI ;
  207. CRIT=1.D-10 ;
  208. 'REPE' BLOC 100 ;
  209. BUMAX = BUMI* ('EXP' (1. - (ADEN/(KGON*BUMAX0)))) ;
  210. BUMAX = (0.2*BUMAX) + (0.8*BUMAX0) ;
  211. TEST='ABS' ((BUMAX-BUMAX0)/BUMAX0) ;
  212. 'SI' ('<' TEST CRIT) ;
  213. 'QUIT' BLOC ;
  214. 'FINS' ;
  215. BUMAX0=BUMAX ;
  216. 'FIN' BLOC ;
  217. AAAA = (-1.D0*RHO0*(ADEN-(KGON*BUMAX))) /
  218. ((1.D0+ADEN)*(LOG(BUMAX/BUMI))) ;
  219. *
  220. * -----------------------*
  221. * Controle des resultats *
  222. * -----------------------*
  223. SS = TAB1 . 'CONTRAINTES' ;
  224. VV = TAB1 . 'VARIABLES_INTERNES' ;
  225. IN = TAB1 . 'DEFORMATIONS_INELASTIQUES' ;
  226. NCONT = ('DIME' (TAB1 . 'CONTRAINTES')) - 1 ;
  227. *
  228. T1 = 0. ;
  229. SMZZ1 = 0. ;
  230. FF1 = TA.'POR0' ;
  231. ERMAX1 = 0. ;
  232. ERMAX2 = 0. ;
  233. *
  234. LTT = 'PROG' ;
  235. LDFF = 'PROG' ;
  236. LEVFF = 'PROG' ;
  237. LEVP3 = 'PROG' ;
  238. LEVTH = 'PROG' ;
  239. LEVCALC = 'PROG' ;
  240. LSMZZ = 'PROG' ;
  241. *
  242. 'REPE' BLOC NCONT ;
  243. *
  244. * -------------------------------------
  245. * VITESSE DE DEFORMATION THEORIQUE EVTH
  246. * -------------------------------------
  247. T2 = 'EXTR' (TAB1.'TEMPS_SAUVES') (&BLOC + 1);
  248. EVTH = DELTAZ / HS2 / TMIL ;
  249. 'SI' (> T2 (TMIL+0.1)) ;
  250. EVTH = -1. * DELTAZ / HS2 / (TFIN - TMIL) ;
  251. 'FINS' ;
  252. * ----------------------------------------------------
  253. * SMZZ EST PREPONDERANTE DEVANT LES AUTRES CONTRAINTES
  254. * ----------------------------------------------------
  255. SMZZ = 'MAXI' ('EXCO' (SS . &BLOC) 'SMZZ') ;
  256. SSM = SMZZ / 3. ;
  257. SSEQ = 'ABS' SMZZ ;
  258. * Deviateur des contraintes
  259. SSPRIM1 = -1. * SMZZ / 3 ;
  260. SSPRIM2 = -1. * SMZZ / 3 ;
  261. SSPRIM3 = 2. * SMZZ / 3 ;
  262. * ---------------------------------------------
  263. * DEFORMATION VISCO-PLASTIQUE EQUIVALENTE EVPEQ
  264. * ---------------------------------------------
  265. EVRR = 'MAXI' ('EXCO' IN.&BLOC 'EIRR') ;
  266. EVTT = 'MAXI' ('EXCO' IN.&BLOC 'EITT') ;
  267. EVZZ = 'MAXI' ('EXCO' IN.&BLOC 'EIZZ') ;
  268. EVH = (EVRR+EVTT+EVZZ) / 3. ;
  269. EVPEQ = ((EVRR - EVH)**2) + ((EVTT - EVH)**2) + ((EVZZ - EVH)**2) ;
  270. EVPEQ = ((2./3.) * EVPEQ)**0.5 ;
  271. * ------------------------------------------
  272. * VITESSE DE DEFORMATION VISCO-PLASTIQUE EVP
  273. * ------------------------------------------
  274. *-- fluage primaire
  275. *
  276. 'SI' ('<' EVPEQ 1E-10) ; EVPEQ = 1E-10 ; 'FINSI' ;
  277. *
  278. EVP01 = 1.5 * TA.'KPUO' *
  279. ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) *
  280. ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM1 ;
  281. *
  282. EVP02 = 1.5 * TA.'KPUO' *
  283. ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) *
  284. ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM2 ;
  285. *
  286. EVP03 = 1.5 * TA.'KPUO' *
  287. ('EXP' (-1.*TA.'QP'/(TA.'R'*TE1))) *
  288. ( (SSEQ**(AP-1)) / (EVPEQ**BP) ) * SSPRIM3 ;
  289. *
  290. *-- fluage secondaire (2 mecanismes)
  291. *
  292. PP = 'MAXI' ('EXCO' VV . &BLOC 'PORO') ;
  293. *
  294. A1 = (N1* (PP**(-1./N1) - 1.)**(-2.*N1/(N1+1.))) ;
  295. B1 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N1/(N1+1.))) ;
  296. AB1 = (9. * A1) / ( (4.*B1) + A1 ) ;
  297. BA1 = B1 / ( B1 + (A1/4.) ) ;
  298. *
  299. GSSEQ = ((BA1 * (SSEQ**2)) + (AB1 * (SSM**2))) ** 0.5 ;
  300. *
  301. A2 = (N2* (PP**(-1./N2) - 1.)**(-2.*N2/(N2+1.))) ;
  302. B2 = (1. + (2.*PP/3.))/ ((1. - PP) **(2.*N2/(N2+1.))) ;
  303. *
  304. EVP11 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  305. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  306. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  307. ((A1*1.5*SSM) + (3.*B1*SSPRIM1))) ;
  308. *
  309. EVP21 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  310. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  311. ((A2*1.5*SSM) + (3.*B2*SSPRIM1))) ;
  312. *
  313. EVP12 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  314. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  315. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  316. ((A1*1.5*SSM) + (3.*B1*SSPRIM2))) ;
  317. *
  318. EVP22 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  319. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  320. ((A2*1.5*SSM) + (3.*B2*SSPRIM2))) ;
  321. *
  322. EVP13 = 0.5 * (TA.'K1' * (TA.'DG'**TA.'M1') * WC1 *
  323. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  324. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1-1.)/2.)) *
  325. ((A1*1.5*SSM) + (3.*B1*SSPRIM3))) ;
  326. *
  327. EVP23 = 0.5 * (TA.'K2' * WC2 * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  328. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2-1.)/2.)) *
  329. ((A2*1.5*SSM) + (3.*B2*SSPRIM3))) ;
  330. *
  331. PSI1 = TA.'K1' * WC1 * (TA.'DG'**TA.'M1')/(N1+1.) *
  332. ('EXP' (-1.*TA.'Q1'/(TA.'R'*TE1))) *
  333. (((A1*((1.5*SSM)**2)) + (B1*(SSEQ ** 2)))**((N1+1.)/2.)) ;
  334. *
  335. PSI2 = TA.'K2' * WC2/(N2+1.) * ('EXP' (-1.*TA.'Q2'/(TA.'R'*TE1))) *
  336. (((A2*((1.5*SSM)**2)) + (B2*(SSEQ ** 2)))**((N2+1.)/2.)) ;
  337. *
  338. EVPC1 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  339. (GSSEQ**(-1.*TA.'Q' - 2.)) *
  340. (1. -
  341. (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))**2))
  342. * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) + (1.5*BA1*SSPRIM1) ) ;
  343. *
  344. EVPC2 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  345. (GSSEQ**(-1.*TA.'Q' - 2.)) *
  346. (1. -
  347. (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))**2))
  348. * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) + (1.5*BA1*SSPRIM2) ) ;
  349. *
  350. EVPC3 = 0.5 * TA.'BETA' / TA.'H' * TA.'Q' * TA.'OMEG' *
  351. (GSSEQ**(-1.*TA.'Q' - 2.)) *
  352. (1. -
  353. (('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))**2))
  354. * (PSI2 - PSI1) * ( ((AB1*SSM)/3.) + (1.5*BA1*SSPRIM3) ) ;
  355. *
  356. TETA = 0.5 * TA.'BETA' *
  357. (1. +
  358. ('TANH' ((TE1 - (TA.'OMEG' * (GSSEQ**(-1.*TA.'Q')))) / TA.'H'))) ;
  359. *
  360. EVP1 = EVP01 + ((1. - TETA) * EVP11) + (TETA * EVP21) + EVPC1 ;
  361. EVP2 = EVP02 + ((1. - TETA) * EVP12) + (TETA * EVP22) + EVPC2 ;
  362. EVP3 = EVP03 + ((1. - TETA) * EVP13) + (TETA * EVP23) + EVPC3 ;
  363. * -------------------------------------
  364. * VITESSE DE DEFORMATION ELASTIQUE EVEL
  365. * -------------------------------------
  366. DSMZZ = (SMZZ - SMZZ1) / (T2 - T1) ;
  367. EVEL = DSMZZ / ('MAXI' EE) ;
  368. * ----------------------------------
  369. * VITESSE DE DEFORMATION IRRADIATION
  370. * ----------------------------------
  371. EVIR1 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) *
  372. ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM1 ;
  373. EVIR2 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) *
  374. ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM2 ;
  375. EVIR3 = 1.5 * TA.'A' * DF1 * (SSEQ **(TA.'N3' - 1.)) *
  376. ('EXP' (-1.*TA.'Q3'/(TA.'R'*TE1))) * SSPRIM3 ;
  377. * ------------------------------------
  378. * VITESSE DE DEFORMATION DENSIFICATION
  379. * ------------------------------------
  380. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  381. BU = AKBU * T2 ;
  382. 'SI' (BU '>' BUMI) ;
  383. NUMER = (RHO0 * RHO0 * AKEVD) - (RHO0 * AAAA * AKEVD) +
  384. (RHO0 * AAAA * AKEVD * ('LOG' (BU / BUMI))) -
  385. (RHO0 * AAAA / T2) ;
  386. DENOM = (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) *
  387. (RHO0 + (AAAA * ('LOG' (BU / BUMI)))) ;
  388. EVD = -1. * (AKEVD - (NUMER/DENOM)) / 3. ;
  389. 'SINO' ;
  390. EVD = 0. ;
  391. 'FINS' ;
  392. * ---------------------------------
  393. * VITESSE DE DEFORMATION GONFLEMENT
  394. * ---------------------------------
  395. * CE QUI SUIT EST VRAI CAR LE FLUX DE FISSIONS EST CONSTANT
  396. EVG = AKEVD/3. ;
  397. *
  398. EVCALC = ((1.+(TA.'K'*DF1))*EVP3) + EVEL + EVIR3 +
  399. EVD + EVG ;
  400. ECART1 = (EVCALC - EVTH) / EVTH ;
  401. ERMAX1 = 'MAXI' ('PROG' ('ABS' ECART1) ERMAX1) ;
  402. * -------------------
  403. * VITESSE DE POROSITE
  404. * -------------------
  405. FF = 'MAXI' ('EXCO' (VV . &BLOC) 'PORO') ;
  406. DFF = (FF - FF1) / (T2 - T1) ;
  407. EVFF = (3.*EVD) +
  408. ((1. - FF) * (1.+(TA.'K'*DF1))*(EVP1+EVP2+EVP3)) +
  409. ((1. - FF) * (EVIR1 + EVIR2 + EVIR3)) ;
  410. ECART2 = ('ABS' (DFF - EVFF)) / FF ;
  411. ERMAX2 = 'MAXI' ('PROG' ('ABS' ECART2) ERMAX2) ;
  412. *
  413. LTT = LTT 'ET' ('PROG' T2) ;
  414. LEVP3 = LEVP3 'ET' ('PROG' EVP3) ;
  415. LEVCALC = LEVCALC 'ET' ('PROG' EVCALC) ;
  416. LEVTH = LEVTH 'ET' ('PROG' EVTH) ;
  417. LDFF = LDFF 'ET' ('PROG' DFF) ;
  418. LEVFF = LEVFF 'ET' ('PROG' EVFF) ;
  419. LSMZZ = LSMZZ 'ET' ('PROG' SMZZ) ;
  420. *
  421. FF1 = FF ;
  422. SMZZ1 = SMZZ ;
  423. T1 = T2 ;
  424. *
  425. 'FIN' BLOC ;
  426. *
  427. 'SI' ( ERMAX1 '&lt;EG' 0.05 );
  428. 'ERRE' 0;
  429. 'SINO';
  430. 'MESS' 'ERREUR MAXIMALE VITESSE DEFORMATION :'
  431. ERMAX1 '> 0.05 ' ;
  432. 'ERRE' 5;
  433. 'FINS';
  434. *
  435. 'SI' ( ERMAX2 '&lt;EG' 0.05 );
  436. 'ERRE' 0;
  437. 'SINO';
  438. 'MESS' 'ERREUR MAXIMALE POROSITE :'
  439. ERMAX2 '> 0.05 ' ;
  440. 'ERRE' 5;
  441. 'FINS';
  442. *
  443. 'SI' GRAPH ;
  444. 'TITR' 'Axisymetrique : Vitesses de Deformation' ;
  445. EVEVP = 'EVOL' 'MANU' LTT 'Temps' LEVP3 'Vitesse' ;
  446. EVEVC = 'EVOL' 'MANU' LTT 'Temps' LEVCALC 'Vitesse' ;
  447. EVEVTH = 'EVOL' 'MANU' LTT 'Temps' LEVTH 'Vitesse' ;
  448. TAD = TABLE ;
  449. TAD . 1 = 'TIRC' ;
  450. TAD . 3 = 'TIRR' ;
  451. TAD . 'TITRE' = TABLE ;
  452. TAD . 'TITRE' . 1 = 'Viscoplastique Analytique' ;
  453. TAD . 'TITRE' . 2 = 'Totale Calculee' ;
  454. TAD . 'TITRE' . 3 = 'Totale Analytique' ;
  455. 'DESS' (EVEVP 'ET' EVEVC 'ET' EVEVTH) TAD 'LEGE' ;
  456. *
  457. 'TITR' 'Axisymetrique : Vitesses de variation de la porosite' ;
  458. EVDFF = 'EVOL' 'MANU' LTT 'Temps' LDFF 'Vitesse' ;
  459. EVEVFF = 'EVOL' 'MANU' LTT 'Temps' LEVFF 'Vitesse' ;
  460. TAF = TABLE ;
  461. TAF . 2 = 'TIRR' ;
  462. TAF . 'TITRE' = TABLE ;
  463. TAF . 'TITRE' . 1 = 'Calculee' ;
  464. TAF . 'TITRE' . 2 = 'Analytique' ;
  465. 'DESS' (EVDFF 'ET' EVEVFF) TAF 'LEGE' ;
  466. *
  467. 'TITR' 'Axisymetrique : Contrainte' ;
  468. EVSMYY = 'EVOL' 'MANU' LTT 'Temps' LSMZZ 'Contrainte' ;
  469. 'DESS' EVSMYY ;
  470. 'FINS' ;
  471. *
  472. 'FIN';
  473.  
  474.  
  475.  
  476.  
  477.  
  478.  
  479.  
  480.  
  481.  
  482.  
  483.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales