Télécharger g_c_etoile_coque_1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : g_c_etoile_coque_1.dgibi
  2. ****************************************************
  3. ****************************************************
  4. * *
  5. * VALIDATION DE LA PROCEDURE G_THETA *
  6. * POUR UN DEFAUT CIRCONFERENTIEL TRAVERSANT *
  7. * DANS UN TUYAU MODELISE AVEC DES ELEMENTS COQUES *
  8. * SOLUTION DE REFERENCE : Ductile Fracture *
  9. * Handbook, A. Zahoor *
  10. * *
  11. * *
  12. * GEOMETRIE : tube *
  13. * *
  14. * longueur du tube : 3000. MM *
  15. * epaisseur du tube : 17.5 MM *
  16. * rayon moyen du tube : 350. MM *
  17. * longueur de la fissure : 50. MM *
  18. * *
  19. * MATERIAU : loi de Norton *
  20. * *
  21. * Module d'Young : 2.E5 MPa *
  22. * Coefficient de poisson : 0.3 *
  23. * Coefficient N (Norton) : 7 *
  24. * Coefficient A (Norton) : 3.E-24 /h/MPa^7 *
  25. * *
  26. * CHARGEMENT : *
  27. * *
  28. * Traction pure : 240.78 MPa *
  29. * *
  30. * SOLUTION ANALYTIQUE (APPROCHEE) : *
  31. * *
  32. * Intégrale C* *
  33. * C* = 2.025 kJ/m^2/h *
  34. * *
  35. ****************************************************
  36.  
  37. * VALIDATION COMPLETE OU JUSTE FONCTIONNEMENT
  38. VALIDATION = FAUX ;
  39.  
  40. * I - REALISATION DU CALCUL
  41. * -------------------------
  42.  
  43. * OPTIONS
  44. OPTI 'DIME' 3 'ELEM' 'TRI3' ;
  45.  
  46. * I.1 - MAILLAGE
  47. * **************
  48.  
  49. * GEOMETRIE :
  50. * R = RAYON
  51. * E = EPAISSEUR
  52. * L = LONGUEUR
  53. * AN = ANGLE TOTAL DE LA FISSURE (15° < AN < 150°)
  54.  
  55. R = 350. ;
  56. E = R/10. ;
  57. L = 3000. ;
  58. AN = 45. ;
  59.  
  60.  
  61. * MAILLAGE
  62. DENS1 = R/350. ;
  63. DENS (100.*DENS1) ;
  64. A = COS (AN/2.) ;
  65. B = SIN (AN/2.) ;
  66. VECT0 = (R/50.) 0. (B*R/(50.*A)) ;
  67. VECT1 = 10.*VECT0 ;
  68. C0 = 0. 0. 0. ;
  69. CI = 0. (L/10.) 0. ;
  70. CII = 0. (L/5.) 0. ;
  71. C1 = 0. L 0. ;
  72. P1 = R 0. 0. ;
  73. FF = (A*R) 0. (B*R) ;
  74. XCI = IPOL (PROG 15 20 60 90 120 150) (PROG 41 8 5 4 3 3) AN ;
  75. LIS1 = PROG 23. 40. 70. 120. XCI ;
  76. LEC1 = LECT 3 4 4 4 5 ;
  77. TF = TABL ;
  78. TL = TABL ;
  79. TP = TABL ;
  80. REPE I (DIME LIS1) ;
  81. FAC = EXTR LIS1 &I ;
  82. N1 = EXTR LEC1 &I ;
  83. A1 = (-1*R/FAC) 0. 0. ;
  84. A2 = 0. (R/FAC) 0. ;
  85. A3 = (R/FAC) 0. 0. ;
  86. TF.&I = ((CERC N1 A1 C0 A2 CERC N1 C0 A3) TOUR (90.-(AN/2.)) C0 CI)
  87. DEPL PLUS VECT1 ;
  88. TL.&I = TF.&I PROJ 'CYLI' VECT0 'CYLI' C0 CI P1 ;
  89. TP.(&I + 1) = TL.&I POIN 'FINAL' ;
  90. TP.(12 - &I) = TL.&I POIN 'INITIAL' ;
  91. FIN I ;
  92. P12 = (-1*R) 0. 0. ;
  93. P13 = (-1*R) (L/10.) 0. ;
  94. P14 = 0. (L/10.) R ;
  95. P15 = R (L/10.) 0. ;
  96. P16 = (-1*R) (L/5.) 0. ;
  97. P17 = 0. (L/5.) R ;
  98. P18 = R (L/5.) 0. ;
  99. P19 = (-1*R) L 0. ;
  100. P20 = 0. L R ;
  101. P21 = R L 0. ;
  102. XC5 = IPOL (PROG 15 20 60 90 120 150) (PROG 35 35 40 40 50 50) AN ;
  103. XC6 = IPOL (PROG 15 20 60 90 120 150) (PROG -1 -3 -4 -4 -5 -5) AN ;
  104. XC6 = ENTI XC6 ;
  105. LIMTF = (TP.(6) CERC XC6 C0 (INVE TL.(1)) 'DINI' (XC5*DENS1) 'DFIN' (30*DENS1))
  106. CERC XC6 C0 TL.(5) 'DINI' (30*DENS1) DFIN (XC5*DENS1) ;
  107. XC3 = IPOL (PROG 15 20 60 90 120 150) (PROG 2 2 4 5 5 5) AN ;
  108. LIMF = P1 CERC (ENTI XC3) C0 (INVE TL.(5)) ;
  109. XC4 = IPOL (PROG 15 20 60 90 120 150) (PROG 16 14 13 12 10 10) AN ;
  110. XC7 = IPOL (PROG 15 20 60 90 120 150) (PROG 3 20 20 30 30 33) AN ;
  111. LIMF = (LIMF CERC (ENTI (0. - XC4)) C0 P12 'DINI' (XC7*DENS1)
  112. 'DFIN' (160*DENS1)) DROI P13 CERC CI P14 CERC CI P15 ;
  113. XC2 = IPOL (PROG 15 20 60 90 120 150) (PROG 15 25 50 70 80 80) AN ;
  114. LIMF = LIMF ET (DROI -5 P15 P1 'DINI' (120*DENS1) 'DFIN' (XC2*DENS1)) ;
  115. SUF = LIMF SURF 'CYLI' C0 CI 'COUL' 'TURQ' ;
  116. Z1 = COUT TL.(4) FF 'COUL' 'ROUG' ;
  117. Z2 = COUT TL.(4) TL.(3) 'COUL' 'VERT' ;
  118. Z3 = COUT TL.(3) TL.(2) 'COUL' 'ROSE' ;
  119. Z4 = COUT TL.(2) TL.(1) 'COUL' 'ROUG' ;
  120. Z5 = LIMTF SURF 'CYLI' C0 CI 'COUL' 'BLEU' ;
  121. ZF = Z1 ET Z2 ET Z3 ET Z4 ET Z5 ;
  122. SUF = SUF ET ZF ;
  123. MIN = ((P15 CERC CI P14 CERC CI P13) TRAN 2 (0. (L/10.) 0.))
  124. TRAN 15 (0. (4.*(L/5.)) 0.) 'COUL' 'TURQ' ;
  125. TOUT = SUF ET MIN ;
  126. TOUT = ORIE TOUT 'POIN' (0. 0. 0.) ;
  127. LIG = COTE 3 MIN ;
  128. CONT1 = CONT TOUT ;
  129. LISY = ELEM CONT1 'COMP' FF P12 ;
  130. LIFI = ELEM CONT1 'COMP' FF P1 ;
  131. ELIM (TOUT ET LIG) 1.E-3 ;
  132. * TRAC 'QUAL' TOUT ;FIN ;
  133.  
  134.  
  135. * I.2 - MODELE ET MATERIAU
  136. * ************************
  137.  
  138. * PROPRIETES :
  139. * MYOUN = MODULE D'YOUNG
  140. * NU1 = COEFFICIENT DE POISSON
  141. * AF1, AF2, AF3 = COEFFICIENTS DE NORTON
  142.  
  143. MYOUN = 2.E5 ;
  144. NU1 = 0.3 ;
  145. AF1 = 3.E-23 ;
  146. AF2 = 7. ;
  147. AF3 = 1. ;
  148.  
  149. * MODELE MULTICOUCHE
  150. * ELEMENT POUR LE MODELE MULTICOUCHE
  151. IELEM = 268 ;
  152. ELEFIS = TOUT ELEM 'TRI3' IELEM ;
  153. * EPAISSEUR TOTALE
  154. EPAI_T = E ;
  155. * NOMBRE DE COUCHES ET LEUR EPAISSEUR
  156. NB_COU = 13 ;
  157. EPAI_C = EPAI_T * 1.E-6 ;
  158. * CREATION DU MODELE MULTICOUCHE
  159. EPAI_I = (EPAI_T - (EPAI_C*NB_COU))/(NB_COU - 1) ;
  160. TBEPAI = TABL ;
  161. TBEXCE = TABLE ;
  162. MOD_MUL = VIDE 'MMODEL' ;
  163. MAT_MUL = VIDE 'MCHAML' ;
  164. REPE I ((2*NB_COU) - 1) ;
  165. EX1 = (EPAI_I + EPAI_C)*(&I - NB_COU)/2. ;
  166. SI (EGA ((&I/2)*2) &I) ;
  167. EP1 = EPAI_I ;
  168. SINON ;
  169. EP1 = EPAI_C ;
  170. FINSI;
  171. MOD_MU1 = MODE ELEFIS 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' 'DKT'
  172. 'CONS' (CHAI &I) ;
  173. MAT_MU1 = MATE MOD_MU1 'YOUN' MYOUN 'NU' NU1 'AF1' AF1 'AF2' AF2 'AF3' AF3
  174. 'EPAI' EP1 'EXCE' EX1 ;
  175. MOD_MUL = MOD_MUL ET MOD_MU1 ;
  176. MAT_MUL = MAT_MUL ET MAT_MU1 ;
  177. FIN I;
  178.  
  179. * RESTE DU MODELE
  180. MOD0 = MODE (TOUT DIFF ELEFIS) 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' 'DKT' ;
  181. MAT0 = MATE MOD0 'YOUN' MYOUN 'NU' NU1 'AF1' AF1 'AF2' AF2 'AF3' AF3 'EPAI' E ;
  182.  
  183. * MODELE TOTAL
  184. MOD1 = MOD0 ET MOD_MUL ;
  185. MAT1 = MAT0 ET MAT_MUL ;
  186.  
  187.  
  188. * I.3 - CONDITIONS AUX LIMITES ET CHARGEMENT
  189. * ******************************************
  190.  
  191. * CHARGE LIMITE
  192. SIG0 = 320. ;
  193. TETARAD = (AN/2.)*(PI/180.) ;
  194. V1 = 0.5*(SIN (AN/2.)) ;
  195. V2 = (PI/180.)*(ATG V1 ((1. - (V1**2))**0.5)) ;
  196. P0 = 2*SIG0*R*E*(PI - TETARAD - (2.*V2)) ;
  197. * MESS 'P0 = ' P0 ;FIN ;
  198. * CHARGEMENT
  199. PINI3 = POIN LIG 'INITIAL' ;
  200. PFIN3 = POIN LIG 'FINAL' ;
  201. PMIL3 = (CHAN 'POI1' LIG) DIFF (PINI3 ET PFIN3) ;
  202. MOEXT = (P0/2) / ((NBNO LIG) - 1) ;
  203. MOMIL = MOEXT*(NBNO PMIL3) ;
  204. F01 = (FORC 'FY' MOEXT (PINI3 ET PFIN3)) ET (FORC 'FY' MOMIL PMIL3) ;
  205. EVT = EVOL 'MANU' 'T' (PROG 0. 0.1 1.E20) 'F(T)' (PROG 0. 1. 1.) ;
  206. CHA1 = CHAR F01 EVT ;
  207.  
  208. * CLS
  209. SXOZ = SYMT 'DEPL' 'ROTA' TP.(10) TP.(11) P12 LISY 1.E-8 ;
  210. SXOY = SYMT 'DEPL' P1 P12 P21 TOUT 1.E-8 ;
  211. CDL = BLOQ 'UX' (POIN LIG 'FINAL') ;
  212. COLIM = SXOZ ET SXOY ET CDL ;
  213.  
  214.  
  215. * I.4 - APPEL A PASAPAS
  216. * *********************
  217.  
  218. TAB1 = TABL ;
  219. TAB1.'MODELE' = MOD1 ;
  220. TAB1.'CARACTERISTIQUES' = MAT1 ;
  221. TAB1.'BLOCAGES_MECANIQUES' = COLIM ;
  222. TAB1.'CHARGEMENT' = CHA1 ;
  223. LIS1 = PROG 0. PAS 0.02 0.2 PAS 0.05 1. PAS 0.5 10. PAS 5. 100. PAS 50. 350. ;
  224. SI VALIDATION ;
  225. TAB1.'TEMPS_CALCULES' = LIS1 ;
  226. SINON ;
  227. TAB1.'TEMPS_CALCULES' = EXTR LIS1 (LECT 1 PAS 1 20) ;
  228. FINSI ;
  229. MES_SAUV = TABL ;
  230. MES_SAUV.'DEFIN' = VRAI ;
  231. TAB1.'MES_SAUVEGARDES' = MES_SAUV ;
  232. PASAPAS TAB1 ;
  233.  
  234. * COD
  235. * COD = 2.*(EVOL 'TEMP' TAB1 'DEPLACEMENTS' 'UY' P1) ;
  236. * DESS COD ;
  237. * DEF1 = DEFO TAB1.'DEPLACEMENTS'.((DIME TAB1.'TEMPS') - 1) TOUT ;
  238. * TRAC DEF1 ;
  239.  
  240.  
  241. * II - APPEL A G_THETA ET COMPARAISON A LA SOLUTION ANALYTIQUE
  242. * ------------------------------------------------------------
  243.  
  244. * II.1 - APPEL A G_THETA
  245. * **********************
  246.  
  247. * ON RECUPERE LA FISSURE
  248. LF = CONT1 ELEM 'COMPRIS' P1 FF ;
  249. * TRAC ((TOUT COUL 'BLAN') ET (LF COUL 'ROUG') ET (ELEFIS COUL 'BLEU')) ;
  250.  
  251. * ON CREE LA TABLE SUPTAB
  252. SUPTAB = TABL ;
  253. SUPTAB.'SOLUTION_PASAPAS' = TAB1 ;
  254. SUPTAB.'OBJECTIF' = 'C*' ;
  255. SUPTAB.'LEVRE_SUPERIEURE' = LF ;
  256. SUPTAB.'FRONT_FISSURE' = FF ;
  257. SUPTAB.'COUCHE' = 4 ;
  258. SUPTAB.'ELEMENT_MULTICOUCHE' = ELEFIS ;
  259.  
  260. * ON APPELLE G_THETA
  261. G_THETA SUPTAB ;
  262. NDER = DIME SUPTAB.'RESULTATS' ;
  263. C_GT = SUPTAB.'RESULTATS'.(NDER-1).'GLOBAL' ;
  264.  
  265.  
  266. * II.2 - SOLUTION ANALYTIQUE
  267. * **************************
  268.  
  269. SI VALIDATION ;
  270. H1 = 0.638 ;
  271. C_AN = SIG0*AF1*(SIG0**AF2)*R*PI*(1. - (AN/360.))*H1 ;
  272. ERR1 = (ABS (C_AN - C_GT)) / C_AN ;
  273. MESS (CHAI 'ERREUR RELATIVE :' ' ' 'FORMAT' '(F4.1)' (100*ERR1) ' %') ;
  274. SI (ERR1 > 3.E-2) ;
  275. ERRE 5 ;
  276. FINSI ;
  277. FINSI ;
  278.  
  279. FIN ;
  280.  
  281.  
  282.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales