Télécharger fsi7.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : fsi7.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *************************************************************
  6. *
  7. * Cas test FSI7
  8. *
  9. * Calcul d'une masse ajoutee en mode de Fourier
  10. * (lame fluide)
  11. *
  12. * creation : D. Combescure Décembre 2006
  13. *
  14. * rem (bp) : - la structure n'est pas modelisee
  15. * - on impose un deplacement de translation harmonique
  16. * sur l'interface (raccord)
  17. *
  18. *
  19. * + +--------+
  20. * | | |
  21. * +-------+ rac2| fluide |
  22. * |fluide |rac2 | |
  23. * | | | |
  24. * . . . .
  25. * . . . .
  26. *
  27. *************************************************************
  28. *
  29. GRAPH = FAUX;
  30. * GRAPH = VRAI; OPTI TRAC PSC ;
  31.  
  32. COMPLET = FAUX;
  33. * COMPLET = VRAI;
  34. *
  35. opti dime 2 elem qua4 mode four 1;
  36. *
  37. *************************************************************
  38. * MAILLAGE
  39. *************************************************************
  40. *
  41. HH1 = 9.D-3;
  42. R1 = 7.85D-3;
  43. h1 = 0.3D-3;
  44. *
  45. HH2 = 20.D-3;
  46. R2 = 10.D-3;
  47. h2 = 0.6D-3;
  48. *
  49. SI COMPLET;
  50. nz12 = 10;
  51. nz1 = 10;
  52. nx1 = 5;
  53. nx2 = 5;
  54. SINON;
  55. nz12 = 1;
  56. nz1 = 1;
  57. nx1 = 1;
  58. nx2 = 1;
  59. FINSI;
  60. *
  61. p1 = 0. 0.;
  62. p2 = (R1 - h1) 0.;
  63. p3 = (R1 + h1) 0.;
  64. surbas1 = droi nx1 p2 p3;
  65. p4 = (R2 - h2) 0.;
  66. p5 = (R2 + h2) 0.;
  67. surbas2 = droi nx2 p4 p5;
  68. *
  69. p3s = p3 plus (0. 0.);
  70. p4s = p4 plus (0. 0.);
  71. sursol = droi 1 p3s p4s;
  72. *
  73. vz1= 0. HH1;
  74. p2h = p2 plus (0.5*vz1);
  75. p3h = p3 plus (0.5*vz1);
  76. p4h = p4 plus (0.5*vz1);
  77. p5h = p5 plus (0.5*vz1);
  78. p2b = p2 plus (-0.5*vz1);
  79. p3b = p3 plus (-0.5*vz1);
  80. p4b = p4 plus (-0.5*vz1);
  81. p5b = p5 plus (-0.5*vz1);
  82. *
  83. vz12= 0. (HH2 - HH1);
  84. p4h2 = p4h plus (0.5*vz12);
  85. p5h2 = p5h plus (0.5*vz12);
  86. p4b2 = p4b plus (-0.5*vz12);
  87. p5b2 = p5b plus (-0.5*vz12);
  88. *
  89. volint1 = ((tran surbas1 nz1 (0.5*vz1)) et
  90. (tran surbas1 nz1 ((-0.5)*vz1))) coul BLEU;
  91. volint2 = ( ((tran surbas2 nz1 (0.5*vz1)) et
  92. (tran (surbas2 plus (0.5*vz1)) nz12 (0.5*vz12)))
  93. et ((tran surbas2 nz1 ((-0.5)*vz1)) et
  94. (tran (surbas2 plus ((-0.5)*vz1)) nz12 ((-0.5)*vz12)))
  95. ) coul AZUR;
  96. volsol = ((tran sursol nz1 (0.5*vz1)) et
  97. (tran (sursol plus (0.5*vz1)) nz12 (0.5*vz12)) et
  98. (tran sursol nz1 ((-0.5)*vz1)) et
  99. (tran (sursol plus ((-0.5)*vz1)) nz12 ((-0.5)*vz12)))
  100. COUL ROUGE;
  101. *
  102. SI GRAPH;
  103. trac (volsol et volint1 et volint2);
  104. FINSI;
  105. *
  106. surint = (d nz1 p2 p2h)
  107. et (d nz1 p2 p2b);
  108. surint2 = (d nz1 p3 p3h)
  109. et (d nz1 p3 p3b);
  110. surext = (d nz1 p4 p4h) et (d nz12 p4h p4h2)
  111. et (d nz1 p4 p4b)
  112. et (d nz12 p4b p4b2);
  113. surext2 = (d nz1 p5 p5h) et (d nz12 p5h p5h2)
  114. et (d nz1 p5 p5b)
  115. et (d nz12 p5b p5b2);
  116. surver1 = (surbas1 plus (0.5*vz1))
  117. et (surbas1 plus (-0.5*vz1));
  118. surver2 = (surbas2 plus (0.5*(vz1 plus vz12)))
  119. et (surbas2 plus (-0.5*(vz1 plus vz12)));
  120. *
  121. elim 0.0001
  122. (surint et surint2 et surext et surext2
  123. et volint1 et volint2 et surver1 et surver2);
  124. surextb = surext plus (0. 0.);
  125. surint2b = surint2 plus (0. 0.);
  126. elim 0.0001
  127. (surint2b et surextb et volsol);
  128. *
  129. SI GRAPH;
  130. trac (surint et surext et surint2 et surext2
  131. et volint1 et volint2 et volsol);
  132. FINSI;
  133. *
  134. *
  135. *
  136. *************************************************************
  137. * MODELE DE FLUIDE
  138. *************************************************************
  139. *
  140. ro1 = 800.;
  141. cf1 = 343.;
  142. *
  143. mod1 = MODE (volint1) liquide lqu4;
  144. mat1 = MATE mod1 rho ro1 rorf ro1
  145. cson cf1 cref cf1 lcar 1.D-3 g 0.;
  146. mod2 = MODE (volint2) liquide lqu4;
  147. mat2 = MATE mod2 rho ro1 rorf ro1
  148. cson cf1 cref cf1 lcar 1.D-3 g 0.;
  149. rig1 = rigi (mod1 et mod2) (mat1 et mat2);
  150. mas1 = mass (mod1 et mod2) (mat1 et mat2);
  151. *
  152. blfl = bloq UR UT UZ
  153. (surint et surext2 );
  154. blflI = bloq IUR IUT IUZ
  155. (surint et surext2 );
  156. blfl2 = bloq UZ
  157. (surver1 et surver2);
  158. blfl2I = bloq IUZ
  159. (surver1 et surver2);
  160. *
  161. *
  162. opti elem rac2;
  163. mrac2 = racc 0.0001 (surext) (surextb);
  164. mrac1 = racc 0.0001 (surint2) (surint2b);
  165. *
  166. modrac1 = MODE mrac1 mecanique liquide rac2;
  167. matrac1 = cara modrac1 liqu volint1;
  168. *
  169. modrac2 = MODE mrac2 mecanique liquide rac2;
  170. matrac2 = cara modrac2 liqu volint2;
  171. *
  172. modliq = MODE (volint1 et volint2) liquide lqu4;
  173. matliq = MATE (modliq et modrac1 et modrac2) rho ro1 rorf ro1
  174. cson cf1 cref cf1 lcar 1. g 0.;
  175.  
  176. modtot = modrac1 et modrac2 et modliq;
  177. mattot = matrac1 et matrac2 et matliq;
  178.  
  179.  
  180. *************************************************************
  181. * MATRICES
  182. *************************************************************
  183.  
  184. bl1 = bloq UR UT UZ (surext2 et surint);
  185. bl2ur = bloq UR (surextb et surint2b);
  186. bl2ut = bloq UT (surextb et surint2b);
  187. bl2uz = bloq UZ (surextb et surint2b);
  188. bl1I = bloq IUR IUT IUZ (surext2 et surint);
  189. bl2Iur = bloq IUR (surextb et surint2b);
  190. bl2Iut = bloq IUT (surextb et surint2b);
  191. bl2Iuz = bloq IUZ (surextb et surint2b);
  192. dep1ur = depi bl2ur 1.;
  193. dep1ut = depi bl2ut -1.;
  194.  
  195. Ktot = rigi modtot mattot;
  196. Mtot = mass modtot mattot;
  197.  
  198. Mimpe = 'IMPE' Mtot 1. 'MASSE';
  199. Kimpe = 'IMPE' Ktot 'RAIDEUR';
  200.  
  201.  
  202. *************************************************************
  203. * CALCULS : REPONSE HARMONIQUE
  204. *************************************************************
  205.  
  206. SI COMPLET;
  207. prfreq = prog 10 pas 10. 1000.;
  208. SINON;
  209. prfreq = prog 100 pas 100. 1000.;
  210. FINSI;
  211. *
  212. prFR = prog;
  213. prFT = prog;
  214. repeter lab1 (dime prfreq);
  215. fr1 = extr prfreq &lab1;
  216. ImpTot = Kimpe et (((2.*pi*fr1)**2)*Mimpe)
  217. et bl1 et bl2ur et bl2ut et bl2uz et
  218. bl1I et bl2Iur et bl2Iut et bl2Iuz et blfl et blflI
  219. et blfl2 et blfl2I;
  220. deptot = reso ImpTot (dep1ur et dep1ut);
  221. reatot = reac deptot (bl2ur et bl2ut);
  222. prFR = prfr et (prog (maxi (exco (resu reatot) FR)));
  223. prFT = prft et (prog (maxi (exco (resu reatot) FT)));
  224. fin lab1;
  225. *
  226. evfr = evol manu prfreq prfr;
  227. evft = evol manu prfreq prft;
  228. *
  229. mm = 57.6d-3;
  230. evfrma = evol rouge manu prfreq ((-1.)*((2.*pi*prfreq)**2)*mm);
  231. *
  232. TEST = ABS ((SOMM ((extr evfrma ordo) - (extr evfr ordo)))/
  233. (SOMM (extr evfrma ordo)));
  234. *
  235. SI GRAPH;
  236. trac (volint1 et volint2) (exco deptot 'P');
  237. trac (volint1 et volint2) (vecteur reatot 'FR' 'FZ');
  238. dess (evfr et evfrma);
  239. FINSI;
  240.  
  241.  
  242.  
  243. *************************************************************
  244. * POST TRAITEMENT VIA FOUR2TRI
  245. *************************************************************
  246.  
  247. * rem : les elements raccords (RAC2) ne seront traites par FOUR2TRI
  248. tab1 = table;
  249. tab1.'MODELE' = modrac1 et modrac2 et modliq;
  250. tab1.'ANGLES' = prog 0. pas 10. 270.;
  251. tab1.'CHPO_SYME' = TABLE;
  252. tab1.'CHPO_SYME'. 1 = exco deptot 'P' 'SCAL';
  253. tab1.'EFFORTS' = TABLE;
  254. tab1.'EFFORTS'. 1 = reatot;
  255. FOUR2TRI tab1 1;
  256. mesh3d1 = tab1 . 'MAILLAGE_3D';
  257. SI GRAPH;
  258. trac mesh3D1 (tab1.'CHPO_SYME_3D'. 1 );
  259. trac mesh3D1 (vect (tab1.'EFFORTS_3D'. 1 ) FX FY FZ);
  260. FINSI;
  261.  
  262.  
  263. *************************************************************
  264. * TEST ET FIN DU CAS-TEST
  265. *************************************************************
  266.  
  267. SI (TEST >EG 1.d-2);
  268. ERRE 5;
  269. FINSI;
  270.  
  271. TEMP IMPR MAXI CPU ;
  272. FIN ;
  273.  
  274.  
  275.  
  276.  
  277.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales