Télécharger formation_pasapas_4_solution.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * FORMATION AVANCEE SUR LA PROCEDURE PASAPAS *
  3. * *
  4. * Variation d'un jeu sous l'action d'une sollicitation thermique en *
  5. * regime transitoire *
  6. * *
  7. * Ce fichier constitue la mise donnee solution du probleme et realise *
  8. * - le maillage *
  9. * - la definition du modele et des parametres materiaux *
  10. * - la definition du chargement *
  11. * - l'ajout et la suppression de blocages thermiques selon le jeu *
  12. * (avec la procedure REEV_MEC) *
  13. * - la resolution avec PASAPAS *
  14. * - le post traitement *
  15. ************************************************************************
  16.  
  17.  
  18. ** Options generales
  19. OPTI 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  20. ITRAC = FAUX ;
  21.  
  22.  
  23. ** Parametres geometriques, materiaux et CL
  24. L = 1. ;
  25. EPAI = 0.1 ;
  26. JEU_INI = 0.01*L ;
  27. LAMBDA1 = 60. ;
  28. LAMBDA2 = 80. ;
  29. CP1 = 800. ;
  30. CP2 = 100. ;
  31. RHO1 = 7800. ;
  32. RHO2 = 7800. ;
  33. ALPHA1 = 12.E-6 ;
  34. ALPHA2 = 12.E-6 ;
  35. YOUNG1 = 200.E9 ;
  36. YOUNG2 = 200.E9 ;
  37. NU1 = 0.3 ;
  38. NU2 = 0.3 ;
  39. T_INI = 20. ;
  40. T1 = 500. ;
  41. T4 = 20. ;
  42. TEMPS_F = 5.E5 ;
  43. XPAS = 5.E3 ;
  44.  
  45.  
  46. ** Maillage
  47. P1 = 0. 0. ;
  48. P2 = L 0. ;
  49. L0 = DROI 10 P1 P2 ;
  50. S1 = L0 TRAN 1 (0. EPAI) ;
  51. L1 = S1 COTE 4 ;
  52. L2 = S1 COTE 2 ;
  53. S2 = S1 PLUS ((L + JEU_INI) 0.) ;
  54. L3 = S2 COTE 4 ;
  55. L4 = S2 COTE 2 ;
  56. P3 = S2 POIN 'PROC' ((L + JEU_INI) 0.) ;
  57. P4 = S2 POIN 'PROC' (((2. * L) + JEU_INI) 0.) ;
  58. MAILT = S1 ET S2 ;
  59. MCONT1 = IMPO 'MAIL' L2 L3 ;
  60. SI ITRAC ;
  61. TRAC MAILT 'TITR' 'Maillage' ;
  62. FINSI ;
  63.  
  64.  
  65. ** Modeles et materiaux
  66. MODM1 = MODE S1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  67. MATM1 = MATE MODM1 'ALPHA' ALPHA1 'YOUN' YOUNG1 'NU' NU1 ;
  68. MODM2 = MODE S2 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  69. MATM2 = MATE MODM2 'ALPHA' ALPHA2 'YOUN' YOUNG2 'NU' NU2 ;
  70. MODC = MODE MCONT1 'CONTACT' 'UNILATERAL' ;
  71. MODT1 = MODE S1 'THERMIQUE' 'ISOTROPE' ;
  72. MATT1 = MATE MODT1 'K' LAMBDA1 'C' CP1 'RHO' RHO1 ;
  73. MODT2 = MODE S2 'THERMIQUE' 'ISOTROPE' ;
  74. MATT2 = MATE MODT2 'K' LAMBDA2 'C' CP2 'RHO' RHO2 ;
  75. MOD_TH = MODT1 ET MODT2 ;
  76. MAT_TH = MATT1 ET MATT2 ;
  77. MOD_ME = MODM1 ET MODM2 ET MODC ;
  78. MAT_ME = MATM1 ET MATM2 ;
  79.  
  80.  
  81. ** Blocages mecaniques
  82. CL1 = BLOQ 'UY' MAILT ;
  83. CL2 = BLOQ 'UX' L1 ;
  84. CL3 = BLOQ 'UX' L4 ;
  85. CL_ME = CL1 ET CL2 ET CL3 ;
  86.  
  87.  
  88. ** Blocages thermiques
  89. CL4 = BLOQ 'T' L1 ;
  90. CL5 = BLOQ 'T' L4 ;
  91. CL_TH = CL4 ET CL5 ;
  92.  
  93.  
  94. ** Chargements en temperatures imposees
  95. TEM1 = DEPI CL4 T1 ;
  96. TEM2 = DEPI CL5 T4 ;
  97. EV1 = EVOL 'MANU' (PROG 0. TEMPS_F) (PROG 1. 1.) ;
  98. CHA1 = CHAR 'TIMP' (TEM1 ET TEM2) EV1 ;
  99.  
  100.  
  101. ** Champ de temperature initiale
  102. TEM0 = MANU 'CHPO' MAILT 1 'T' T_INI ;
  103.  
  104.  
  105. ** Procedure REEV_MEC pour ajouter/supprimer un blocage thermique lors
  106. * du contact mecanique
  107. DEBP REEV_MEC T1*'TABLE' N1*'ENTIER' ;
  108. U1 = T1 . 'ESTIMATION' . 'DEPLACEMENTS' ;
  109. WT = T1 . 'WTABLE' ;
  110. TAM = T1 . 'AMOI' ;
  111. * calcul du jeu
  112. PT2 = TAM . 'POINT_2' ;
  113. PT3 = TAM . 'POINT_3' ;
  114. X2 = (COOR 1 PT2) + (EXTR U1 'UX' PT2) ;
  115. X3 = (COOR 1 PT3) + (EXTR U1 'UX' PT3) ;
  116. J1 = X3 - X2 ;
  117. * si jeu ferme, on utilise le blocage thermique initial + le RELA
  118. SI (J1 <EG 1.E-15) ;
  119. WT . 'BLOCAGES_THERMIQUES' = (TAM . 'BLOQ_0') ET (TAM . 'BLOQ_1') ;
  120. * si jeu ouvert, on utilise le blocage thermique initial seul
  121. SINON ;
  122. WT . 'BLOCAGES_THERMIQUES' = TAM . 'BLOQ_0' ;
  123. FINSI ;
  124. FINP ;
  125.  
  126.  
  127. ** Resolution avec PASAPAS
  128. TAB1 = TABL ;
  129. TAB1 . 'MODELE' = MOD_ME ET MOD_TH ;
  130. TAB1 . 'CARACTERISTIQUES' = MAT_ME ET MAT_TH ;
  131. TAB1 . 'BLOCAGES_MECANIQUES' = CL_ME ;
  132. TAB1 . 'BLOCAGES_THERMIQUES' = CL_TH ;
  133. TAB1 . 'TEMPERATURES' = TABL ;
  134. TAB1 . 'TEMPERATURES' . 0 = TEM0 ;
  135. TAB1 . 'CHARGEMENT' = CHA1 ;
  136. TAB1 . 'TEMPS_CALCULES' = PROG XPAS 'PAS' XPAS TEMPS_F ;
  137. TAB1 . 'CONVERGENCE_MEC_THE' = VRAI ;
  138. TAB1 . 'PROCEDURE_REEV_MEC' = VRAI ;
  139. TAB1 . 'AMOI' = TABL ;
  140. TAB1 . 'AMOI' . 'POINT_2' = P2 ;
  141. TAB1 . 'AMOI' . 'POINT_3' = P3 ;
  142. TAB1 . 'AMOI' . 'BLOQ_0' = CL_TH ;
  143. TAB1 . 'AMOI' . 'BLOQ_1' = RELA 'T' L2 - 'T' L3 ;
  144. PASAPAS TAB1 ;
  145.  
  146.  
  147. ** Post-traitement
  148. LTPS = PROG ;
  149. LJEU = PROG ;
  150. LT2 = PROG ;
  151. LT3 = PROG ;
  152. NB1 = DIME (TAB1 . 'TEMPS') ;
  153. MESS ' Temps Jeu T2 T3' ;
  154. * listage du jeu et des temperatures a chaque pas de temps
  155. CONF0 = FORM ;
  156. REPE B1 NB1 ;
  157. TPS1 = TAB1 . 'TEMPS' . (&B1 - 1) ;
  158. LTPS = LTPS ET TPS1 ;
  159. TE1 = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
  160. U1 = TAB1 . 'DEPLACEMENTS' . (&B1 - 1) ;
  161. CONF1 = FORM U1 ;
  162. J1 = NORM (P3 MOIN P2) ;
  163. T2 = EXTR TE1 'T' P2 ;
  164. T3 = EXTR TE1 'T' P3 ;
  165. MESS TPS1 J1 T2 T3 ;
  166. LJEU = LJEU ET J1 ;
  167. LT2 = LT2 ET T2 ;
  168. LT3 = LT3 ET T3 ;
  169. SI ITRAC ;
  170. TRAC TE1 MAILT (PROG T4 PAS ((T1 - T4) / 20.) T1) 'TITR'
  171. (CHAI 'Temperature au temps' TPS1) ;
  172. FINSI ;
  173. FORM CONF0 ;
  174. FIN B1 ;
  175. * temperature VS temps aux points P2 et P3
  176. JEUVST = EVOL 'ROUG' 'MANU' 'Temps' LTPS
  177. 'Jeu' LJEU ;
  178. T2VST = EVOL 'ROUG' 'MANU' 'Temps' LTPS
  179. 'Temperature' LT2 ;
  180. T3VST = EVOL 'BLEU' 'MANU' 'Temps' LTPS
  181. 'Temperature' LT3 ;
  182. TLEG = TABL ;
  183. TLEG . 'TITRE' = TABL ;
  184. TLEG . 'TITRE' . 1 = 'Point P2';
  185. TLEG . 'TITRE' . 2 = 'Point P3' ;
  186. SI ITRAC ;
  187. DESS JEUVST 'TITR' 'Jeu VS temps' ;
  188. DESS (T2VST ET T3VST) 'TITR' 'Temperature VS temps' 'LEGE' TLEG ;
  189. FINSI ;
  190.  
  191. FIN ;
  192.  
  193.  
  194.  
  195.  
  196.  
  197.  
  198.  
  199.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales