Télécharger g_decouplage_2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : g_decouplage_2.dgibi
  2. ****************************************************
  3. ****************************************************
  4. * *
  5. * VERIFICATION DE LA PROCEDURE G_THETA *
  6. * POUR LE CALCUL DES FIC POUR UNE FISSURE *
  7. * PENNY-SHAPED DANS UN CYLINDRE *
  8. * - *
  9. * VERIFICATION DU CALCUL DES 3 FIC VIA *
  10. * DECOUPLAGE EN 3D AVEC UNE SOLUTION ANALYTIQUE *
  11. * *
  12. * SOLUTION ANALYTIQUE TIREE DE : *
  13. * "PENNY-SHAPED CRACKS", GUIDERA ET LARDNER 1974 *
  14. * *
  15. ****************************************************
  16.  
  17. * I - CALCUL 3D COMPLET
  18. * ---------------------
  19.  
  20. OPTI 'DIME' 3 'ELEM' 'CUB8' ;
  21. BTRAC = FAUX ;
  22.  
  23. * MAILLAGE AUTOUR DE LA FISSURE
  24. L1 H1 LP = 10. 5. 5. ;
  25. L2 = L1 + 10. ;
  26. H2 = H1 + 5. ;
  27. DENS1 = 1. ;
  28. DENS DENS1 ;
  29.  
  30. P1 = DENS1 0. 0. ;
  31. P2 = DENS1 H1 0. ;
  32. P3 = L1 H1 0. ;
  33. P4 = L1 0. 0. ;
  34. D1 = DROI P1 P2 ;
  35. S1 = D1 TRAN ((0.-DENS1) 0. 0.) ;
  36. N1 = ((ENTI ((L1 - DENS1) / DENS1)) / 2) * 2 ;
  37. D2 = DROI N1 P2 P3 ;
  38. D3 = DROI P3 P4 ;
  39.  
  40. P5 = (LP - DENS1) 0. 0. ;
  41. P6 = (LP - DENS1) DENS1 0. ;
  42. P7 = (LP + DENS1) DENS1 0. ;
  43. P8 = (LP + DENS1) 0. 0. ;
  44. D4 = DROI (NBEL D1) P5 P6 ;
  45. D5 = DROI (NBEL D2) P6 P7 ;
  46. D6 = DROI (NBEL D3) P7 P8 ;
  47. DENS2 = DENS1 / H1 ;
  48. S2 = (D1 ET D2 ET D3) REGL (D4 ET D5 ET D6) 'DINI' DENS1 'DFIN' DENS2 ;
  49.  
  50. PP = LP 0. 0. ;
  51. D7 = DROI (N1/2) (DROI (N1/2) P8 PP) P5 ;
  52. S3 = DALL D4 D5 D6 D7 'PLAN' ;
  53. SURF1 = S1 ET S2 ET S3 ;
  54.  
  55. PSUP = (COOR 2 SURF1) POIN 'MAXI' ;
  56. ELSUP = (CONT SURF1) ELEM 'APPUYE' PSUP ;
  57. S4 = ELSUP TRAN (0. (H2 - H1) 0.) ;
  58. SURF1 = SURF1 ET S4 ;
  59. PDROI = (COOR 1 SURF1) POIN 'MAXI' ;
  60. ELDROI = (CONT SURF1) ELEM 'APPUYE' PDROI ;
  61. S5 = ELDROI TRAN ((L2 - L1) 0. 0.) ;
  62. SURF1 = SURF1 ET S5 ;
  63.  
  64. NFRON = 18 ;
  65. VOLU1 = SURF1 VOLU NFRON 'ROTA' 360. (0. 1. 0.) (0. 0. 0.) ;
  66. ELIM VOLU1 1.E-10 ;
  67. VOLU1 = REGE VOLU1 ;
  68. VOLU2 = VOLU1 SYME 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  69. OMEGA1 = VOLU1 ET VOLU2 ;
  70.  
  71. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  72. * PARTIE SUP
  73. ENVE1 = ENVE VOLU1 ;
  74. POIN1 = (COOR 2 ENVE1) POIN 'MINI' ;
  75. ELEM1 = ENVE1 ELEM 'APPUYE' POIN1 ;
  76. R1 = (((COOR 1 ELEM1)**2) + ((COOR 3 ELEM1)**2))**0.5 ;
  77. POIN1 = R1 POIN 'EGINFE' (LP + 0.02) ;
  78. LVSUP = ELEM1 ELEM 'APPUYE' POIN1 ;
  79. LIGSUP = ELEM1 DIFF LVSUP ;
  80. * PARTIE INF
  81. ENVE2 = ENVE VOLU2 ;
  82. POIN2 = (COOR 2 ENVE2) POIN 'MAXI' ;
  83. ELEM2 = ENVE2 ELEM 'APPUYE' POIN2 ;
  84. R2 = (((COOR 1 ELEM2)**2) + ((COOR 3 ELEM2)**2))**0.5 ;
  85. POIN2 = R2 POIN 'EGINFE' (LP + 0.02) ;
  86. LVINF = ELEM2 ELEM 'APPUYE' POIN2 ;
  87. LIGINF = ELEM2 DIFF LVINF ;
  88. * ELIMINATION
  89. ELIM LIGSUP LIGINF 1.E-10 ;
  90. * DEFINITION DU FRONT DE FISSURE
  91. FRONFISS = (CONT LIGSUP) INTE (CONT LVSUP) ;
  92. SI BTRAC ;
  93. TRAC SURF1 ;
  94. TRAC 'CACH' (VOLU1 ET (LVSUP COUL 'ROUG') ET (LIGSUP COUL 'VERT')) ;
  95. FINSI ;
  96.  
  97. * MODELE ET MATERIAU
  98. MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
  99. YOUN1 NU1 = 2.E5 0.3 ;
  100. MAT1 = MATE MOD1 'YOUN' YOUN1 'NU' NU1 ;
  101. RIG1 = RIGI MOD1 MAT1 ;
  102.  
  103. * CL EN EFFORTS
  104. SIG0 = ZERO MOD1 'CONTRAIN' ;
  105. SIG1 = MANU 'CHML' MOD1 'SMYY' 1. 'SMXY' 1. 'STRESSES' ;
  106. SIG2 = SIG0 + SIG1 ;
  107. DOMEGA1 = ENVE OMEGA1 ;
  108. DOMEGA1 = DIFF DOMEGA1 (LVSUP ET LVINF) ;
  109. T1 = REDU (BSIG MOD1 SIG2) DOMEGA1 ;
  110.  
  111. * CL EN DEPLACEMENTS
  112. PSUP = (COOR 2 DOMEGA1) POIN 'MAXI' ;
  113. P1 = PSUP POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
  114. PINF = (COOR 2 DOMEGA1) POIN 'MINI' ;
  115. P2 = PINF POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
  116. PMIL = DOMEGA1 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  117. P3 = (COOR 1 PMIL) POIN 'MAXI' ;
  118. P4 = (COOR 1 PMIL) POIN 'MINI' ;
  119. BLOQ1 = BLOQ (MOTS 'UX' 'UZ') (P1 ET P2) ;
  120. BLOQ3 = BLOQ 'UZ' P3 ;
  121. RELA3 = RELA 'UY' P3 + 'UY' P4 ;
  122. BLOQ0 = BLOQ1 ET BLOQ3 ET RELA3 ;
  123.  
  124. * RESO
  125. U1 = RESO (RIG1 ET BLOQ0) T1 ;
  126.  
  127. * G_THETA
  128. SUPTAB = TABL ;
  129. SUPTAB.'MODELE' = MOD1 ;
  130. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  131. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  132. SUPTAB.'CHARGEMENTS_MECANIQUES' = T1 ;
  133. SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
  134. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  135. SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
  136. SUPTAB.'COUCHE' = 4 ;
  137. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  138. SUPTAB.'SOLUTION_RESO' = U1 ;
  139.  
  140. G_THETA SUPTAB ;
  141.  
  142. K3D = TABL ;
  143. REPE IMOD 3 ;
  144. MMOD = EXTR 'III' 1 &IMOD ;
  145. K3D.MMOD = PROG ;
  146. KSUPTAB = SUPTAB.'RESULTATS'.MMOD ;
  147. IND1 = INDE KSUPTAB ;
  148. NFRON = (DIME IND1) - 1 ;
  149. REPE IFRON NFRON ;
  150. PFRON = IND1.&IFRON ;
  151. K3D.MMOD = K3D.MMOD ET (PROG KSUPTAB.PFRON) ;
  152. FIN IFRON ;
  153. FIN IMOD ;
  154.  
  155.  
  156. * II - SOLUTION ANALYTIQUE
  157. * ------------------------
  158.  
  159. KANA = TABL ;
  160. NFISS = NBNO FRONFISS ;
  161. KIANA = 2. / PI * ((PI * LP)**0.5) ;
  162. KANA.'I' = PROG NFISS * KIANA ;
  163. X = PROG ;
  164. Z = PROG ;
  165. IND1 = INDE SUPTAB.'RESULTATS'.'II' ;
  166. NFRON = (DIME IND1) - 1 ;
  167. REPE IFRON NFRON ;
  168. PFRON = IND1.&IFRON ;
  169. X = X ET (PROG (COOR 1 PFRON)) ;
  170. Z = Z ET (PROG (COOR 3 PFRON)) ;
  171. FIN IFRON ;
  172. COSTH = X / (((X**2) + (Z**2))**0.5) ;
  173. SINTH = Z / (((X**2) + (Z**2))**0.5) ;
  174. KANA.'II' = 2. / PI * ((PI * LP)**0.5) * (2./(2.-NU1)) * COSTH ;
  175. KANA.'III' = 2. / PI * ((PI * LP)**0.5) * (2.*(1.-NU1)/(2.-NU1)) * SINTH ;
  176.  
  177. SI BTRAC ;
  178. PROG1 = PROG 1 PAS 1 NFISS ;
  179. REPE IMOD 3 ;
  180. MMOD = EXTR 'III' 1 &IMOD ;
  181. EVO1 = EVOL 'BLEU' 'MANU' PROG1 KANA.MMOD ;
  182. EVO2 = EVOL 'MANU' PROG1 K3D.MMOD ;
  183. DESS (EVO1 ET EVO2) ;
  184. FIN IMOD ;
  185. FINSI ;
  186.  
  187.  
  188. * III - COMPARAISON
  189. * -----------------
  190.  
  191. ACCEPT = TABL ;
  192. ACCEPT.'I' ACCEPT.'II' ACCEPT.'III' = 0.025 0.2 0.45 ;
  193. REPE IMOD 3 ;
  194. MMOD = EXTR 'III' 1 &IMOD ;
  195. CRIT1 = MAXI (K3D.MMOD - KANA.MMOD) 'ABS' ;
  196. CMAX1 = MAXI KANA.MMOD 'ABS' ;
  197. MESS 'ERREUR RELATIVE = ' (CRIT1 / CMAX1 * 100.) '%' ;
  198. SI (CRIT1 > (CMAX1 * ACCEPT.MMOD)) ;
  199. MESS 'LA SOLUTION NUMERIQUE EST TROP ELOIGNEE DE LA SOLUTION' ;
  200. MESS 'ANALYTIQUE POUR LE CALCUL DU FIC EN MODE' ' ' MMOD ;
  201. ERRE 5 ;
  202. FINSI ;
  203. FIN IMOD ;
  204.  
  205. FIN ;
  206.  
  207.  
  208.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales