Télécharger four2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : four2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Four2.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. *******************************************************
  9. * Test four2.dgibi: Jeux de données *
  10. * --------------------------------- *
  11. *******************************************************
  12.  
  13. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  14. * SINON SI GRAPH DIFFERENT DE N TOUS
  15. * LES GRAPHIQUES SONT AFFICHES
  16.  
  17. GRAPH = 'N' ;
  18.  
  19. SAUT PAGE;
  20. SI (NEG GRAPH 'N') ;
  21. OPTI ECHO 1 ;
  22. OPTI TRAC PSC ;
  23. SINO ;
  24. OPTI ECHO 0 ;
  25. FINSI ;
  26.  
  27. SAUT PAGE;
  28. *************************************************************************
  29. * TEST FOUR2
  30. *
  31. * CYLINDRE INFINI SOUS PRESSION EXTERNE(NU=0)
  32. *
  33. * Soit un cylindre infini soumis a une pression externe.
  34. *
  35. * Une analyse de flambage permet de determiner la charge critique
  36. * associée aux 10 premiers modes de Fourier de la structure :
  37. * (u = u°*cos(2*Teta) )
  38. * (u = u°*cos(3*Teta) )
  39. * (u = u°*cos(4*Teta) )
  40. * (u = u°*cos(5*Teta) )
  41. * ...
  42. * Les éléments utilisés sont des éléments massifs.
  43. *
  44. * Comparaison a une solution analytique
  45. *************************************************************************
  46. *
  47. TITRE 'CYLINDRE INFINI SOUS PRESSION EXTERNE';
  48. OPTI DIME 2 ELEM qua8 MODE FOUR 0;
  49. OPTI EPSI LINEAIRE;
  50. *
  51. *------------------ CONSTRUCTION DE LA GEOMETRIE ------------------------
  52. *
  53. PA1=999.5 0.;PB1=999.5 10.;PO1=0. 0.;PO2=0. 10.;
  54. PA2=1000.5 0.;PB2=1000.5 10.;
  55. L1 = PA1 DROI 5 PA2;
  56. L2 = PA2 DROI 19 PB2;
  57. L3 = PB2 DROI 5 PB1;
  58. L4 = PB1 DROI 19 PA1;
  59.  
  60. CYL = DALLER L1 L2 L3 L4 PLAN;
  61. SI (NEG GRAPH 'N');
  62. TRAC 'QUAL' CYL;
  63. FINSI;
  64.  
  65. MOD1=MODE CYL MECANIQUE ELASTIQUE qua8;
  66.  
  67. *
  68. *--- DECLARATION DE FOURIER NOHARM POUR LES OBJETS QUI SERONT UTILISES --
  69. *------------- POUR PLUSIEURS NUMEROS D'HARMONIQUE ----------------------
  70. *
  71. OPTI MODE FOUR NOHARM;
  72. *
  73. *
  74. *-------------- CONDITIONS AUX LIMITES SYMETRIQUES ----------------------
  75. *
  76. SYMB=SYMT CYL DEPL PA1 PO1 0.05;
  77. SYMH=SYMT CYL DEPL PB1 PO2 0.05;
  78. CDL=SYMB ET SYMH;
  79. *
  80. *-------------- MATERIAU ET CARACTERISTIQUES ----------------------------
  81. *
  82. MAT =MATE MOD1 YOUN 20000. NU 0.;
  83. *
  84. *------ DECLARATION DE FOURIER MODE 0 POUR LE CALCUL DES CONTRAINTES ----
  85. *
  86. OPTI MODE FOUR 0;
  87.  
  88. FP=PRES MASS MOD1 1. L2 ;
  89. RIG=RIGI MOD1 MAT;
  90. *
  91. *
  92. AAA = RIG ET CDL et (bloq PA1 UT);
  93. U = RESO AAA FP ;
  94. SIG = SIGMA U MOD1 MAT;
  95. I = 1;
  96. ERRMAX = 0.;
  97. REPE BOUC1 9;
  98. I = I + 1;
  99. *
  100. *----- DECLARATION DE FOURIER MODE I POUR L'ANALYSE DE FLAMBAGE ---------
  101. *
  102. OPTI MODE FOUR I;
  103. MKSI = KSIGMA MOD1 MAT (SIG * -1.) FLAM;
  104. RIG = RIGI MOD1 MAT ;
  105. *
  106. *--------- RECHERCHE DE LA 1ERE FREQUENCE PROPRE ------------------------
  107. *
  108. MODF=VIBR PROC (PROG 0.01) (RIG ET CDL) MKSI;
  109. W1 = MODF . MODES . 1 . FREQUENCE;
  110. LAMBDA1=(W1 * 2. * PI) ** 2 * (SIGN W1);
  111. LDUM = (20000./(1. - 0.))*((1./1000.)**3)/12.;
  112. LTH1 = LDUM*I*I;
  113. ERR1 = (LTH1 - LAMBDA1)/LTH1*100;
  114.  
  115. SAUT 1 LIGN ;
  116. MESS 'Mode : ' I;
  117. SAUT 1 LIGN ;
  118. MESS ' K(SIG) SEUL : ON DOIT TROUVER LAMBDA=' LTH1;
  119. MESS ' LE CALCUL DONNE LAMBDA=' LAMBDA1;
  120. MESS ' SOIT UN ECART DE : ' ERR1 '%' ;
  121. SAUT 1 LIGN ;
  122.  
  123. ERRMAX = MAXI ABS (PROG ERRMAX ERR1);
  124. FIN BOUC1;
  125.  
  126. mess ' errmax vaut ' errmax '%';
  127. SI (ERRMAX < 1.1D0 );
  128. ERRE 0;
  129. SINON ;
  130. ERRE 5;
  131. FINSI;
  132.  
  133. FIN;
  134.  
  135.  
  136.  
  137.  
  138.  
  139.  
  140.  
  141.  
  142.  
  143.  
  144.  
  145.  
  146.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales