Télécharger g_thermique_coque_1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : g_thermique_coque_1.dgibi
  2. ****************************************************
  3. ****************************************************
  4. * *
  5. * VALIDATION DE LA PROCEDURE G_THETA *
  6. * POUR UNE FISSURE DANS UNE PLAQUE SOUMISE A *
  7. * UN CHARGEMENT THERMIQUE DANS L'EPAISSEUR *
  8. * - *
  9. * VALIDATION DE LA MODELISATION COQUE PAR *
  10. * COMPARAISON A UN CALCUL 3D *
  11. * *
  12. * *
  13. * GEOMETRIE : plaque *
  14. * *
  15. * longueur du tube : 3000. MM *
  16. * epaisseur du tube : 17.5 MM *
  17. * rayon moyen du tube : 350. MM *
  18. * longueur de la fissure : 50. MM *
  19. * *
  20. * MATERIAU : élastique *
  21. * *
  22. * Module d'Young : 2.E5 MPa *
  23. * Coefficient de poisson : 0.3 *
  24. * *
  25. * CHARGEMENT : température imposée *
  26. * *
  27. ****************************************************
  28.  
  29. * I - MAILLAGE
  30. * ------------
  31.  
  32. * I.1 - MAILLAGE 2D
  33. * *****************
  34.  
  35. * OPTIONS
  36. ORD_EF = 2 ;
  37. SI (EGA ORD_EF 1) ;
  38. SUP_GEO_2D = 'QUA4' ;
  39. SUP_GEO_3D = 'CUB8' ;
  40. EF_Q = 'COQ4' ;
  41. EF_T = 'COQ3' ;
  42. SINON ;
  43. SI (EGA ORD_EF 2) ;
  44. SUP_GEO_2D = 'QUA8' ;
  45. SUP_GEO_3D = 'CU20' ;
  46. EF_Q = 'COQ8' ;
  47. EF_T = 'COQ6' ;
  48. SINON ;
  49. MESS 'ERREUR : L''ORDRE DES ELEMENTS DOIT ETRE 1 OU 2' ;
  50. ERRE 21 ;
  51. FINSI ;
  52. FINSI ;
  53. OPTI 'DIME' 2 'ELEM' SUP_GEO_2D ;
  54.  
  55. * PARAMETRES
  56. * TM = TAILLE DE MAILLE EN POINTE DE FISSURE
  57. * N = NOMBRE DE COUCHES D'ELEMENTS SUR 45 DEGRES
  58. * C = DEMI-COTE DU CARRE
  59. * R = RAYON DU DISQUE
  60. * LDEP = LARGEUR DE BANDE DEPOSEE (POUR UN METAL BIPHASE)
  61. * EPAI_T = EPAISSEUR TOTALE DE L'EPROUVETTE
  62.  
  63. A = 17.5 ;
  64. W = 70. ;
  65. H = 280. ;
  66. RAP1 = A/W ;
  67. RAP2 = H/W ;
  68. TM = 0.2 ;
  69. N = 4 ;
  70. LCRITW = (W*(1.-RAP1)) ;
  71. LCRITA = W*RAP1 ;
  72. LDEP = 10. ;
  73. C = MINI (PROG (W/5.) LDEP LCRITA LCRITW) ;
  74. R = C / 2. ;
  75. EPAI_T = .7 * 40;
  76.  
  77. * DEBUT DU MAILLAGE
  78. P0 = 0. 0. ;
  79. P1 = A 0. ;
  80. DENS1 = 2.*TM ;
  81. DENS DENS1 ;
  82. P2 = P1 PLUS ((TM*N*2.) 0.) ;
  83. SI ((TM * N * 2.) > R) ;
  84. NC = R / 2. ;
  85. MESS 'LE PRODUIT (TM*N) DOIT ETRE INFERIEUR A' NC ;
  86. FINSI ;
  87. DENS2 = 1.5*(PI*R)/(4.*N) ;
  88. DENS DENS2 ;
  89. P10 = P1 PLUS (R 0.) ;
  90.  
  91. LIGAM0 = P2 DROI P10 ;
  92.  
  93. SU21 = LIGAM0 ROTA N 45. P1 ;
  94. L21 = SU21 COTE 4 ;
  95. C21 = SU21 COTE 2 ;
  96. SU22 = (SU21 COTE 3) ROTA N 45. P1 ;
  97. L22 = SU22 COTE 2 ;
  98. C22 = SU22 COTE 4 ;
  99. SU23 = (SU22 COTE 3) ROTA N 45. P1 ;
  100. L23 = SU23 COTE 4 ;
  101. C23 = SU23 COTE 2 ;
  102. SU24 = (SU23 COTE 3) ROTA N 45. P1 ;
  103. L24 = SU24 COTE 2 ;
  104. C24 = SU24 COTE 4 ;
  105.  
  106. RAC = L21 ET L22 ET L23 ET L24 ;
  107. SU2 = SU21 ET SU22 ET SU23 ET SU24 ;
  108.  
  109. DENS TM ;
  110. QAD = P1 PLUS ((TM*N) 0.) ;
  111. QAG = P1 MOIN ((TM*N) 0.) ;
  112. BASD = P1 DROI N QAD ;
  113. BASG = P1 DROI N QAG ;
  114. BAS = ORDO (BASG ET BASD) ;
  115. PAVE1 = BAS TRAN N (0. (TM*N)) ;
  116. COPAV1 = PAVE1 COTE 2 ;
  117. COPAV2 = PAVE1 COTE 3 ;
  118. COPAV3 = PAVE1 COTE 4 ;
  119. COPAV = COPAV1 ET COPAV2 ET COPAV3 ;
  120. DEC = (ENTI (N / 1.2)) * (-1) ;
  121. JONCD = QAD DROI P2 ;
  122. JONCG = QAG DROI (SU24 POIN 'PROC' QAG) ;
  123. SUJON = DALL COPAV JONCD RAC JONCG 'PLAN' ;
  124. SU0 = SUJON ET PAVE1 ;
  125. LIG0 = BASD ET JONCD ;
  126. LIGAM0 = LIGAM0 ET LIG0 ;
  127. L1 = LIGAM0 ;
  128.  
  129. * CARRE EXTERIEUR AUTOUR DU FOND DE FISSURE
  130. DENS (2.*DENS2) ;
  131. PDB = P1 PLUS (C 0.) ;
  132. PDH = P1 PLUS (C C) ;
  133. PMH = P1 PLUS (0. C) ;
  134. PGH = P1 PLUS (((-1) * C) C) ;
  135. PGB = P1 PLUS (((-1) * C) 0.) ;
  136.  
  137. CARD = PDB DROI N PDH ;
  138. CARHD = PDH DROI N PMH ;
  139. CARHG = PMH DROI N PGH ;
  140. CARG = PGH DROI N PGB ;
  141.  
  142. DECC = ((-1) * (ENTI ((C - R) / (1. * DENS2)))) - 1 ;
  143.  
  144. DIAD1 = (C21 POIN 'INITIAL') DROI DECC PDB ;
  145. DIAD1H = (C22 POIN 'FINAL') DROI DECC PDH ;
  146. DIAM = (C23 POIN 'INITIAL') DROI DECC PMH ;
  147. DIAG1H = (C24 POIN 'FINAL') DROI DECC PGH ;
  148. DIAG1 = (C24 POIN 'INITIAL') DROI DECC PGB ;
  149.  
  150. SU3 = DALL C21 DIAD1H CARD DIAD1 'PLAN';
  151. SU4 = (DALL C22 DIAM CARHD DIAD1H 'PLAN') ET
  152. (DALL C23 DIAG1H CARHG DIAM 'PLAN') ;
  153. SU5 = DALL C24 DIAG1 CARG DIAG1H 'PLAN' ;
  154.  
  155. CARRE = SU0 ET SU2 ET SU3 ET SU4 ET SU5 ;
  156. LIGAM1 = LIGAM0 ET DIAD1 ;
  157.  
  158. * PARTIE METAL DEPOSE
  159. CLCRITW = (C < (LCRITW + 0.01)) ET (C > (LCRITW - 0.01)) ;
  160. CLCRITA = (C < (LCRITA + 0.01)) ET (C > (LCRITA - 0.01)) ;
  161. CLDEP = (C < (LDEP + 0.01)) ET (C > (LDEP - 0.01)) ;
  162.  
  163. SI ((NON CLCRITW ) ET (NON CLCRITA)) ;
  164. MESS 'CAS GENERAL' ;
  165. VTL = 0. (LDEP - C) ;
  166. VTG = (((-1) * (LCRITA - C)) 0.) ;
  167. VTD = (LCRITW - C) 0. ;
  168. NFL = ENTI ((LDEP - C) / (MESU (CARHD ELEM 1) LONG)) ;
  169. NFG = ENTI ((LCRITA - C) / (MESU (CARG ELEM 1) LONG)) ;
  170. NFD = ENTI ((LCRITW - C) / (MESU (CARD ELEM 1) LONG)) ;
  171. SI (NFG EGA 0) ;
  172. NFG = 1 ;
  173. SU7 = CARG TRAN NFG VTG ;
  174. SINON ;
  175. DENSI = (MESU (CARG ELEM 1) LONG) ;
  176. DENSF = DENSI * (1 + (NFG / 20.)) ;
  177. SU7 = CARG TRAN 'DINI' DENSI 'DFIN' DENSF VTG ;
  178. FINSI ;
  179. SI (NFD EGA 0) ;
  180. NFD = 1 ;
  181. SU6 = CARD TRAN NFD VTD ;
  182. SINON ;
  183. DENSI = (MESU (CARD ELEM 1) LONG) ;
  184. DENSF = DENSI * (1 + (NFD / 20.)) ;
  185. SU6 = CARD TRAN 'DINI' DENSI 'DFIN' DENSF VTD ;
  186. FINSI ;
  187. L8 = (SU7 COTE 4) ET (SU6 COTE 2) ET CARHD ET CARHG ;
  188. L8 = ORDO L8 ;
  189. SI CLDEP ;
  190. MESS 'CAS CRITIQUE LDEP' ;
  191. MDEP = CARRE ET SU6 ET SU7 ;
  192. L8B = INVE L8 ;
  193. LIGAM = LIGAM1 ET (SU6 COTE 4) ;
  194. LSYM1 = (SU7 COTE 3) ;
  195. SINON ;
  196. SI (NFL EGA 0) ;
  197. NFL = 1 ;
  198. SU8 = L8 TRAN NFL VTL ;
  199. SINON ;
  200. DENSI = (MESU (CARHD ELEM 1) LONG) ;
  201. DENSF = DENSI * (1 + (NFL / 10.)) ;
  202. SU8 = L8 TRAN 'DINI' DENSI 'DFIN' DENSF VTL ;
  203. FINSI ;
  204. MDEP = CARRE ET SU6 ET SU7 ET SU8 ;
  205. L8B = SU8 COTE 3 ;
  206. LIGAM = LIGAM1 ET (SU6 COTE 4) ;
  207. LSYM1 = (SU7 COTE 3) ET (SU8 COTE 4) ;
  208. FINSI ;
  209. FINSI ;
  210.  
  211. SI CLCRITW ;
  212. MESS 'CAS CRITIQUE W' ;
  213. VTL = 0. (LDEP - C) ;
  214. VTT = (((-1) * (LCRITA - C)) 0.) ;
  215. NFL = ENTI ((LDEP - C) / (MESU (CARHD ELEM 1) LONG)) ;
  216. NFT = ENTI ((LCRITA - C) / (MESU (CARG ELEM 1) LONG)) ;
  217. SI (NFT EGA 0) ;
  218. NFT = 1 ;
  219. SU7 = CARG TRAN NFT VTT ;
  220. SINON ;
  221. DENSI = (MESU (CARG ELEM 1) LONG) ;
  222. DENSF = DENSI * (1 + (NFT / 20.)) ;
  223. SU7 = CARG TRAN 'DINI' DENSI 'DFIN' DENSF VTT ;
  224. FINSI ;
  225. L8 = (SU7 COTE 4) ET CARHD ET CARHG ;
  226. L8 = ORDO L8 ;
  227. SI (CLDEP) ;
  228. MESS 'CAS CRITIQUE LDEP ET LCRITW' ;
  229. MDEP = CARRE ET SU7 ;
  230. L8B = INVE L8 ;
  231. LIGAM = LIGAM1 ;
  232. LSYM1 = (SU7 COTE 3) ;
  233. SINON ;
  234. SI (NFL EGA 0) ;
  235. NFL = 1 ;
  236. SU8 = L8 TRAN NFL VTL ;
  237. SINON ;
  238. DENSI = (MESU (CARHD ELEM 1) LONG) ;
  239. DENSF = DENSI * (1 + (NFL / 10.)) ;
  240. SU8 = L8 TRAN 'DINI' DENSI 'DFIN' DENSF VTL ;
  241. FINSI ;
  242. MDEP = CARRE ET SU7 ET SU8 ;
  243. L8B = SU8 COTE 3 ;
  244. LIGAM = LIGAM1 ;
  245. LSYM1 = (SU7 COTE 3) ET (SU8 COTE 4) ;
  246. FINSI ;
  247. FINSI ;
  248.  
  249. SI CLCRITA ;
  250. MESS 'CAS CRITIQUE A' ;
  251. VTL = 0. (LDEP - C) ;
  252. VTT = (LCRITW - C) 0. ;
  253. NFL = ENTI ((LDEP - C) / (MESU (CARHD ELEM 1) LONG)) ;
  254. NFT = ENTI ((LCRITW - C) / (MESU (CARD ELEM 1) LONG)) ;
  255. SI (NFT EGA 0) ;
  256. NFT = 1 ;
  257. SU6 = CARD TRAN NFT VTT ;
  258. SINON ;
  259. DENSI = (MESU (CARD ELEM 1) LONG) ;
  260. DENSF = DENSI * (1 + (NFT / 20.)) ;
  261. SU6 = CARD TRAN 'DINI' DENSI 'DFIN' DENSF VTT ;
  262. FINSI ;
  263. L8 = (SU6 COTE 2) ET CARHD ET CARHG ;
  264. L8 = ORDO L8 ;
  265. SI (CLDEP) ;
  266. * MESS 'CAS CRITIQUE LDEP ET LCRITA' ;
  267. MDEP = CARRE ET SU6 ;
  268. L8B = L8 ;
  269. LIGAM = LIGAM1 ET (SU6 COTE 4) ; ;
  270. LSYM1 = CARG ;
  271. SINON ;
  272. SI (NFL EGA 0) ;
  273. NFL = 1 ;
  274. SU8 = L8 TRAN NFL VTL ;
  275. SINON ;
  276. DENSI = (MESU (CARHD ELEM 1) LONG) ;
  277. DENSF = DENSI * (1 + (NFL / 10.)) ;
  278. SU8 = L8 TRAN 'DINI' DENSI 'DFIN' DENSF VTL ;
  279. FINSI ;
  280. MDEP = CARRE ET SU6 ET SU8 ;
  281. L8B = SU8 COTE 3 ;
  282. L8B = INVE L8B ;
  283. LIGAM = LIGAM1 ET (SU6 COTE 4) ;
  284. LSYM1 = (SU8 COTE 2) ET CARG ;
  285. FINSI ;
  286. FINSI ;
  287.  
  288. * PARTIE METAL DE BASE
  289. L8B = ORDO L8B ;
  290. PPI = L8B POIN 'INITIAL' ;
  291. PF = L8B POIN 'FINAL' ;
  292. LU = (MESU L8B LONG) / (NBEL L8B) * 1.2 ;
  293. FRON1 = (PPI PLUS (0. LU)) DROI (ENTI ((NBEL L8B) / 1.51))
  294. (PF PLUS (0. LU)) ;
  295. LUB = ((MESU FRON1 LONG) / (NBEL FRON1)) * 1.2 ;
  296. PIB = FRON1 POIN 'INITIAL' ;
  297. PFB = FRON1 POIN 'FINAL' ;
  298. FRON2 = (PIB PLUS (0. LUB)) D (ENTI ((NBEL FRON1) / 1.51))
  299. (PFB PLUS (0. LUB)) ;
  300.  
  301. JOIN1 = COUT L8B FRON1 ;
  302. JOIN2 = COUT FRON1 FRON2 ;
  303. JOIN = JOIN1 ET JOIN2 ;
  304. JOINL = CHAN JOIN LIGNE ;
  305. JOINP = JOINL POIN 'DROIT' P0 (P0 PLUS (0. 10.)) (TM / 10.) ;
  306. LSYM2 = JOINL ELEM 'APPUYE' 'STRICTEMENT' JOINP ;
  307.  
  308. LREST = ((W * RAP2) / 2.) - (LDEP + LU + LUB) ;
  309. VT = 0. LREST ;
  310. LE = MESU (FRON2 ELEM 1) LONG ;
  311. CORP = FRON2 TRAN (ENTI (LREST / LE)) VT ;
  312. LSYM3 = CORP COTE 2 ;
  313. PINIF = LIGAM POIN 'INITIAL' ;
  314.  
  315. * FIN DU MAILLAGE
  316. MBAS = CORP ET JOIN ;
  317. * PLAN VERTICALE DE SYMETRIE
  318. LSYM = LSYM1 ET LSYM2 ET LSYM3 ;
  319. LSYM = LSYM COUL VERT ;
  320. * FACE DE CHARGEMENT
  321. SCHAR = CORP COTE 3 ;
  322. SCHAR = SCHAR COUL ROUG ;
  323. * LIGAMENT
  324. LIGAM = LIGAM COUL BLEU ;
  325. * MAILLAGE COMPLET
  326. CCP = MBAS ET MDEP ;
  327. * TRAC 'QUAL' (CCP ET LIGAM ET LSYM ET SCHAR) ;FIN ;
  328.  
  329. * PREMIERE COUCHE D'ELEMENT AUTOUR DE LA FISSURE
  330. IELEM = 53 ;
  331. ELEFIS = CCP ELEM SUP_GEO_2D IELEM ;
  332.  
  333.  
  334. * I.2 - MAILLAGE 3D
  335. * *****************
  336.  
  337. OPTI 'DIME' 3 'ELEM' SUP_GEO_3D ;
  338.  
  339. * EXTRUSION
  340. VOL1 = CCP VOLU 5 'TRAN' (0. 0. (EPAI_T/2.)) ;
  341. * TRAC 'CACH' VOL1 ;FIN ;
  342.  
  343.  
  344. * II - CALCULS
  345. * ------------
  346.  
  347. * PROPRIETES :
  348. * YOUN1 = MODULE D'YOUNG
  349. * NU1 = COEFFICIENT DE POISSON
  350. * ALPH1 = COEFFICIENT DE DILATATION
  351. * TALP1 = TEMPERATURE DE REFERENCE POUR LE COEFFICIENT DE DILATATION SECANT
  352. * TREF1 = TEMPERATURE DE REFERENCE POUR LA DEFORMATION THERMIQUE
  353.  
  354. YOUN1 = 2.E05;
  355. NU1 = 0.3 ;
  356. ALPH1 = 0.5 ;
  357. TALP1 = 0. ;
  358. TREF1 = 0. ;
  359.  
  360. * II.1 - CALCUL 3D MASSIF
  361. * ***********************
  362.  
  363. * MODELE ET MATERIAU
  364. MOD1 = MODE VOL1 'MECANIQUE' 'ELASTIQUE' ;
  365. MAT1 = MATE MOD1 'YOUN' YOUN1 'NU' NU1 'ALPH' ALPH1 'TALP' TALP1 'TREF' TREF1 ;
  366. RIG1 = RIGI MOD1 MAT1 ;
  367.  
  368. * CL
  369. XLIGAM = MINI (COOR 1 LIGAM) ;
  370. D_VOL1 = ENVE VOL1 ;
  371. Y1 = COOR 2 D_VOL1 ;
  372. YLIM = (MINI Y1) + 1.E-5 ;
  373. PLIGAM3D = Y1 POIN 'EGINFE' YLIM ;
  374. PLIGAM3D = (COOR 1 PLIGAM3D) POIN 'EGSUPE' XLIGAM ;
  375. LIGAM3D = D_VOL1 ELEM 'APPUYE' PLIGAM3D ;
  376. CL1 = BLOQ 'UY' LIGAM3D ;
  377.  
  378. X1 = COOR 1 D_VOL1 ;
  379. XLIM = (MINI X1) + 1.E-5 ;
  380. PYOZ = X1 POIN 'EGINFE' XLIM ;
  381. YOZ = D_VOL1 ELEM 'APPUYE' PYOZ ;
  382. CL2 = BLOQ 'UX' YOZ ;
  383.  
  384. Z1 = COOR 3 D_VOL1 ;
  385. ZLIM = (MINI Z1) + 1.E-5 ;
  386. PXOY = Z1 POIN 'EGINFE' ZLIM ;
  387. XOY = D_VOL1 ELEM 'APPUYE' PXOY ;
  388. CL3 = BLOQ 'UZ' XOY ;
  389.  
  390. * TRAC 'CACH' (VOL1 ET (LIGAM3D COUL 'ROUG') ET (YOZ COUL 'BLEU')
  391. * ET (XOY COUL 'VERT')) ;FIN ;
  392.  
  393. CL0 = CL1 ET CL2 ET CL3 ;
  394.  
  395. * TEMPERATURE IMPOSEE
  396. EV1 = EVOL 'MANU' 'X1' (PROG 0 70) (PROG -0.0005 0);
  397. TIMP = VARI EV1 (COOR 1 VOL1) 'T' ;
  398. CHAR1 = BSIG MOD1 (THET MOD1 MAT1 TIMP) ;
  399.  
  400. * RESOLUTION
  401. DEP1 = RESO (RIG1 ET CL0) CHAR1 ;
  402. * DEF1 = DEFO VOL1 DEP1 ;
  403. * TRAC 'CACH' DEF1 ;FIN ;
  404.  
  405. * APPEL A G_THETA
  406. PLEVRE = Y1 POIN 'EGINFE' YLIM ;
  407. LEVRE = D_VOL1 ELEM 'APPUYE' PLEVRE ;
  408. LEVRE = LEVRE DIFF LIGAM3D ;
  409. D_LEVRE = CONT LEVRE ;
  410. PFRONT = (COOR 1 D_LEVRE) POIN 'MAXI' ;
  411. FRONT_FISS = D_LEVRE ELEM 'APPUYE' PFRONT ;
  412. * TRAC 'CACH' (VOL1 ET (LEVRE COUL 'ROUG') ET (FRONT_FISS COUL 'BLEU')) ;FIN ;
  413.  
  414. SUPTAB = TABL ;
  415. SUPTAB.'OBJECTIF' = MOT 'J' ;
  416. SUPTAB.'LEVRE_SUPERIEURE' = LEVRE ;
  417. SUPTAB.'FRONT_FISSURE' = FRONT_FISS ;
  418. SUPTAB.'SOLUTION_RESO' = DEP1 ;
  419. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  420. SUPTAB.'MODELE' = MOD1 ;
  421. SUPTAB.'TEMPERATURES' = TIMP ;
  422. SUPTAB.'COUCHE' = 4 ;
  423.  
  424. G_THETA SUPTAB ;
  425.  
  426. G3D = SUPTAB.'RESULTATS'.'GLOBAL' ;
  427.  
  428.  
  429. * II.2 - CALCUL COQUE
  430. * *******************
  431.  
  432. OPTI 'ELEM' SUP_GEO_2D ;
  433.  
  434. * MODELE MULTICOUCHE
  435. * ELEMENT POUR LE MODELE MULTICOUCHE
  436. * NOMBRE DE COUCHES ET LEUR EPAISSEUR
  437. NB_COU = 13 ;
  438. EPAI_C = EPAI_T * 1.E-6 ;
  439. * CREATION DU MODELE MULTICOUCHE
  440. EPAI_I = (EPAI_T - (EPAI_C*NB_COU))/(NB_COU - 1) ;
  441. TBEPAI = TABL ;
  442. TBEXCE = TABLE ;
  443. MOD_MUL = VIDE 'MMODEL' ;
  444. MAT_MUL = VIDE 'MCHAML' ;
  445. REPE I ((2*NB_COU) - 1) ;
  446. EX1 = (EPAI_I + EPAI_C)*(&I - NB_COU)/2. ;
  447. SI (EGA ((&I/2)*2) &I) ;
  448. EP1 = EPAI_I ;
  449. SINON ;
  450. EP1 = EPAI_C ;
  451. FINSI;
  452. MOD_MU1 = MODE ELEFIS 'MECANIQUE' 'ELASTIQUE' EF_Q 'CONS' (CHAI &I) ;
  453. MAT_MU1 = MATE MOD_MU1 'YOUN' YOUN1 'NU' NU1 'ALPH' ALPH1 'TALP' TALP1
  454. 'TREF' TREF1 'EPAI' EP1 'EXCE' EX1 ;
  455. MOD_MUL = MOD_MUL ET MOD_MU1 ;
  456. MAT_MUL = MAT_MUL ET MAT_MU1 ;
  457. FIN I;
  458.  
  459. * RESTE DU MODELE
  460. MOD0 = MODE (CCP DIFF ELEFIS) 'MECANIQUE' 'ELASTIQUE' EF_T EF_Q ;
  461. MAT0 = MATE MOD0 'YOUN' YOUN1 'NU' NU1 'ALPH' ALPH1 'TALP' TALP1 'TREF' TREF1
  462. 'EPAI' EPAI_T ;
  463. MOD2 = MOD0 ET MOD_MUL ;
  464. MAT2 = MAT0 ET MAT_MUL ;
  465. RIG2 = RIGI MOD2 MAT2 ;
  466.  
  467. * CL
  468. CL1 = BLOQ 'UY' 'RX' 'RZ' LIGAM ;
  469. CL2 = BLOQ 'UX' 'RY' 'RZ' LSYM ;
  470. CL3 = BLOQ 'UZ' SCHAR ;
  471. CL0 = CL1 ET CL2 ET CL3 ;
  472.  
  473. * CHARGEMENT
  474. TCOQ = (NOMC 'TINF' TIMP) + TIMP + (NOMC 'TSUP' TIMP) ;
  475. CHAR2 = BSIG MOD2 (THET MOD2 MAT2 TCOQ) MAT2 ;
  476.  
  477. * RESOLUTION
  478. DEP2 = RESO (RIG2 ET CL0) CHAR2 ;
  479. * DEF2 = DEFO CCP DEP2 ;
  480. * TRAC 'CACH' DEF2 ;FIN ;
  481.  
  482. * APPEL A G_THETA
  483. Y2 = COOR 2 CCP ;
  484. YLIM = (MINI Y2) + 1.E-5 ;
  485. PLEVRE = Y2 POIN 'EGINFE' YLIM ;
  486. D_CCP = CONT CCP ;
  487. LEVRE = D_CCP ELEM 'APPUYE' PLEVRE ;
  488. LEVRE = LEVRE DIFF LIGAM ;
  489. XFISS = COOR 1 LEVRE ;
  490. FRONT_FISS = XFISS POIN 'MAXI' ;
  491. * TRAC 'CACH' (CCP ET (LEVRE COUL 'ROUG') ET (FRONT_FISS COUL 'BLEU')) ;FIN ;
  492.  
  493. SUPTAB = TABL ;
  494. SUPTAB.'OBJECTIF' = MOT 'J' ;
  495. SUPTAB.'LEVRE_SUPERIEURE' = LEVRE ;
  496. SUPTAB.'FRONT_FISSURE' = FRONT_FISS POIN 1 ;
  497. SUPTAB.'ELEMENT_MULTICOUCHE' = ELEFIS ;
  498. SUPTAB.'SOLUTION_RESO' = DEP2 ;
  499. SUPTAB.'CARACTERISTIQUES' = MAT2 ;
  500. SUPTAB.'MODELE' = MOD2 ;
  501. SUPTAB.'TEMPERATURES' = TCOQ ;
  502. SUPTAB.'COUCHE' = 4 ;
  503.  
  504. G_THETA SUPTAB ;
  505.  
  506. GCOQ = SUPTAB.'RESULTATS'.'GLOBAL' ;
  507.  
  508.  
  509. * II.3 - COMPARAISON
  510. * ******************
  511.  
  512. ERR1 = (ABS (GCOQ - G3D)) / G3D ;
  513. MESS (CHAI 'ERREUR RELATIVE :' ' ' 'FORMAT' '(F4.1)' (100*ERR1) ' %') ;
  514. SI (ERR1 > 5.E-3) ;
  515. ERRE 5 ;
  516. FINSI ;
  517.  
  518. FIN ;
  519.  
  520.  
  521.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales