Télécharger g_decouplage_6.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : g_decouplage_6.dgibi
  2. ****************************************************
  3. ****************************************************
  4. * *
  5. * VERIFICATION DE LA PROCEDURE G_THETA *
  6. * POUR LE CALCUL DES FIC POUR UNE FISSURE *
  7. * DROITE DANS UN CARRE *
  8. * - *
  9. * VERIFICATION DU CALCUL DE KI ET KII VIA *
  10. * DECOUPLAGE EN 2D AVEC ELEMENTS STANDARDS *
  11. * ET LA SOLUTION ANALYTIQUE DE WESTERGAARD *
  12. * *
  13. ****************************************************
  14.  
  15. * I - INIT DES DONNÉES CAS_TEST
  16. * -----------------------------
  17.  
  18. OPTI 'DIME' 2 'ELEM' 'QUA4' ;
  19. BTRA = FAUX ;
  20.  
  21. * DONNEES GEOMETRIQUES
  22. A0 = 1. ;
  23. L1 = A0 / 4. ;
  24. DENS1 = L1 / 5. ;
  25. DENS2 = A0 / L1 * DENS1 ;
  26. DENS DENS1 ;
  27.  
  28. * PROPRIÉTÉS MATÉRIAU
  29. MYOU = 2E11 ;
  30. POI = 0.001 ;
  31. KAPPA = 3-(4*POI) ;
  32. MU = MYOU/(2*(1+POI)) ;
  33.  
  34.  
  35. * II - MAILLAGE
  36. * -------------
  37.  
  38. * CREATION DES SURFACES
  39. P0 = 0. 0. ;
  40. D1 = DROI (P0 MOIN (L1 0.)) (P0 PLUS (L1 0.)) ;
  41. S1 = D1 TRAN (0. L1) ;
  42. CONT1 = CONT S1 ;
  43. CONT1 = DIFF CONT1 D1 ;
  44. CONT2 = CONT1 HOMO (A0 / L1) P0 ;
  45. S2 = CONT1 REGL 'DFIN' DENS2 CONT2 ;
  46. S1 = S1 ET S2 ;
  47. S2 = S1 SYME 'DROI' P0 (1. 0.) ;
  48. S0 = (S1 COUL 'BLEU') ET (S2 COUL 'ROUG') ;
  49. * TRAC S0 ;FIN ;
  50.  
  51. * FUSION
  52. PRE1 = 1.E-10 ;
  53. PLIGS = S1 POIN 'DROI' P0 (1. 0.) ;
  54. PLIGS = (COOR 1 PLIGS) POIN 'EGSUPE' (0. - PRE1) ;
  55. PLIGI = S2 POIN 'DROI' P0 (1. 0.) ;
  56. PLIGI = (COOR 1 PLIGI) POIN 'EGSUPE' (0. - PRE1) ;
  57. ELIM PLIGS PLIGI PRE1 ;
  58.  
  59. * LEVRES ET FRONT
  60. CON0 = CONT S0 ;
  61. PLEVS = S1 POIN 'DROI' P0 (1. 0.) ;
  62. PLEVS = (COOR 1 PLEVS) POIN 'EGINFE' PRE1 ;
  63. LVSUP = CON0 ELEM 'APPUYE' PLEVS ;
  64. PLEVI = S2 POIN 'DROI' P0 (1. 0.) ;
  65. PLEVI = (COOR 1 PLEVI) POIN 'EGINFE' PRE1 ;
  66. LVINF = CON0 ELEM 'APPUYE' PLEVI ;
  67. FRON1 = INTE (CHAN 'POI1' LVSUP) (CHAN 'POI1' LVINF) ;
  68. FRON1 = FRON1 POIN 1 ;
  69.  
  70.  
  71. * III - MODELE ET MATERIAU
  72. * ------------------------
  73.  
  74. MOD1 = MODE S0 'MECANIQUE' 'ELASTIQUE' ;
  75. MAT1 = MATE MOD1 'YOUN' MYOU 'NU' POI ;
  76.  
  77.  
  78. * IV - CONDITIONS AUX LIMITES POUR LES 2 MODES
  79. * --------------------------------------------
  80.  
  81. T_CHAR = TABL ;
  82. T_DEPL = TABL ;
  83.  
  84. * IV.1 - EFFORTS DONNES
  85. * *********************
  86.  
  87. * PREPARATIFS
  88. CEXT = DIFF CON0 (LVSUP ET LVINF) ;
  89. SEXT = S0 ELEM 'APPUYE' 'LARGEMENT' CON0 ;
  90. MOD2 = REDU MOD1 SEXT ;
  91. X Y = COOR SEXT ;
  92. X Y = (CHAN 'CHAM' X MOD2 'STRESSES') (CHAN 'CHAM' Y MOD2 'STRESSES') ;
  93. TETA = CHAN (ATG Y (X + 1.E-30)) 'TYPE' 'SCALAIRE' ;
  94. RAY1 = (((X)**2) + ((Y)**2))**0.5 ;
  95. RAY1 = CHAN RAY1 'TYPE' 'SCALAIRE' ;
  96. PREF = 1. / ((2*PI*RAY1)**0.5) ;
  97. COS05 = COS (TETA/2) ;
  98. SIN05 = SIN (TETA/2) ;
  99. COS15 = COS (3*TETA/2) ;
  100. SIN15 = SIN (3*TETA/2) ;
  101. SIG0 = ZERO MOD2 'CONTRAIN' ;
  102.  
  103. * MODE I :
  104. SXX = PREF*(COS05*(1.-(SIN05*SIN15))) ;
  105. SXY = PREF*(COS05*SIN05*COS15) ;
  106. SYY = PREF*(COS05*(1.+(SIN05*SIN15))) ;
  107. SZZ = POI * (SXX + SYY) ;
  108. SIG1 = SIG0 + (NOMC 'SMXX' SXX) + (NOMC 'SMXY' SXY) + (NOMC 'SMYY' SYY)
  109. + (NOMC 'SMZZ' SZZ) ;
  110. T_CHAR.'I' = REDU (BSIG MOD2 SIG1) CEXT ;
  111.  
  112. * MODE II :
  113. SXX = PREF*(0. - (SIN05*(2.+(COS05*COS15)))) ;
  114. SXY = PREF*(COS05*(1.-(SIN05*SIN15))) ;
  115. SYY = PREF*(SIN05*COS05*COS15) ;
  116. SZZ = POI * (SXX + SYY) ;
  117. SIG1 = SIG0 + (NOMC 'SMXX' SXX) + (NOMC 'SMXY' SXY) + (NOMC 'SMYY' SYY)
  118. + (NOMC 'SMZZ' SZZ) ;
  119. T_CHAR.'II' = REDU (BSIG MOD2 SIG1) CEXT ;
  120.  
  121.  
  122. * IV.2 - DEPLACEMENT ANALYTIQUE
  123. * *****************************
  124.  
  125. * PREPARATIFS
  126. X Y = COOR S0 ;
  127. LSUP = (COOR 1 PLEVS) POIN 'EGINFE' (0. - PRE1) ;
  128. LINF = (COOR 1 PLEVI) POIN 'EGINFE' (0. - PRE1) ;
  129. Y = Y + ((COOR 2 LSUP) + 1.E-30) + ((COOR 2 LINF) - 1.E-30) ;
  130. TETA = ATG Y (X + 1.E-30) ;
  131. RAY1 = (((X)**2) + ((Y)**2))**0.5 ;
  132. PREF = (RAY1/(2*PI))**0.5 ;
  133. COS05 = COS (TETA/2) ;
  134. SIN05 = SIN (TETA/2) ;
  135. XI0 = CHAN 'CHPO' MOD1 (ZERO MOD1 'DEPLACEM') ;
  136.  
  137. * MODE I :
  138. XIX = PREF/(2.*MU)*(COS05*(KAPPA - 1. + (2.*(SIN05**2)))) ;
  139. XIY = PREF/(2.*MU)*(SIN05*(KAPPA + 1. - (2.*(COS05**2)))) ;
  140. T_DEPL.'I' = XI0 + (NOMC 'UX' XIX) + (NOMC 'UY' XIY) ;
  141.  
  142. * MODE II :
  143. XIX = PREF/(2.*MU)*(SIN05*(KAPPA + 1. + (2.*(COS05**2)))) ;
  144. XIY = PREF/(2.*MU)*(0. - (COS05*(KAPPA - 1. - (2.*(SIN05**2))))) ;
  145. T_DEPL.'II' = XI0 + (NOMC 'UX' XIX) + (NOMC 'UY' XIY) ;
  146.  
  147.  
  148. * V - APPEL A G_THETA
  149. * -------------------
  150.  
  151. * CREATION DE LA TABLE
  152. SUPTAB = TABL ;
  153. SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
  154. SUPTAB.'FRONT_FISSURE' = FRON1 ;
  155. SUPTAB.'MODELE' = MOD1 ;
  156. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  157. SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
  158. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  159. SUPTAB.'COUCHE' = 4 ;
  160.  
  161. * APPELS A G_THETA
  162. GTAB = TABL ;
  163. REPE IMOD 2 ;
  164. MMOD = EXTR 'II' 1 &IMOD ;
  165. TAB1 = COPI SUPTAB ;
  166. TAB1.'SOLUTION_RESO' = T_DEPL.MMOD ;
  167. TAB1.'CHARGEMENTS_MECANIQUES' = T_CHAR.MMOD ;
  168. G_THETA TAB1 ;
  169. GTAB.MMOD = TAB1 ;
  170. FIN IMOD ;
  171.  
  172. * CALCUL DES ERREURS
  173. SAUT 'LIGNE' ;
  174. REPE IMOD 2 ;
  175. * ON ITERE SUR CHAQUE CHAMP DE DEPLACEMENT UTILISE
  176. MMOD = EXTR 'II' 1 &IMOD ;
  177. MESS 'SOLUTION EN MODE' ' ' MMOD ' :' ;
  178. SAUT 'LIGNE' ;
  179. TAB1 = GTAB.MMOD ;
  180. REPE JMOD 2 ;
  181. * ET ON ITERE SUR LES 2 MODES
  182. MMOD = EXTR 'II' 1 &JMOD ;
  183. KNUM = EXTR TAB1.'CHPO_RESULTATS' 'VALE' (CHAI 'K' &JMOD) FRON1 ;
  184. KNUM = EXTR KNUM 1 ;
  185. SI (EGA &IMOD &JMOD) ;
  186. * SI LE MODE CORRESPOND A CELUI DU CHAMP ANALYTIQUE ON DOIT TROUVER K=1
  187. KANA = 1. ;
  188. SINON ;
  189. * SINON ON DOIT TROUVER K=0
  190. KANA = 0 ;
  191. FINSI ;
  192. * ON CALCULE L'ERREUR
  193. ERR1 = ABS (KANA - KNUM) ;
  194. MESS 'ERREUR SUR LE CALCUL DE K' MMOD ' :'*30 ERR1 ;
  195. CRI1 = 1.E-3 ;
  196. SI (ERR1 >EG CRI1) ;
  197. MESS 'ERREUR : L''ERREUR SUR K' MMOD ' DEPASSE LE CRITERE' ;
  198. MESS ' POUR LE CHAMP ANALYTIQUE EN MODE' ' ' &IMOD ;
  199. ERRE 5 ;
  200. FINSI ;
  201. FIN JMOD ;
  202. SAUT 'LIGNE' ;
  203. FIN IMOD ;
  204.  
  205. FIN ;
  206.  
  207.  
  208.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales