Télécharger formation_pasapas_4_initial.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * FORMATION AVANCEE SUR LA PROCEDURE PASAPAS *
  3. * *
  4. * Variation d'un jeu sous l'action d'une sollicitation thermique en *
  5. * regime transitoire *
  6. * *
  7. * Ce fichier constitue la mise donnee initiale du probleme et realise *
  8. * - le maillage *
  9. * - la definition du modele et des parametres materiaux *
  10. * - la definition du chargement *
  11. * - la resolution avec PASAPAS *
  12. * - le post traitement *
  13. ************************************************************************
  14.  
  15.  
  16. ** Options generales
  17. OPTI 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  18. ITRAC = FAUX ;
  19.  
  20.  
  21. ** Parametres geometriques, materiaux et CL
  22. L = 1. ;
  23. EPAI = 0.1 ;
  24. JEU_INI = 0.01*L ;
  25. T_INI = 20. ;
  26. T1 = 500. ;
  27. T4 = 20. ;
  28. TEMPS_F = 5.E5 ;
  29. XPAS = 5.E3 ;
  30.  
  31.  
  32. ** Maillage
  33. P1 = 0. 0. ;
  34. P2 = L 0. ;
  35. L0 = DROI 10 P1 P2 ;
  36. S1 = L0 TRAN 1 (0. EPAI) ;
  37. L1 = S1 COTE 4 ;
  38. L2 = S1 COTE 2 ;
  39. S2 = S1 PLUS ((L + JEU_INI) 0.) ;
  40. L3 = S2 COTE 4 ;
  41. L4 = S2 COTE 2 ;
  42. P3 = S2 POIN 'PROC' ((L + JEU_INI) 0.) ;
  43. P4 = S2 POIN 'PROC' (((2. * L) + JEU_INI) 0.) ;
  44. MAILT = S1 ET S2 ;
  45. SI ITRAC ;
  46. TRAC MAILT 'TITR' 'Maillage' ;
  47. FINSI ;
  48.  
  49.  
  50. ** Modeles et materiaux
  51. MODM1 = MODE S1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  52. MATM1 = MATE MODM1 'ALPHA' 12.E-6 'YOUN' 200.E9 'NU' 0.3 ;
  53. MODM2 = MODE S2 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' ;
  54. MATM2 = MATE MODM2 'ALPHA' 12.E-6 'YOUN' 200.E9 'NU' 0.3 ;
  55. MODT1 = MODE S1 'THERMIQUE' 'ISOTROPE' ;
  56. MATT1 = MATE MODT1 'K' 60. 'C' 800. 'RHO' 7800. ;
  57. MODT2 = MODE S2 'THERMIQUE' 'ISOTROPE' ;
  58. MATT2 = MATE MODT2 'K' 80. 'C' 100. 'RHO' 7800. ;
  59. MOD_TH = MODT1 ET MODT2 ;
  60. MAT_TH = MATT1 ET MATT2 ;
  61. MOD_ME = MODM1 ET MODM2 ;
  62. MAT_ME = MATM1 ET MATM2 ;
  63.  
  64.  
  65. ** Blocages mecaniques
  66. CL1 = BLOQ 'UY' MAILT ;
  67. CL2 = BLOQ 'UX' L1 ;
  68. CL3 = BLOQ 'UX' L4 ;
  69. RE1 = RELA 'MAXI' 'UX' L2 - 'UX' L3 ;
  70. CL_ME = CL1 ET CL2 ET CL3 ET RE1 ;
  71.  
  72.  
  73. ** Blocages thermiques
  74. CL4 = BLOQ 'T' L1 ;
  75. CL5 = BLOQ 'T' L4 ;
  76. CL_TH = CL4 ET CL5 ;
  77.  
  78.  
  79. ** Chargements mecaniques et thermiques
  80. EV1 = EVOL 'MANU' (PROG 0. TEMPS_F) (PROG 1. 1.) ;
  81. F1 = DEPI RE1 JEU_INI ;
  82. CHA1 = CHAR 'DIMP' F1 EV1 ;
  83. TEM1 = DEPI CL4 T1 ;
  84. TEM2 = DEPI CL5 T4 ;
  85. CHA2 = CHAR 'TIMP' (TEM1 ET TEM2) EV1 ;
  86.  
  87.  
  88. ** Champ de temperature initiale
  89. TEM0 = MANU 'CHPO' MAILT 1 'T' T_INI ;
  90.  
  91.  
  92. ** Resolution avec PASAPAS
  93. TAB1 = TABL ;
  94. TAB1 . 'MODELE' = MOD_ME ET MOD_TH ;
  95. TAB1 . 'CARACTERISTIQUES' = MAT_ME ET MAT_TH ;
  96. TAB1 . 'BLOCAGES_MECANIQUES' = CL_ME ;
  97. TAB1 . 'BLOCAGES_THERMIQUES' = CL_TH ;
  98. TAB1 . 'TEMPERATURES' = TABL ;
  99. TAB1 . 'TEMPERATURES' . 0 = TEM0 ;
  100. TAB1 . 'CHARGEMENT' = CHA1 ET CHA2 ;
  101. TAB1 . 'TEMPS_CALCULES' = PROG XPAS 'PAS' XPAS TEMPS_F ;
  102. PASAPAS TAB1 ;
  103.  
  104.  
  105. ** Post-traitement
  106. LTPS = PROG ;
  107. LJEU = PROG ;
  108. LT2 = PROG ;
  109. LT3 = PROG ;
  110. NB1 = DIME (TAB1 . 'TEMPS') ;
  111. MESS ' Temps Jeu T2 T3' ;
  112. * listage du jeu et des temperatures a chaque pas de temps
  113. CONF0 = FORM ;
  114. REPE B1 NB1 ;
  115. TPS1 = TAB1 . 'TEMPS' . (&B1 - 1) ;
  116. LTPS = LTPS ET TPS1 ;
  117. TE1 = TAB1 . 'TEMPERATURES' . (&B1 - 1) ;
  118. U1 = TAB1 . 'DEPLACEMENTS' . (&B1 - 1) ;
  119. CONF1 = FORM U1 ;
  120. J1 = NORM (P3 MOIN P2) ;
  121. T2 = EXTR TE1 'T' P2 ;
  122. T3 = EXTR TE1 'T' P3 ;
  123. MESS TPS1 J1 T2 T3 ;
  124. LJEU = LJEU ET J1 ;
  125. LT2 = LT2 ET T2 ;
  126. LT3 = LT3 ET T3 ;
  127. SI ITRAC ;
  128. TRAC TE1 MAILT (PROG T4 PAS ((T1 - T4) / 20.) T1) 'TITR' (CHAI 'Temperature au temps' TPS1) ;
  129. FINSI ;
  130. FORM CONF0 ;
  131. FIN B1 ;
  132. * jeu P2 <--> P3 VS temps
  133. JEUVST = EVOL 'ROUG' 'MANU' 'Temps' LTPS 'Jeu' LJEU ;
  134. * temperatures en P2 et P3 VS temps
  135. T2VST = EVOL 'ROUG' 'MANU' 'Temps' LTPS 'Temperature' LT2 ;
  136. T3VST = EVOL 'BLEU' 'MANU' 'Temps' LTPS 'Temperature' LT3 ;
  137. TLEG = TABL ;
  138. TLEG . 'TITRE' = TABL ;
  139. TLEG . 'TITRE' . 1 = 'Point P2';
  140. TLEG . 'TITRE' . 2 = 'Point P3' ;
  141. SI ITRAC ;
  142. DESS JEUVST 'TITR' 'Jeu VS temps' ;
  143. DESS (T2VST ET T3VST) 'TITR' 'Temperature VS temps' 'LEGE' TLEG ;
  144. FINSI ;
  145.  
  146. FIN ;
  147.  
  148.  
  149.  
  150.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales