Télécharger la plaquette Cast3M


fr en

Télécharger g_decouplage_1.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : g_decouplage_1.dgibi
  2. ****************************************************
  3. ****************************************************
  4. *                                                  *
  5. *      VERIFICATION DE LA PROCEDURE G_THETA        *
  6. *    POUR LE CALCUL DES FIC POUR UNE FISSURE       *
  7. *         PENNY-SHAPED DANS UN CYLINDRE            *
  8. *                        -                         *
  9. *  VERIFICATION DU CALCUL DE KI VIA DECOUPLAGE     *
  10. *        EN 3D ET 2D AXISYMETRIQUE AVEC UNE        *
  11. *            SOLUTION ANALYTIQUE                   *
  12. *                                                  *
  13. *  SOLUTION ANALYTIQUE TIREE DE :                  *
  14. *  "THE STRESS ANALYSIS OF CRACKS HANDBOOK"        * 
  15. *  TADA, PARIS AND IRWIN (2000)                    *
  16. *                                                  *
  17. ****************************************************
  18.  
  19. * I - CALCUL 3D COMPLET
  20. * ---------------------
  21.  
  22. * OPTIONS ET BOOLEEN POUR LES TRACERS
  23. OPTI 'DIME' 3 'ELEM' 'CUB8' ;
  24. BTRAC = FAUX ;
  25.  
  26. * MAILLAGE AUTOUR DE LA FISSURE
  27. L1 H1 LP = 10. 5. 5. ;
  28. L2 = L1 + 10. ;
  29. H2 = H1 + 20. ;
  30. DENS1 = 1. ;
  31. DENS DENS1 ;
  32.  
  33. P1 = DENS1 0. 0. ;
  34. P2 = DENS1 H1 0. ;
  35. P3 = L1 H1 0. ;
  36. P4 = L1 0. 0. ;
  37. D1 = DROI P1 P2 ;
  38. S1 = D1 TRAN ((0.-DENS1) 0. 0.) ;
  39. N1 = ((ENTI ((L1 - DENS1) / DENS1)) / 2) * 2 ;
  40. D2 = DROI N1 P2 P3 ;
  41. D3 = DROI P3 P4 ;
  42.  
  43. P5 = (LP - DENS1) 0. 0. ;
  44. P6 = (LP - DENS1) DENS1 0. ;
  45. P7 = (LP + DENS1) DENS1 0. ;
  46. P8 = (LP + DENS1) 0. 0. ;
  47. D4 = DROI (NBEL D1) P5 P6 ;
  48. D5 = DROI (NBEL D2) P6 P7 ;
  49. D6 = DROI (NBEL D3) P7 P8 ;
  50. DENS2 = DENS1 / H1 ;
  51. S2 = (D1 ET D2 ET D3) REGL (D4 ET D5 ET D6) 'DINI' DENS1 'DFIN' DENS2 ;
  52.  
  53. PP = LP 0. 0. ;
  54. D7 = DROI (N1/2) (DROI (N1/2) P8 PP) P5 ;
  55. S3 = DALL D4 D5 D6 D7 'PLAN' ;
  56. SURF1 = S1 ET S2 ET S3 ;
  57.  
  58. PSUP = (COOR 2 SURF1) POIN 'MAXI' ;
  59. ELSUP = (CONT SURF1) ELEM 'APPUYE' PSUP ;
  60. S4 = ELSUP TRAN (0. (H2 - H1) 0.) ;
  61. SURF1 = SURF1 ET S4 ;
  62. PDROI = (COOR 1 SURF1) POIN 'MAXI' ;
  63. ELDROI = (CONT SURF1) ELEM 'APPUYE' PDROI ;
  64. S5 = ELDROI TRAN ((L2 - L1) 0. 0.) ;
  65. SURF1 = SURF1 ET S5 ;
  66.  
  67. NFRON = 18 ;
  68. VOLU1 = SURF1 VOLU NFRON 'ROTA' 360. (0. 1. 0.) (0. 0. 0.) ;
  69. ELIM VOLU1 1.E-10 ;
  70. VOLU1 = REGE VOLU1 ;
  71. VOLU2 = VOLU1 SYME 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  72. OMEGA1 = VOLU1 ET VOLU2 ;
  73.  
  74. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  75. * PARTIE SUP
  76. ENVE1 = ENVE VOLU1 ;
  77. POIN1 = (COOR 2 ENVE1) POIN 'MINI' ;
  78. ELEM1 = ENVE1 ELEM 'APPUYE' POIN1 ;
  79. R1 = (((COOR 1 ELEM1)**2) + ((COOR 3 ELEM1)**2))**0.5 ;
  80. POIN1 = R1 POIN 'EGINFE' (LP + 0.02) ;
  81. LVSUP = ELEM1 ELEM 'APPUYE' POIN1 ;
  82. LVSUP = ORIE LVSUP 'POIN' (0. 1. 0.) ;
  83. LIGSUP = ELEM1 DIFF LVSUP ;
  84. * PARTIE INF
  85. ENVE2 = ENVE VOLU2 ;
  86. POIN2 = (COOR 2 ENVE2) POIN 'MAXI' ;
  87. ELEM2 = ENVE2 ELEM 'APPUYE' POIN2 ;
  88. R2 = (((COOR 1 ELEM2)**2) + ((COOR 3 ELEM2)**2))**0.5 ;
  89. POIN2 = R2 POIN 'EGINFE' (LP + 0.02) ;
  90. LVINF = ELEM2 ELEM 'APPUYE' POIN2 ;
  91. LVINF = ORIE LVINF 'POIN' (0. (-1.) 0.) ;
  92. LIGINF = ELEM2 DIFF LVINF ;
  93. * ELIMINATION
  94. ELIM LIGSUP LIGINF 1.E-10 ;
  95. * DEFINITION DU FRONT DE FISSURE
  96. FRONFISS = (CONT LIGSUP) INTE (CONT LVSUP) ;
  97. SI BTRAC ;
  98.     TRAC SURF1 ;
  99.     TRAC 'CACH' (VOLU1 ET (LVSUP COUL 'ROUG') ET (LIGSUP COUL 'VERT')) ;
  100. FINSI ;
  101.  
  102. * MODELE ET MATERIAU
  103. MOD1 = MODE OMEGA1 'MECANIQUE' 'ELASTIQUE' ;
  104. YOUN1 NU1 = 2.E5 0.3 ;
  105. MAT1 = MATE MOD1 'YOUN' YOUN1 'NU' NU1 ;
  106. RIG1 = RIGI MOD1 MAT1 ;
  107.  
  108. * CL EN EFFORTS
  109. SIG0 = ZERO MOD1 'CONTRAIN' ;
  110. SIG1 = MANU 'CHML' MOD1 'SMYY' 1. 'STRESSES' ;
  111. SIG2 = SIG0 + SIG1 ;
  112. DOMEGA1 = ENVE OMEGA1 ;
  113. DOMEGA1 = DIFF DOMEGA1 (LVSUP ET LVINF) ;
  114. T1 = REDU (BSIG MOD1 SIG2) DOMEGA1 ;
  115.  
  116. * CL EN DEPLACEMENTS
  117. PSUP = (COOR 2 DOMEGA1) POIN 'MAXI' ;
  118. P1 = PSUP POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
  119. PINF = (COOR 2 DOMEGA1) POIN 'MINI' ;
  120. P2 = PINF POIN 'DROIT' (0. 0. 0.) (0. 1. 0.) ;
  121. PMIL = DOMEGA1 POIN 'PLAN' (0. 0. 0.) (1. 0. 0.) (0. 0. 1.) ;
  122. P3 = (COOR 1 PMIL) POIN 'MAXI' ;
  123. P4 = (COOR 1 PMIL) POIN 'MINI' ;
  124. BLOQ1 = BLOQ (MOTS 'UX' 'UZ') (P1 ET P2) ;
  125. BLOQ3 = BLOQ 'UZ' P3 ;
  126. RELA3 = RELA 'UY' P3 + 'UY' P4 ;
  127. BLOQ0 = BLOQ1 ET BLOQ3 ET RELA3 ;
  128.  
  129. * RESO
  130. U1 = RESO (RIG1 ET BLOQ0) T1 ;
  131.  
  132. * G_THETA
  133. SUPTAB = TABL ;
  134. SUPTAB.'MODELE' = MOD1 ;
  135. SUPTAB.'CARACTERISTIQUES' = MAT1 ;
  136. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  137. SUPTAB.'CHARGEMENTS_MECANIQUES' = T1 ;
  138. SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
  139. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  140. SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
  141. SUPTAB.'COUCHE' = 3 ;
  142. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  143. SUPTAB.'SOLUTION_RESO' = U1 ;
  144.  
  145. G_THETA SUPTAB ;
  146.  
  147. KI3D = PROG ;
  148. KSUPTAB = SUPTAB.'RESULTATS'.'I' ;
  149. IND1 = INDE KSUPTAB ;
  150. REPE IFRON NFRON ;
  151.     PFRON = IND1.&IFRON ;
  152.     KI3D = KI3D ET (PROG KSUPTAB.PFRON) ;
  153. FIN IFRON ;
  154.  
  155.  
  156. * II - CALCUL 2D AXISYMETRIQUE
  157. * ----------------------------
  158.  
  159. OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA4' ;
  160.  
  161. * H3 = H2 + 20. ;
  162.  
  163. * PSUP = (COOR 2 SURF1) POIN 'MAXI' ;
  164. * ELSUP = (CONT SURF1) ELEM 'APPUYE' PSUP ;
  165. * S4 = ELSUP TRAN (0. (H3 - H2)) ;
  166. * SURF1 = SURF1 ET S4 ;
  167.  
  168. SURF2 = SURF1 SYME 'DROI' (0. 0.) (1. 0.) ;
  169. OMEGA2 = SURF1 ET SURF2 ;
  170.  
  171. * DEFINITION DE LA FISSURE ET FUSION DES NOEUDS COINCIDENTS
  172. C1 = CONT SURF1 ;
  173. POIN1 = (COOR 2 C1) POIN 'MINI' ;
  174. ELEM1 = C1 ELEM 'APPUYE' POIN1 ;
  175. POIN1 = (COOR 1 POIN1) POIN 'EGINFE' LP ;
  176. LVSUP = C1 ELEM 'APPUYE' POIN1 ;
  177. LIGSUP = ELEM1 DIFF LVSUP ;
  178. C2 = CONT SURF2 ;
  179. POIN2 = (COOR 2 C2) POIN 'MAXI' ;
  180. ELEM2 = C2 ELEM 'APPUYE' POIN2 ;
  181. POIN2 = (COOR 1 POIN2) POIN 'EGINFE' LP ;
  182. LVINF = C2 ELEM 'APPUYE' POIN2 ;
  183. LIGINF = ELEM2 DIFF LVINF ;
  184. ELIM LIGSUP LIGINF 1.E-10 ;
  185. SI BTRAC ;
  186.     TRAC (OMEGA2 ET (LVSUP COUL 'ROUG')) ;
  187. FINSI ;
  188.  
  189. * DEFINITION DU FRONT DE FISSURE
  190. FRONFISS = ((COOR 1 LVSUP) POIN 'MAXI') POIN 1 ;
  191.  
  192. * MODELE ET MATERIAU
  193. MOD2 = MODE OMEGA2 'MECANIQUE' 'ELASTIQUE' ;
  194. MAT2 = MATE MOD2 'YOUN' YOUN1 'NU' NU1 ;
  195. RIG2 = RIGI MOD2 MAT2 ;
  196.  
  197. * CL EN EFFORTS
  198. SIG0 = ZERO MOD2 'CONTRAIN' ;
  199. SIG1 = MANU 'CHML' MOD2 'SMZZ' 1. 'STRESSES' ;
  200. SIG2 = SIG0 + SIG1 ;
  201. DOMEGA2 = CONT OMEGA2 ;
  202. DOMEGA2 = DIFF DOMEGA2 (LVSUP ET LVINF) ;
  203. T2 = REDU (BSIG MOD2 SIG2) DOMEGA2 ;
  204.  
  205. * CL EN DEPLACEMENTS
  206. ZOM = COOR 2 OMEGA2 ;
  207. PSUP = ZOM POIN 'MAXI' ;
  208. P1 = PSUP POIN 'DROIT' (0. 0.) (0. 1.) ;
  209. PINF = ZOM POIN 'MINI' ;
  210. P2 = PINF POIN 'DROIT' (0. 0.) (0. 1.) ;
  211. RELA1 = RELA 'UZ' P1 + 'UZ' P2 ;
  212. BLOQ0 = RELA1 ;
  213.  
  214. * RESO
  215. U2 = RESO (RIG2 ET BLOQ0) T2 ;
  216.  
  217. * G_THETA
  218. SUPTAB = TABL ;
  219. SUPTAB.'MODELE' = MOD2 ;
  220. SUPTAB.'CARACTERISTIQUES' = MAT2 ;
  221. SUPTAB.'BLOCAGES_MECANIQUES' = BLOQ0 ;
  222. SUPTAB.'CHARGEMENTS_MECANIQUES' = T2 ;
  223. SUPTAB.'OBJECTIF' = MOT 'DECOUPLAGE' ;
  224. SUPTAB.'LEVRE_SUPERIEURE' = LVSUP ;
  225. SUPTAB.'LEVRE_INFERIEURE' = LVINF ;
  226. SUPTAB.'COUCHE' = 3 ;
  227. SUPTAB.'FRONT_FISSURE' = FRONFISS ;
  228. SUPTAB.'SOLUTION_RESO' = U2 ;
  229.  
  230. G_THETA SUPTAB ;
  231. KI2D = PROG NFRON * (SUPTAB.'RESULTATS'.'I') ;
  232.  
  233.  
  234. * III - SOLUTION ANALYTIQUE
  235. * -------------------------
  236.  
  237. A B = LP L2 ;
  238. P = PI * (B**2) ;
  239. SNET = P / (PI * ((B**2) - (A**2))) ;
  240. ASB = A / B ;
  241. GASB = 2. / PI * (1. + (0.5 * ASB) - (5./8. * (ASB**2)) + (0.421 * (ASB**3))) ;
  242. F1ASB = GASB * ((1. - ASB)**0.5) ;
  243. KIANA = SNET * ((PI * A)**0.5) * F1ASB ;
  244. MESS 'SOLUTION ANALYTIQUE :' KIANA ;
  245. KIANA = PROG NFRON * KIANA ;
  246.  
  247.  
  248. * IV - COMPARAISON
  249. * ----------------
  250.  
  251. KINUM = TABL ;
  252. KINUM.'2D' = KI2D ;
  253. KINUM.'3D' = KI3D ;
  254. ACCEPT = 3.E-2 ;
  255. CMAX1 = MAXI KIANA 'ABS' ;
  256. DIM = 2 ;
  257. REPE I 2 ;
  258.     MDIM = CHAI DIM 'D' ;
  259.     CRIT1 = MAXI (KINUM.MDIM - KIANA) 'ABS' ;
  260.     MESS 'ERREUR RELATIVE SUR KI EN' ' ' MDIM ' :' (CRIT1 / CMAX1 * 100.) '%' ;
  261.     SI (CRIT1 > (CMAX1*ACCEPT)) ;
  262.         MESS 'LA SOLUTION' ' ' MDIM ' EST TROP ELOIGNEE DE LA SOLUTION' ;
  263.         MESS 'ANALYTIQUE POUR LE CALCUL DU FIC EN MODE I' ;
  264.         ERRE 5 ;
  265.     FINSI ;
  266.     DIM = DIM + 1 ;
  267. FIN I ;
  268.  
  269. FIN ;
  270.  
  271.  
  272.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales