Télécharger fusion.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier fusion.dgibi
  2. * section : Mecanique, Plastique
  3. *----------------------------------------------------------------------*
  4. * Test de validation de l'option FUSION du modele. *
  5. * *
  6. * Cette option permet de mettre a zero les variables internes du modele*
  7. * lorsque la temperature depasse la temperature de fusion (TFUS). *
  8. * *
  9. * Essai de traction sur 1 element carre de cote 1. *
  10. * On fait un premier essai de traction. *
  11. * Puis, on fait un traitement de restauration en depassant TFUS. *
  12. * On fait un 2e essai de traction, identique au 1er. *
  13. * Les 2 courbes de traction doivent etre identiques a la deformation *
  14. * plastique initiale pres, qui n'est pas remise a zero par l'option *
  15. * FUSION du modele (seules les variables internes le sont). *
  16. * *
  17. * Enfin, on compare les solutions avec ou sans l'option FUSION. *
  18. * Sans, le materiau ne plastifie pas a la 2e charge car celle-ci est *
  19. * identique a la premiere et que le materiau est ecroui. Il n'y a donc *
  20. * pas d'effet de restauration au cours du traitement thermique. *
  21. * *
  22. * Description : *
  23. * ------------- *
  24. * *
  25. * Type de calcul : Thermomecanique, plastique *
  26. * Mode de calcul : 2D *
  27. * Type d'element : QUA4 *
  28. * Chargement : Force, Temperature *
  29. * Reference : validation restauration propriete elastoplastique *
  30. * avec option FUSION du modele et verification de la *
  31. * relation de comportement (loi de l'elasticite). *
  32. * *
  33. *----------------------------------------------------------------------*
  34. opti dime 2 elem qua4 mode plan cont ;
  35.  
  36. * Pour affichages, mettre ig1 a VRAI :
  37. ig1 = faux ;
  38.  
  39. *----------------------- Construction du modele -----------------------*
  40.  
  41. * Maillage :
  42. l1 = (0 0) droi 1 (1 0) ;
  43. s1 = l1 tran 1 (0 1) ;
  44. l3 = s1 cote 3 ;
  45. l4 = s1 cote 4 ;
  46.  
  47. si ig1 ;
  48. trac qual S1 titr 'Maillage' ;
  49. fins ;
  50.  
  51. * Modele, Caracteristiques :
  52. ecro1 = evol vert manu (prog 0. 1.) ecro (prog 200.e6 (10.e9+200.e6)) ;
  53. si ig1 ;
  54. dess ecro1 titr 'Courbe d ecrouissage : module = 10.E9 Pa' xbor 0. 0.1 ybor 0. 1.25e9 ygra 0.2e9 ;
  55. fins ;
  56. mo1 = mode s1 mecanique elastique plastique isotrope fusion ;
  57. ma1 = mate mo1 youn 200.e9 nu 0.3 alph 1.e-5 ecro ecro1 tref 20. talp 20. tfus 100. ;
  58.  
  59. * C.L., Chargement :
  60. clm1 = bloq uy l1 ;
  61. clm2 = bloq ux l4 ;
  62.  
  63. si ig1 ;
  64. trac qual ((l1 coul roug) et (l4 coul vert) et s1) titr ' Uy = 0 sur L1, Ux = 0 sur L4' ;
  65. fins ;
  66.  
  67. fimp1 = forc l3 (0. 1.e6) ;
  68. lt1 = prog 0. 1. 2. 3. 4. 5. 6. 7. 8. ;
  69. lfimp1 = prog 0. 200. 300. 0. 0. 0. 200. 300. 0. ;
  70. lt2 = prog 20. 20. 20. 20. 120. 20. 20. 20. 20. ;
  71. evfimp1 = evol vert manu temp lt1 meca lfimp1 ;
  72. cgfimp1 = char dimp fimp1 evfimp1 ;
  73.  
  74. * Chargement en temperature :
  75. cht1 = manu chpo s1 1 'T' 1. ;
  76. evt1 = evol roug manu temp lt1 t lt2 ;
  77. cgt1 = char 'T' cht1 evt1 ;
  78.  
  79. si ig1 ;
  80. trac (vect fimp1 forc vert) s1 titre 'Force appliquee' ;
  81. dess evfimp1 titre 'Evolution temporelle de l effort (Re = 200)' ;
  82. dess evt1 titre 'Evolution de la temperature en temps (Tfus = 100)' ;
  83. fins ;
  84.  
  85. *----------------------------- Resolution -----------------------------*
  86.  
  87. * Resolution PASAPAS a 20 deg. C :
  88. tpas1 = table ;
  89. tpas1. modele = mo1 ;
  90. tpas1. caracteristiques = ma1 ;
  91. tpas1. blocages_mecaniques = clm1 et clm2 ;
  92. tpas1. chargement = cgfimp1 et cgt1 ;
  93. tpas1. temps_calcules = prog 0. 1. pas 0.1 2. 3. 4. 5. 6. pas 0.1 7. 8. ;
  94.  
  95. * Sauvegarde deformations pour verif. comportement :
  96. tpas1. mes_sauvegardes = table ;
  97. tpas1. mes_sauvegardes. defin = vrai ;
  98. tpas1. mes_sauvegardes. defto = vrai ;
  99.  
  100. pasapas tpas1 ;
  101.  
  102. *-------------------------- Post-traitement ---------------------------*
  103.  
  104. * Courbe traction initiale :
  105. p4 = s1 poin proc (0 1) ;
  106. lf1 = ipol evfimp1 (prog 0. 1. pas 0.1 2. 3.) ;
  107. evu1 = evol temp tpas1 deplacements UY P4 ;
  108. lu1 = ipol evu1 (prog 0. 1. pas 0.1 2. 3.) ;
  109. evfu1 = evol vert manu 'Uy' lu1 'Fy' lf1 ;
  110.  
  111. * Courbe dilatation a effort nul (traitement restauration) :
  112. lf2 = ipol evfimp1 (prog 3. 4. 5.) ;
  113. evu2 = evol temp tpas1 deplacements UY P4 ;
  114. lu2 = ipol evu2 (prog 3. 4. 5.) ;
  115. evfu2 = evol rose manu 'Uy' lu2 'Fy' lf2 ;
  116.  
  117. * Courbe traction apres traitement thermique restauration :
  118. lf3 = ipol evfimp1 (prog 5. 6. pas 0.1 7. 8.) ;
  119. evu3 = evol temp tpas1 deplacements UY P4 ;
  120. lu3 = ipol evu3 (prog 5. 6. pas 0.1 7. 8.) ;
  121. evfu3 = evol oran manu 'Uy' lu3 'Fy' lf3 ;
  122.  
  123. si ig1 ;
  124. tleg1 = table ;
  125. tleg1. titre = table ;
  126. tleg1. titre. 1 = 'Courbe initiale' ;
  127. tleg1. titre. 2 = 'Dilatation TT' ;
  128. tleg1. titre. 3 = 'Apres TT restauration' ;
  129. titre 'Courbes force-deplacement initiale et apres TT restauration' ;
  130. dess (evfu1 et evfu2 et evfu3) ybor 0. 310. ygra 50. lege tleg1 ;
  131. fins ;
  132.  
  133. *----------------------------- Validation -----------------------------*
  134.  
  135. * Validation option FUSION :
  136. * --------------------------
  137. * On veut que les 2 courbes de traction soient identiques,
  138. * a la deformation inelastique pres car elle n'est pas remise a zero.
  139. * evfu4 : courbe de traction corrigee de la def. plast. initiale
  140. u3ini = lu3 extr 1 ;
  141. lu4 = lu3 - u3ini ;
  142. evfu4 = evol manu 'Uy' lu4 'Fy' lf3 ;
  143.  
  144. si ig1 ;
  145. tleg1 = table ;
  146. tleg1. 2 = mot 'MARQ S ROND NOLI' ;
  147. tleg1. titre = table ;
  148. tleg1. titre. 1 = 'Courbe initiale' ;
  149. tleg1. titre. 2 = 'Apres TT corrigee' ;
  150. titre 'Comparaison courbe initiale-apres TT corrigee de la def. plast. ini.' ;
  151. dess (evfu1 et evfu4) lege tleg1 ;
  152. fins ;
  153.  
  154. * test validation :
  155. err1 = (maxi abs (lu1 - lu4)) / (maxi abs lu1) ;
  156. list err1 ;
  157. si (err1 > 1.e-8) ;
  158. erre 5 ;
  159. fins ;
  160.  
  161. * Validation relation de comportement :
  162. * -------------------------------------
  163. * On compare les contraintes obtenues par PASAPAS au max. des courbes de traction,
  164. * aux contraintes calculees par loi de l'elasticite a l'aide des deformations
  165.  
  166. * Contraintes calculees par PASAPAS :
  167. sig2 = peche tpas1 contraintes 2. ;
  168. sig7 = peche tpas1 contraintes 7. ;
  169.  
  170. * Calcul contraintes a partir des deformations :
  171. dep2 = peche tpas1 deplacements 2. ;
  172. dep7 = peche tpas1 deplacements 7. ;
  173. eto2 = epsi dep2 mo1 ;
  174. eto7 = epsi dep7 mo1 ;
  175. cht2 = tire cgt1 t 2. ;
  176. cht7 = tire cgt1 t 7. ;
  177. eth2 = epth mo1 ma1 cht2 ;
  178. eth7 = epth mo1 ma1 cht7 ;
  179. ein2 = peche tpas1 deformations_inelastiques 2. ;
  180. ein7 = peche tpas1 deformations_inelastiques 7. ;
  181. lmein1 = extr ein2 comp ;
  182. lmeto1 = extr mo1 deformations ;
  183. ein2 = exco ein2 lmein1 lmeto1 ;
  184. ein7 = exco ein7 lmein1 lmeto1 ;
  185. sel2 = elas mo1 ma1 (eto2 - eth2 - ein2) ;
  186. sel7 = elas mo1 ma1 (eto7 - eth7 - ein7) ;
  187.  
  188. * Ecart relatif a la loi de l'elasticite :
  189. err2 = (maxi abs (sig2 - sel2)) / (maxi abs sig2) ;
  190. err3 = (maxi abs (sig7 - sel7)) / (maxi abs sig7) ;
  191. err0 = maxi (prog err2 err3) ;
  192. list err0 ;
  193.  
  194. * Validation relation de comportement :
  195. si (err0 > 1.e-5) ;
  196. erre 5 ;
  197. fins ;
  198.  
  199. *------------------------- Sans Option FUSION -------------------------*
  200.  
  201. mo2 = mode s1 mecanique elastique plastique isotrope ;
  202. ma2 = mate mo2 youn 200.e9 nu 0.3 alph 1.e-5 ecro ecro1 tref 20. talp 20. ;
  203.  
  204. tpas2 = table ;
  205. tpas2. modele = mo2 ;
  206. tpas2. caracteristiques = ma2 ;
  207. tpas2. blocages_mecaniques = clm1 et clm2 ;
  208. tpas2. chargement = cgfimp1 et cgt1 ;
  209. tpas2. temps_calcules = prog 0. 1. pas 0.1 2. 3. 4. 5. 6. pas 0.1 7. 8. ;
  210.  
  211. * Sauvegarde deformations pour verif. comportement :
  212. tpas2. mes_sauvegardes = table ;
  213. tpas2. mes_sauvegardes. defin = vrai ;
  214. tpas2. mes_sauvegardes. defto = vrai ;
  215.  
  216. pasapas tpas2 ;
  217.  
  218. * Comparaison avec / sans option FUSION :
  219. lf1 = ipol evfimp1 tpas1.temps_calcules ;
  220. evu1 = evol temp tpas1 deplacements UY P4 ;
  221. lu1 = ipol evu1 tpas1.temps_calcules ;
  222. evfu1 = evol vert manu 'Uy' lu1 'Fy' lf1 ;
  223. evu2 = evol temp tpas2 deplacements UY P4 ;
  224. lu2 = ipol evu2 tpas2.temps_calcules ;
  225. evfu2 = evol blan manu 'Uy' lu2 'Fy' lf1 ;
  226. evut1 = evol vert manu 't' tpas1.temps_calcules 'Uy' lu1 ;
  227. evut2 = evol blan manu 't' tpas1.temps_calcules 'Uy' lu2 ;
  228.  
  229. si ig1 ;
  230. tleg1 = table ;
  231. tleg1. 2 = mot 'MARQ S ROND POIN' ;
  232. tleg1. titre = table ;
  233. tleg1. titre. 1 = 'avec option FUSION' ;
  234. tleg1. titre. 2 = 'sans option FUSION' ;
  235. titre 'Courbes traction : sans option FUSION, on ne plastifie pas a la 2e charge' ;
  236. dess (evfu1 et evfu2) lege tleg1 ;
  237. titre 'Evolution temporelle du deplacement' ;
  238. dess (evut1 et evut2) lege tleg1 xbor 0. 9. xgra 1. ;
  239. fins ;
  240.  
  241. fin ;
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales