Télécharger g_rotation_tuyauterie_droite_1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : g_rotation_tuyauterie_droite_1.dgibi
  2. ****************************************************
  3. ****************************************************
  4. * *
  5. * VERIFICATION DE LA PROCEDURE G_THETA *
  6. * POUR LE CALCUL DE G POUR UNE FISSURE *
  7. * DANS UNE SECTION DE TUYAU DROIT *
  8. * - *
  9. * COMPARAISON ENTRE LE RESULTAT 3D *
  10. * AVEC ET SANS LES OPTIONS 'POINT_1' ET 'POINT_2' *
  11. * ET UNE SOLUTION ANALYTIQUE. ON EN PROFITE *
  12. * POUR TESTER EGALEMENT L'UTILISATION DE *
  13. * L'INDICE 'NOEUDS_AVANCES'. *
  14. * *
  15. * SOLUTION ANALYTIQUE TIREE DE : *
  16. * "THE STRESS ANALYSIS OF CRACKS HANDBOOK" *
  17. * TADA, PARIS AND IRWIN (2000) *
  18. * *
  19. ****************************************************
  20.  
  21. * I - OPTIONS ET DONNEES
  22. * ----------------------
  23.  
  24. * OPTIONS
  25. OPTI 'DIME' 3 'ELEM' 'CUB8' ;
  26. * SI BTRAC = VRAI ON TRACE LE MAILLAGE
  27. BTRAC = FAUX ;
  28.  
  29. * DONNEES
  30. * RCYL = RAYON
  31. * ECYL = EPAISSEUR
  32. * LCYL = LONGUEUR
  33. * ANG1 = SECTEUR ANGULAIRE DE LA FISSURE
  34. RCYL = 350. ;
  35. ECYL = RCYL/10. ;
  36. LCYL = 3000. ;
  37. ANG1 = 45. ;
  38.  
  39. * PROPRIÉTÉS MATÉRIAU
  40. MYOU = 2.E5 ;
  41. POI = 0.3 ;
  42.  
  43.  
  44. * II - MAILLAGE
  45. * -------------
  46.  
  47. * PARAMETRES DU MAILLAGE
  48. DENS1 = ECYL / 5. ;
  49. DENS DENS1 ;
  50. PREC1 = DENS1 * 1.E-10 ;
  51.  
  52. * MAILLAGE RAYONNANT AUTOUR DE LA POINTE DE FISSURE
  53. LF = RCYL * ANG1 / 180. * PI ;
  54. RRAY = LF / 6. ;
  55. PF = 0. 0. 0. ;
  56. P1 = RRAY 0. 0. ;
  57. D1 = DROI 5 PF P1 ;
  58. S1 = D1 ROTA 8 180. PF (PF PLUS (0. 0. 1.)) ;
  59. X Y = (COOR 1 S1) (COOR 2 S1) ;
  60. R = ((X**2) + (Y**2))**0.5 ;
  61. PELIM = R POIN 'MINI' ;
  62. ELIM PELIM PREC1 ;
  63. S1 = REGE S1 ;
  64.  
  65. * PASSAGE EN RECTANGLE
  66. CON1 = CONT S1 ;
  67. PCER = R POIN 'MAXI' ;
  68. CER1 = CON1 ELEM 'APPUYE' PCER ;
  69. NEL = (NBEL CER1) / 4 ;
  70. XP = RRAY * 1.5 ;
  71. XN = 0. - XP ;
  72. REC1 = DROI NEL (XP 0. 0.) (XP XP 0.) ;
  73. REC1 = DROI (2 * NEL) REC1 (XN XP 0.) ;
  74. REC1 = DROI NEL REC1 (XN 0. 0.) ;
  75. S2 = CER1 REGL 2 REC1 ;
  76. STOT = S1 ET S2 ;
  77.  
  78. * EXTENSION JUSQU'AU BORT DU CYLINDRE (COTE FISSURE)
  79. REC2 = REC1 HOMO (LF / XP) (0. 0. 0.) ;
  80. S3 = REC1 REGL REC2 ;
  81. STOT = STOT ET S3 ;
  82.  
  83. * EXTENSION JUSQU'AU BORD DU CYLINDRE (COTE LIGAMENT)
  84. XMIN = MINI (COOR 1 REC2) ;
  85. XMAX = MAXI (COOR 1 REC2) ;
  86. PGAU = REC2 POIN 'DROI' (XMIN 0. 0.) (XMIN 1. 0.) ;
  87. DGAU = REC2 ELEM 'APPUYE' PGAU ;
  88. S4 = DGAU TRAN 'DFIN' (RCYL / 3.) ((XMAX - XMIN - (RCYL * PI)) 0. 0.) ;
  89. STOT = STOT ET S4 ;
  90.  
  91. * EXTENSION SUR LA LONGUEUR DU CYLINDRE
  92. Y = COOR 2 STOT ;
  93. YMAX = MAXI Y ;
  94. PHAU = STOT POIN 'DROI' (0. YMAX 0.) (1. YMAX 0.) ;
  95. DHAU = (CONT STOT) ELEM 'APPUYE' PHAU ;
  96. S5 = DHAU TRAN 'DFIN' (LCYL / 5) (0. (LCYL - YMAX) 0.) ;
  97. STOT = STOT ET S5 ;
  98.  
  99. * EXTRUSION DANS L'EPAISSEUR
  100. VTOT = STOT VOLU 10 'TRAN' (0. 0. ECYL) ;
  101.  
  102. * DEFINITION DE LA FISSURE ET DU FRONT
  103. PPLAN = VTOT POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  104. PFIS = (COOR 1 PPLAN) POIN 'EGSUPE' 0. ;
  105. ENVTOT = ENVE VTOT ;
  106. LVSUP = ENVTOT ELEM 'APPUYE' PFIS ;
  107. LVSUP = LVSUP COUL 'ROUG' ;
  108. PFRO = PFIS POIN 'DROI' (0. 0. 0.) (0. 0. 1.) ;
  109. FRO1 = (CONT LVSUP) ELEM 'APPUYE' PFRO ;
  110. FRO1 = (ORDO FRO1) COUL 'BLEU' ;
  111. VTRAC = VTOT ET LVSUP ET FRO1 ;
  112.  
  113. * TRANSFORMATION EN CYLINDRE ;
  114. XMIN = MINI (COOR 1 VTOT) ;
  115. DEPL VTOT 'MOIN' (XMIN 0. (ECYL / 2.)) ;
  116. X1 Y1 Z1 = COOR VTRAC ;
  117. THET1 = (X1 / RCYL) * 180. / PI ;
  118. THET1 = 180. - THET1 ;
  119. R1 = RCYL + Z1 ;
  120. X2 = R1 * (COS THET1) ;
  121. Y2 = Y1 ;
  122. Z2 = R1 * (SIN THET1) ;
  123. UDEP = (NOMC 'UX' (X2 - X1)) + (NOMC 'UY' (Y2 - Y1)) + (NOMC 'UZ' (Z2 - Z1)) ;
  124. DEPL VTOT 'PLUS' UDEP ;
  125. SI BTRAC ;
  126. TRAC 'CACH' VTRAC ;
  127. FINSI ;
  128.  
  129.  
  130. * III - MODELE, MATERIAU, CLS ET RESOLUTION
  131. * -----------------------------------------
  132.  
  133. * MODELE ET MATERIAU
  134. MOD1 = MODE VTOT 'MECANIQUE' 'ELASTIQUE' ;
  135. MAT1 = MATE MOD1 'YOUN' MYOU 'NU' POI ;
  136. RIG1 = RIGI MAT1 MOD1 ;
  137.  
  138. * CONDITIONS AUX LIMITES ET CHARGEMENT
  139. SPLAN = ENVTOT ELEM 'APPUYE' PPLAN ;
  140. SLIG = DIFF SPLAN LVSUP ;
  141. BLO1 = BLOQ 'UY' SLIG ;
  142. PBAS = VTOT POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) ;
  143. BLO2 = BLOQ 'UZ' PBAS ;
  144. BLO0 = BLO1 ET BLO2 ;
  145. PEXT = VTOT POIN 'PLAN' (0. LCYL 0.) (1. LCYL 0.) (0. LCYL 1.) ;
  146. SEXT = ENVTOT ELEM 'APPUYE' PEXT ;
  147. F0 = PRES 'MASS' MOD1 -1. SEXT ;
  148.  
  149. * RESOLUTION
  150. U0 = RESO (RIG1 ET BLO0) F0 ;
  151.  
  152. SI BTRAC ;
  153. DEF0 = DEFO VTRAC U0 0. ;
  154. DEF1 = DEFO VTRAC U0 'ROUG' ;
  155. TRAC 'CACH' (DEF0 ET DEF1) ;
  156. FINSI ;
  157.  
  158.  
  159. * IV - POST-TRAITEMENT
  160. * --------------------
  161.  
  162. * APPEL A G_THETA
  163. SUPTAB = TABL ;
  164. SUPTAB.'OBJECTIF' = MOT 'J' ;
  165. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  166. SUPTAB.'FRONT_FISSURE' = FRO1 ;
  167. SUPTAB.'MODELE' = MOD1 ;
  168. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  169. SUPTAB.'SOLUTION_RESO' = U0 ;
  170. SUPTAB.'CHARGEMENTS_MECANIQUES' = F0 ;
  171. SUPTAB.'COUCHE' = 10 ;
  172. NOAV = FRO1 ELEM 'COMPRIS' (FRO1 POIN 2) (FRO1 POIN ((NBNO FRO1) - 1)) ;
  173. SUPTAB.'NOEUDS_AVANCES' = NOAV ;
  174. SUPSANS = COPI SUPTAB ;
  175. SUPTAB.'POINT_1' = (0. 1. 0.) ;
  176. SUPTAB.'POINT_2' = (0. 0. 0.) ;
  177. SUPAVEC = COPI SUPTAB ;
  178. G_THETA SUPAVEC ;
  179. GAVEC = SUPAVEC.'RESULTATS' ;
  180. G_THETA SUPSANS ;
  181. GSANS = SUPSANS.'RESULTATS' ;
  182.  
  183. * SOLUTION ANALYTIQUE
  184. ANG2 = ANG1 / 180. ;
  185. FDETH = 1. + (7.5 * (ANG2**1.5)) - (15. * (ANG2**2.5)) + (33. * (ANG2**3.5)) ;
  186. GANA = (1.-(POI**2)) / MYOU * PI * LF * (FDETH**2.) ;
  187. LIST GANA ;
  188.  
  189. * COMPARAISON
  190. GCHPO1 = SUPAVEC.'CHPO_RESULTATS' ;
  191. EVO1 = EXTR (EVOL 'CHPO' GCHPO1 NOAV) 'COUR' 1 ;
  192. GCHPO2 = SUPSANS.'CHPO_RESULTATS' ;
  193. EVO2 = EXTR (EVOL 'CHPO' GCHPO2 NOAV) 'COUR' 1 ;
  194. EVO3 = (EVO1 / EVO1) * GANA ;
  195. SI BTRAC ;
  196. DESS (EVO1 ET EVO2 ET EVO3) ;
  197. FINSI ;
  198. ERRAVEC = (INTG ((EVO1 - EVO3)**2))**0.5 ;
  199. ERRSANS = (INTG ((EVO2 - EVO3)**2))**0.5 ;
  200. CRI1 = (INTG EVO3 'ABS') * 3.E-2 ;
  201. MESS 'ERREUR SUR LE CALCUL DE G AVEC POINT_1 ET POIN_2 :' ERRAVEC ;
  202. MESS 'ERREUR SUR LE CALCUL DE G SANS POINT_1 ET POIN_2 :' ERRSANS ;
  203. SI (ERRAVEC > CRI1) ;
  204. MESS 'ERREUR : L''ERREUR SUR G DEPASSE LE CRITERE' ;
  205. ERRE 5 ;
  206. FINSI ;
  207. SI (ERRAVEC > ERRSANS) ;
  208. MESS 'ERREUR : L''ERREUR SUR G AVEC POINT_1 ET POIN_2 EST' ;
  209. MESS ' SUPERIEURE A L''ERREUR SANS CES OPTIONS' ;
  210. ERRE 5 ;
  211. FINSI ;
  212.  
  213. FIN ;
  214.  
  215.  
  216.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales