Exemples de jeux de données Cast3M

Télécharger g_defaut_circonferentiel_3.dgibi
* fichier : g_defaut_circonferentiel_3.dgibi
****************************************************
****************************************************
*                                                  *
*      VERIFICATION DE LA PROCEDURE G_THETA        *
*    POUR UN DEFAUT CIRCONFERENTIEL DEBOUCHANT     *
*          DANS UN TUYAU (FRONT DEBOUCHANT,        *
*               2 LEVRES MODELISEES)               *
*                        -                         *
*  COMPARAISON ENTRE LE CALCUL 3D ET UN CALCUL     *
*                2D AXISYMETRIQUE                  *
*                                                  *
****************************************************
 
* I - CALCUL 3D COMPLET
* ---------------------
 
OPTI 'DIME' 3 'ELEM' 'CU20' 'DENS' 1. ;
BTRAC = FAUX ;
 
* FRONT OUVERT, DEUX LEVRES MODELISEES
 
* MAILLAGE DE LA TRANCHE
L1 = 10. ;
L2 = 20. ;
H1 = 5. ;
SURF1 = (DROI (L1 0. 0.) (L2 0. 0.)) TRAN (0. H1 0.) ;
ANG1 = 36. ;
VOLU1 = SURF1 VOLU 1 'ROTA' ANG1 (0. 1. 0.) (0. 0. 0.) ;
ELIM VOLU1 1.E-10 ;
VOLU2 = VOLU1 SYME 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
OMEGA1 = VOLU1 ET VOLU2 ;
 
* DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
* PARTIE SUP
ENVE1 = ENVE VOLU1 ;
POIN1 = (COOR 2 ENVE1) POIN 'MINI' ;
ELEM1 = ENVE1 ELEM 'APPUYE' POIN1 ;
R1 = (((COOR 1 ELEM1)**2) + ((COOR 3 ELEM1)**2))**0.5 ;
POIN1 = R1 POIN 'EGINFE' ((L1 + L2)/2) ;
LVSUP = ELEM1 ELEM 'APPUYE' POIN1 ;
LIGSUP = ELEM1 DIFF LVSUP ;
SI BTRAC ;
        TRAC 'CACH' (VOLU1 ET (LVSUP COUL 'ROUG') ET (LIGSUP COUL 'VERT')) ;
FINSI ;
* PARTIE INF
ENVE2 = ENVE VOLU2 ;
POIN2 = (COOR 2 ENVE2) POIN 'MAXI' ;
ELEM2 = ENVE2 ELEM 'APPUYE' POIN2 ;
R2 = (((COOR 1 ELEM2)**2) + ((COOR 3 ELEM2)**2))**0.5 ;
POIN2 = R2 POIN 'EGINFE' ((L1 + L2)/2) ;
LVINF = ELEM2 ELEM 'APPUYE' POIN2 ;
LIGINF = ELEM2 DIFF LVINF ;
SI BTRAC ;
        TRAC 'CACH' (VOLU2 ET (LVINF COUL 'ROUG') ET (LIGINF COUL 'VERT')) ;
FINSI ;
* ELIMINATION
ELIM LIGSUP LIGINF 1.E-10 ;
SI BTRAC ;
        TRAC 'CACH' OMEGA1 ;
FINSI ;
* DEFINITION DU FRONT DE FISSURE
FRONFISS = (CONT LIGSUP) INTE (CONT LVSUP) ;
 
* MODELE ET MATERIAU
MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
MAT1 = MATE MOD1 'YOUN' 2.E5 'NU' 0.3 ;
RIG1 = RIGI MOD1 MAT1 ;
 
* CL
PSUP = (COOR 2 OMEGA1) POIN 'MAXI' ;
BLOQ1 = BLOQ (MOTS 'UX' 'UZ') PSUP ;
BLOQ2 = BLOQ 'UY' PSUP ;
PINF = (COOR 2 OMEGA1) POIN 'MINI' ;
BLOQ3 = BLOQ (MOTS 'UX' 'UZ') PINF ;
BLOQ4 = BLOQ 'UY' PINF ;
SYM1 = OMEGA1 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) ;
BLOQ5 = SYMT 'DEPL' (0. 0. 0.) (1. 0. 0.) (0. 1. 0.) SYM1 ;
SYM2 = OMEGA1 POIN 'PLAN' (0. 0. 0.) (0. 1. 0.) ((COS ANG1) 0. (SIN ANG1)) ;
BLOQ6 = SYMT 'DEPL' (0. 0. 0.) (0. 1. 0.) ((COS ANG1) 0. (SIN ANG1)) SYM2 ;
BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ET BLOQ4 ET BLOQ5 ET BLOQ6 ;
DEP1 = DEPI BLOQ2 1. ;
DEP2 = DEPI BLOQ4 (0.-1.) ;
DEP0 = DEP1 ET DEP2 ;
 
* RESO
U1 = RESO (RIG1 ET BLOQ0) DEP0 ;
 
* G_THETA
SUPTAB = TABL ;
SUPTAB.'MODELE' = MOD1 ;
SUPTAB.'CARACTERISTIQUES' = MAT1 ;
SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
SUPTAB.'CHARGEMENTS_MECANIQUES' = DEP0 ;
SUPTAB.'OBJECTIF' = 'J' ;
SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
SUPTAB.'COUCHE' = 4 ;
SUPTAB.'FRONT_FISSURE' = FRONFISS ;
SUPTAB.'SOLUTION_RESO' = U1 ;
 
G_THETA SUPTAB ;
G3D = PROG ;
IND1 = INDE SUPTAB.'RESULTATS' ;
NFRON = DIME IND1 ;
REPE IFRON NFRON ;
        PFRON = IND1.&IFRON ;
        G3D = G3D ET (PROG SUPTAB.'RESULTATS'.PFRON) ;
FIN IFRON ;
 
 
* II - CALCUL 2D AXISYMETRIQUE
* ----------------------------
 
OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA8' ;
 
SURF2 = SURF1 SYME 'DROI' (0. 0.) (1. 0.) ;
OMEGA2 = SURF1 ET SURF2 ;
 
* DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
C1 = CONT SURF1 ;
POIN1 = (COOR 2 C1) POIN 'MINI' ;
ELEM1 = C1 ELEM 'APPUYE' POIN1 ;
POIN1 = (COOR 1 POIN1) POIN 'EGINFE' ((L1 + L2)/2) ;
LVSUP = C1 ELEM 'APPUYE' POIN1 ;
LIGSUP = ELEM1 DIFF LVSUP ;
C2 = CONT SURF2 ;
POIN2 = (COOR 2 C2) POIN 'MAXI' ;
ELEM2 = C2 ELEM 'APPUYE' POIN2 ;
POIN2 = (COOR 1 POIN2) POIN 'EGINFE' ((L1 + L2)/2) ;
LVINF = C2 ELEM 'APPUYE' POIN2 ;
LIGINF = ELEM2 DIFF LVINF ;
ELIM LIGSUP LIGINF 1.E-10 ;
SI BTRAC ;
        TRAC (OMEGA2 ET (LVSUP COUL 'ROUG')) ;
FINSI ;
 
* DEFINITION DU FRONT DE FISSURE
FRONFISS = ((COOR 1 LVSUP) POIN 'MAXI') POIN 1 ;
 
* MODELE ET MATERIAU
MOD2 = MODE OMEGA2 'MECANIQUE' 'ELASTIQUE' ;
MAT2 = MATE MOD2 'YOUN' 2.E5 'NU' 0.3 ;
RIG2 = RIGI MOD2 MAT2 ;
 
* CL
PSUP = (COOR 2 OMEGA2) POIN 'MAXI' ;
BLOQ1 = BLOQ 'UR' PSUP ;
BLOQ2 = BLOQ 'UZ' PSUP ;
PINF = (COOR 2 OMEGA2) POIN 'MINI' ;
BLOQ3 = BLOQ 'UR' PINF ;
BLOQ4 = BLOQ 'UZ' PINF ;
BLOQ0 = BLOQ1 ET BLOQ2 ET BLOQ3 ET BLOQ4 ;
DEP1 = DEPI BLOQ2 1. ;
DEP2 = DEPI BLOQ4 (0.-1.) ;
DEP0 = DEP1 ET DEP2 ;
 
* RESO
U2 = RESO (RIG2 ET BLOQ0) DEP0 ;
 
* G_THETA
SUPTAB = TABL ;
SUPTAB.'MODELE' = MOD2 ;
SUPTAB.'CARACTERISTIQUES' = MAT2 ;
SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
SUPTAB.'CHARGEMENTS_MECANIQUES' = DEP0 ;
SUPTAB.'OBJECTIF' = 'J' ;
SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
SUPTAB.'COUCHE' = 4 ;
SUPTAB.'FRONT_FISSURE' = FRONFISS ;
SUPTAB.'SOLUTION_RESO' = U2 ;
 
G_THETA SUPTAB ;
G2D = PROG NFRON * SUPTAB.'RESULTATS' ;
 
 
* III - COMPARAISON
* -----------------
 
CRIT1 = MAXI (G3D - G2D) 'ABS' ;
CMAX = MAXI G2D 'ABS' ;
SI (CRIT1 > (CMAX*5.E-3)) ;
        MESS 'LA SOLUTION 3D EST TROP ELOIGNEE DE LA SOLUTION 2D AXIS' ;
        ERRE ;
FINSI ;
 
FIN ;